New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdydta.F90 in NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/OCE/BDY – NEMO

source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/OCE/BDY/bdydta.F90 @ 12202

Last change on this file since 12202 was 12202, checked in by cetlod, 4 years ago

dev_merge_option2 : merge in dev_r11613_ENHANCE-04_namelists_as_internalfiles
  • Property svn:keywords set to Id
File size: 39.8 KB
Line 
1MODULE bdydta
2   !!======================================================================
3   !!                       ***  MODULE bdydta  ***
4   !! Open boundary data : read the data for the unstructured open boundaries.
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-01  (D. Storkey) Update to use IOM module
8   !!             -   !  2007-07  (D. Storkey) add bdy_dta_fla
9   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!            3.6  !  2012-01  (C. Rousset) add ice boundary conditions for sea ice
14   !!            4.0  !  2018     (C. Rousset) SI3 compatibility
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!    bdy_dta      : read external data along open boundaries from file
19   !!    bdy_dta_init : initialise arrays etc for reading of external data
20   !!----------------------------------------------------------------------
21   USE oce            ! ocean dynamics and tracers
22   USE dom_oce        ! ocean space and time domain
23   USE phycst         ! physical constants
24   USE sbcapr         ! atmospheric pressure forcing
25   USE tide_mod, ONLY: ln_tide ! tidal forcing
26   USE bdy_oce        ! ocean open boundary conditions 
27   USE bdytides       ! tidal forcing at boundaries
28#if defined key_si3
29   USE ice            ! sea-ice variables
30   USE icevar         ! redistribute ice input into categories
31#endif
32   !
33   USE lib_mpp, ONLY: ctl_stop, ctl_nam
34   USE fldread        ! read input fields
35   USE iom            ! IOM library
36   USE in_out_manager ! I/O logical units
37   USE timing         ! Timing
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   bdy_dta          ! routine called by step.F90 and dynspg_ts.F90
43   PUBLIC   bdy_dta_init     ! routine called by nemogcm.F90
44
45   INTEGER , PARAMETER ::   jpbdyfld  = 16    ! maximum number of files to read
46   INTEGER , PARAMETER ::   jp_bdyssh = 1     !
47   INTEGER , PARAMETER ::   jp_bdyu2d = 2     !
48   INTEGER , PARAMETER ::   jp_bdyv2d = 3     !
49   INTEGER , PARAMETER ::   jp_bdyu3d = 4     !
50   INTEGER , PARAMETER ::   jp_bdyv3d = 5     !
51   INTEGER , PARAMETER ::   jp_bdytem = 6     !
52   INTEGER , PARAMETER ::   jp_bdysal = 7     !
53   INTEGER , PARAMETER ::   jp_bdya_i = 8     !
54   INTEGER , PARAMETER ::   jp_bdyh_i = 9     !
55   INTEGER , PARAMETER ::   jp_bdyh_s = 10    !
56   INTEGER , PARAMETER ::   jp_bdyt_i = 11    !
57   INTEGER , PARAMETER ::   jp_bdyt_s = 12    !
58   INTEGER , PARAMETER ::   jp_bdytsu = 13    !
59   INTEGER , PARAMETER ::   jp_bdys_i = 14    !
60   INTEGER , PARAMETER ::   jp_bdyaip = 15    !
61   INTEGER , PARAMETER ::   jp_bdyhip = 16    !
62#if ! defined key_si3
63   INTEGER , PARAMETER ::   jpl = 1
64#endif
65
66!$AGRIF_DO_NOT_TREAT
67   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:,:), TARGET ::   bf   ! structure of input fields (file informations, fields read)
68!$AGRIF_END_DO_NOT_TREAT
69
70   !!----------------------------------------------------------------------
71   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
72   !! $Id$
73   !! Software governed by the CeCILL license (see ./LICENSE)
74   !!----------------------------------------------------------------------
75CONTAINS
76
77   SUBROUTINE bdy_dta( kt, kt_offset )
78      !!----------------------------------------------------------------------
79      !!                   ***  SUBROUTINE bdy_dta  ***
80      !!                   
81      !! ** Purpose :   Update external data for open boundary conditions
82      !!
83      !! ** Method  :   Use fldread.F90
84      !!               
85      !!----------------------------------------------------------------------
86      INTEGER, INTENT(in)           ::   kt           ! ocean time-step index
87      INTEGER, INTENT(in), OPTIONAL ::   kt_offset    ! time offset in units of timesteps
88      !                                               ! kt_offset = 0 => get data at "now" time level
89      !                                               ! kt_offset = -1 => get data at "before" time level
90      !                                               ! kt_offset = +1 => get data at "after" time level
91      !                                               ! etc.
92      !
93      INTEGER ::  jbdy, jfld, jstart, jend, ib, jl    ! dummy loop indices
94      INTEGER ::  ii, ij, ik, igrd, ipl               ! local integers
95      INTEGER,   DIMENSION(jpbgrd)     ::   ilen1 
96      INTEGER,   DIMENSION(:), POINTER ::   nblen, nblenrim  ! short cuts
97      TYPE(OBC_DATA)         , POINTER ::   dta_alias        ! short cut
98      TYPE(FLD), DIMENSION(:), POINTER ::   bf_alias
99      !!---------------------------------------------------------------------------
100      !
101      IF( ln_timing )   CALL timing_start('bdy_dta')
102      !
103      ! Initialise data arrays once for all from initial conditions where required
104      !---------------------------------------------------------------------------
105      IF( kt == nit000 ) THEN
106
107         ! Calculate depth-mean currents
108         !-----------------------------
109
110         DO jbdy = 1, nb_bdy
111            !
112            nblen    => idx_bdy(jbdy)%nblen
113            nblenrim => idx_bdy(jbdy)%nblenrim
114            !
115            IF( nn_dyn2d_dta(jbdy) == 0 ) THEN
116               ilen1(:) = nblen(:)
117               IF( dta_bdy(jbdy)%lneed_ssh ) THEN
118                  igrd = 1
119                  DO ib = 1, ilen1(igrd)
120                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
121                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
122                     dta_bdy(jbdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)         
123                  END DO
124               ENDIF
125               IF( dta_bdy(jbdy)%lneed_dyn2d) THEN
126                  igrd = 2
127                  DO ib = 1, ilen1(igrd)
128                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
129                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
130                     dta_bdy(jbdy)%u2d(ib) = un_b(ii,ij) * umask(ii,ij,1)         
131                  END DO
132                  igrd = 3
133                  DO ib = 1, ilen1(igrd)
134                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
135                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
136                     dta_bdy(jbdy)%v2d(ib) = vn_b(ii,ij) * vmask(ii,ij,1)         
137                  END DO
138               ENDIF
139            ENDIF
140            !
141            IF( nn_dyn3d_dta(jbdy) == 0 ) THEN
142               ilen1(:) = nblen(:)
143               IF( dta_bdy(jbdy)%lneed_dyn3d ) THEN
144                  igrd = 2 
145                  DO ib = 1, ilen1(igrd)
146                     DO ik = 1, jpkm1
147                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
148                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
149                        dta_bdy(jbdy)%u3d(ib,ik) =  ( un(ii,ij,ik) - un_b(ii,ij) ) * umask(ii,ij,ik)         
150                     END DO
151                  END DO
152                  igrd = 3 
153                  DO ib = 1, ilen1(igrd)
154                     DO ik = 1, jpkm1
155                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
156                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
157                        dta_bdy(jbdy)%v3d(ib,ik) =  ( vn(ii,ij,ik) - vn_b(ii,ij) ) * vmask(ii,ij,ik)         
158                     END DO
159                  END DO
160               ENDIF
161            ENDIF
162
163            IF( nn_tra_dta(jbdy) == 0 ) THEN
164               ilen1(:) = nblen(:)
165               IF( dta_bdy(jbdy)%lneed_tra ) THEN
166                  igrd = 1 
167                  DO ib = 1, ilen1(igrd)
168                     DO ik = 1, jpkm1
169                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
170                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
171                        dta_bdy(jbdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_tem) * tmask(ii,ij,ik)         
172                        dta_bdy(jbdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_sal) * tmask(ii,ij,ik)         
173                     END DO
174                  END DO
175               ENDIF
176            ENDIF
177
178#if defined key_si3
179            IF( nn_ice_dta(jbdy) == 0 ) THEN    ! set ice to initial values
180               ilen1(:) = nblen(:)
181               IF( dta_bdy(jbdy)%lneed_ice ) THEN
182                  igrd = 1   
183                  DO jl = 1, jpl
184                     DO ib = 1, ilen1(igrd)
185                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
186                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
187                        dta_bdy(jbdy)%a_i(ib,jl) =  a_i (ii,ij,jl) * tmask(ii,ij,1) 
188                        dta_bdy(jbdy)%h_i(ib,jl) =  h_i (ii,ij,jl) * tmask(ii,ij,1) 
189                        dta_bdy(jbdy)%h_s(ib,jl) =  h_s (ii,ij,jl) * tmask(ii,ij,1) 
190                        dta_bdy(jbdy)%t_i(ib,jl) =  SUM(t_i (ii,ij,:,jl)) * r1_nlay_i * tmask(ii,ij,1) 
191                        dta_bdy(jbdy)%t_s(ib,jl) =  SUM(t_s (ii,ij,:,jl)) * r1_nlay_s * tmask(ii,ij,1)
192                        dta_bdy(jbdy)%tsu(ib,jl) =  t_su(ii,ij,jl) * tmask(ii,ij,1) 
193                        dta_bdy(jbdy)%s_i(ib,jl) =  s_i (ii,ij,jl) * tmask(ii,ij,1)
194                        ! melt ponds
195                        dta_bdy(jbdy)%aip(ib,jl) =  a_ip(ii,ij,jl) * tmask(ii,ij,1) 
196                        dta_bdy(jbdy)%hip(ib,jl) =  h_ip(ii,ij,jl) * tmask(ii,ij,1) 
197                     END DO
198                  END DO
199               ENDIF
200            ENDIF
201#endif
202         END DO ! jbdy
203         !
204      ENDIF ! kt == nit000
205
206      ! update external data from files
207      !--------------------------------
208
209      DO jbdy = 1, nb_bdy
210
211         dta_alias => dta_bdy(jbdy)
212         bf_alias  => bf(:,jbdy)
213
214         ! read/update all bdy data
215         ! ------------------------
216         CALL fld_read( kt, 1, bf_alias, kt_offset = kt_offset )
217
218         ! apply some corrections in some specific cases...
219         ! --------------------------------------------------
220         !
221         ! if runoff condition: change river flow we read (in m3/s) into barotropic velocity (m/s)
222         IF( cn_tra(jbdy) == 'runoff' .AND. TRIM(bf_alias(jp_bdyu2d)%clrootname) /= 'NOT USED' ) THEN   ! runoff and we read u/v2d
223            !
224            igrd = 2                      ! zonal flow (m3/s) to barotropic zonal velocity (m/s)
225            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
226               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
227               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
228               dta_alias%u2d(ib) = dta_alias%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
229            END DO
230            igrd = 3                      ! meridional flow (m3/s) to barotropic meridional velocity (m/s)
231            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
232               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
233               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
234               dta_alias%v2d(ib) = dta_alias%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
235            END DO
236         ENDIF
237
238         ! tidal harmonic forcing ONLY: initialise arrays
239         IF( nn_dyn2d_dta(jbdy) == 2 ) THEN   ! we did not read ssh, u/v2d
240            IF( dta_alias%lneed_ssh   ) dta_alias%ssh(:) = 0._wp
241            IF( dta_alias%lneed_dyn2d ) dta_alias%u2d(:) = 0._wp
242            IF( dta_alias%lneed_dyn2d ) dta_alias%v2d(:) = 0._wp
243         ENDIF
244
245         ! If full velocities in boundary data, then split it into barotropic and baroclinic component
246         IF( bf_alias(jp_bdyu3d)%ltotvel ) THEN     ! if we read 3D total velocity (can be true only if u3d was read)
247            !
248            igrd = 2                       ! zonal velocity
249            dta_alias%u2d(:) = 0._wp       ! compute barotrope zonal velocity and put it in u2d
250            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
251               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
252               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
253               DO ik = 1, jpkm1
254                  dta_alias%u2d(ib) = dta_alias%u2d(ib) + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta_alias%u3d(ib,ik)
255               END DO
256               dta_alias%u2d(ib) =  dta_alias%u2d(ib) * r1_hu_n(ii,ij)
257               DO ik = 1, jpkm1            ! compute barocline zonal velocity and put it in u3d
258                  dta_alias%u3d(ib,ik) = dta_alias%u3d(ib,ik) - dta_alias%u2d(ib)
259               END DO
260            END DO
261            igrd = 3                       ! meridional velocity
262            dta_alias%v2d(:) = 0._wp       ! compute barotrope meridional velocity and put it in v2d
263            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
264               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
265               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
266               DO ik = 1, jpkm1
267                  dta_alias%v2d(ib) = dta_alias%v2d(ib) + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta_alias%v3d(ib,ik)
268               END DO
269               dta_alias%v2d(ib) =  dta_alias%v2d(ib) * r1_hv_n(ii,ij)
270               DO ik = 1, jpkm1            ! compute barocline meridional velocity and put it in v3d
271                  dta_alias%v3d(ib,ik) = dta_alias%v3d(ib,ik) - dta_alias%v2d(ib)
272               END DO
273            END DO
274         ENDIF   ! ltotvel
275
276         !  atm surface pressure : add inverted barometer effect to ssh if it was read
277         IF ( ln_apr_obc .AND. TRIM(bf_alias(jp_bdyssh)%clrootname) /= 'NOT USED' ) THEN
278            igrd = 1
279            DO ib = 1, idx_bdy(jbdy)%nblenrim(igrd)   ! ssh is used only on the rim
280               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
281               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
282               dta_alias%ssh(ib) = dta_alias%ssh(ib) + ssh_ib(ii,ij)
283            END DO
284         ENDIF
285
286#if defined key_si3
287         IF( dta_alias%lneed_ice ) THEN
288            ! fill temperature and salinity arrays
289            IF( TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyt_i)%fnow(:,1,:) = rice_tem (jbdy)
290            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyt_s)%fnow(:,1,:) = rice_tem (jbdy)
291            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' )   bf_alias(jp_bdytsu)%fnow(:,1,:) = rice_tem (jbdy)
292            IF( TRIM(bf_alias(jp_bdys_i)%clrootname) == 'NOT USED' )   bf_alias(jp_bdys_i)%fnow(:,1,:) = rice_sal (jbdy)
293            IF( TRIM(bf_alias(jp_bdyaip)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyaip)%fnow(:,1,:) = rice_apnd(jbdy) * & ! rice_apnd is the pond fraction
294               &                                                                         bf_alias(jp_bdya_i)%fnow(:,1,:)     !   ( a_ip = rice_apnd * a_i )
295            IF( TRIM(bf_alias(jp_bdyhip)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyhip)%fnow(:,1,:) = rice_hpnd(jbdy)
296            ! if T_su is read and not T_i, set T_i = (T_su + T_freeze)/2
297            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' ) &
298               &   bf_alias(jp_bdyt_i)%fnow(:,1,:) = 0.5_wp * ( bf_alias(jp_bdytsu)%fnow(:,1,:) + 271.15 )
299            ! if T_su is read and not T_s, set T_s = T_su
300            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' ) &
301               &   bf_alias(jp_bdyt_s)%fnow(:,1,:) = bf_alias(jp_bdytsu)%fnow(:,1,:)
302            ! if T_s is read and not T_su, set T_su = T_s
303            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' ) &
304               &   bf_alias(jp_bdytsu)%fnow(:,1,:) = bf_alias(jp_bdyt_s)%fnow(:,1,:)
305            ! if T_s is read and not T_i, set T_i = (T_s + T_freeze)/2
306            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' ) &
307               &   bf_alias(jp_bdyt_i)%fnow(:,1,:) = 0.5_wp * ( bf_alias(jp_bdyt_s)%fnow(:,1,:) + 271.15 )
308
309            ! make sure ponds = 0 if no ponds scheme
310            IF ( .NOT.ln_pnd ) THEN
311               bf_alias(jp_bdyaip)%fnow(:,1,:) = 0._wp
312               bf_alias(jp_bdyhip)%fnow(:,1,:) = 0._wp
313            ENDIF
314           
315            ! convert N-cat fields (input) into jpl-cat (output)
316            ipl = SIZE(bf_alias(jp_bdya_i)%fnow, 3)           
317            IF( ipl /= jpl ) THEN      ! ice: convert N-cat fields (input) into jpl-cat (output)
318               CALL ice_var_itd( bf_alias(jp_bdyh_i)%fnow(:,1,:), bf_alias(jp_bdyh_s)%fnow(:,1,:), bf_alias(jp_bdya_i)%fnow(:,1,:), &
319                  &              dta_alias%h_i                  , dta_alias%h_s                  , dta_alias%a_i                  , &
320                  &              bf_alias(jp_bdyt_i)%fnow(:,1,:), bf_alias(jp_bdyt_s)%fnow(:,1,:), &
321                  &              bf_alias(jp_bdytsu)%fnow(:,1,:), bf_alias(jp_bdys_i)%fnow(:,1,:), &
322                  &              bf_alias(jp_bdyaip)%fnow(:,1,:), bf_alias(jp_bdyhip)%fnow(:,1,:), &
323                  &              dta_alias%t_i                  , dta_alias%t_s                  , &
324                  &              dta_alias%tsu                  , dta_alias%s_i                  , &
325                  &              dta_alias%aip                  , dta_alias%hip )
326            ENDIF
327         ENDIF
328#endif
329      END DO  ! jbdy
330
331      IF ( ln_tide ) THEN
332         IF (ln_dynspg_ts) THEN      ! Fill temporary arrays with slow-varying bdy data                           
333            DO jbdy = 1, nb_bdy      ! Tidal component added in ts loop
334               IF ( nn_dyn2d_dta(jbdy) .GE. 2 ) THEN
335                  nblen => idx_bdy(jbdy)%nblen
336                  nblenrim => idx_bdy(jbdy)%nblenrim
337                  IF( cn_dyn2d(jbdy) == 'frs' ) THEN ; ilen1(:)=nblen(:) ; ELSE ; ilen1(:)=nblenrim(:) ; ENDIF
338                     IF ( dta_bdy(jbdy)%lneed_ssh   ) dta_bdy_s(jbdy)%ssh(1:ilen1(1)) = dta_bdy(jbdy)%ssh(1:ilen1(1))
339                     IF ( dta_bdy(jbdy)%lneed_dyn2d ) dta_bdy_s(jbdy)%u2d(1:ilen1(2)) = dta_bdy(jbdy)%u2d(1:ilen1(2))
340                     IF ( dta_bdy(jbdy)%lneed_dyn2d ) dta_bdy_s(jbdy)%v2d(1:ilen1(3)) = dta_bdy(jbdy)%v2d(1:ilen1(3))
341                  ENDIF
342               END DO
343            ELSE ! Add tides if not split-explicit free surface else this is done in ts loop
344               !
345               CALL bdy_dta_tides( kt=kt, kt_offset=kt_offset )
346            ENDIF
347         ENDIF
348         !
349         IF( ln_timing )   CALL timing_stop('bdy_dta')
350         !
351      END SUBROUTINE bdy_dta
352
353
354   SUBROUTINE bdy_dta_init
355      !!----------------------------------------------------------------------
356      !!                   ***  SUBROUTINE bdy_dta_init  ***
357      !!                   
358      !! ** Purpose :   Initialise arrays for reading of external data
359      !!                for open boundary conditions
360      !!
361      !! ** Method  :   
362      !!               
363      !!----------------------------------------------------------------------
364      INTEGER ::   jbdy, jfld    ! Local integers
365      INTEGER ::   ierror, ios     !
366      !
367      INTEGER ::   nbdy_rdstart, nbdy_loc
368      CHARACTER(LEN=50)                      ::   cerrmsg       ! error string
369      CHARACTER(len=3)                       ::   cl3           !
370      CHARACTER(len=100)                     ::   cn_dir        ! Root directory for location of data files
371      LOGICAL                                ::   ln_full_vel   ! =T => full velocities in 3D boundary data
372      !                                                         ! =F => baroclinic velocities in 3D boundary data
373      LOGICAL                                ::   ln_zinterp    ! =T => requires a vertical interpolation of the bdydta
374      REAL(wp)                               ::   rn_ice_tem, rn_ice_sal, rn_ice_age, rn_ice_apnd, rn_ice_hpnd 
375      INTEGER                                ::   ipk,ipl       !
376      INTEGER                                ::   idvar         ! variable ID
377      INTEGER                                ::   indims        ! number of dimensions of the variable
378      INTEGER                                ::   iszdim        ! number of dimensions of the variable
379      INTEGER, DIMENSION(4)                  ::   i4dimsz       ! size of variable dimensions
380      INTEGER                                ::   igrd          ! index for grid type (1,2,3 = T,U,V)
381      LOGICAL                                ::   lluld         ! is the variable using the unlimited dimension
382      LOGICAL                                ::   llneed        !
383      LOGICAL                                ::   llread        !
384      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_tem, bn_sal, bn_u3d, bn_v3d   ! must be an array to be used with fld_fill
385      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_ssh, bn_u2d, bn_v2d           ! informations about the fields to be read
386      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_a_i, bn_h_i, bn_h_s, bn_t_i, bn_t_s, bn_tsu, bn_s_i, bn_aip, bn_hip       
387      TYPE(FLD_N), DIMENSION(:), POINTER ::   bn_alias                        ! must be an array to be used with fld_fill
388      TYPE(FLD  ), DIMENSION(:), POINTER ::   bf_alias
389      !
390      NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d 
391      NAMELIST/nambdy_dta/ bn_a_i, bn_h_i, bn_h_s, bn_t_i, bn_t_s, bn_tsu, bn_s_i, bn_aip, bn_hip
392      NAMELIST/nambdy_dta/ rn_ice_tem, rn_ice_sal, rn_ice_age, rn_ice_apnd, rn_ice_hpnd
393      NAMELIST/nambdy_dta/ ln_full_vel, ln_zinterp
394      !!---------------------------------------------------------------------------
395      !
396      IF(lwp) WRITE(numout,*)
397      IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
398      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
399      IF(lwp) WRITE(numout,*) ''
400
401      ALLOCATE( bf(jpbdyfld,nb_bdy), STAT=ierror )
402      IF( ierror > 0 ) THEN   
403         CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' )   ;   RETURN 
404      ENDIF
405      bf(:,:)%clrootname = 'NOT USED'   ! default definition used as a flag in fld_read to do nothing.
406      bf(:,:)%lzint      = .FALSE.      ! default definition
407      bf(:,:)%ltotvel    = .FALSE.      ! default definition
408 
409      ! Read namelists
410      ! --------------
411      nbdy_rdstart = 1
412      DO jbdy = 1, nb_bdy
413
414         WRITE(ctmp1, '(a,i2)') 'BDY number ', jbdy
415         WRITE(ctmp2, '(a,i2)') 'block nambdy_dta number ', jbdy
416
417         ! There is only one nambdy_dta block in namelist_ref -> use it for each bdy so we read from the beginning
418         READ  ( numnam_ref, nambdy_dta, IOSTAT = ios, ERR = 901)
419901      IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy_dta in reference namelist' )
420
421         !   by-pass nambdy_dta reading if no input data used in this bdy   
422         IF(       ( dta_bdy(jbdy)%lneed_dyn2d .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1 )   &
423            & .OR. ( dta_bdy(jbdy)%lneed_dyn3d .AND.     nn_dyn3d_dta(jbdy)    == 1 )   &
424            & .OR. ( dta_bdy(jbdy)%lneed_tra   .AND.       nn_tra_dta(jbdy)    == 1 )   &
425            & .OR. ( dta_bdy(jbdy)%lneed_ice   .AND.       nn_ice_dta(jbdy)    == 1 )   )   THEN
426            !
427            ! Need to support possibility of reading more than one
428            ! nambdy_dta from the namelist_cfg internal file.
429            ! Do this by finding the jbdy'th occurence of nambdy_dta in the
430            ! character buffer as the starting point.
431            !
432            nbdy_loc = INDEX( numnam_cfg( nbdy_rdstart: ), 'nambdy_dta' )
433            IF( nbdy_loc .GT. 0 ) THEN
434               nbdy_rdstart = nbdy_rdstart + nbdy_loc
435            ELSE
436               WRITE(cerrmsg,'(A,I4,A)') 'Error: entry number ',jbdy,' of nambdy_dta not found'
437               ios = -1
438               CALL ctl_nam ( ios , cerrmsg )
439            ENDIF
440            READ  ( numnam_cfg( MAX( 1, nbdy_rdstart - 2 ): ), nambdy_dta, IOSTAT = ios, ERR = 902)
441902         IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy_dta in configuration namelist' )
442            IF(lwm) WRITE( numond, nambdy_dta )           
443         ENDIF
444
445         ! get the number of ice categories in bdy data file (use a_i information to do this)
446         ipl = jpl   ! default definition
447         IF( dta_bdy(jbdy)%lneed_ice ) THEN    ! if we need ice bdy data
448            IF( nn_ice_dta(jbdy) == 1 ) THEN   ! if we get ice bdy data from netcdf file
449               CALL fld_fill(  bf(jp_bdya_i,jbdy:jbdy), bn_a_i, cn_dir, 'bdy_dta', 'a_i'//' '//ctmp1, ctmp2 )   ! use namelist info
450               CALL fld_clopn( bf(jp_bdya_i,jbdy), nyear, nmonth, nday )   ! not a problem when we call it again after
451               idvar = iom_varid( bf(jp_bdya_i,jbdy)%num, bf(jp_bdya_i,jbdy)%clvar, kndims=indims, kdimsz=i4dimsz, lduld=lluld )
452               IF( indims == 4 .OR. ( indims == 3 .AND. .NOT. lluld ) ) THEN   ;   ipl = i4dimsz(3)   ! xylt or xyl
453               ELSE                                                            ;   ipl = 1            ! xy or xyt
454               ENDIF
455               bf(jp_bdya_i,jbdy)%clrootname = 'NOT USED'   ! reset to default value as this subdomain may not need to read this bdy
456            ENDIF
457         ENDIF
458
459#if defined key_si3
460         IF( .NOT.ln_pnd ) THEN
461            rn_ice_apnd = 0. ; rn_ice_hpnd = 0.
462            CALL ctl_warn( 'rn_ice_apnd & rn_ice_hpnd = 0 when no ponds' )
463         ENDIF
464#endif
465
466         ! temp, salt, age and ponds of incoming ice
467         rice_tem (jbdy) = rn_ice_tem
468         rice_sal (jbdy) = rn_ice_sal
469         rice_age (jbdy) = rn_ice_age
470         rice_apnd(jbdy) = rn_ice_apnd
471         rice_hpnd(jbdy) = rn_ice_hpnd
472         
473         
474         DO jfld = 1, jpbdyfld
475
476            ! =====================
477            !          ssh
478            ! =====================
479            IF( jfld == jp_bdyssh ) THEN
480               cl3 = 'ssh'
481               igrd = 1                                                    ! T point
482               ipk = 1                                                     ! surface data
483               llneed = dta_bdy(jbdy)%lneed_ssh                            ! dta_bdy(jbdy)%ssh will be needed
484               llread = MOD(nn_dyn2d_dta(jbdy),2) == 1                     ! get data from NetCDF file
485               bf_alias => bf(jp_bdyssh,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
486               bn_alias => bn_ssh                                          ! alias for ssh structure of nambdy_dta
487               iszdim = idx_bdy(jbdy)%nblenrim(igrd)                       ! length of this bdy on this MPI processus : used only on the rim
488            ENDIF
489            ! =====================
490            !         dyn2d
491            ! =====================
492            IF( jfld == jp_bdyu2d ) THEN
493               cl3 = 'u2d'
494               igrd = 2                                                    ! U point
495               ipk = 1                                                     ! surface data
496               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%ssh will be needed
497               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get u2d from u3d and read NetCDF file
498               bf_alias => bf(jp_bdyu2d,jbdy:jbdy)                         ! alias for u2d structure of bdy number jbdy
499               bn_alias => bn_u2d                                          ! alias for u2d structure of nambdy_dta
500               IF( ln_full_vel ) THEN  ;   iszdim = idx_bdy(jbdy)%nblen(igrd)      ! will be computed from u3d -> need on the full bdy
501               ELSE                    ;   iszdim = idx_bdy(jbdy)%nblenrim(igrd)   ! used only on the rim
502               ENDIF
503            ENDIF
504            IF( jfld == jp_bdyv2d ) THEN
505               cl3 = 'v2d'
506               igrd = 3                                                    ! V point
507               ipk = 1                                                     ! surface data
508               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%ssh will be needed
509               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get v2d from v3d and read NetCDF file
510               bf_alias => bf(jp_bdyv2d,jbdy:jbdy)                         ! alias for v2d structure of bdy number jbdy
511               bn_alias => bn_v2d                                          ! alias for v2d structure of nambdy_dta
512               IF( ln_full_vel ) THEN  ;   iszdim = idx_bdy(jbdy)%nblen(igrd)      ! will be computed from v3d -> need on the full bdy
513               ELSE                    ;   iszdim = idx_bdy(jbdy)%nblenrim(igrd)   ! used only on the rim
514               ENDIF
515            ENDIF
516            ! =====================
517            !         dyn3d
518            ! =====================
519            IF( jfld == jp_bdyu3d ) THEN
520               cl3 = 'u3d'
521               igrd = 2                                                    ! U point
522               ipk = jpk                                                   ! 3d data
523               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%u3d will be needed
524                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   u3d needed to compute u2d
525               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
526               bf_alias => bf(jp_bdyu3d,jbdy:jbdy)                         ! alias for u3d structure of bdy number jbdy
527               bn_alias => bn_u3d                                          ! alias for u3d structure of nambdy_dta
528               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
529           ENDIF
530            IF( jfld == jp_bdyv3d ) THEN
531               cl3 = 'v3d'
532               igrd = 3                                                    ! V point
533               ipk = jpk                                                   ! 3d data
534               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%v3d will be needed
535                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   v3d needed to compute v2d
536               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
537               bf_alias => bf(jp_bdyv3d,jbdy:jbdy)                         ! alias for v3d structure of bdy number jbdy
538               bn_alias => bn_v3d                                          ! alias for v3d structure of nambdy_dta
539               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
540           ENDIF
541
542            ! =====================
543            !          tra
544            ! =====================
545            IF( jfld == jp_bdytem ) THEN
546               cl3 = 'tem'
547               igrd = 1                                                    ! T point
548               ipk = jpk                                                   ! 3d data
549               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%tem will be needed
550               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
551               bf_alias => bf(jp_bdytem,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
552               bn_alias => bn_tem                                          ! alias for ssh structure of nambdy_dta
553               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
554            ENDIF
555            IF( jfld == jp_bdysal ) THEN
556               cl3 = 'sal'
557               igrd = 1                                                    ! T point
558               ipk = jpk                                                   ! 3d data
559               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%sal will be needed
560               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
561               bf_alias => bf(jp_bdysal,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
562               bn_alias => bn_sal                                          ! alias for ssh structure of nambdy_dta
563               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
564            ENDIF
565
566            ! =====================
567            !          ice
568            ! =====================
569            IF(  jfld == jp_bdya_i .OR. jfld == jp_bdyh_i .OR. jfld == jp_bdyh_s .OR. &
570               & jfld == jp_bdyt_i .OR. jfld == jp_bdyt_s .OR. jfld == jp_bdytsu .OR. &
571               & jfld == jp_bdys_i .OR. jfld == jp_bdyaip .OR. jfld == jp_bdyhip      ) THEN
572               igrd = 1                                                    ! T point
573               ipk = ipl                                                   ! jpl-cat data
574               llneed = dta_bdy(jbdy)%lneed_ice                            ! ice will be needed
575               llread = nn_ice_dta(jbdy) == 1                              ! get data from NetCDF file
576               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
577            ENDIF
578            IF( jfld == jp_bdya_i ) THEN
579               cl3 = 'a_i'
580               bf_alias => bf(jp_bdya_i,jbdy:jbdy)                         ! alias for a_i structure of bdy number jbdy
581               bn_alias => bn_a_i                                          ! alias for a_i structure of nambdy_dta
582            ENDIF
583            IF( jfld == jp_bdyh_i ) THEN
584               cl3 = 'h_i'
585               bf_alias => bf(jp_bdyh_i,jbdy:jbdy)                         ! alias for h_i structure of bdy number jbdy
586               bn_alias => bn_h_i                                          ! alias for h_i structure of nambdy_dta
587            ENDIF
588            IF( jfld == jp_bdyh_s ) THEN
589               cl3 = 'h_s'
590               bf_alias => bf(jp_bdyh_s,jbdy:jbdy)                         ! alias for h_s structure of bdy number jbdy
591               bn_alias => bn_h_s                                          ! alias for h_s structure of nambdy_dta
592            ENDIF
593            IF( jfld == jp_bdyt_i ) THEN
594               cl3 = 't_i'
595               bf_alias => bf(jp_bdyt_i,jbdy:jbdy)                         ! alias for t_i structure of bdy number jbdy
596               bn_alias => bn_t_i                                          ! alias for t_i structure of nambdy_dta
597            ENDIF
598            IF( jfld == jp_bdyt_s ) THEN
599               cl3 = 't_s'
600               bf_alias => bf(jp_bdyt_s,jbdy:jbdy)                         ! alias for t_s structure of bdy number jbdy
601               bn_alias => bn_t_s                                          ! alias for t_s structure of nambdy_dta
602            ENDIF
603            IF( jfld == jp_bdytsu ) THEN
604               cl3 = 'tsu'
605               bf_alias => bf(jp_bdytsu,jbdy:jbdy)                         ! alias for tsu structure of bdy number jbdy
606               bn_alias => bn_tsu                                          ! alias for tsu structure of nambdy_dta
607            ENDIF
608            IF( jfld == jp_bdys_i ) THEN
609               cl3 = 's_i'
610               bf_alias => bf(jp_bdys_i,jbdy:jbdy)                         ! alias for s_i structure of bdy number jbdy
611               bn_alias => bn_s_i                                          ! alias for s_i structure of nambdy_dta
612            ENDIF
613            IF( jfld == jp_bdyaip ) THEN
614               cl3 = 'aip'
615               bf_alias => bf(jp_bdyaip,jbdy:jbdy)                         ! alias for aip structure of bdy number jbdy
616               bn_alias => bn_aip                                          ! alias for aip structure of nambdy_dta
617            ENDIF
618            IF( jfld == jp_bdyhip ) THEN
619               cl3 = 'hip'
620               bf_alias => bf(jp_bdyhip,jbdy:jbdy)                         ! alias for hip structure of bdy number jbdy
621               bn_alias => bn_hip                                          ! alias for hip structure of nambdy_dta
622            ENDIF
623
624            IF( llneed .AND. iszdim > 0 ) THEN                             ! dta_bdy(jbdy)%xxx will be needed
625               !                                                           !   -> must be associated with an allocated target
626               ALLOCATE( bf_alias(1)%fnow( iszdim, 1, ipk ) )              ! allocate the target
627               !
628               IF( llread ) THEN                                           ! get data from NetCDF file
629                  CALL fld_fill( bf_alias, bn_alias, cn_dir, 'bdy_dta', cl3//' '//ctmp1, ctmp2 )   ! use namelist info
630                  IF( bf_alias(1)%ln_tint ) ALLOCATE( bf_alias(1)%fdta( iszdim, 1, ipk, 2 ) )
631                  bf_alias(1)%imap    => idx_bdy(jbdy)%nbmap(1:iszdim,igrd)   ! associate the mapping used for this bdy
632                  bf_alias(1)%igrd    = igrd                                  ! used only for vertical integration of 3D arrays
633                  bf_alias(1)%ibdy    = jbdy                                  !  "    "    "     "          "      "  "    "   
634                  bf_alias(1)%ltotvel = ln_full_vel                           ! T if u3d is full velocity
635                  bf_alias(1)%lzint   = ln_zinterp                            ! T if it requires a vertical interpolation
636               ENDIF
637
638               ! associate the pointer and get rid of the dimensions with a size equal to 1
639               IF( jfld == jp_bdyssh )        dta_bdy(jbdy)%ssh => bf_alias(1)%fnow(:,1,1)
640               IF( jfld == jp_bdyu2d )        dta_bdy(jbdy)%u2d => bf_alias(1)%fnow(:,1,1)
641               IF( jfld == jp_bdyv2d )        dta_bdy(jbdy)%v2d => bf_alias(1)%fnow(:,1,1)
642               IF( jfld == jp_bdyu3d )        dta_bdy(jbdy)%u3d => bf_alias(1)%fnow(:,1,:)
643               IF( jfld == jp_bdyv3d )        dta_bdy(jbdy)%v3d => bf_alias(1)%fnow(:,1,:)
644               IF( jfld == jp_bdytem )        dta_bdy(jbdy)%tem => bf_alias(1)%fnow(:,1,:)
645               IF( jfld == jp_bdysal )        dta_bdy(jbdy)%sal => bf_alias(1)%fnow(:,1,:)
646               IF( jfld == jp_bdya_i ) THEN
647                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%a_i => bf_alias(1)%fnow(:,1,:)
648                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%a_i(iszdim,jpl) )
649                  ENDIF
650               ENDIF
651               IF( jfld == jp_bdyh_i ) THEN
652                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_i => bf_alias(1)%fnow(:,1,:)
653                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_i(iszdim,jpl) )
654                  ENDIF
655               ENDIF
656               IF( jfld == jp_bdyh_s ) THEN
657                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_s => bf_alias(1)%fnow(:,1,:)
658                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_s(iszdim,jpl) )
659                  ENDIF
660               ENDIF
661               IF( jfld == jp_bdyt_i ) THEN
662                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%t_i => bf_alias(1)%fnow(:,1,:)
663                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%t_i(iszdim,jpl) )
664                  ENDIF
665               ENDIF
666               IF( jfld == jp_bdyt_s ) THEN
667                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%t_s => bf_alias(1)%fnow(:,1,:)
668                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%t_s(iszdim,jpl) )
669                  ENDIF
670               ENDIF
671               IF( jfld == jp_bdytsu ) THEN
672                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%tsu => bf_alias(1)%fnow(:,1,:)
673                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%tsu(iszdim,jpl) )
674                  ENDIF
675               ENDIF
676               IF( jfld == jp_bdys_i ) THEN
677                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%s_i => bf_alias(1)%fnow(:,1,:)
678                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%s_i(iszdim,jpl) )
679                  ENDIF
680               ENDIF
681               IF( jfld == jp_bdyaip ) THEN
682                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%aip => bf_alias(1)%fnow(:,1,:)
683                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%aip(iszdim,jpl) )
684                  ENDIF
685               ENDIF
686               IF( jfld == jp_bdyhip ) THEN
687                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%hip => bf_alias(1)%fnow(:,1,:)
688                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%hip(iszdim,jpl) )
689                  ENDIF
690               ENDIF
691            ENDIF
692
693         END DO   ! jpbdyfld
694         !
695      END DO ! jbdy
696      !
697   END SUBROUTINE bdy_dta_init
698   
699   !!==============================================================================
700END MODULE bdydta
Note: See TracBrowser for help on using the repository browser.