source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/PISCES/P4Z/p4zmeso.F90 @ 12236

Last change on this file since 12236 was 12236, checked in by acc, 11 months ago

Branch 2019/dev_r11943_MERGE_2019. Merge in changes from 2019/fix_sn_cfctl_ticket2328. Fully SETTE tested

  • Property svn:keywords set to Id
File size: 18.7 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_meso       : Compute the sources/sinks for mesozooplankton
11   !!   p4z_meso_init  : Initialization of the parameters for mesozooplankton
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zprod         ! production
17   USE prtctl_trc      ! print control for debugging
18   USE iom             ! I/O manager
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p4z_meso              ! called in p4zbio.F90
24   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
25
26   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
27   REAL(wp), PUBLIC ::  xpref2d      !: mesozoo preference for diatoms
28   REAL(wp), PUBLIC ::  xpref2n      !: mesozoo preference for nanophyto
29   REAL(wp), PUBLIC ::  xpref2z      !: mesozoo preference for microzooplankton
30   REAL(wp), PUBLIC ::  xpref2c      !: mesozoo preference for POC
31   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
32   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
33   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
34   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
35   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
36   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
37   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
38   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
39   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
40   REAL(wp), PUBLIC ::  unass2       !: Efficicency of mesozoo growth
41   REAL(wp), PUBLIC ::  sigma2       !: Fraction of mesozoo excretion as DOM
42   REAL(wp), PUBLIC ::  epsher2      !: growth efficiency
43   REAL(wp), PUBLIC ::  epsher2min   !: minimum growth efficiency at high food for grazing 2
44   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
45
46   !!----------------------------------------------------------------------
47   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
48   !! $Id$
49   !! Software governed by the CeCILL license (see ./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE p4z_meso( kt, knt, Kbb, Krhs )
54      !!---------------------------------------------------------------------
55      !!                     ***  ROUTINE p4z_meso  ***
56      !!
57      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
58      !!
59      !! ** Method  : - ???
60      !!---------------------------------------------------------------------
61      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step and ???
62      INTEGER, INTENT(in)  ::  Kbb, Krhs ! time level indices
63      !
64      INTEGER  :: ji, jj, jk
65      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
66      REAL(wp) :: zgraze2 , zdenom, zdenom2
67      REAL(wp) :: zfact   , zfood, zfoodlim, zproport, zbeta
68      REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2, zfracal, zgrazcal
69      REAL(wp) :: zepsherf, zepshert, zepsherv, zgrarsig, zgraztotc, zgraztotn, zgraztotf
70      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz, zgrasrat, zgrasratn
71      REAL(wp) :: zrespz, ztortz, zgrazd, zgrazz, zgrazpof
72      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
73      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
74      CHARACTER (len=25) :: charout
75      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo2
76      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zw3d, zz2ligprod
77      !!---------------------------------------------------------------------
78      !
79      IF( ln_timing )   CALL timing_start('p4z_meso')
80      !
81      zgrazing(:,:,:) = 0._wp
82      zfezoo2 (:,:,:) = 0._wp
83      !
84      IF (ln_ligand) THEN
85         ALLOCATE( zz2ligprod(jpi,jpj,jpk) )
86         zz2ligprod(:,:,:) = 0._wp
87      ENDIF
88      !
89      DO jk = 1, jpkm1
90         DO jj = 1, jpj
91            DO ji = 1, jpi
92               zcompam   = MAX( ( tr(ji,jj,jk,jpmes,Kbb) - 1.e-9 ), 0.e0 )
93               zfact     = xstep * tgfunc2(ji,jj,jk) * zcompam
94
95               !  Respiration rates of both zooplankton
96               !  -------------------------------------
97               zrespz    = resrat2 * zfact * ( tr(ji,jj,jk,jpmes,Kbb) / ( xkmort + tr(ji,jj,jk,jpmes,Kbb) )  &
98               &           + 3. * nitrfac(ji,jj,jk) )
99
100               !  Zooplankton mortality. A square function has been selected with
101               !  no real reason except that it seems to be more stable and may mimic predation
102               !  ---------------------------------------------------------------
103               ztortz    = mzrat2 * 1.e6 * zfact * tr(ji,jj,jk,jpmes,Kbb)  * (1. - nitrfac(ji,jj,jk) )
104               !
105               zcompadi  = MAX( ( tr(ji,jj,jk,jpdia,Kbb) - xthresh2dia ), 0.e0 )
106               zcompaz   = MAX( ( tr(ji,jj,jk,jpzoo,Kbb) - xthresh2zoo ), 0.e0 )
107               zcompapoc = MAX( ( tr(ji,jj,jk,jppoc,Kbb) - xthresh2poc ), 0.e0 )
108               ! Size effect of nanophytoplankton on grazing : the smaller it is, the less prone
109               ! it is to predation by mesozooplankton
110               ! -------------------------------------------------------------------------------
111               zcompaph  = MAX( ( tr(ji,jj,jk,jpphy,Kbb) - xthresh2phy ), 0.e0 ) &
112                  &      * MIN(1., MAX( 0., ( quotan(ji,jj,jk) - 0.2) / 0.3 ) )
113
114               !   Mesozooplankton grazing
115               !   ------------------------
116               zfood     = xpref2d * zcompadi + xpref2z * zcompaz + xpref2n * zcompaph + xpref2c * zcompapoc 
117               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
118               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
119               zdenom2   = zdenom / ( zfood + rtrn )
120               zgraze2   = grazrat2 * xstep * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jpmes,Kbb) * (1. - nitrfac(ji,jj,jk)) 
121
122               zgrazd    = zgraze2  * xpref2d  * zcompadi  * zdenom2 
123               zgrazz    = zgraze2  * xpref2z  * zcompaz   * zdenom2 
124               zgrazn    = zgraze2  * xpref2n  * zcompaph  * zdenom2 
125               zgrazpoc  = zgraze2  * xpref2c  * zcompapoc * zdenom2 
126
127               zgraznf   = zgrazn   * tr(ji,jj,jk,jpnfe,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn)
128               zgrazf    = zgrazd   * tr(ji,jj,jk,jpdfe,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn)
129               zgrazpof  = zgrazpoc * tr(ji,jj,jk,jpsfe,Kbb) / ( tr(ji,jj,jk,jppoc,Kbb) + rtrn)
130
131               !  Mesozooplankton flux feeding on GOC
132               !  ----------------------------------
133               zgrazffeg = grazflux  * xstep * wsbio4(ji,jj,jk)      &
134               &           * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jpgoc,Kbb) * tr(ji,jj,jk,jpmes,Kbb) &
135               &           * (1. - nitrfac(ji,jj,jk))
136               zgrazfffg = zgrazffeg * tr(ji,jj,jk,jpbfe,Kbb) / (tr(ji,jj,jk,jpgoc,Kbb) + rtrn)
137               zgrazffep = grazflux  * xstep *  wsbio3(ji,jj,jk)     &
138               &           * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jppoc,Kbb) * tr(ji,jj,jk,jpmes,Kbb) &
139               &           * (1. - nitrfac(ji,jj,jk))
140               zgrazfffp = zgrazffep * tr(ji,jj,jk,jpsfe,Kbb) / (tr(ji,jj,jk,jppoc,Kbb) + rtrn)
141               !
142               zgraztotc = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
143               ! Compute the proportion of filter feeders
144               zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztotc)
145               ! Compute fractionation of aggregates. It is assumed that
146               ! diatoms based aggregates are more prone to fractionation
147               ! since they are more porous (marine snow instead of fecal pellets)
148               zratio    = tr(ji,jj,jk,jpgsi,Kbb) / ( tr(ji,jj,jk,jpgoc,Kbb) + rtrn )
149               zratio2   = zratio * zratio
150               zfrac     = zproport * grazflux  * xstep * wsbio4(ji,jj,jk)      &
151               &          * tr(ji,jj,jk,jpgoc,Kbb) * tr(ji,jj,jk,jpmes,Kbb)          &
152               &          * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
153               zfracfe   = zfrac * tr(ji,jj,jk,jpbfe,Kbb) / (tr(ji,jj,jk,jpgoc,Kbb) + rtrn)
154
155               zgrazffep = zproport * zgrazffep
156               zgrazffeg = zproport * zgrazffeg
157               zgrazfffp = zproport * zgrazfffp
158               zgrazfffg = zproport * zgrazfffg
159               zgraztotc = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
160               zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk)   &
161               &   + zgrazpoc + zgrazffep + zgrazffeg
162               zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg
163
164               ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
165               zgrazing(ji,jj,jk) = zgraztotc
166
167               !    Mesozooplankton efficiency
168               !    --------------------------
169               zgrasrat  =  ( zgraztotf + rtrn )/ ( zgraztotc + rtrn )
170               zgrasratn =  ( zgraztotn + rtrn )/ ( zgraztotc + rtrn )
171               zepshert  = MIN( 1., zgrasratn, zgrasrat / ferat3)
172               zbeta     = MAX(0., (epsher2 - epsher2min) )
173               zepsherf  = epsher2min + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta ) 
174               zepsherv  = zepsherf * zepshert 
175
176               zgrarem2  = zgraztotc * ( 1. - zepsherv - unass2 ) &
177               &         + ( 1. - epsher2 - unass2 ) / ( 1. - epsher2 ) * ztortz
178               zgrafer2  = zgraztotc * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
179               &         + ferat3 * ( ( 1. - epsher2 - unass2 ) /( 1. - epsher2 ) * ztortz )
180               zgrapoc2  = zgraztotc * unass2
181
182               !   Update the arrays TRA which contain the biological sources and sinks
183               zgrarsig  = zgrarem2 * sigma2
184               tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zgrarsig
185               tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zgrarsig
186               tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zgrarem2 - zgrarsig
187               !
188               IF( ln_ligand ) THEN
189                  tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + (zgrarem2 - zgrarsig) * ldocz
190                  zz2ligprod(ji,jj,jk) = (zgrarem2 - zgrarsig) * ldocz
191               ENDIF
192               !
193               tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - o2ut * zgrarsig
194               tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + zgrafer2
195               zfezoo2(ji,jj,jk)   = zgrafer2
196               tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zgrarsig
197               tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * zgrarsig             
198
199               zmortz = ztortz + zrespz
200               zmortzgoc = unass2 / ( 1. - epsher2 ) * ztortz + zrespz
201               tr(ji,jj,jk,jpmes,Krhs) = tr(ji,jj,jk,jpmes,Krhs) - zmortz + zepsherv * zgraztotc 
202               tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs) - zgrazd
203               tr(ji,jj,jk,jpzoo,Krhs) = tr(ji,jj,jk,jpzoo,Krhs) - zgrazz
204               tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs) - zgrazn
205               tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) - zgrazn * tr(ji,jj,jk,jpnch,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn )
206               tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) - zgrazd * tr(ji,jj,jk,jpdch,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
207               tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) - zgrazd * tr(ji,jj,jk,jpdsi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
208               tr(ji,jj,jk,jpgsi,Krhs) = tr(ji,jj,jk,jpgsi,Krhs) + zgrazd * tr(ji,jj,jk,jpdsi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
209               tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) - zgraznf
210               tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) - zgrazf
211
212               tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) - zgrazpoc - zgrazffep + zfrac
213               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zfrac
214               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc - zgrazffep
215               tr(ji,jj,jk,jpgoc,Krhs) = tr(ji,jj,jk,jpgoc,Krhs) + zmortzgoc - zgrazffeg + zgrapoc2 - zfrac
216               prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zmortzgoc + zgrapoc2
217               consgoc(ji,jj,jk) = consgoc(ji,jj,jk) - zgrazffeg - zfrac
218               tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) - zgrazpof - zgrazfffp + zfracfe
219               tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + ferat3 * zmortzgoc - zgrazfffg     &
220                 &                + zgraztotf * unass2 - zfracfe
221               zfracal = tr(ji,jj,jk,jpcal,Kbb) / (tr(ji,jj,jk,jppoc,Kbb) + tr(ji,jj,jk,jpgoc,Kbb) + rtrn )
222               zgrazcal = (zgrazffeg + zgrazpoc) * (1. - part2) * zfracal
223               ! calcite production
224               zprcaca = xfracal(ji,jj,jk) * zgrazn
225               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
226               !
227               zprcaca = part2 * zprcaca
228               tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zgrazcal - zprcaca
229               tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) - 2. * ( zgrazcal + zprcaca )
230               tr(ji,jj,jk,jpcal,Krhs) = tr(ji,jj,jk,jpcal,Krhs) - zgrazcal + zprcaca
231            END DO
232         END DO
233      END DO
234      !
235      IF( lk_iomput .AND. knt == nrdttrc ) THEN
236         ALLOCATE( zw3d(jpi,jpj,jpk) )
237         IF( iom_use( "GRAZ2" ) ) THEN
238            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !   Total grazing of phyto by zooplankton
239            CALL iom_put( "GRAZ2", zw3d )
240         ENDIF
241         IF( iom_use( "PCAL" ) ) THEN
242            zw3d(:,:,:) = prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)   !  Calcite production
243            CALL iom_put( "PCAL", zw3d ) 
244         ENDIF
245         IF( iom_use( "FEZOO2" ) ) THEN
246            zw3d(:,:,:) = zfezoo2(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)   !
247            CALL iom_put( "FEZOO2", zw3d )
248         ENDIF
249         IF( iom_use( "LPRODZ2" ) .AND. ln_ligand )  THEN
250            zw3d(:,:,:) = zz2ligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
251            CALL iom_put( "LPRODZ2"  , zw3d )
252         ENDIF
253         DEALLOCATE( zw3d )
254      ENDIF
255      !
256      IF (ln_ligand)  DEALLOCATE( zz2ligprod )
257      !
258      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
259        WRITE(charout, FMT="('meso')")
260        CALL prt_ctl_trc_info(charout)
261        CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
262      ENDIF
263      !
264      IF( ln_timing )   CALL timing_stop('p4z_meso')
265      !
266   END SUBROUTINE p4z_meso
267
268
269   SUBROUTINE p4z_meso_init
270      !!----------------------------------------------------------------------
271      !!                  ***  ROUTINE p4z_meso_init  ***
272      !!
273      !! ** Purpose :   Initialization of mesozooplankton parameters
274      !!
275      !! ** Method  :   Read the nampismes namelist and check the parameters
276      !!      called at the first timestep (nittrc000)
277      !!
278      !! ** input   :   Namelist nampismes
279      !!----------------------------------------------------------------------
280      INTEGER ::   ios   ! Local integer
281      !
282      NAMELIST/namp4zmes/ part2, grazrat2, resrat2, mzrat2, xpref2n, xpref2d, xpref2z,   &
283         &                xpref2c, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
284         &                xthresh2, xkgraz2, epsher2, epsher2min, sigma2, unass2, grazflux
285      !!----------------------------------------------------------------------
286      !
287      IF(lwp) THEN
288         WRITE(numout,*) 
289         WRITE(numout,*) 'p4z_meso_init : Initialization of mesozooplankton parameters'
290         WRITE(numout,*) '~~~~~~~~~~~~~'
291      ENDIF
292      !
293      READ  ( numnatp_ref, namp4zmes, IOSTAT = ios, ERR = 901)
294901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zmes in reference namelist' )
295      READ  ( numnatp_cfg, namp4zmes, IOSTAT = ios, ERR = 902 )
296902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zmes in configuration namelist' )
297      IF(lwm) WRITE( numonp, namp4zmes )
298      !
299      IF(lwp) THEN                         ! control print
300         WRITE(numout,*) '   Namelist : namp4zmes'
301         WRITE(numout,*) '      part of calcite not dissolved in mesozoo guts  part2        =', part2
302         WRITE(numout,*) '      mesozoo preference for phyto                   xpref2n      =', xpref2n
303         WRITE(numout,*) '      mesozoo preference for diatoms                 xpref2d      =', xpref2d
304         WRITE(numout,*) '      mesozoo preference for zoo                     xpref2z      =', xpref2z
305         WRITE(numout,*) '      mesozoo preference for poc                     xpref2c      =', xpref2c
306         WRITE(numout,*) '      microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
307         WRITE(numout,*) '      diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
308         WRITE(numout,*) '      nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
309         WRITE(numout,*) '      poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
310         WRITE(numout,*) '      feeding threshold for mesozooplankton          xthresh2     =', xthresh2
311         WRITE(numout,*) '      exsudation rate of mesozooplankton             resrat2      =', resrat2
312         WRITE(numout,*) '      mesozooplankton mortality rate                 mzrat2       =', mzrat2
313         WRITE(numout,*) '      maximal mesozoo grazing rate                   grazrat2     =', grazrat2
314         WRITE(numout,*) '      mesozoo flux feeding rate                      grazflux     =', grazflux
315         WRITE(numout,*) '      non assimilated fraction of P by mesozoo       unass2       =', unass2
316         WRITE(numout,*) '      Efficiency of Mesozoo growth                   epsher2      =', epsher2
317         WRITE(numout,*) '      Minimum Efficiency of Mesozoo growth           epsher2min  =', epsher2min
318         WRITE(numout,*) '      Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
319         WRITE(numout,*) '      half sturation constant for grazing 2          xkgraz2      =', xkgraz2
320      ENDIF
321      !
322   END SUBROUTINE p4z_meso_init
323
324   !!======================================================================
325END MODULE p4zmeso
Note: See TracBrowser for help on using the repository browser.