source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/OCE/DOM/closea.F90

Last change on this file was 12202, checked in by cetlod, 10 months ago

dev_merge_option2 : merge in dev_r11613_ENHANCE-04_namelists_as_internalfiles

  • Property svn:keywords set to Id
File size: 12.7 KB
Line 
1MODULE closea
2   !!======================================================================
3   !!                   ***  MODULE  closea  ***
4   !!
5   !! User define : specific treatments associated with closed seas
6   !!======================================================================
7   !! History :   8.2  !  2000-05  (O. Marti)  Original code
8   !!   NEMO      1.0  !  2002-06  (E. Durand, G. Madec)  F90
9   !!             3.0  !  2006-07  (G. Madec)  add clo_rnf, clo_ups, clo_bat
10   !!             3.4  !  2014-12  (P.G. Fogli) sbc_clo bug fix & mpp reproducibility
11   !!             4.0  !  2016-06  (G. Madec)  move to usrdef_closea, remove clo_ups
12   !!             4.0  !  2017-12  (D. Storkey) new formulation based on masks read from file
13   !!             4.1  !  2019-07  (P. Mathiot) update to the new domcfg.nc input file
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   dom_clo    : read in masks which define closed seas and runoff areas
18   !!   clo_rnf    : set close sea outflows as river mouths (see sbcrnf)
19   !!   clo_msk    : set to zero a field over closed sea (see domzgr)
20   !!----------------------------------------------------------------------
21   USE in_out_manager  ! I/O manager
22   !
23   USE diurnal_bulk, ONLY: ln_diurnal_only            ! used for sanity check
24   USE iom         , ONLY: iom_open, iom_get, iom_close, jpdom_data ! I/O routines
25   USE lib_fortran , ONLY: glob_sum                   ! fortran library
26   USE lib_mpp     , ONLY: mpp_max, ctl_nam, ctl_stop ! MPP library
27
28   IMPLICIT NONE
29
30   PRIVATE
31
32   PUBLIC dom_clo      ! called by domain module
33   PUBLIC clo_rnf      ! called by sbcrnf module
34   PUBLIC clo_msk      ! called in domzgr module
35
36   LOGICAL, PUBLIC :: ln_maskcs        !: logical to mask all closed sea
37   LOGICAL, PUBLIC :: ln_mask_csundef  !: logical to mask all undefined closed sea
38   LOGICAL, PUBLIC :: ln_clo_rnf       !: closed sea treated as runoff (update rnf mask)
39
40   LOGICAL, PUBLIC :: l_sbc_clo  !: T => net evap/precip over closed seas spread outover the globe/river mouth
41   LOGICAL, PUBLIC :: l_clo_rnf  !: T => Some closed seas output freshwater (RNF) to specified runoff points.
42
43   INTEGER, PUBLIC :: ncsg      !: number of closed seas global mappings (inferred from closea_mask_glo field)
44   INTEGER, PUBLIC :: ncsr      !: number of closed seas rnf    mappings (inferred from closea_mask_rnf field)
45   INTEGER, PUBLIC :: ncse      !: number of closed seas empmr  mappings (inferred from closea_mask_emp field)
46
47   INTEGER, PUBLIC, SAVE, ALLOCATABLE, DIMENSION(:,:) :: mask_opnsea, mask_csundef  !: mask defining the open sea and the undefined closed sea
48 
49   INTEGER, PUBLIC, SAVE, ALLOCATABLE, DIMENSION(:,:) :: mask_csglo , mask_csgrpglo !: mask of integers defining closed seas
50   INTEGER, PUBLIC, SAVE, ALLOCATABLE, DIMENSION(:,:) :: mask_csrnf , mask_csgrprnf !: mask of integers defining closed seas rnf mappings
51   INTEGER, PUBLIC, SAVE, ALLOCATABLE, DIMENSION(:,:) :: mask_csemp , mask_csgrpemp !: mask of integers defining closed seas empmr mappings
52
53   !! * Substitutions
54#  include "vectopt_loop_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
57   !! $Id$
58   !! Software governed by the CeCILL license (see ./LICENSE)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE dom_clo()
63      !!---------------------------------------------------------------------
64      !!                  ***  ROUTINE dom_clo  ***
65      !!       
66      !! ** Purpose :   Closed sea domain initialization
67      !!
68      !! ** Action  :   Read mask_cs* fields (if needed) from domain_cfg file and infer
69      !!                number of closed seas for each case (glo, rnf, emp) from mask_cs* field.
70      !!
71      !! ** Output  :   mask_csglo and mask_csgrpglo  : integer values defining mappings from closed seas and associated groups to the open ocean for net fluxes.
72      !!                mask_csrnf and mask_csgrprnf  : integer values defining mappings from closed seas and associated groups to a runoff area for downwards flux only.
73      !!                mask_csemp and mask_csgrpemp  : integer values defining mappings from closed seas and associated groups to a runoff area for net fluxes.
74      !!----------------------------------------------------------------------
75      INTEGER ::   ios     ! io status
76      !!
77      NAMELIST/namclo/ ln_maskcs, ln_mask_csundef, ln_clo_rnf
78      !!---------------------------------------------------------------------
79      !!
80      READ  ( numnam_ref, namclo, IOSTAT = ios, ERR = 901 )
81901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namclo in reference namelist')
82      READ  ( numnam_cfg, namclo, IOSTAT = ios, ERR = 902 )
83902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namclo in configuration namelist')
84      IF(lwm) WRITE ( numond, namclo )
85      !!
86      IF(lwp) WRITE(numout,*)
87      IF(lwp) WRITE(numout,*)'dom_clo : read in masks to define closed seas '
88      IF(lwp) WRITE(numout,*)'~~~~~~~'
89      IF(lwp) WRITE(numout,*)
90      !!
91      !! check option compatibility
92      IF( .NOT. ln_read_cfg ) THEN
93         CALL ctl_stop('Suppression of closed seas does not work with ln_read_cfg = .true. . Set ln_closea = .false. .')
94      ENDIF
95      !!
96      IF( (.NOT. ln_maskcs) .AND. ln_diurnal_only ) THEN
97         CALL ctl_stop('Special handling of freshwater fluxes over closed seas not compatible with ln_diurnal_only.')
98      END IF
99      !
100      ! read the closed seas masks (if they exist) from domain_cfg file (if it exists)
101      ! ------------------------------------------------------------------------------
102      !
103      ! load mask of open sea
104      CALL alloc_csmask( mask_opnsea )
105      CALL read_csmask( cn_domcfg, 'mask_opensea' , mask_opnsea  )
106      !
107      IF ( ln_maskcs ) THEN
108         ! closed sea are masked
109         IF(lwp) WRITE(numout,*)'          ln_maskcs = T : all closed seas are masked'
110         IF(lwp) WRITE(numout,*)
111         ! no special treatment of closed sea
112         ! no redistribution of emp unbalance over closed sea into river mouth/open ocean
113         l_sbc_clo = .false. ; l_clo_rnf = .false.
114      ELSE
115         ! redistribution of emp unbalance over closed sea into river mouth/open ocean
116         IF(lwp) WRITE(numout,*)'          ln_maskcs = F : net emp is corrected over defined closed seas'
117         !
118         l_sbc_clo = .true.
119         !
120         ! river mouth from lakes added to rnf mask for special treatment
121         IF ( ln_clo_rnf) l_clo_rnf = .true.
122         !
123         IF ( ln_mask_csundef) THEN
124            ! closed sea not defined (ie not in the domcfg namelist used to build the domcfg.nc file) are masked
125            IF(lwp) WRITE(numout,*)'          ln_mask_csundef = T : all undefined closed seas are masked'
126            !
127            CALL alloc_csmask( mask_csundef )
128            CALL read_csmask( cn_domcfg, 'mask_csundef', mask_csundef )
129            ! revert the mask for masking of undefined closed seas in domzgr
130            ! (0 over the undefined closed sea and 1 elsewhere)
131            mask_csundef(:,:) = 1 - mask_csundef(:,:)
132         END IF
133         IF(lwp) WRITE(numout,*)
134         !
135         ! allocate source mask for each cases
136         CALL alloc_csmask( mask_csglo )
137         CALL alloc_csmask( mask_csrnf )
138         CALL alloc_csmask( mask_csemp )
139         !
140         ! load source mask of cs for each cases
141         CALL read_csmask( cn_domcfg, 'mask_csglo', mask_csglo )
142         CALL read_csmask( cn_domcfg, 'mask_csrnf', mask_csrnf )
143         CALL read_csmask( cn_domcfg, 'mask_csemp', mask_csemp )
144         !
145         ! compute number of cs for each cases
146         ncsg = MAXVAL( mask_csglo(:,:) ) ; CALL mpp_max( 'closea', ncsg )
147         ncsr = MAXVAL( mask_csrnf(:,:) ) ; CALL mpp_max( 'closea', ncsr )
148         ncse = MAXVAL( mask_csemp(:,:) ) ; CALL mpp_max( 'closea', ncse )
149         !
150         ! allocate closed sea group masks
151         !(used to defined the target area in case multiple lakes have the same river mouth (great lakes for example))
152         CALL alloc_csmask( mask_csgrpglo )
153         CALL alloc_csmask( mask_csgrprnf )
154         CALL alloc_csmask( mask_csgrpemp )
155
156         ! load mask of cs group for each cases
157         CALL read_csmask( cn_domcfg, 'mask_csgrpglo', mask_csgrpglo )
158         CALL read_csmask( cn_domcfg, 'mask_csgrprnf', mask_csgrprnf )
159         CALL read_csmask( cn_domcfg, 'mask_csgrpemp', mask_csgrpemp )
160         !
161      END IF
162   END SUBROUTINE dom_clo
163
164   SUBROUTINE clo_rnf( p_rnfmsk )
165      !!---------------------------------------------------------------------
166      !!                  ***  ROUTINE clo_rnf  ***
167      !!                   
168      !! ** Purpose :   allow the treatment of closed sea outflow grid-points
169      !!                to be the same as river mouth grid-points
170      !!
171      !! ** Method  :   set to 1 the runoff mask (mskrnf, see sbcrnf module)
172      !!                at the closed sea outflow grid-point.
173      !!
174      !! ** Action  :   update (p_)mskrnf (set 1 at closed sea outflow)
175      !!----------------------------------------------------------------------
176      !! subroutine parameter
177      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   p_rnfmsk   ! river runoff mask (rnfmsk array)
178      !!
179      !! local variables
180      REAL(wp), DIMENSION(jpi,jpj) :: zmsk
181      !!----------------------------------------------------------------------
182      !
183      ! zmsk > 0 where cs river mouth defined (case rnf and emp)
184      zmsk(:,:) = ( mask_csgrprnf (:,:) + mask_csgrpemp(:,:) ) * mask_opnsea(:,:)
185      WHERE( zmsk(:,:) > 0 )
186         p_rnfmsk(:,:) = 1.0_wp
187      END WHERE
188      !
189   END SUBROUTINE clo_rnf
190     
191   SUBROUTINE clo_msk( k_top, k_bot, k_mask, cd_prt )
192      !!---------------------------------------------------------------------
193      !!                  ***  ROUTINE clo_msk  ***
194      !!                   
195      !! ** Purpose :   Suppress closed sea from the domain
196      !!
197      !! ** Method  :   Where closea_mask > 0 set first and last ocean level to 0
198      !!                (As currently coded you can't define a closea_mask field in
199      !!                usr_def_zgr).
200      !!
201      !! ** Action  :   set k_top=0 and k_bot=0 over closed seas
202      !!----------------------------------------------------------------------
203      !! subroutine parameter
204      INTEGER, DIMENSION(:,:), INTENT(inout) ::   k_top, k_bot   ! ocean first and last level indices
205      INTEGER, DIMENSION(:,:), INTENT(in   ) ::   k_mask         ! mask used to mask ktop and k_bot
206      CHARACTER(len=*),          INTENT(in   ) ::   cd_prt         ! text for control print
207      !!
208      !! local variables
209      !!----------------------------------------------------------------------
210      !!
211      IF ( lwp ) THEN
212         WRITE(numout,*)
213         WRITE(numout,*) 'clo_msk : Suppression closed seas based on ',TRIM(cd_prt),' field.'
214         WRITE(numout,*) '~~~~~~~'
215         WRITE(numout,*)
216      ENDIF
217      !!
218      k_top(:,:) = k_top(:,:) * k_mask(:,:)
219      k_bot(:,:) = k_bot(:,:) * k_mask(:,:)
220      !!
221   END SUBROUTINE clo_msk
222
223   SUBROUTINE read_csmask(cd_file, cd_var, k_mskout)
224      !!---------------------------------------------------------------------
225      !!                  ***  ROUTINE read_csmask  ***
226      !!                   
227      !! ** Purpose : read mask in cd_filec file
228      !!----------------------------------------------------------------------
229      ! subroutine parameter
230      CHARACTER(len=*)       , INTENT(in   ) :: cd_file, cd_var     ! netcdf file and variable name
231      INTEGER, DIMENSION(:,:), INTENT(  out) :: k_mskout            ! output mask variable
232      !
233      ! local variables
234      INTEGER :: ics                       ! netcdf id
235      REAL(wp), DIMENSION(jpi,jpj) :: zdta ! netcdf data
236      !!----------------------------------------------------------------------
237      !
238      CALL iom_open ( cd_file, ics )
239      CALL iom_get  ( ics, jpdom_data, TRIM(cd_var), zdta )
240      CALL iom_close( ics )
241      k_mskout(:,:) = NINT(zdta(:,:))
242      !
243   END SUBROUTINE read_csmask
244
245   SUBROUTINE alloc_csmask( kmask )
246      !!---------------------------------------------------------------------
247      !!                  ***  ROUTINE alloc_csmask  ***
248      !!                   
249      !! ** Purpose : allocated cs mask
250      !!----------------------------------------------------------------------
251      ! subroutine parameter
252      INTEGER, ALLOCATABLE, DIMENSION(:,:), INTENT(inout) :: kmask
253      !
254      ! local variables
255      INTEGER :: ierr
256      !!----------------------------------------------------------------------
257      !
258      ALLOCATE( kmask(jpi,jpj) , STAT=ierr )
259      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'alloc_csmask: failed to allocate surf array')
260      !
261   END SUBROUTINE
262
263END MODULE closea
Note: See TracBrowser for help on using the repository browser.