New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcbc.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/trcbc.F90 @ 12250

Last change on this file since 12250 was 12250, checked in by smasson, 4 years ago

rev12240_dev_r11943_MERGE_2019: same as [12246], add modifications from dev_r12114_ticket_2263, results unchanged except SPITZ12 as explained in #2263
  • Property svn:keywords set to Id
File size: 23.6 KB
Line 
1MODULE trcbc
2   !!======================================================================
3   !!                     ***  MODULE  trcbc  ***
4   !! TOP :  module for passive tracer boundary conditions
5   !!=====================================================================
6   !! History :  3.5 !  2014 (M. Vichi, T. Lovato)  Original
7   !!            3.6 !  2015 (T . Lovato) Revision and BDY support
8   !!            4.0 !  2016 (T . Lovato) Include application of sbc and cbc
9   !!----------------------------------------------------------------------
10#if defined key_top
11   !!----------------------------------------------------------------------
12   !!   'key_top'                                                TOP model
13   !!----------------------------------------------------------------------
14   !!   trc_bc       :  Apply tracer Boundary Conditions
15   !!----------------------------------------------------------------------
16   USE par_trc       !  passive tracers parameters
17   USE oce_trc       !  shared variables between ocean and passive tracers
18   USE trc           !  passive tracers common variables
19   USE iom           !  I/O manager
20   USE lib_mpp       !  MPP library
21   USE fldread       !  read input fields
22   USE bdy_oce,  ONLY: ln_bdy, nb_bdy , idx_bdy, ln_coords_file, rn_time_dmp, rn_time_dmp_out
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   trc_bc         ! called in trcstp.F90 or within TOP modules
28   PUBLIC   trc_bc_ini     ! called in trcini.F90
29
30   INTEGER  , SAVE, PUBLIC                             :: nb_trcobc    ! number of tracers with open BC
31   INTEGER  , SAVE, PUBLIC                             :: nb_trcsbc    ! number of tracers with surface BC
32   INTEGER  , SAVE, PUBLIC                             :: nb_trccbc    ! number of tracers with coastal BC
33   INTEGER  , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: n_trc_indobc ! index of tracer with OBC data
34   INTEGER  , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: n_trc_indsbc ! index of tracer with SBC data
35   INTEGER  , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: n_trc_indcbc ! index of tracer with CBC data
36   REAL(wp) , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: rf_trsfac    ! multiplicative factor for SBC tracer values
37   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: sf_trcsbc    ! structure of data input SBC (file informations, fields read)
38   REAL(wp) , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: rf_trcfac    ! multiplicative factor for CBC tracer values
39   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: sf_trccbc    ! structure of data input CBC (file informations, fields read)
40   REAL(wp) , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: rf_trofac    ! multiplicative factor for OBCtracer values
41#if defined key_agrif
42   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: sf_trcobc    ! structure of data input OBC (file informations, fields read)
43#else
44   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET  :: sf_trcobc
45#endif
46
47   !! * Substitutions
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE trc_bc_ini( ntrc, Kmm )
57      !!----------------------------------------------------------------------
58      !!                   ***  ROUTINE trc_bc_ini  ***
59      !!                   
60      !! ** Purpose :   initialisation of passive tracer BC data
61      !!
62      !! ** Method  : - Read namtsd namelist
63      !!              - allocates passive tracer BC data structure
64      !!----------------------------------------------------------------------
65      INTEGER, INTENT(in) :: ntrc                          ! number of tracers
66      INTEGER, INTENT(in) ::   Kmm                         ! time level index
67      !
68      INTEGER            :: jl, jn , ib, ibd, ii, ij, ik   ! dummy loop indices
69      INTEGER            :: ierr0, ierr1, ierr2, ierr3     ! temporary integers
70      INTEGER            :: ios                            ! Local integer output status for namelist read
71      INTEGER            :: nblen, igrd                    ! support arrays for BDY
72      CHARACTER(len=100) :: clndta, clntrc
73      !
74      CHARACTER(len=100) :: cn_dir_sbc, cn_dir_cbc, cn_dir_obc
75      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: slf_i  ! local array of namelist informations on the fields to read
76      TYPE(FLD_N), DIMENSION(jpmaxtrc) :: sn_trcobc    ! open
77      TYPE(FLD_N), DIMENSION(jpmaxtrc) :: sn_trcsbc    ! surface
78      TYPE(FLD_N), DIMENSION(jpmaxtrc) :: sn_trccbc    ! coastal
79      REAL(wp)   , DIMENSION(jpmaxtrc) :: rn_trofac    ! multiplicative factor for tracer values
80      REAL(wp)   , DIMENSION(jpmaxtrc) :: rn_trsfac    ! multiplicative factor for tracer values
81      REAL(wp)   , DIMENSION(jpmaxtrc) :: rn_trcfac    ! multiplicative factor for tracer values
82      !!
83      NAMELIST/namtrc_bc/ cn_dir_obc, sn_trcobc, rn_trofac, cn_dir_sbc, sn_trcsbc, rn_trsfac, & 
84                        & cn_dir_cbc, sn_trccbc, rn_trcfac, ln_rnf_ctl, rn_sbc_time, rn_cbc_time
85      NAMELIST/namtrc_bdy/ cn_trc_dflt, cn_trc, nn_trcdmp_bdy
86      !!----------------------------------------------------------------------
87      !
88      IF( lwp ) THEN
89         WRITE(numout,*)
90         WRITE(numout,*) 'trc_bc_ini : Tracers Boundary Conditions (BC)'
91         WRITE(numout,*) '~~~~~~~~~~~ '
92      ENDIF
93      !  Initialisation and local array allocation
94      ierr0 = 0   ;   ierr1 = 0   ;   ierr2 = 0   ;   ierr3 = 0 
95      ALLOCATE( slf_i(ntrc), STAT=ierr0 )
96      IF( ierr0 > 0 ) THEN
97         CALL ctl_stop( 'trc_bc_ini: unable to allocate local slf_i' )   ;   RETURN
98      ENDIF
99
100      ! Compute the number of tracers to be initialised with open, surface and boundary data
101      ALLOCATE( n_trc_indobc(ntrc), STAT=ierr0 )
102      IF( ierr0 > 0 ) THEN
103         CALL ctl_stop( 'trc_bc_ini: unable to allocate n_trc_indobc' )   ;   RETURN
104      ENDIF
105      nb_trcobc       = 0
106      n_trc_indobc(:) = 0
107      !
108      ALLOCATE( n_trc_indsbc(ntrc), STAT=ierr0 )
109      IF( ierr0 > 0 ) THEN
110         CALL ctl_stop( 'trc_bc_ini: unable to allocate n_trc_indsbc' )   ;   RETURN
111      ENDIF
112      nb_trcsbc       = 0
113      n_trc_indsbc(:) = 0
114      !
115      ALLOCATE( n_trc_indcbc(ntrc), STAT=ierr0 )
116      IF( ierr0 > 0 ) THEN
117         CALL ctl_stop( 'trc_bc_ini: unable to allocate n_trc_indcbc' )   ;   RETURN
118      ENDIF
119      nb_trccbc       = 0
120      n_trc_indcbc(:) = 0
121      !
122      ! Read Boundary Conditions Namelists
123      READ  ( numnat_ref, namtrc_bc, IOSTAT = ios, ERR = 901)
124901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_bc in reference namelist' )
125      READ  ( numnat_cfg, namtrc_bc, IOSTAT = ios, ERR = 902 )
126902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtrc_bc in configuration namelist' )
127      IF(lwm) WRITE ( numont, namtrc_bc )
128
129      IF ( ln_bdy ) THEN
130         READ  ( numnat_ref, namtrc_bdy, IOSTAT = ios, ERR = 903)
131903      IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_bdy in reference namelist' )
132         ! make sur that all elements of the namelist variables have a default definition from namelist_ref
133         cn_trc     (2:jp_bdy) = cn_trc     (1)
134         cn_trc_dflt(2:jp_bdy) = cn_trc_dflt(1)
135         READ  ( numnat_cfg, namtrc_bdy, IOSTAT = ios, ERR = 904 )
136904      IF( ios >  0 )   CALL ctl_nam ( ios , 'namtrc_bdy in configuration namelist' )
137         IF(lwm) WRITE ( numont, namtrc_bdy )
138     
139         ! setup up preliminary informations for BDY structure
140         DO jn = 1, ntrc
141            DO ib = 1, nb_bdy
142               ! Set type of obc in BDY data structure (around here we may plug user override of obc type from nml)
143               IF ( ln_trc_obc(jn) ) THEN   ;   trcdta_bdy(jn,ib)%cn_obc = TRIM( cn_trc     (ib) )
144               ELSE                         ;   trcdta_bdy(jn,ib)%cn_obc = TRIM( cn_trc_dflt(ib) )
145               ENDIF
146               ! set damping use in BDY data structure
147               trcdta_bdy(jn,ib)%dmp = .false.
148               IF(nn_trcdmp_bdy(ib) == 1 .AND. ln_trc_obc(jn) )   trcdta_bdy(jn,ib)%dmp = .true.
149               IF(nn_trcdmp_bdy(ib) == 2                      )   trcdta_bdy(jn,ib)%dmp = .true.
150               IF(trcdta_bdy(jn,ib)%cn_obc == 'frs' .AND. nn_trcdmp_bdy(ib) /= 0 )  &
151                   & CALL ctl_stop( 'trc_bc_ini: Use FRS OR relaxation' )
152               IF(  .NOT.( 0 < nn_trcdmp_bdy(ib)  .AND.  nn_trcdmp_bdy(ib) <= 2 )  )   &
153                   & CALL ctl_stop( 'trc_bc_ini: Not a valid option for nn_trcdmp_bdy. Allowed: 0,1,2.' )
154            END DO
155         END DO
156      ELSE
157         ! Force all tracers OBC to false if bdy not used
158         ln_trc_obc = .false.
159      ENDIF
160
161      ! compose BC data indexes
162      DO jn = 1, ntrc
163         IF( ln_trc_obc(jn) ) THEN
164             nb_trcobc       = nb_trcobc + 1   ;   n_trc_indobc(jn) = nb_trcobc
165         ENDIF
166         IF( ln_trc_sbc(jn) ) THEN
167             nb_trcsbc       = nb_trcsbc + 1   ;   n_trc_indsbc(jn) = nb_trcsbc
168         ENDIF
169         IF( ln_trc_cbc(jn) ) THEN
170             nb_trccbc       = nb_trccbc + 1   ;   n_trc_indcbc(jn) = nb_trccbc
171         ENDIF
172      END DO
173
174      ! Print summmary of Boundary Conditions
175      IF( lwp ) THEN
176         WRITE(numout,*)
177         WRITE(numout,'(a,i3)') '   Total tracers to be initialized with SURFACE BCs data:', nb_trcsbc
178         IF ( nb_trcsbc > 0 ) THEN
179            WRITE(numout,*) '   #trc        NAME        Boundary     Mult.Fact. '
180            DO jn = 1, ntrc
181               IF ( ln_trc_sbc(jn) ) WRITE(numout,9001) jn, TRIM( sn_trcsbc(jn)%clvar ), 'SBC', rn_trsfac(jn)
182            END DO
183         ENDIF
184         WRITE(numout,'(2a)') '   SURFACE BC data repository : ', TRIM(cn_dir_sbc)
185         !
186         WRITE(numout,*)
187         WRITE(numout,'(a,i3)') '   Total tracers to be initialized with COASTAL BCs data:', nb_trccbc
188         IF( nb_trccbc > 0 ) THEN
189            WRITE(numout,*) '   #trc        NAME        Boundary     Mult.Fact. '
190            DO jn = 1, ntrc
191               IF ( ln_trc_cbc(jn) ) WRITE(numout, 9001) jn, TRIM( sn_trccbc(jn)%clvar ), 'CBC', rn_trcfac(jn)
192            END DO
193         ENDIF
194         WRITE(numout,'(2a)') '   COASTAL BC data repository : ', TRIM(cn_dir_cbc)
195         IF( .NOT.ln_rnf .OR. .NOT.ln_linssh )   ln_rnf_ctl = .FALSE.
196         IF( ln_rnf_ctl )  WRITE(numout,'(a)') &
197              &            ' -> Remove runoff dilution effect on tracers with absent river load (ln_rnf_ctl = .TRUE.)'
198         WRITE(numout,*)
199         WRITE(numout,'(a,i3)') '   Total tracers to be initialized with OPEN BCs data:', nb_trcobc
200
201         IF( ln_bdy .AND. nb_trcobc > 0 ) THEN
202            WRITE(numout,*) '   #trc        NAME        Boundary     Mult.Fact.   OBC Settings'
203            DO jn = 1, ntrc
204               IF (       ln_trc_obc(jn) )  WRITE(numout, 9001) jn, TRIM( sn_trcobc(jn)%clvar ), 'OBC', rn_trofac(jn), &
205                    &                                           (trcdta_bdy(jn,ib)%cn_obc,ib=1,nb_bdy)
206               IF ( .NOT. ln_trc_obc(jn) )  WRITE(numout, 9002) jn, 'Set data to IC and use default condition'       , &
207                    &                                           (trcdta_bdy(jn,ib)%cn_obc,ib=1,nb_bdy)
208            END DO
209            WRITE(numout,*) ' '
210            DO ib = 1, nb_bdy
211               IF(nn_trcdmp_bdy(ib) == 0) WRITE(numout,9003) '   Boundary ', ib, &
212                  &                                          ' -> NO damping of tracers'
213               IF(nn_trcdmp_bdy(ib) == 1) WRITE(numout,9003) '   Boundary ', ib, &
214                  &                                          ' -> damping ONLY for tracers with external data provided'
215               IF(nn_trcdmp_bdy(ib) == 2) WRITE(numout,9003) '   Boundary ', ib, &
216                  &                                          ' -> damping of ALL tracers'
217               IF(nn_trcdmp_bdy(ib) >  0) THEN
218                   WRITE(numout,9003) '     USE damping parameters from nambdy for boundary ', ib,' : '
219                   WRITE(numout,'(a,f10.2,a)') '     - Inflow damping time scale  : ',rn_time_dmp    (ib),' days'
220                   WRITE(numout,'(a,f10.2,a)') '     - Outflow damping time scale : ',rn_time_dmp_out(ib),' days'
221               ENDIF
222            END DO
223         ENDIF
224         !
225         WRITE(numout,'(2a)') '   OPEN BC data repository : ', TRIM(cn_dir_obc)
226      ENDIF
2279001  FORMAT(2x,i5, 3x, a15, 3x, a5, 6x, e11.3, 4x, 10a13)
2289002  FORMAT(2x,i5, 3x, a41, 3x, 10a13)
2299003  FORMAT(a, i5, a)
230      !
231      !
232      ! OPEN Lateral boundary conditions
233      IF( ln_bdy .AND. nb_trcobc > 0 ) THEN
234         ALLOCATE ( sf_trcobc(nb_trcobc), rf_trofac(nb_trcobc), STAT=ierr1 )
235         IF( ierr1 > 0 ) THEN
236            CALL ctl_stop( 'trc_bc_ini: unable to allocate sf_trcobc structure' )   ;   RETURN
237         ENDIF
238         !
239         igrd = 1                       ! Everything is at T-points here
240         !
241         DO jn = 1, ntrc
242            DO ib = 1, nb_bdy
243               !
244               nblen = idx_bdy(ib)%nblen(igrd)
245               !
246               IF( ln_trc_obc(jn) ) THEN     !* Initialise from external data *!
247                  jl = n_trc_indobc(jn)
248                  slf_i(jl)    = sn_trcobc(jn)
249                  rf_trofac(jl) = rn_trofac(jn)
250                                                ALLOCATE( sf_trcobc(jl)%fnow(nblen,1,jpk)   , STAT=ierr2 )
251                  IF( sn_trcobc(jn)%ln_tint )   ALLOCATE( sf_trcobc(jl)%fdta(nblen,1,jpk,2) , STAT=ierr3 )
252                  IF( ierr2 + ierr3 > 0 ) THEN
253                    CALL ctl_stop( 'trc_bc_ini : unable to allocate passive tracer OBC data arrays' )   ;   RETURN
254                  ENDIF
255                  trcdta_bdy(jn,ib)%trc => sf_trcobc(jl)%fnow(:,1,:)
256                  trcdta_bdy(jn,ib)%rn_fac = rf_trofac(jl)
257               ELSE                          !* Initialise obc arrays from initial conditions *!
258                  ALLOCATE ( trcdta_bdy(jn,ib)%trc(nblen,jpk) )
259                  DO ibd = 1, nblen
260                     DO ik = 1, jpkm1
261                        ii = idx_bdy(ib)%nbi(ibd,igrd)
262                        ij = idx_bdy(ib)%nbj(ibd,igrd)
263                        trcdta_bdy(jn,ib)%trc(ibd,ik) = tr(ii,ij,ik,jn,Kmm) * tmask(ii,ij,ik)
264                     END DO
265                  END DO
266                  trcdta_bdy(jn,ib)%rn_fac = 1._wp
267               ENDIF
268            END DO
269         END DO
270         !
271         CALL fld_fill( sf_trcobc, slf_i, cn_dir_obc, 'trc_bc_ini', 'Passive tracer OBC data', 'namtrc_bc' )
272         DO jn = 1, ntrc   ! define imap pointer, must be done after the call to fld_fill
273            DO ib = 1, nb_bdy
274               IF( ln_trc_obc(jn) ) THEN     !* Initialise from external data *!
275                  jl = n_trc_indobc(jn)
276                  sf_trcobc(jl)%imap => idx_bdy(ib)%nbmap(1:idx_bdy(ib)%nblen(igrd),igrd)
277               ENDIF
278            END DO
279         END DO
280         !
281      ENDIF
282
283      ! SURFACE Boundary conditions
284      IF( nb_trcsbc > 0 ) THEN       !  allocate only if the number of tracer to initialise is greater than zero
285         ALLOCATE( sf_trcsbc(nb_trcsbc), rf_trsfac(nb_trcsbc), STAT=ierr1 )
286         IF( ierr1 > 0 ) THEN
287            CALL ctl_stop( 'trc_bc_ini: unable to allocate  sf_trcsbc structure' )   ;   RETURN
288         ENDIF
289         !
290         DO jn = 1, ntrc
291            IF( ln_trc_sbc(jn) ) THEN      ! update passive tracers arrays with input data read from file
292               jl = n_trc_indsbc(jn)
293               slf_i(jl)    = sn_trcsbc(jn)
294               rf_trsfac(jl) = rn_trsfac(jn)
295                                            ALLOCATE( sf_trcsbc(jl)%fnow(jpi,jpj,1)   , STAT=ierr2 )
296               IF( sn_trcsbc(jn)%ln_tint )  ALLOCATE( sf_trcsbc(jl)%fdta(jpi,jpj,1,2) , STAT=ierr3 )
297               IF( ierr2 + ierr3 > 0 ) THEN
298                 CALL ctl_stop( 'trc_bc_ini : unable to allocate passive tracer SBC data arrays' )   ;   RETURN
299               ENDIF
300            ENDIF
301            !   
302         END DO
303         !                         ! fill sf_trcsbc with slf_i and control print
304         CALL fld_fill( sf_trcsbc, slf_i, cn_dir_sbc, 'trc_bc_ini', 'Passive tracer SBC data', 'namtrc_bc' )
305         !
306      ENDIF
307      !
308      ! COSTAL Boundary conditions
309      IF( nb_trccbc > 0 ) THEN       !  allocate only if the number of tracer to initialise is greater than zero
310         ALLOCATE( sf_trccbc(nb_trccbc), rf_trcfac(nb_trccbc), STAT=ierr1 )
311         IF( ierr1 > 0 ) THEN
312            CALL ctl_stop( 'trc_bc_ini: unable to allocate  sf_trccbc structure' )   ;   RETURN
313         ENDIF
314         !
315         DO jn = 1, ntrc
316            IF( ln_trc_cbc(jn) ) THEN      ! update passive tracers arrays with input data read from file
317               jl = n_trc_indcbc(jn)
318               slf_i(jl)    = sn_trccbc(jn)
319               rf_trcfac(jl) = rn_trcfac(jn)
320                                            ALLOCATE( sf_trccbc(jl)%fnow(jpi,jpj,1)   , STAT=ierr2 )
321               IF( sn_trccbc(jn)%ln_tint )  ALLOCATE( sf_trccbc(jl)%fdta(jpi,jpj,1,2) , STAT=ierr3 )
322               IF( ierr2 + ierr3 > 0 ) THEN
323                 CALL ctl_stop( 'trc_bc_ini : unable to allocate passive tracer CBC data arrays' )   ;   RETURN
324               ENDIF
325            ENDIF
326            !   
327         END DO
328         !                         ! fill sf_trccbc with slf_i and control print
329         CALL fld_fill( sf_trccbc, slf_i, cn_dir_cbc, 'trc_bc_ini', 'Passive tracer CBC data', 'namtrc_bc' )
330         !
331      ENDIF
332      !
333      DEALLOCATE( slf_i )          ! deallocate local field structure
334      !
335   END SUBROUTINE trc_bc_ini
336
337
338   SUBROUTINE trc_bc(kt, Kmm, ptr, Krhs, jit)
339      !!----------------------------------------------------------------------
340      !!                   ***  ROUTINE trc_bc  ***
341      !!
342      !! ** Purpose :  Apply Boundary Conditions data to tracers
343      !!
344      !! ** Method  :  1) Read BC inputs and update data structures using fldread
345      !!               2) Apply Boundary Conditions to tracers
346      !!----------------------------------------------------------------------
347      USE fldread
348      !!     
349      INTEGER                                   , INTENT(in)           ::   kt        ! ocean time-step index
350      INTEGER                                   , INTENT(in)           ::   Kmm, Krhs ! time level indices
351      INTEGER                                   , INTENT(in), OPTIONAL ::   jit       ! subcycle time-step index (for timesplitting option)
352      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr            ! passive tracers and RHS of tracer equation
353      !!
354      INTEGER  :: ji, jj, jk, jn, jl             ! Loop index
355      REAL(wp) :: zfact, zrnf
356      !!---------------------------------------------------------------------
357      !
358      IF( ln_timing )   CALL timing_start('trc_bc')
359
360      IF( kt == nit000 .AND. lwp) THEN
361         WRITE(numout,*)
362         WRITE(numout,*) 'trc_bc : Surface boundary conditions for passive tracers.'
363         WRITE(numout,*) '~~~~~~~ '
364      ENDIF
365
366      ! 1. Update Boundary conditions data
367      IF( PRESENT(jit) ) THEN 
368         !
369         ! OPEN boundary conditions (use pt_offset=1. as they are applied at the end of the step)
370         IF( nb_trcobc > 0 ) THEN
371           if (lwp) write(numout,'(a,i5,a,i10)') '   reading OBC data for ', nb_trcobc ,' variable(s) at step ', kt
372           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trcobc, kit=jit, pt_offset=1.)
373         ENDIF
374         !
375         ! SURFACE boundary conditions
376         IF( nb_trcsbc > 0 ) THEN
377           if (lwp) write(numout,'(a,i5,a,i10)') '   reading SBC data for ', nb_trcsbc ,' variable(s) at step ', kt
378           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trcsbc, kit=jit)
379         ENDIF
380         !
381         ! COASTAL boundary conditions
382         IF( nb_trccbc > 0 ) THEN
383           if (lwp) write(numout,'(a,i5,a,i10)') '   reading CBC data for ', nb_trccbc ,' variable(s) at step ', kt
384           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trccbc, kit=jit)
385         ENDIF
386         !
387      ELSE
388         !
389         ! OPEN boundary conditions (use pt_offset=1. as they are applied at the end of the step)
390         IF( nb_trcobc > 0 ) THEN
391           if (lwp) write(numout,'(a,i5,a,i10)') '   reading OBC data for ', nb_trcobc ,' variable(s) at step ', kt
392           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trcobc, pt_offset=1.)
393         ENDIF
394         !
395         ! SURFACE boundary conditions
396         IF( nb_trcsbc > 0 ) THEN
397           if (lwp) write(numout,'(a,i5,a,i10)') '   reading SBC data for ', nb_trcsbc ,' variable(s) at step ', kt
398           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trcsbc )
399         ENDIF
400         !
401         ! COASTAL boundary conditions
402         IF( nb_trccbc > 0 ) THEN
403           if (lwp) write(numout,'(a,i5,a,i10)') '   reading CBC data for ', nb_trccbc ,' variable(s) at step ', kt
404           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trccbc )
405         ENDIF
406         !
407      ENDIF
408
409      ! 2. Apply Boundary conditions data
410      !
411      DO jn = 1 , jptra
412         !
413         ! Remove river dilution for tracers with absent river load
414         IF( ln_rnf_ctl .AND. .NOT.ln_trc_cbc(jn) ) THEN
415            DO jj = 2, jpj
416               DO ji = fs_2, fs_jpim1
417                  DO jk = 1, nk_rnf(ji,jj)
418                     zrnf = (rnf(ji,jj) + rnf_b(ji,jj)) * 0.5_wp * r1_rau0 / h_rnf(ji,jj)
419                     ptr(ji,jj,jk,jn,Krhs) = ptr(ji,jj,jk,jn,Krhs)  + (ptr(ji,jj,jk,jn,Kmm) * zrnf)
420                  END DO
421               END DO
422            END DO
423         ENDIF
424         !
425         ! OPEN boundary conditions: trcbdy is called in trcnxt !
426         !
427         ! SURFACE boundary conditions
428         IF( ln_trc_sbc(jn) ) THEN
429            jl = n_trc_indsbc(jn)
430            sf_trcsbc(jl)%fnow(:,:,1) = MAX( rtrn, sf_trcsbc(jl)%fnow(:,:,1) ) ! avoid nedgative value due to interpolation
431            DO jj = 2, jpj
432               DO ji = fs_2, fs_jpim1   ! vector opt.
433                  zfact = 1. / ( e3t(ji,jj,1,Kmm) * rn_sbc_time )
434                  ptr(ji,jj,1,jn,Krhs) = ptr(ji,jj,1,jn,Krhs) + rf_trsfac(jl) * sf_trcsbc(jl)%fnow(ji,jj,1) * zfact
435               END DO
436            END DO
437         ENDIF
438         !
439         ! COASTAL boundary conditions
440         IF( ( ln_rnf .OR. l_offline ) .AND. ln_trc_cbc(jn) ) THEN
441            IF( l_offline )   rn_rfact = 1._wp
442            jl = n_trc_indcbc(jn)
443            DO jj = 2, jpj
444               DO ji = fs_2, fs_jpim1   ! vector opt.
445                  DO jk = 1, nk_rnf(ji,jj)
446                     zfact = rn_rfact / ( e1e2t(ji,jj) * h_rnf(ji,jj) * rn_cbc_time ) * tmask(ji,jj,1)
447                     ptr(ji,jj,jk,jn,Krhs) = ptr(ji,jj,jk,jn,Krhs) + rf_trcfac(jl) * sf_trccbc(jl)%fnow(ji,jj,1) * zfact
448                  END DO
449               END DO
450            END DO
451         ENDIF
452         !                                                       ! ===========
453      END DO                                                     ! tracer loop
454      !                                                          ! ===========
455      IF( ln_timing )   CALL timing_stop('trc_bc')
456      !
457   END SUBROUTINE trc_bc
458
459#else
460   !!----------------------------------------------------------------------
461   !!   Dummy module                              NO 3D passive tracer data
462   !!----------------------------------------------------------------------
463CONTAINS
464   SUBROUTINE trc_bc_ini( ntrc, Kmm )        ! Empty routine
465      INTEGER, INTENT(IN) :: ntrc                           ! number of tracers
466      INTEGER, INTENT(in) :: Kmm                            ! time level index
467      WRITE(*,*) 'trc_bc_ini: You should not have seen this print! error?', kt
468   END SUBROUTINE trc_bc_ini
469   SUBROUTINE trc_bc( kt, Kmm, Krhs )        ! Empty routine
470      INTEGER, INTENT(in) :: Kmm, Krhs ! time level indices
471      WRITE(*,*) 'trc_bc: You should not have seen this print! error?', kt
472   END SUBROUTINE trc_bc
473#endif
474
475   !!======================================================================
476END MODULE trcbc
Note: See TracBrowser for help on using the repository browser.