New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diahsb.F90 in NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/OCE/DIA – NEMO

source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/OCE/DIA/diahsb.F90 @ 12166

Last change on this file since 12166 was 12166, checked in by cetlod, 4 years ago

dev_merge_option2 : merge in ENHANCE-02_ISF_nemo branch

  • Property svn:keywords set to Id
File size: 22.6 KB
Line 
1MODULE diahsb
2   !!======================================================================
3   !!                       ***  MODULE  diahsb  ***
4   !! Ocean diagnostics: Heat, salt and volume budgets
5   !!======================================================================
6   !! History :  3.3  ! 2010-09  (M. Leclair)  Original code
7   !!                 ! 2012-10  (C. Rousset)  add iom_put
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   dia_hsb       : Diagnose the conservation of ocean heat and salt contents, and volume
12   !!   dia_hsb_rst   : Read or write DIA file in restart file
13   !!   dia_hsb_init  : Initialization of the conservation diagnostic
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE phycst         ! physical constants
18   USE sbc_oce        ! surface thermohaline fluxes
19   USE isf_oce        ! ice shelf fluxes
20   USE sbcrnf         ! river runoff
21   USE domvvl         ! vertical scale factors
22   USE traqsr         ! penetrative solar radiation
23   USE trabbc         ! bottom boundary condition
24   USE trabbc         ! bottom boundary condition
25   USE restart        ! ocean restart
26   USE bdy_oce , ONLY : ln_bdy
27   !
28   USE iom            ! I/O manager
29   USE in_out_manager ! I/O manager
30   USE lib_fortran    ! glob_sum
31   USE lib_mpp        ! distributed memory computing library
32   USE timing         ! preformance summary
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   dia_hsb        ! routine called by step.F90
38   PUBLIC   dia_hsb_init   ! routine called by nemogcm.F90
39
40   LOGICAL, PUBLIC ::   ln_diahsb   !: check the heat and salt budgets
41
42   REAL(wp) ::   surf_tot              ! ocean surface
43   REAL(wp) ::   frc_t, frc_s, frc_v   ! global forcing trends
44   REAL(wp) ::   frc_wn_t, frc_wn_s    ! global forcing trends
45   !
46   REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   surf 
47   REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   surf_ini      , ssh_ini          !
48   REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   ssh_hc_loc_ini, ssh_sc_loc_ini   !
49   REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   hc_loc_ini, sc_loc_ini, e3t_ini  !
50   REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   tmask_ini
51
52   !! * Substitutions
53#  include "vectopt_loop_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
56   !! $Id$
57   !! Software governed by the CeCILL license (see ./LICENSE)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   SUBROUTINE dia_hsb( kt )
62      !!---------------------------------------------------------------------------
63      !!                  ***  ROUTINE dia_hsb  ***
64      !!     
65      !! ** Purpose: Compute the ocean global heat content, salt content and volume conservation
66      !!
67      !! ** Method : - Compute the deviation of heat content, salt content and volume
68      !!             at the current time step from their values at nit000
69      !!             - Compute the contribution of forcing and remove it from these deviations
70      !!
71      !!---------------------------------------------------------------------------
72      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
73      !
74      INTEGER    ::   ji, jj, jk                  ! dummy loop indice
75      REAL(wp)   ::   zdiff_hc    , zdiff_sc      ! heat and salt content variations
76      REAL(wp)   ::   zdiff_hc1   , zdiff_sc1     !  -         -     -        -
77      REAL(wp)   ::   zdiff_v1    , zdiff_v2      ! volume variation
78      REAL(wp)   ::   zerr_hc1    , zerr_sc1      ! heat and salt content misfit
79      REAL(wp)   ::   zvol_tot                    ! volume
80      REAL(wp)   ::   z_frc_trd_t , z_frc_trd_s   !    -     -
81      REAL(wp)   ::   z_frc_trd_v                 !    -     -
82      REAL(wp)   ::   z_wn_trd_t , z_wn_trd_s     !    -     -
83      REAL(wp)   ::   z_ssh_hc , z_ssh_sc         !    -     -
84      REAL(wp), DIMENSION(jpi,jpj)       ::   z2d0, z2d1   ! 2D workspace
85      REAL(wp), DIMENSION(jpi,jpj,jpkm1) ::   zwrk         ! 3D workspace
86      !!---------------------------------------------------------------------------
87      IF( ln_timing )   CALL timing_start('dia_hsb')     
88      !
89      tsn(:,:,:,1) = tsn(:,:,:,1) * tmask(:,:,:) ; tsb(:,:,:,1) = tsb(:,:,:,1) * tmask(:,:,:) ;
90      tsn(:,:,:,2) = tsn(:,:,:,2) * tmask(:,:,:) ; tsb(:,:,:,2) = tsb(:,:,:,2) * tmask(:,:,:) ;
91      ! ------------------------- !
92      ! 1 - Trends due to forcing !
93      ! ------------------------- !
94      z_frc_trd_v = r1_rau0 * glob_sum( 'diahsb', - ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) ) * surf(:,:) )   ! volume fluxes
95      z_frc_trd_t =           glob_sum( 'diahsb', sbc_tsc(:,:,jp_tem) * surf(:,:) )                       ! heat fluxes
96      z_frc_trd_s =           glob_sum( 'diahsb', sbc_tsc(:,:,jp_sal) * surf(:,:) )                       ! salt fluxes
97      !                    !  Add runoff    heat & salt input
98      IF( ln_rnf    )   z_frc_trd_t = z_frc_trd_t + glob_sum( 'diahsb', rnf_tsc(:,:,jp_tem) * surf(:,:) )
99      IF( ln_rnf_sal)   z_frc_trd_s = z_frc_trd_s + glob_sum( 'diahsb', rnf_tsc(:,:,jp_sal) * surf(:,:) )
100      !                    ! Add ice shelf heat & salt input
101      IF( ln_isf    )   z_frc_trd_t = z_frc_trd_t &
102         &                          + glob_sum( 'diahsb', ( risf_cav_tsc(:,:,jp_tem) + risf_par_tsc(:,:,jp_tem) ) * surf(:,:) )
103      !                    ! Add penetrative solar radiation
104      IF( ln_traqsr )   z_frc_trd_t = z_frc_trd_t + r1_rau0_rcp * glob_sum( 'diahsb', qsr     (:,:) * surf(:,:) )
105      !                    ! Add geothermal heat flux
106      IF( ln_trabbc )   z_frc_trd_t = z_frc_trd_t +               glob_sum( 'diahsb', qgh_trd0(:,:) * surf(:,:) )
107      !
108      IF( ln_linssh ) THEN
109         IF( ln_isfcav ) THEN
110            DO ji=1,jpi
111               DO jj=1,jpj
112                  z2d0(ji,jj) = surf(ji,jj) * wn(ji,jj,mikt(ji,jj)) * tsb(ji,jj,mikt(ji,jj),jp_tem)
113                  z2d1(ji,jj) = surf(ji,jj) * wn(ji,jj,mikt(ji,jj)) * tsb(ji,jj,mikt(ji,jj),jp_sal)
114               END DO
115            END DO
116         ELSE
117            z2d0(:,:) = surf(:,:) * wn(:,:,1) * tsb(:,:,1,jp_tem)
118            z2d1(:,:) = surf(:,:) * wn(:,:,1) * tsb(:,:,1,jp_sal)
119         END IF
120         z_wn_trd_t = - glob_sum( 'diahsb', z2d0 ) 
121         z_wn_trd_s = - glob_sum( 'diahsb', z2d1 )
122      ENDIF
123
124      frc_v = frc_v + z_frc_trd_v * rdt
125      frc_t = frc_t + z_frc_trd_t * rdt
126      frc_s = frc_s + z_frc_trd_s * rdt
127      !                                          ! Advection flux through fixed surface (z=0)
128      IF( ln_linssh ) THEN
129         frc_wn_t = frc_wn_t + z_wn_trd_t * rdt
130         frc_wn_s = frc_wn_s + z_wn_trd_s * rdt
131      ENDIF
132
133      ! ------------------------ !
134      ! 2 -  Content variations  !
135      ! ------------------------ !
136      ! glob_sum_full is needed because you keep the full interior domain to compute the sum (iscpl)
137
138      !                    ! volume variation (calculated with ssh)
139      zdiff_v1 = glob_sum_full( 'diahsb', surf(:,:)*sshn(:,:) - surf_ini(:,:)*ssh_ini(:,:) )
140
141      !                    ! heat & salt content variation (associated with ssh)
142      IF( ln_linssh ) THEN       ! linear free surface case
143         IF( ln_isfcav ) THEN          ! ISF case
144            DO ji = 1, jpi
145               DO jj = 1, jpj
146                  z2d0(ji,jj) = surf(ji,jj) * ( tsn(ji,jj,mikt(ji,jj),jp_tem) * sshn(ji,jj) - ssh_hc_loc_ini(ji,jj) ) 
147                  z2d1(ji,jj) = surf(ji,jj) * ( tsn(ji,jj,mikt(ji,jj),jp_sal) * sshn(ji,jj) - ssh_sc_loc_ini(ji,jj) ) 
148               END DO
149            END DO
150         ELSE                          ! no under ice-shelf seas
151            z2d0(:,:) = surf(:,:) * ( tsn(:,:,1,jp_tem) * sshn(:,:) - ssh_hc_loc_ini(:,:) ) 
152            z2d1(:,:) = surf(:,:) * ( tsn(:,:,1,jp_sal) * sshn(:,:) - ssh_sc_loc_ini(:,:) ) 
153         END IF
154         z_ssh_hc = glob_sum_full( 'diahsb', z2d0 ) 
155         z_ssh_sc = glob_sum_full( 'diahsb', z2d1 ) 
156      ENDIF
157      !
158      DO jk = 1, jpkm1           ! volume variation (calculated with scale factors)
159         zwrk(:,:,jk) = surf(:,:)*e3t_n(:,:,jk)*tmask(:,:,jk) - surf_ini(:,:)*e3t_ini(:,:,jk)*tmask_ini(:,:,jk)
160      END DO
161      zdiff_v2 = glob_sum_full( 'diahsb', zwrk(:,:,:) )     ! glob_sum_full needed as tmask and tmask_ini could be different
162      DO jk = 1, jpkm1           ! heat content variation
163         zwrk(:,:,jk) = ( surf(:,:)*e3t_n(:,:,jk)*tsn(:,:,jk,jp_tem) - surf_ini(:,:)*hc_loc_ini(:,:,jk) )
164      END DO
165      zdiff_hc = glob_sum_full( 'diahsb', zwrk(:,:,:) )
166      DO jk = 1, jpkm1           ! salt content variation
167         zwrk(:,:,jk) = ( surf(:,:)*e3t_n(:,:,jk)*tsn(:,:,jk,jp_sal) - surf_ini(:,:)*sc_loc_ini(:,:,jk) )
168      END DO
169      zdiff_sc = glob_sum_full( 'diahsb', zwrk(:,:,:) )
170
171      ! ------------------------ !
172      ! 3 -  Drifts              !
173      ! ------------------------ !
174      zdiff_v1 = zdiff_v1 - frc_v
175      IF( .NOT.ln_linssh )   zdiff_v2 = zdiff_v2 - frc_v
176      zdiff_hc = zdiff_hc - frc_t
177      zdiff_sc = zdiff_sc - frc_s
178      IF( ln_linssh ) THEN
179         zdiff_hc1 = zdiff_hc + z_ssh_hc 
180         zdiff_sc1 = zdiff_sc + z_ssh_sc
181         zerr_hc1  = z_ssh_hc - frc_wn_t
182         zerr_sc1  = z_ssh_sc - frc_wn_s
183      ENDIF
184
185      ! ----------------------- !
186      ! 4 - Diagnostics writing !
187      ! ----------------------- !
188      DO jk = 1, jpkm1           ! total ocean volume (calculated with scale factors)
189         zwrk(:,:,jk) = surf(:,:) * e3t_n(:,:,jk) * tmask(:,:,jk)
190      END DO
191      zvol_tot = glob_sum( 'diahsb', zwrk(:,:,:) )
192
193!!gm to be added ?
194!      IF( ln_linssh ) THEN            ! fixed volume, add the ssh contribution
195!        zvol_tot = zvol_tot + glob_sum( 'diahsb', surf(:,:) * sshn(:,:) )
196!      ENDIF
197!!gm end
198
199      CALL iom_put(   'bgfrcvol' , frc_v    * 1.e-9    )              ! vol - surface forcing (km3)
200      CALL iom_put(   'bgfrctem' , frc_t    * rau0 * rcp * 1.e-20 )   ! hc  - surface forcing (1.e20 J)
201      CALL iom_put(   'bgfrchfx' , frc_t    * rau0 * rcp /  &         ! hc  - surface forcing (W/m2)
202         &                       ( surf_tot * kt * rdt )        )
203      CALL iom_put(   'bgfrcsal' , frc_s    * 1.e-9    )              ! sc  - surface forcing (psu*km3)
204
205      IF( .NOT. ln_linssh ) THEN
206         CALL iom_put( 'bgtemper' , zdiff_hc / zvol_tot )              ! Temperature drift     (C)
207         CALL iom_put( 'bgsaline' , zdiff_sc / zvol_tot )              ! Salinity    drift     (PSU)
208         CALL iom_put( 'bgheatco' , zdiff_hc * 1.e-20 * rau0 * rcp )   ! Heat content drift    (1.e20 J)
209         CALL iom_put( 'bgheatfx' , zdiff_hc * rau0 * rcp /  &         ! Heat flux drift       (W/m2)
210            &                       ( surf_tot * kt * rdt )        )
211         CALL iom_put( 'bgsaltco' , zdiff_sc * 1.e-9    )              ! Salt content drift    (psu*km3)
212         CALL iom_put( 'bgvolssh' , zdiff_v1 * 1.e-9    )              ! volume ssh drift      (km3) 
213         CALL iom_put( 'bgvole3t' , zdiff_v2 * 1.e-9    )              ! volume e3t drift      (km3) 
214         !
215         IF( kt == nitend .AND. lwp ) THEN
216            WRITE(numout,*)
217            WRITE(numout,*) 'dia_hsb : last time step hsb diagnostics: at it= ', kt,' date= ', ndastp
218            WRITE(numout,*) '~~~~~~~'
219            WRITE(numout,*) '   Temperature drift = ', zdiff_hc / zvol_tot, ' C'
220            WRITE(numout,*) '   Salinity    drift = ', zdiff_sc / zvol_tot, ' PSU'
221            WRITE(numout,*) '   volume ssh  drift = ', zdiff_v1 * 1.e-9   , ' km^3'
222            WRITE(numout,*) '   volume e3t  drift = ', zdiff_v2 * 1.e-9   , ' km^3'
223         ENDIF
224         !
225      ELSE
226         CALL iom_put( 'bgtemper' , zdiff_hc1 / zvol_tot)              ! Heat content drift    (C)
227         CALL iom_put( 'bgsaline' , zdiff_sc1 / zvol_tot)              ! Salt content drift    (PSU)
228         CALL iom_put( 'bgheatco' , zdiff_hc1 * 1.e-20 * rau0 * rcp )  ! Heat content drift    (1.e20 J)
229         CALL iom_put( 'bgheatfx' , zdiff_hc1 * rau0 * rcp /  &        ! Heat flux drift       (W/m2)
230            &                       ( surf_tot * kt * rdt )         )
231         CALL iom_put( 'bgsaltco' , zdiff_sc1 * 1.e-9    )             ! Salt content drift    (psu*km3)
232         CALL iom_put( 'bgvolssh' , zdiff_v1 * 1.e-9    )              ! volume ssh drift      (km3) 
233         CALL iom_put( 'bgmistem' , zerr_hc1 / zvol_tot )              ! hc  - error due to free surface (C)
234         CALL iom_put( 'bgmissal' , zerr_sc1 / zvol_tot )              ! sc  - error due to free surface (psu)
235      ENDIF
236      !
237      IF( lrst_oce )   CALL dia_hsb_rst( kt, 'WRITE' )
238      !
239      IF( ln_timing )   CALL timing_stop('dia_hsb')
240      !
241   END SUBROUTINE dia_hsb
242
243
244   SUBROUTINE dia_hsb_rst( kt, cdrw )
245      !!---------------------------------------------------------------------
246      !!                   ***  ROUTINE dia_hsb_rst  ***
247      !!                     
248      !! ** Purpose :   Read or write DIA file in restart file
249      !!
250      !! ** Method  :   use of IOM library
251      !!----------------------------------------------------------------------
252      INTEGER         , INTENT(in) ::   kt     ! ocean time-step
253      CHARACTER(len=*), INTENT(in) ::   cdrw   ! "READ"/"WRITE" flag
254      !
255      INTEGER ::   ji, jj, jk   ! dummy loop indices
256      !!----------------------------------------------------------------------
257      !
258      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
259         IF( ln_rstart ) THEN                   !* Read the restart file
260            !
261            IF(lwp) WRITE(numout,*)
262            IF(lwp) WRITE(numout,*) '   dia_hsb_rst : read hsb restart at it= ', kt,' date= ', ndastp
263            IF(lwp) WRITE(numout,*)
264            CALL iom_get( numror, 'frc_v', frc_v, ldxios = lrxios )
265            CALL iom_get( numror, 'frc_t', frc_t, ldxios = lrxios )
266            CALL iom_get( numror, 'frc_s', frc_s, ldxios = lrxios )
267            IF( ln_linssh ) THEN
268               CALL iom_get( numror, 'frc_wn_t', frc_wn_t, ldxios = lrxios )
269               CALL iom_get( numror, 'frc_wn_s', frc_wn_s, ldxios = lrxios )
270            ENDIF
271            CALL iom_get( numror, jpdom_autoglo, 'surf_ini'  , surf_ini  , ldxios = lrxios ) ! ice sheet coupling
272            CALL iom_get( numror, jpdom_autoglo, 'ssh_ini'   , ssh_ini   , ldxios = lrxios )
273            CALL iom_get( numror, jpdom_autoglo, 'e3t_ini'   , e3t_ini   , ldxios = lrxios )
274            CALL iom_get( numror, jpdom_autoglo, 'tmask_ini' , tmask_ini , ldxios = lrxios )
275            CALL iom_get( numror, jpdom_autoglo, 'hc_loc_ini', hc_loc_ini, ldxios = lrxios )
276            CALL iom_get( numror, jpdom_autoglo, 'sc_loc_ini', sc_loc_ini, ldxios = lrxios )
277            IF( ln_linssh ) THEN
278               CALL iom_get( numror, jpdom_autoglo, 'ssh_hc_loc_ini', ssh_hc_loc_ini, ldxios = lrxios )
279               CALL iom_get( numror, jpdom_autoglo, 'ssh_sc_loc_ini', ssh_sc_loc_ini, ldxios = lrxios )
280            ENDIF
281         ELSE
282            IF(lwp) WRITE(numout,*)
283            IF(lwp) WRITE(numout,*) '   dia_hsb_rst : initialise hsb at initial state '
284            IF(lwp) WRITE(numout,*)
285            surf_ini(:,:) = e1e2t(:,:) * tmask_i(:,:)         ! initial ocean surface
286            ssh_ini(:,:) = sshn(:,:)                          ! initial ssh
287            DO jk = 1, jpk
288              ! if ice sheet/oceqn coupling, need to mask ini variables here (mask could change at the next NEMO instance).
289               e3t_ini   (:,:,jk) = e3t_n(:,:,jk)                      * tmask(:,:,jk)  ! initial vertical scale factors
290               tmask_ini (:,:,jk) = tmask(:,:,jk)                                       ! initial mask
291               hc_loc_ini(:,:,jk) = tsn(:,:,jk,jp_tem) * e3t_n(:,:,jk) * tmask(:,:,jk)  ! initial heat content
292               sc_loc_ini(:,:,jk) = tsn(:,:,jk,jp_sal) * e3t_n(:,:,jk) * tmask(:,:,jk)  ! initial salt content
293            END DO
294            frc_v = 0._wp                                           ! volume       trend due to forcing
295            frc_t = 0._wp                                           ! heat content   -    -   -    -   
296            frc_s = 0._wp                                           ! salt content   -    -   -    -       
297            IF( ln_linssh ) THEN
298               IF( ln_isfcav ) THEN
299                  DO ji = 1, jpi
300                     DO jj = 1, jpj
301                        ssh_hc_loc_ini(ji,jj) = tsn(ji,jj,mikt(ji,jj),jp_tem) * sshn(ji,jj)   ! initial heat content in ssh
302                        ssh_sc_loc_ini(ji,jj) = tsn(ji,jj,mikt(ji,jj),jp_sal) * sshn(ji,jj)   ! initial salt content in ssh
303                     END DO
304                   END DO
305                ELSE
306                  ssh_hc_loc_ini(:,:) = tsn(:,:,1,jp_tem) * sshn(:,:)   ! initial heat content in ssh
307                  ssh_sc_loc_ini(:,:) = tsn(:,:,1,jp_sal) * sshn(:,:)   ! initial salt content in ssh
308               END IF
309               frc_wn_t = 0._wp                                       ! initial heat content misfit due to free surface
310               frc_wn_s = 0._wp                                       ! initial salt content misfit due to free surface
311            ENDIF
312         ENDIF
313         !
314      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
315         !                                   ! -------------------
316         IF(lwp) WRITE(numout,*)
317         IF(lwp) WRITE(numout,*) '   dia_hsb_rst : write restart at it= ', kt,' date= ', ndastp
318         IF(lwp) WRITE(numout,*)
319         !
320         IF( lwxios ) CALL iom_swap(      cwxios_context          )
321         CALL iom_rstput( kt, nitrst, numrow, 'frc_v', frc_v, ldxios = lwxios )
322         CALL iom_rstput( kt, nitrst, numrow, 'frc_t', frc_t, ldxios = lwxios )
323         CALL iom_rstput( kt, nitrst, numrow, 'frc_s', frc_s, ldxios = lwxios )
324         IF( ln_linssh ) THEN
325            CALL iom_rstput( kt, nitrst, numrow, 'frc_wn_t', frc_wn_t, ldxios = lwxios )
326            CALL iom_rstput( kt, nitrst, numrow, 'frc_wn_s', frc_wn_s, ldxios = lwxios )
327         ENDIF
328         CALL iom_rstput( kt, nitrst, numrow, 'surf_ini'  , surf_ini  , ldxios = lwxios )      ! ice sheet coupling
329         CALL iom_rstput( kt, nitrst, numrow, 'ssh_ini'   , ssh_ini   , ldxios = lwxios )
330         CALL iom_rstput( kt, nitrst, numrow, 'e3t_ini'   , e3t_ini   , ldxios = lwxios )
331         CALL iom_rstput( kt, nitrst, numrow, 'tmask_ini' , tmask_ini , ldxios = lwxios )
332         CALL iom_rstput( kt, nitrst, numrow, 'hc_loc_ini', hc_loc_ini, ldxios = lwxios )
333         CALL iom_rstput( kt, nitrst, numrow, 'sc_loc_ini', sc_loc_ini, ldxios = lwxios )
334         IF( ln_linssh ) THEN
335            CALL iom_rstput( kt, nitrst, numrow, 'ssh_hc_loc_ini', ssh_hc_loc_ini, ldxios = lwxios )
336            CALL iom_rstput( kt, nitrst, numrow, 'ssh_sc_loc_ini', ssh_sc_loc_ini, ldxios = lwxios )
337         ENDIF
338         IF( lwxios ) CALL iom_swap(      cxios_context          )
339         !
340      ENDIF
341      !
342   END SUBROUTINE dia_hsb_rst
343
344
345   SUBROUTINE dia_hsb_init
346      !!---------------------------------------------------------------------------
347      !!                  ***  ROUTINE dia_hsb  ***
348      !!     
349      !! ** Purpose: Initialization for the heat salt volume budgets
350      !!
351      !! ** Method : Compute initial heat content, salt content and volume
352      !!
353      !! ** Action : - Compute initial heat content, salt content and volume
354      !!             - Initialize forcing trends
355      !!             - Compute coefficients for conversion
356      !!---------------------------------------------------------------------------
357      INTEGER ::   ierror, ios   ! local integer
358      !!
359      NAMELIST/namhsb/ ln_diahsb
360      !!----------------------------------------------------------------------
361      !
362      IF(lwp) THEN
363         WRITE(numout,*)
364         WRITE(numout,*) 'dia_hsb_init : heat and salt budgets diagnostics'
365         WRITE(numout,*) '~~~~~~~~~~~~ '
366      ENDIF
367      REWIND( numnam_ref )              ! Namelist namhsb in reference namelist
368      READ  ( numnam_ref, namhsb, IOSTAT = ios, ERR = 901)
369901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namhsb in reference namelist' )
370      REWIND( numnam_cfg )              ! Namelist namhsb in configuration namelist
371      READ  ( numnam_cfg, namhsb, IOSTAT = ios, ERR = 902 )
372902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namhsb in configuration namelist' )
373      IF(lwm) WRITE( numond, namhsb )
374
375      IF(lwp) THEN
376         WRITE(numout,*) '   Namelist  namhsb :'
377         WRITE(numout,*) '      check the heat and salt budgets (T) or not (F)       ln_diahsb = ', ln_diahsb
378      ENDIF
379      !
380      IF( .NOT. ln_diahsb )   RETURN
381
382      IF(lwxios) THEN
383! define variables in restart file when writing with XIOS
384        CALL iom_set_rstw_var_active('frc_v')
385        CALL iom_set_rstw_var_active('frc_t')
386        CALL iom_set_rstw_var_active('frc_s')
387        CALL iom_set_rstw_var_active('surf_ini')
388        CALL iom_set_rstw_var_active('ssh_ini')
389        CALL iom_set_rstw_var_active('e3t_ini')
390        CALL iom_set_rstw_var_active('hc_loc_ini')
391        CALL iom_set_rstw_var_active('sc_loc_ini')
392        IF( ln_linssh ) THEN
393           CALL iom_set_rstw_var_active('ssh_hc_loc_ini')
394           CALL iom_set_rstw_var_active('ssh_sc_loc_ini')
395           CALL iom_set_rstw_var_active('frc_wn_t')
396           CALL iom_set_rstw_var_active('frc_wn_s')
397        ENDIF
398      ENDIF
399      ! ------------------- !
400      ! 1 - Allocate memory !
401      ! ------------------- !
402      ALLOCATE( hc_loc_ini(jpi,jpj,jpk), sc_loc_ini(jpi,jpj,jpk), surf_ini(jpi,jpj), &
403         &      e3t_ini(jpi,jpj,jpk), surf(jpi,jpj),  ssh_ini(jpi,jpj), tmask_ini(jpi,jpj,jpk),STAT=ierror  )
404      IF( ierror > 0 ) THEN
405         CALL ctl_stop( 'dia_hsb_init: unable to allocate hc_loc_ini' )   ;   RETURN
406      ENDIF
407
408      IF( ln_linssh )   ALLOCATE( ssh_hc_loc_ini(jpi,jpj), ssh_sc_loc_ini(jpi,jpj),STAT=ierror )
409      IF( ierror > 0 ) THEN
410         CALL ctl_stop( 'dia_hsb: unable to allocate ssh_hc_loc_ini' )   ;   RETURN
411      ENDIF
412
413      ! ----------------------------------------------- !
414      ! 2 - Time independant variables and file opening !
415      ! ----------------------------------------------- !
416      surf(:,:) = e1e2t(:,:) * tmask_i(:,:)               ! masked surface grid cell area
417      surf_tot  = glob_sum( 'diahsb', surf(:,:) )         ! total ocean surface area
418
419      IF( ln_bdy ) CALL ctl_warn( 'dia_hsb_init: heat/salt budget does not consider open boundary fluxes' )         
420      !
421      ! ---------------------------------- !
422      ! 4 - initial conservation variables !
423      ! ---------------------------------- !
424      CALL dia_hsb_rst( nit000, 'READ' )  !* read or initialize all required files
425      !
426   END SUBROUTINE dia_hsb_init
427
428   !!======================================================================
429END MODULE diahsb
Note: See TracBrowser for help on using the repository browser.