New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcstp.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/trcstp.F90 @ 11949

Last change on this file since 11949 was 11949, checked in by acc, 4 years ago

Merge in changes from 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. This just creates a fresh copy of this branch to use as the merge base. See ticket #2341
  • Property svn:keywords set to Id
File size: 11.5 KB
Line 
1MODULE trcstp
2   !!======================================================================
3   !!                       ***  MODULE trcstp  ***
4   !! Time-stepping    : time loop of opa for passive tracer
5   !!======================================================================
6   !! History :  1.0  !  2004-03  (C. Ethe)  Original
7   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   trc_stp       : passive tracer system time-stepping
12   !!----------------------------------------------------------------------
13   USE oce_trc        ! ocean dynamics and active tracers variables
14   USE sbc_oce
15   USE trc
16   USE trctrp         ! passive tracers transport
17   USE trcsms         ! passive tracers sources and sinks
18   USE trcwri
19   USE trcrst
20   USE trdtrc_oce
21   USE trdmxl_trc
22   USE sms_pisces,  ONLY : ln_check_mass
23   !
24   USE prtctl_trc     ! Print control for debbuging
25   USE iom            !
26   USE in_out_manager !
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   trc_stp    ! called by step
32
33   LOGICAL  ::   llnew                   ! ???
34   REAL(wp) ::   rdt_sampl               ! ???
35   INTEGER  ::   nb_rec_per_day, ktdcy   ! ???
36   REAL(wp) ::   rsecfst, rseclast       ! ???
37   REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   qsr_arr   ! save qsr during TOP time-step
38
39   !!----------------------------------------------------------------------
40   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
41   !! $Id$
42   !! Software governed by the CeCILL license (see ./LICENSE)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE trc_stp( kt, Kbb, Kmm, Krhs, Kaa )
47      !!-------------------------------------------------------------------
48      !!                     ***  ROUTINE trc_stp  ***
49      !!                     
50      !! ** Purpose :   Time loop of opa for passive tracer
51      !!
52      !! ** Method  :   Compute the passive tracers trends
53      !!                Update the passive tracers
54      !!-------------------------------------------------------------------
55      INTEGER, INTENT( in ) :: kt                  ! ocean time-step index
56      INTEGER, INTENT( in ) :: Kbb, Kmm, Krhs, Kaa ! time level indices
57      !
58      INTEGER ::   jk, jn   ! dummy loop indices
59      REAL(wp)::   ztrai    ! local scalar
60      LOGICAL ::   ll_trcstat ! local logical
61      CHARACTER (len=25) ::   charout   !
62      !!-------------------------------------------------------------------
63      !
64      IF( ln_timing )   CALL timing_start('trc_stp')
65      !
66      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN     ! at nittrc000
67         r2dttrc =  rdttrc           ! = rdttrc (use or restarting with Euler time stepping)
68      ELSEIF( kt <= nittrc000 + 1 ) THEN                                     ! at nittrc000 or nittrc000+1
69         r2dttrc = 2. * rdttrc       ! = 2 rdttrc (leapfrog)
70      ENDIF
71      !
72      ll_trcstat  = ( ln_ctl .OR. sn_cfctl%l_trcstat ) .AND. &
73     &              ( ( MOD( kt, sn_cfctl%ptimincr ) == 0 ) .OR. ( kt == nitend ) )
74      IF( kt == nittrc000 .AND. lk_trdmxl_trc )  CALL trd_mxl_trc_init    ! trends: Mixed-layer
75      !
76      IF( .NOT.ln_linssh ) THEN                                           ! update ocean volume due to ssh temporal evolution
77         DO jk = 1, jpk
78            cvol(:,:,jk) = e1e2t(:,:) * e3t(:,:,jk,Kmm) * tmask(:,:,jk)
79         END DO
80         IF ( ln_ctl .OR. kt == nitrst .OR. ( ln_check_mass .AND. kt == nitend )              &
81            & .OR. iom_use( "pno3tot" ) .OR. iom_use( "ppo4tot" ) .OR. iom_use( "psiltot" )   &
82            & .OR. iom_use( "palktot" ) .OR. iom_use( "pfertot" ) )                           &
83            &     areatot = glob_sum( 'trcstp', cvol(:,:,:) )
84      ENDIF
85      !
86      IF( l_trcdm2dc )   CALL trc_mean_qsr( kt )
87      !   
88      !
89      IF(ln_ctl) THEN
90         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
91         CALL prt_ctl_trc_info(charout)
92      ENDIF
93      !
94      tr(:,:,:,:,Krhs) = 0._wp
95      !
96      CALL trc_rst_opn  ( kt )                            ! Open tracer restart file
97      IF( lrst_trc )  CALL trc_rst_cal  ( kt, 'WRITE' )   ! calendar
98      CALL trc_wri      ( kt,      Kmm            )       ! output of passive tracers with iom I/O manager
99      CALL trc_sms      ( kt, Kbb, Kmm, Krhs      )       ! tracers: sinks and sources
100      CALL trc_trp      ( kt, Kbb, Kmm, Krhs, Kaa )       ! transport of passive tracers
101           !
102           ! Note passive tracers have been time-filtered in trc_trp but the time level
103           ! indices will not be swapped until after tra_atf/dyn_atf/ssh_atf in stp. Subsequent calls here
104           ! anticipate this update which will be: Nrhs= Nbb ; Nbb = Nnn ; Nnn = Naa ; Naa = Nrhs
105           ! and use the filtered levels explicitly.
106           !
107      IF( kt == nittrc000 ) THEN
108         CALL iom_close( numrtr )                         ! close input tracer restart file
109         IF(lwm) CALL FLUSH( numont )                     ! flush namelist output
110      ENDIF
111      IF( lrst_trc )            CALL trc_rst_wri  ( kt, Kmm, Kaa, Kbb  )       ! write tracer restart file
112      IF( lk_trdmxl_trc  )      CALL trd_mxl_trc  ( kt,      Kaa       )       ! trends: Mixed-layer
113      !
114      IF (ll_trcstat) THEN
115         ztrai = 0._wp                                                   !  content of all tracers
116         DO jn = 1, jptra
117            ztrai = ztrai + glob_sum( 'trcstp', tr(:,:,:,jn,Kaa) * cvol(:,:,:)   )
118         END DO
119         IF( lwm ) WRITE(numstr,9300) kt,  ztrai / areatot
120      ENDIF
1219300  FORMAT(i10,D23.16)
122      !
123      IF( ln_timing )   CALL timing_stop('trc_stp')
124      !
125   END SUBROUTINE trc_stp
126
127   SUBROUTINE trc_mean_qsr( kt )
128      !!----------------------------------------------------------------------
129      !!             ***  ROUTINE trc_mean_qsr  ***
130      !!
131      !! ** Purpose :  Compute daily mean qsr for biogeochemical model in case
132      !!               of diurnal cycle
133      !!
134      !! ** Method  : store in TOP the qsr every hour ( or every time-step if the latter
135      !!              is greater than 1 hour ) and then, compute the  mean with
136      !!              a moving average over 24 hours.
137      !!              In coupled mode, the sampling is done at every coupling frequency
138      !!----------------------------------------------------------------------
139      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
140      !
141      INTEGER  ::   jn   ! dummy loop indices
142      REAL(wp) ::   zkt, zrec     ! local scalars
143      CHARACTER(len=1) ::   cl1   ! 1 character
144      CHARACTER(len=2) ::   cl2   ! 2 characters
145      !!----------------------------------------------------------------------
146      !
147      IF( ln_timing )   CALL timing_start('trc_mean_qsr')
148      !
149      IF( kt == nittrc000 ) THEN
150         IF( ln_cpl )  THEN 
151            rdt_sampl = rday / ncpl_qsr_freq
152            nb_rec_per_day = ncpl_qsr_freq
153         ELSE 
154            rdt_sampl = MAX( 3600., rdttrc )
155            nb_rec_per_day = INT( rday / rdt_sampl )
156         ENDIF
157         !
158         IF(lwp) THEN
159            WRITE(numout,*) 
160            WRITE(numout,*) ' Sampling frequency dt = ', rdt_sampl, 's','   Number of sampling per day  nrec = ', nb_rec_per_day
161            WRITE(numout,*) 
162         ENDIF
163         !
164         ALLOCATE( qsr_arr(jpi,jpj,nb_rec_per_day ) )
165         !
166         !                                            !* Restart: read in restart file
167         IF( ln_rsttr .AND. nn_rsttr /= 0 .AND. iom_varid( numrtr, 'qsr_mean' , ldstop = .FALSE. ) > 0  &
168           &                              .AND. iom_varid( numrtr, 'qsr_arr_1', ldstop = .FALSE. ) > 0  &
169           &                              .AND. iom_varid( numrtr, 'ktdcy'    , ldstop = .FALSE. ) > 0  &
170           &                              .AND. iom_varid( numrtr, 'nrdcy'    , ldstop = .FALSE. ) > 0  ) THEN
171
172            CALL iom_get( numrtr, 'ktdcy', zkt ) 
173            rsecfst = INT( zkt ) * rdttrc
174            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean read in the restart file at time-step rsecfst =', rsecfst, ' s '
175            CALL iom_get( numrtr, jpdom_autoglo, 'qsr_mean', qsr_mean )   !  A mean of qsr
176            CALL iom_get( numrtr, 'nrdcy', zrec )   !  Number of record per days
177            IF( INT( zrec ) == nb_rec_per_day ) THEN
178               DO jn = 1, nb_rec_per_day 
179                  IF( jn <= 9 )  THEN
180                    WRITE(cl1,'(i1)') jn
181                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )   !  A mean of qsr
182                  ELSE
183                    WRITE(cl2,'(i2.2)') jn
184                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )   !  A mean of qsr
185                  ENDIF
186              END DO
187            ELSE
188               DO jn = 1, nb_rec_per_day
189                  qsr_arr(:,:,jn) = qsr_mean(:,:)
190               ENDDO
191            ENDIF
192         ELSE                                         !* no restart: set from nit000 values
193            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean set to nit000 values'
194            rsecfst  = kt * rdttrc
195            !
196            qsr_mean(:,:) = qsr(:,:)
197            DO jn = 1, nb_rec_per_day
198               qsr_arr(:,:,jn) = qsr_mean(:,:)
199            END DO
200         ENDIF
201         !
202      ENDIF
203      !
204      rseclast = kt * rdttrc
205      !
206      llnew   = ( rseclast - rsecfst ) .ge.  rdt_sampl    !   new shortwave to store
207      IF( llnew ) THEN
208          ktdcy = kt
209          IF( lwp .AND. kt < nittrc000 + 100 ) WRITE(numout,*) ' New shortwave to sample for TOP at time kt = ', ktdcy, &
210             &                      ' time = ', rseclast/3600.,'hours '
211          rsecfst = rseclast
212          DO jn = 1, nb_rec_per_day - 1
213             qsr_arr(:,:,jn) = qsr_arr(:,:,jn+1)
214          ENDDO
215          qsr_arr (:,:,nb_rec_per_day) = qsr(:,:)
216          qsr_mean(:,:                ) = SUM( qsr_arr(:,:,:), 3 ) / nb_rec_per_day
217      ENDIF
218      !
219      IF( lrst_trc ) THEN    !* Write the mean of qsr in restart file
220         IF(lwp) WRITE(numout,*)
221         IF(lwp) WRITE(numout,*) 'trc_mean_qsr : write qsr_mean in restart file  kt =', kt
222         IF(lwp) WRITE(numout,*) '~~~~~~~'
223         zkt  = REAL( ktdcy, wp )
224         zrec = REAL( nb_rec_per_day, wp )
225         CALL iom_rstput( kt, nitrst, numrtw, 'ktdcy', zkt  )
226         CALL iom_rstput( kt, nitrst, numrtw, 'nrdcy', zrec )
227          DO jn = 1, nb_rec_per_day 
228             IF( jn <= 9 )  THEN
229               WRITE(cl1,'(i1)') jn
230               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )
231             ELSE
232               WRITE(cl2,'(i2.2)') jn
233               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )
234             ENDIF
235         END DO
236         CALL iom_rstput( kt, nitrst, numrtw, 'qsr_mean', qsr_mean(:,:) )
237      ENDIF
238      !
239      IF( ln_timing )   CALL timing_stop('trc_mean_qsr')
240      !
241   END SUBROUTINE trc_mean_qsr
242
243#else
244   !!----------------------------------------------------------------------
245   !!   Default key                                     NO passive tracers
246   !!----------------------------------------------------------------------
247CONTAINS
248   SUBROUTINE trc_stp( kt )        ! Empty routine
249      WRITE(*,*) 'trc_stp: You should not have seen this print! error?', kt
250   END SUBROUTINE trc_stp
251#endif
252
253   !!======================================================================
254END MODULE trcstp
Note: See TracBrowser for help on using the repository browser.