New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcsink.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/TRP – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/TRP/trcsink.F90 @ 11960

Last change on this file since 11960 was 11960, checked in by acc, 4 years ago

Branch 2019/dev_r11943_MERGE_2019. Merge in changes from 2019/dev_r11613_ENHANCE-04_namelists_as_internalfiles. (svn merge -r 11614:11954). Resolved tree conflicts and one actual conflict. Sette tested(these changes alter the ext/AGRIF reference; remember to update). See ticket #2341
File size: 10.2 KB
Line 
1MODULE trcsink
2   !!======================================================================
3   !!                         ***  MODULE trcsink  ***
4   !! TOP :  vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Change aggregation formula
9   !!             3.5  !  2012-07  (O. Aumont) Introduce potential time-splitting
10   !!             4.0  !  2018-12  (O. Aumont) Generalize the PISCES code to make it usable by any model
11   !!----------------------------------------------------------------------
12   !!   trc_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE lib_mpp
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC trc_sink
22   PUBLIC trc_sink_ini
23
24   INTEGER, PUBLIC :: nitermax      !: Maximum number of iterations for sinking
25
26   !!----------------------------------------------------------------------
27   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
28   !! $Id: trcsink.F90 10069 2018-08-28 14:12:24Z nicolasmartin $
29   !! Software governed by the CeCILL license (see ./LICENSE)
30   !!----------------------------------------------------------------------
31CONTAINS
32
33   !!----------------------------------------------------------------------
34   !!   'standard sinking parameterisation'                  ???
35   !!----------------------------------------------------------------------
36
37   SUBROUTINE trc_sink ( kt, Kbb, Kmm, pwsink, psinkflx, jp_tra, rsfact )
38      !!---------------------------------------------------------------------
39      !!                     ***  ROUTINE trc_sink  ***
40      !!
41      !! ** Purpose :   Compute vertical flux of particulate matter due to
42      !!                gravitational sinking
43      !!
44      !! ** Method  : - ???
45      !!---------------------------------------------------------------------
46      INTEGER , INTENT(in)  :: kt
47      INTEGER , INTENT(in)  :: Kbb, Kmm
48      INTEGER , INTENT(in)  :: jp_tra    ! tracer index index     
49      REAL(wp), INTENT(in)  :: rsfact    ! time step duration
50      REAL(wp), INTENT(in)   , DIMENSION(jpi,jpj,jpk) :: pwsink
51      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: psinkflx
52      INTEGER  ::   ji, jj, jk
53      INTEGER, DIMENSION(jpi, jpj) ::   iiter
54      REAL(wp) ::   zfact, zwsmax, zmax
55      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwsink
56      !!---------------------------------------------------------------------
57      !
58      IF( ln_timing )   CALL timing_start('trc_sink')
59      !
60      !
61      ! OA This is (I hope) a temporary solution for the problem that may
62      ! OA arise in specific situation where the CFL criterion is broken
63      ! OA for vertical sedimentation of particles. To avoid this, a time
64      ! OA splitting algorithm has been coded. A specific maximum
65      ! OA iteration number is provided and may be specified in the namelist
66      ! OA This is to avoid very large iteration number when explicit free
67      ! OA surface is used (for instance). When niter?max is set to 1,
68      ! OA this computation is skipped. The crude old threshold method is
69      ! OA then applied. This also happens when niter exceeds nitermax.
70      IF( nitermax == 1 ) THEN
71         iiter(:,:) = 1
72      ELSE
73         DO jj = 1, jpj
74            DO ji = 1, jpi
75               iiter(ji,jj) = 1
76               DO jk = 1, jpkm1
77                  IF( tmask(ji,jj,jk) == 1.0 ) THEN
78                      zwsmax =  0.5 * e3t(ji,jj,jk,Kmm) * rday / rsfact
79                      iiter(ji,jj) =  MAX( iiter(ji,jj), INT( pwsink(ji,jj,jk) / zwsmax ) )
80                  ENDIF
81               END DO
82            END DO
83         END DO
84         iiter(:,:) = MIN( iiter(:,:), nitermax )
85      ENDIF
86
87      DO jk = 1,jpkm1
88         DO jj = 1, jpj
89            DO ji = 1, jpi
90               IF( tmask(ji,jj,jk) == 1.0 ) THEN
91                 zwsmax = 0.5 * e3t(ji,jj,jk,Kmm) * rday / rsfact
92                 zwsink(ji,jj,jk) = MIN( pwsink(ji,jj,jk), zwsmax * REAL( iiter(ji,jj), wp ) )
93               ELSE
94                 ! provide a default value so there is no use of undefinite value in trc_sink2 for zwsink2 initialization
95                 zwsink(ji,jj,jk) = 0.
96               ENDIF
97            END DO
98         END DO
99      END DO
100
101      !  Initializa to zero all the sinking arrays
102      !  -----------------------------------------
103      psinkflx(:,:,:) = 0.e0
104
105      !   Compute the sedimentation term using trc_sink2 for the considered sinking particle
106      !   -----------------------------------------------------
107      CALL trc_sink2( Kbb, Kmm, zwsink, psinkflx, jp_tra, iiter, rsfact )
108      !
109      IF( ln_timing )   CALL timing_stop('trc_sink')
110      !
111   END SUBROUTINE trc_sink
112
113   SUBROUTINE trc_sink2( Kbb, Kmm, pwsink, psinkflx, jp_tra, kiter, rsfact )
114      !!---------------------------------------------------------------------
115      !!                     ***  ROUTINE trc_sink2  ***
116      !!
117      !! ** Purpose :   Compute the sedimentation terms for the various sinking
118      !!     particles. The scheme used to compute the trends is based
119      !!     on MUSCL.
120      !!
121      !! ** Method  : - this ROUTINE compute not exactly the advection but the
122      !!      transport term, i.e.  div(u*tra).
123      !!---------------------------------------------------------------------
124      INTEGER,  INTENT(in   )                         ::   Kbb, Kmm  ! time level indices
125      INTEGER,  INTENT(in   )                         ::   jp_tra    ! tracer index index     
126      REAL(wp), INTENT(in   )                         ::   rsfact    ! duration of time step
127      INTEGER,  INTENT(in   ), DIMENSION(jpi,jpj)     ::   kiter     ! number of iterations for time-splitting
128      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
129      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
130      !
131      INTEGER  ::   ji, jj, jk, jn
132      REAL(wp) ::   zigma,zew,zign, zflx, zstep
133      REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztraz, zakz, zwsink2, ztrb 
134      !!---------------------------------------------------------------------
135      !
136      IF( ln_timing )   CALL timing_start('trc_sink2')
137      !
138      ztraz(:,:,:) = 0.e0
139      zakz (:,:,:) = 0.e0
140      ztrb (:,:,:) = tr(:,:,:,jp_tra,Kbb)
141
142      DO jk = 1, jpkm1
143         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) 
144      END DO
145      zwsink2(:,:,1) = 0.e0
146
147
148      ! Vertical advective flux
149      DO jn = 1, 2
150         !  first guess of the slopes interior values
151         DO jj = 1, jpj
152            DO ji = 1, jpi
153               !
154               zstep = rsfact / REAL( kiter(ji,jj), wp ) / 2.
155               !             
156               DO jk = 2, jpkm1
157                  ztraz(ji,jj,jk) = ( tr(ji,jj,jk-1,jp_tra,Kbb) - tr(ji,jj,jk,jp_tra,Kbb) ) * tmask(ji,jj,jk)
158               END DO
159               ztraz(ji,jj,1  ) = 0.0
160               ztraz(ji,jj,jpk) = 0.0
161
162               ! slopes
163               DO jk = 2, jpkm1
164                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
165                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
166               END DO
167         
168               ! Slopes limitation
169               DO jk = 2, jpkm1
170                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
171                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
172               END DO
173         
174               ! vertical advective flux
175               DO jk = 1, jpkm1
176                  zigma = zwsink2(ji,jj,jk+1) * zstep / e3w(ji,jj,jk+1,Kmm)
177                  zew   = zwsink2(ji,jj,jk+1)
178                  psinkflx(ji,jj,jk+1) = -zew * ( tr(ji,jj,jk,jp_tra,Kbb) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
179               END DO
180               !
181               ! Boundary conditions
182               psinkflx(ji,jj,1  ) = 0.e0
183               psinkflx(ji,jj,jpk) = 0.e0
184         
185               DO jk=1,jpkm1
186                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / e3t(ji,jj,jk,Kmm)
187                  tr(ji,jj,jk,jp_tra,Kbb) = tr(ji,jj,jk,jp_tra,Kbb) + zflx
188               END DO
189            END DO
190         END DO
191      END DO
192
193      DO jk = 1,jpkm1
194         DO jj = 1,jpj
195            DO ji = 1, jpi
196               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / e3t(ji,jj,jk,Kmm)
197               ztrb(ji,jj,jk) = ztrb(ji,jj,jk) + 2. * zflx
198            END DO
199         END DO
200      END DO
201
202      tr(:,:,:,jp_tra,Kbb) = ztrb(:,:,:)
203      psinkflx(:,:,:)   = 2. * psinkflx(:,:,:)
204      !
205      IF( ln_timing )  CALL timing_stop('trc_sink2')
206      !
207   END SUBROUTINE trc_sink2
208
209  SUBROUTINE trc_sink_ini
210      !!---------------------------------------------------------------------
211      !!                  ***  ROUTINE trc_sink_ini ***
212      !!
213      !! ** Purpose :   read  namelist options
214      !!----------------------------------------------------------------------
215      INTEGER ::   ios   ! Local integer output status for namelist read
216      !!
217      NAMELIST/namtrc_snk/ nitermax
218      !!----------------------------------------------------------------------
219      !
220      READ  ( numnat_ref, namtrc_snk, IOSTAT = ios, ERR = 907)
221907   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_snk in reference namelist' )
222      READ  ( numnat_cfg, namtrc_snk, IOSTAT = ios, ERR = 908 )
223908   IF( ios > 0 )   CALL ctl_nam ( ios , 'namtrc_snk in configuration namelist' )
224      IF(lwm) WRITE( numont, namtrc_snk )
225
226      IF(lwp) THEN                     !   ! Control print
227         WRITE(numout,*)
228         WRITE(numout,*) 'trc_sink : Sedimentation of particles '
229         WRITE(numout,*) '~~~~~~~ '
230         WRITE(numout,*) '   Namelist namtrc_snk : sedimentation of particles'
231         WRITE(numout,*) '   Maximum number of iterations   nitermax = ', nitermax
232         WRITE(numout,*)
233      ENDIF
234
235   END SUBROUTINE trc_sink_ini
236
237   !!======================================================================
238END MODULE trcsink
Note: See TracBrowser for help on using the repository browser.