New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/PISCES/P4Z/p4zrem.F90 @ 11960

Last change on this file since 11960 was 11960, checked in by acc, 4 years ago

Branch 2019/dev_r11943_MERGE_2019. Merge in changes from 2019/dev_r11613_ENHANCE-04_namelists_as_internalfiles. (svn merge -r 11614:11954). Resolved tree conflicts and one actual conflict. Sette tested(these changes alter the ext/AGRIF reference; remember to update). See ticket #2341
  • Property svn:keywords set to Id
File size: 19.3 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
11   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
12   !!   p4z_rem_alloc :  Allocate remineralisation variables
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zche          !  chemical model
18   USE p4zprod         !  Growth rate of the 2 phyto groups
19   USE p4zlim
20   USE prtctl_trc      !  print control for debugging
21   USE iom             !  I/O manager
22
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   p4z_rem         ! called in p4zbio.F90
28   PUBLIC   p4z_rem_init    ! called in trcsms_pisces.F90
29   PUBLIC   p4z_rem_alloc
30
31   REAL(wp), PUBLIC ::   xremikc    !: remineralisation rate of DOC
32   REAL(wp), PUBLIC ::   xremikn    !: remineralisation rate of DON
33   REAL(wp), PUBLIC ::   xremikp    !: remineralisation rate of DOP
34   REAL(wp), PUBLIC ::   xremik     !: remineralisation rate of POC
35   REAL(wp), PUBLIC ::   nitrif     !: NH4 nitrification rate
36   REAL(wp), PUBLIC ::   xsirem     !: remineralisation rate of POC
37   REAL(wp), PUBLIC ::   xsiremlab  !: fast remineralisation rate of POC
38   REAL(wp), PUBLIC ::   xsilab     !: fraction of labile biogenic silica
39   REAL(wp), PUBLIC ::   feratb     !: Fe/C quota in bacteria
40   REAL(wp), PUBLIC ::   xkferb     !: Half-saturation constant for bacteria Fe/C
41
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr   !: denitrification array
43
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE p4z_rem( kt, knt, Kbb, Kmm, Krhs )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_rem  ***
54      !!
55      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
56      !!
57      !! ** Method  : - ???
58      !!---------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   kt, knt         ! ocean time step
60      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs  ! time level indices
61      !
62      INTEGER  ::   ji, jj, jk
63      REAL(wp) ::   zremik, zremikc, zremikn, zremikp, zsiremin, zfact 
64      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
65      REAL(wp) ::   zbactfer, zolimit, zonitr, zrfact2
66      REAL(wp) ::   zammonic, zoxyremc, zoxyremn, zoxyremp
67      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
68      CHARACTER (len=25) :: charout
69      REAL(wp), DIMENSION(jpi,jpj    ) :: ztempbac
70      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdepbac, zolimi, zdepprod, zfacsi, zfacsib, zdepeff, zfebact
71      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
72      !!---------------------------------------------------------------------
73      !
74      IF( ln_timing )   CALL timing_start('p4z_rem')
75      !
76      ! Initialisation of arrys
77      zdepprod(:,:,:) = 1._wp
78      zdepeff (:,:,:) = 0.3_wp
79      ztempbac(:,:)   = 0._wp
80      zfacsib(:,:,:)  = xsilab / ( 1.0 - xsilab )
81      zfebact(:,:,:)  = 0._wp
82      zfacsi(:,:,:)   = xsilab
83
84      ! Computation of the mean phytoplankton concentration as
85      ! a crude estimate of the bacterial biomass
86      ! this parameterization has been deduced from a model version
87      ! that was modeling explicitely bacteria
88      ! -------------------------------------------------------
89      DO jk = 1, jpkm1
90         DO jj = 1, jpj
91            DO ji = 1, jpi
92               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
93               IF( gdept(ji,jj,jk,Kmm) < zdep ) THEN
94                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( tr(ji,jj,jk,jpzoo,Kbb) + 2.* tr(ji,jj,jk,jpmes,Kbb) ), 4.e-6 )
95                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
96               ELSE
97                  zdepmin = MIN( 1., zdep / gdept(ji,jj,jk,Kmm) )
98                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
99                  zdepprod(ji,jj,jk) = zdepmin**0.273
100                  zdepeff (ji,jj,jk) = zdepeff(ji,jj,jk) * zdepmin**0.3
101               ENDIF
102            END DO
103         END DO
104      END DO
105
106      IF( ln_p4z ) THEN
107         DO jk = 1, jpkm1
108            DO jj = 1, jpj
109               DO ji = 1, jpi
110                  ! DOC ammonification. Depends on depth, phytoplankton biomass
111                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
112                  zremik = xremik * xstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
113                  zremik = MAX( zremik, 2.74e-4 * xstep )
114                  ! Ammonification in oxic waters with oxygen consumption
115                  ! -----------------------------------------------------
116                  zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * tr(ji,jj,jk,jpdoc,Kbb) 
117                  zolimi(ji,jj,jk) = MIN( ( tr(ji,jj,jk,jpoxy,Kbb) - rtrn ) / o2ut, zolimit ) 
118                  ! Ammonification in suboxic waters with denitrification
119                  ! -------------------------------------------------------
120                  zammonic = zremik * nitrfac(ji,jj,jk) * tr(ji,jj,jk,jpdoc,Kbb)
121                  denitr(ji,jj,jk)  = zammonic * ( 1. - nitrfac2(ji,jj,jk) )
122                  denitr(ji,jj,jk)  = MIN( ( tr(ji,jj,jk,jpno3,Kbb) - rtrn ) / rdenit, denitr(ji,jj,jk) )
123                  zoxyremc          = zammonic - denitr(ji,jj,jk)
124                  !
125                  zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
126                  denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
127                  zoxyremc          = MAX( 0.e0, zoxyremc )
128
129                  !
130                  tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc
131                  tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc
132                  tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) - denitr (ji,jj,jk) * rdenit
133                  tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) - zolimi (ji,jj,jk) - denitr(ji,jj,jk) - zoxyremc
134                  tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - zolimi (ji,jj,jk) * o2ut
135                  tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc
136                  tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * ( zolimi(ji,jj,jk) + zoxyremc    &
137                  &                     + ( rdenit + 1.) * denitr(ji,jj,jk) )
138               END DO
139            END DO
140         END DO
141      ELSE
142         DO jk = 1, jpkm1
143            DO jj = 1, jpj
144               DO ji = 1, jpi
145                  ! DOC ammonification. Depends on depth, phytoplankton biomass
146                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
147                  ! -----------------------------------------------------------------
148                  zremik = xstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) 
149                  zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
150
151                  zremikc = xremikc * zremik
152                  zremikn = xremikn / xremikc
153                  zremikp = xremikp / xremikc
154
155                  ! Ammonification in oxic waters with oxygen consumption
156                  ! -----------------------------------------------------
157                  zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * tr(ji,jj,jk,jpdoc,Kbb) 
158                  zolimic = MAX( 0.e0, MIN( ( tr(ji,jj,jk,jpoxy,Kbb) - rtrn ) / o2ut, zolimit ) ) 
159                  zolimi(ji,jj,jk) = zolimic
160                  zolimin = zremikn * zolimic * tr(ji,jj,jk,jpdon,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn )
161                  zolimip = zremikp * zolimic * tr(ji,jj,jk,jpdop,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn ) 
162
163                  ! Ammonification in suboxic waters with denitrification
164                  ! -------------------------------------------------------
165                  zammonic = zremikc * nitrfac(ji,jj,jk) * tr(ji,jj,jk,jpdoc,Kbb)
166                  denitr(ji,jj,jk)  = zammonic * ( 1. - nitrfac2(ji,jj,jk) )
167                  denitr(ji,jj,jk)  = MAX(0., MIN(  ( tr(ji,jj,jk,jpno3,Kbb) - rtrn ) / rdenit, denitr(ji,jj,jk) ) )
168                  zoxyremc          = MAX(0., zammonic - denitr(ji,jj,jk))
169                  zdenitrn  = zremikn * denitr(ji,jj,jk) * tr(ji,jj,jk,jpdon,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn )
170                  zdenitrp  = zremikp * denitr(ji,jj,jk) * tr(ji,jj,jk,jpdop,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn )
171                  zoxyremn  = zremikn * zoxyremc * tr(ji,jj,jk,jpdon,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn )
172                  zoxyremp  = zremikp * zoxyremc * tr(ji,jj,jk,jpdop,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn )
173
174                  tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zolimip + zdenitrp + zoxyremp
175                  tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zolimin + zdenitrn + zoxyremn
176                  tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) - denitr(ji,jj,jk) * rdenit
177                  tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) - zolimic - denitr(ji,jj,jk) - zoxyremc
178                  tr(ji,jj,jk,jpdon,Krhs) = tr(ji,jj,jk,jpdon,Krhs) - zolimin - zdenitrn - zoxyremn
179                  tr(ji,jj,jk,jpdop,Krhs) = tr(ji,jj,jk,jpdop,Krhs) - zolimip - zdenitrp - zoxyremp
180                  tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - zolimic * o2ut
181                  tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zolimic + denitr(ji,jj,jk) + zoxyremc
182                  tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * ( zolimin + zoxyremn + ( rdenit + 1.) * zdenitrn )
183               END DO
184            END DO
185         END DO
186         !
187      ENDIF
188
189
190      DO jk = 1, jpkm1
191         DO jj = 1, jpj
192            DO ji = 1, jpi
193               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
194               ! below 2 umol/L. Inhibited at strong light
195               ! ----------------------------------------------------------
196               zonitr  = nitrif * xstep * tr(ji,jj,jk,jpnh4,Kbb) * ( 1.- nitrfac(ji,jj,jk) )  &
197               &         / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) 
198               zdenitnh4 = nitrif * xstep * tr(ji,jj,jk,jpnh4,Kbb) * nitrfac(ji,jj,jk)
199               zdenitnh4 = MIN(  ( tr(ji,jj,jk,jpno3,Kbb) - rtrn ) / rdenita, zdenitnh4 ) 
200               ! Update of the tracers trends
201               ! ----------------------------
202               tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) - zonitr - zdenitnh4
203               tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) + zonitr - rdenita * zdenitnh4
204               tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - o2nit * zonitr
205               tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
206            END DO
207         END DO
208      END DO
209
210       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
211         WRITE(charout, FMT="('rem1')")
212         CALL prt_ctl_trc_info(charout)
213         CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
214       ENDIF
215
216      DO jk = 1, jpkm1
217         DO jj = 1, jpj
218            DO ji = 1, jpi
219
220               ! Bacterial uptake of iron. No iron is available in DOC. So
221               ! Bacteries are obliged to take up iron from the water. Some
222               ! studies (especially at Papa) have shown this uptake to be significant
223               ! ----------------------------------------------------------
224               zbactfer = feratb *  rfact2 * 0.6_wp / rday * tgfunc(ji,jj,jk) * xlimbacl(ji,jj,jk)     &
225                  &              * tr(ji,jj,jk,jpfer,Kbb) / ( xkferb + tr(ji,jj,jk,jpfer,Kbb) )    &
226                  &              * zdepprod(ji,jj,jk) * zdepeff(ji,jj,jk) * zdepbac(ji,jj,jk)
227               tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zbactfer*0.33
228               tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + zbactfer*0.25
229               tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + zbactfer*0.08
230               zfebact(ji,jj,jk)   = zbactfer * 0.33
231               blim(ji,jj,jk)      = xlimbacl(ji,jj,jk)  * zdepbac(ji,jj,jk) / 1.e-6 * zdepprod(ji,jj,jk)
232            END DO
233         END DO
234      END DO
235
236       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
237         WRITE(charout, FMT="('rem2')")
238         CALL prt_ctl_trc_info(charout)
239         CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
240       ENDIF
241
242      ! Initialization of the array which contains the labile fraction
243      ! of bSi. Set to a constant in the upper ocean
244      ! ---------------------------------------------------------------
245
246      DO jk = 1, jpkm1
247         DO jj = 1, jpj
248            DO ji = 1, jpi
249               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
250               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - tr(ji,jj,jk,jpsil,Kbb) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
251               zsatur2  = ( 1. + ts(ji,jj,jk,jp_tem,Kmm) / 400.)**37
252               znusil   = 0.225  * ( 1. + ts(ji,jj,jk,jp_tem,Kmm) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
253               ! Remineralization rate of BSi depedant on T and saturation
254               ! ---------------------------------------------------------
255               IF ( gdept(ji,jj,jk,Kmm) > zdep ) THEN
256                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
257                  &                   * znusil * e3t(ji,jj,jk,Kmm) / wsbio4(ji,jj,jk) )
258                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
259                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
260                  &                   * znusil * e3t(ji,jj,jk,Kmm) / wsbio4(ji,jj,jk) )
261               ENDIF
262               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * xstep * znusil
263               zosil    = zsiremin * tr(ji,jj,jk,jpgsi,Kbb)
264               !
265               tr(ji,jj,jk,jpgsi,Krhs) = tr(ji,jj,jk,jpgsi,Krhs) - zosil
266               tr(ji,jj,jk,jpsil,Krhs) = tr(ji,jj,jk,jpsil,Krhs) + zosil
267            END DO
268         END DO
269      END DO
270
271      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
272         WRITE(charout, FMT="('rem3')")
273         CALL prt_ctl_trc_info(charout)
274         CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
275       ENDIF
276
277      IF( knt == nrdttrc ) THEN
278          zrfact2 = 1.e3 * rfact2r
279          ALLOCATE( zw3d(jpi,jpj,jpk) )
280          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
281          !
282          IF( iom_use( "REMIN" ) )  THEN
283              zw3d(:,:,:) = zolimi(:,:,:) * tmask(:,:,:) * zfact !  Remineralisation rate
284              CALL iom_put( "REMIN"  , zw3d )
285          ENDIF
286          IF( iom_use( "DENIT" ) )  THEN
287              zw3d(:,:,:) = denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zfact ! Denitrification
288              CALL iom_put( "DENIT"  , zw3d )
289          ENDIF
290          IF( iom_use( "BACT" ) )  THEN
291               zw3d(:,:,:) = zdepbac(:,:,:) * 1.E6 * tmask(:,:,:)  ! Bacterial biomass
292               CALL iom_put( "BACT", zw3d )
293          ENDIF
294          IF( iom_use( "FEBACT" ) )  THEN
295               zw3d(:,:,:) = zfebact(:,:,:) * 1E9 * tmask(:,:,:) * zrfact2   ! Bacterial iron consumption
296               CALL iom_put( "FEBACT" , zw3d )
297          ENDIF
298          !
299          DEALLOCATE( zw3d )
300       ENDIF
301      !
302      IF( ln_timing )   CALL timing_stop('p4z_rem')
303      !
304   END SUBROUTINE p4z_rem
305
306
307   SUBROUTINE p4z_rem_init
308      !!----------------------------------------------------------------------
309      !!                  ***  ROUTINE p4z_rem_init  ***
310      !!
311      !! ** Purpose :   Initialization of remineralization parameters
312      !!
313      !! ** Method  :   Read the nampisrem namelist and check the parameters
314      !!      called at the first timestep
315      !!
316      !! ** input   :   Namelist nampisrem
317      !!
318      !!----------------------------------------------------------------------
319      NAMELIST/nampisrem/ xremik, nitrif, xsirem, xsiremlab, xsilab, feratb, xkferb, & 
320         &                xremikc, xremikn, xremikp
321      INTEGER :: ios                 ! Local integer output status for namelist read
322      !!----------------------------------------------------------------------
323      !
324      IF(lwp) THEN
325         WRITE(numout,*)
326         WRITE(numout,*) 'p4z_rem_init : Initialization of remineralization parameters'
327         WRITE(numout,*) '~~~~~~~~~~~~'
328      ENDIF
329      !
330      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
331901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisrem in reference namelist' )
332      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
333902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisrem in configuration namelist' )
334      IF(lwm) WRITE( numonp, nampisrem )
335
336      IF(lwp) THEN                         ! control print
337         WRITE(numout,*) '   Namelist parameters for remineralization, nampisrem'
338         IF( ln_p4z ) THEN
339            WRITE(numout,*) '      remineralization rate of DOC              xremik    =', xremik
340         ELSE
341            WRITE(numout,*) '      remineralization rate of DOC              xremikc   =', xremikc
342            WRITE(numout,*) '      remineralization rate of DON              xremikn   =', xremikn
343            WRITE(numout,*) '      remineralization rate of DOP              xremikp   =', xremikp
344         ENDIF
345         WRITE(numout,*) '      remineralization rate of Si               xsirem    =', xsirem
346         WRITE(numout,*) '      fast remineralization rate of Si          xsiremlab =', xsiremlab
347         WRITE(numout,*) '      fraction of labile biogenic silica        xsilab    =', xsilab
348         WRITE(numout,*) '      NH4 nitrification rate                    nitrif    =', nitrif
349         WRITE(numout,*) '      Bacterial Fe/C ratio                      feratb    =', feratb
350         WRITE(numout,*) '      Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
351      ENDIF
352      !
353      denitr(:,:,:) = 0._wp
354      !
355   END SUBROUTINE p4z_rem_init
356
357
358   INTEGER FUNCTION p4z_rem_alloc()
359      !!----------------------------------------------------------------------
360      !!                     ***  ROUTINE p4z_rem_alloc  ***
361      !!----------------------------------------------------------------------
362      ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc )
363      !
364      IF( p4z_rem_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_rem_alloc: failed to allocate arrays' )
365      !
366   END FUNCTION p4z_rem_alloc
367
368   !!======================================================================
369END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.