New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p2zopt.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/PISCES/P2Z – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/PISCES/P2Z/p2zopt.F90 @ 11949

Last change on this file since 11949 was 11949, checked in by acc, 4 years ago

Merge in changes from 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. This just creates a fresh copy of this branch to use as the merge base. See ticket #2341
  • Property svn:keywords set to Id
File size: 9.6 KB
Line 
1MODULE p2zopt
2   !!======================================================================
3   !!                         ***  MODULE p2zopt  ***
4   !! TOP :   LOBSTER Compute the light availability in the water column
5   !!======================================================================
6   !! History :    -   !  1995-05  (M. Levy) Original code
7   !!              -   !  1999-09  (J.-M. Andre, M. Levy)
8   !!              -   !  1999-11  (C. Menkes, M.-A. Foujols) itabe initial
9   !!              -   !  2000-02  (M.A. Foujols) change x**y par exp(y*log(x))
10   !!   NEMO      2.0  !  2007-12  (C. Deltel, G. Madec)  F90
11   !!             3.2  !  2009-04  (C. Ethe, G. Madec)  minor optimisation + style
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   p2z_opt        :   Compute the light availability in the water column
16   !!----------------------------------------------------------------------
17   USE oce_trc         !
18   USE trc
19   USE sms_pisces
20   USE prtctl_trc      ! Print control for debbuging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p2z_opt   !
26   PUBLIC   p2z_opt_init   !
27
28   REAL(wp), PUBLIC ::  xkr0      !: water coefficient absorption in red     
29   REAL(wp), PUBLIC ::  xkg0      !: water coefficient absorption in green   
30   REAL(wp), PUBLIC ::  xkrp      !: pigment coefficient absorption in red   
31   REAL(wp), PUBLIC ::  xkgp      !: pigment coefficient absorption in green 
32   REAL(wp), PUBLIC ::  xlr       !: exposant for pigment absorption in red 
33   REAL(wp), PUBLIC ::  xlg       !: exposant for pigment absorption in green
34   REAL(wp), PUBLIC ::  rpig      !: chla/chla+phea ratio   
35   !                 
36   REAL(wp), PUBLIC ::  rcchl     ! Carbone/Chlorophyl ratio [mgC.mgChla-1]
37   REAL(wp), PUBLIC ::  redf      ! redfield ratio (C:N) for phyto
38   REAL(wp), PUBLIC ::  reddom    ! redfield ratio (C:N) for DOM
39
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE p2z_opt( kt, Kmm )
48      !!---------------------------------------------------------------------
49      !!                     ***  ROUTINE p2z_opt  ***
50      !!
51      !! ** Purpose :   computes the light propagation in the water column
52      !!              and the euphotic layer depth
53      !!
54      !! ** Method  :   local par is computed in w layers using light propagation
55      !!              mean par in t layers are computed by integration
56      !!
57!!gm please remplace the '???' by true comments
58      !! ** Action  :   etot   ???
59      !!                neln   ???
60      !!---------------------------------------------------------------------
61      !!
62      INTEGER, INTENT( in ) ::   kt   ! index of the time stepping
63      INTEGER, INTENT( in ) ::   Kmm  ! time level index
64      !!
65      INTEGER  ::   ji, jj, jk          ! dummy loop indices
66      CHARACTER (len=25) ::   charout   ! temporary character
67      REAL(wp) ::   zpig                ! log of the total pigment
68      REAL(wp) ::   zkr, zkg            ! total absorption coefficient in red and green
69      REAL(wp) ::   zcoef               ! temporary scalar
70      REAL(wp), DIMENSION(jpi,jpj    ) :: zpar100, zpar0m
71      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zparr, zparg
72      !!---------------------------------------------------------------------
73      !
74      IF( ln_timing )   CALL timing_start('p2z_opt')
75      !
76
77      IF( kt == nittrc000 ) THEN
78         IF(lwp) WRITE(numout,*)
79         IF(lwp) WRITE(numout,*) ' p2z_opt : LOBSTER optic-model'
80         IF(lwp) WRITE(numout,*) ' ~~~~~~~ '
81      ENDIF
82
83      !                                          ! surface irradiance
84      !                                          ! ------------------
85      IF( ln_dm2dc ) THEN   ;   zpar0m(:,:) = qsr_mean(:,:) * 0.43
86      ELSE                  ;   zpar0m(:,:) = qsr     (:,:) * 0.43
87      ENDIF
88      zpar100(:,:)   = zpar0m(:,:) * 0.01
89      zparr  (:,:,1) = zpar0m(:,:) * 0.5
90      zparg  (:,:,1) = zpar0m(:,:) * 0.5
91
92      !                                          ! Photosynthetically Available Radiation (PAR)
93      zcoef = 12 * redf / rcchl / rpig           ! --------------------------------------
94      DO jk = 2, jpk                                  ! local par at w-levels
95         DO jj = 1, jpj
96            DO ji = 1, jpi
97               zpig = LOG(  MAX( TINY(0.), tr(ji,jj,jk-1,jpphy,Kmm) ) * zcoef  )
98               zkr  = xkr0 + xkrp * EXP( xlr * zpig )
99               zkg  = xkg0 + xkgp * EXP( xlg * zpig )
100               zparr(ji,jj,jk) = zparr(ji,jj,jk-1) * EXP( -zkr * e3t(ji,jj,jk-1,Kmm) )
101               zparg(ji,jj,jk) = zparg(ji,jj,jk-1) * EXP( -zkg * e3t(ji,jj,jk-1,Kmm) )
102            END DO
103        END DO
104      END DO
105      DO jk = 1, jpkm1                                ! mean par at t-levels
106         DO jj = 1, jpj
107            DO ji = 1, jpi
108               zpig = LOG(  MAX( TINY(0.), tr(ji,jj,jk,jpphy,Kmm) ) * zcoef  )
109               zkr  = xkr0 + xkrp * EXP( xlr * zpig )
110               zkg  = xkg0 + xkgp * EXP( xlg * zpig )
111               zparr(ji,jj,jk) = zparr(ji,jj,jk) / ( zkr * e3t(ji,jj,jk,Kmm) ) * ( 1 - EXP( -zkr * e3t(ji,jj,jk,Kmm) ) )
112               zparg(ji,jj,jk) = zparg(ji,jj,jk) / ( zkg * e3t(ji,jj,jk,Kmm) ) * ( 1 - EXP( -zkg * e3t(ji,jj,jk,Kmm) ) )
113               etot (ji,jj,jk) = MAX( zparr(ji,jj,jk) + zparg(ji,jj,jk), 1.e-15 )
114            END DO
115         END DO
116      END DO
117
118      !                                          ! Euphotic layer
119      !                                          ! --------------
120      neln(:,:) = 1                                   ! euphotic layer level
121      DO jk = 1, jpkm1                                ! (i.e. 1rst T-level strictly below EL bottom)
122         DO jj = 1, jpj
123           DO ji = 1, jpi
124              IF( etot(ji,jj,jk) >= zpar100(ji,jj) )   neln(ji,jj) = jk + 1 
125           END DO
126         END DO
127      END DO
128      !                                               ! Euphotic layer depth
129      DO jj = 1, jpj
130         DO ji = 1, jpi
131            heup(ji,jj) = gdepw(ji,jj,neln(ji,jj),Kmm)
132         END DO
133      END DO
134
135
136      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
137         WRITE(charout, FMT="('opt')")
138         CALL prt_ctl_trc_info( charout )
139         CALL prt_ctl_trc( tab4d=tr(:,:,:,:,Kmm), mask=tmask, clinfo=ctrcnm )
140      ENDIF
141      !
142      IF( ln_timing )   CALL timing_stop('p2z_opt')
143      !
144   END SUBROUTINE p2z_opt
145
146
147   SUBROUTINE p2z_opt_init
148      !!----------------------------------------------------------------------
149      !!                  ***  ROUTINE p2z_opt_init  ***
150      !!
151      !! ** Purpose :  optical parameters
152      !!
153      !! ** Method  :   Read the namlobopt namelist and check the parameters
154      !!
155      !!----------------------------------------------------------------------
156      INTEGER ::   ios   ! Local integer
157      !!
158      NAMELIST/namlobopt/ xkg0, xkr0, xkgp, xkrp, xlg, xlr, rpig
159      NAMELIST/namlobrat/ rcchl, redf, reddom
160      !!----------------------------------------------------------------------
161
162      REWIND( numnatp_ref )              ! Namelist namlobopt in reference namelist : Lobster options
163      READ  ( numnatp_ref, namlobopt, IOSTAT = ios, ERR = 901)
164901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namlobopt in reference namelist' )
165
166      REWIND( numnatp_cfg )              ! Namelist namlobopt in configuration namelist : Lobster options
167      READ  ( numnatp_cfg, namlobopt, IOSTAT = ios, ERR = 902 )
168902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namlobopt in configuration namelist' )
169      IF(lwm) WRITE ( numonp, namlobopt )
170
171      IF(lwp) THEN
172         WRITE(numout,*)
173         WRITE(numout,*) ' Namelist namlobopt'
174         WRITE(numout,*) '    green   water absorption coeff                       xkg0  = ', xkg0
175         WRITE(numout,*) '    red water absorption coeff                           xkr0  = ', xkr0
176         WRITE(numout,*) '    pigment red absorption coeff                         xkrp  = ', xkrp
177         WRITE(numout,*) '    pigment green absorption coeff                       xkgp  = ', xkgp
178         WRITE(numout,*) '    green chl exposant                                   xlg   = ', xlg
179         WRITE(numout,*) '    red   chl exposant                                   xlr   = ', xlr
180         WRITE(numout,*) '    chla/chla+phea ratio                                 rpig  = ', rpig
181         WRITE(numout,*) ' '
182      ENDIF
183      !
184      REWIND( numnatp_ref )              ! Namelist namlobrat in reference namelist : Lobster ratios
185      READ  ( numnatp_ref, namlobrat, IOSTAT = ios, ERR = 903)
186903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namlobrat in reference namelist' )
187
188      REWIND( numnatp_cfg )              ! Namelist namlobrat in configuration namelist : Lobster ratios
189      READ  ( numnatp_cfg, namlobrat, IOSTAT = ios, ERR = 904 )
190904   IF( ios >  0 ) CALL ctl_nam ( ios , 'namlobrat in configuration namelist' )
191      IF(lwm) WRITE ( numonp, namlobrat )
192
193      IF(lwp) THEN
194          WRITE(numout,*) ' Namelist namlobrat'
195         WRITE(numout,*) '     carbone/chlorophyl ratio                             rcchl = ', rcchl
196          WRITE(numout,*) '    redfield ratio  c:n for phyto                        redf      =', redf
197          WRITE(numout,*) '    redfield ratio  c:n for DOM                          reddom    =', reddom
198          WRITE(numout,*) ' '
199      ENDIF
200      !
201   END SUBROUTINE p2z_opt_init
202
203   !!======================================================================
204END MODULE p2zopt
Note: See TracBrowser for help on using the repository browser.