New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
closea.F90 in NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/OCE/DOM – NEMO

source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/OCE/DOM/closea.F90 @ 12172

Last change on this file since 12172 was 12172, checked in by cetlod, 4 years ago

dev_merge_option2 : merge in ENHANCE-03_closea branch

  • Property svn:keywords set to Id
File size: 13.0 KB
Line 
1MODULE closea
2   !!======================================================================
3   !!                   ***  MODULE  closea  ***
4   !!
5   !! User define : specific treatments associated with closed seas
6   !!======================================================================
7   !! History :   8.2  !  2000-05  (O. Marti)  Original code
8   !!   NEMO      1.0  !  2002-06  (E. Durand, G. Madec)  F90
9   !!             3.0  !  2006-07  (G. Madec)  add clo_rnf, clo_ups, clo_bat
10   !!             3.4  !  2014-12  (P.G. Fogli) sbc_clo bug fix & mpp reproducibility
11   !!             4.0  !  2016-06  (G. Madec)  move to usrdef_closea, remove clo_ups
12   !!             4.0  !  2017-12  (D. Storkey) new formulation based on masks read from file
13   !!             4.1  !  2019-07  (P. Mathiot) update to the new domcfg.nc input file
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   dom_clo    : read in masks which define closed seas and runoff areas
18   !!   clo_rnf    : set close sea outflows as river mouths (see sbcrnf)
19   !!   clo_msk    : set to zero a field over closed sea (see domzgr)
20   !!----------------------------------------------------------------------
21   USE in_out_manager  ! I/O manager
22   !
23   USE diurnal_bulk, ONLY: ln_diurnal_only            ! used for sanity check
24   USE iom         , ONLY: iom_open, iom_get, iom_close, jpdom_data ! I/O routines
25   USE lib_fortran , ONLY: glob_sum                   ! fortran library
26   USE lib_mpp     , ONLY: mpp_max, ctl_nam, ctl_stop ! MPP library
27
28   IMPLICIT NONE
29
30   PRIVATE
31
32   PUBLIC dom_clo      ! called by domain module
33   PUBLIC clo_rnf      ! called by sbcrnf module
34   PUBLIC clo_msk      ! called in domzgr module
35
36   LOGICAL, PUBLIC :: ln_maskcs        !: logical to mask all closed sea
37   LOGICAL, PUBLIC :: ln_mask_csundef  !: logical to mask all undefined closed sea
38   LOGICAL, PUBLIC :: ln_clo_rnf       !: closed sea treated as runoff (update rnf mask)
39
40   LOGICAL, PUBLIC :: l_sbc_clo  !: T => net evap/precip over closed seas spread outover the globe/river mouth
41   LOGICAL, PUBLIC :: l_clo_rnf  !: T => Some closed seas output freshwater (RNF) to specified runoff points.
42
43   INTEGER, PUBLIC :: ncsg      !: number of closed seas global mappings (inferred from closea_mask_glo field)
44   INTEGER, PUBLIC :: ncsr      !: number of closed seas rnf    mappings (inferred from closea_mask_rnf field)
45   INTEGER, PUBLIC :: ncse      !: number of closed seas empmr  mappings (inferred from closea_mask_emp field)
46
47   INTEGER, PUBLIC, SAVE, ALLOCATABLE, DIMENSION(:,:) :: mask_opnsea, mask_csundef  !: mask defining the open sea and the undefined closed sea
48 
49   INTEGER, PUBLIC, SAVE, ALLOCATABLE, DIMENSION(:,:) :: mask_csglo , mask_csgrpglo !: mask of integers defining closed seas
50   INTEGER, PUBLIC, SAVE, ALLOCATABLE, DIMENSION(:,:) :: mask_csrnf , mask_csgrprnf !: mask of integers defining closed seas rnf mappings
51   INTEGER, PUBLIC, SAVE, ALLOCATABLE, DIMENSION(:,:) :: mask_csemp , mask_csgrpemp !: mask of integers defining closed seas empmr mappings
52
53   !! * Substitutions
54#  include "vectopt_loop_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
57   !! $Id$
58   !! Software governed by the CeCILL license (see ./LICENSE)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE dom_clo()
63      !!---------------------------------------------------------------------
64      !!                  ***  ROUTINE dom_clo  ***
65      !!       
66      !! ** Purpose :   Closed sea domain initialization
67      !!
68      !! ** Action  :   Read mask_cs* fields (if needed) from domain_cfg file and infer
69      !!                number of closed seas for each case (glo, rnf, emp) from mask_cs* field.
70      !!
71      !! ** Output  :   mask_csglo and mask_csgrpglo  : integer values defining mappings from closed seas and associated groups to the open ocean for net fluxes.
72      !!                mask_csrnf and mask_csgrprnf  : integer values defining mappings from closed seas and associated groups to a runoff area for downwards flux only.
73      !!                mask_csemp and mask_csgrpemp  : integer values defining mappings from closed seas and associated groups to a runoff area for net fluxes.
74      !!----------------------------------------------------------------------
75      INTEGER ::   ios     ! io status
76      !!
77      NAMELIST/namclo/ ln_maskcs, ln_mask_csundef, ln_clo_rnf
78      !!---------------------------------------------------------------------
79      !!
80      REWIND( numnam_ref )              ! Namelist namclo in reference namelist : Lateral momentum boundary condition
81      READ  ( numnam_ref, namclo, IOSTAT = ios, ERR = 901 )
82901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namclo in reference namelist')
83      REWIND( numnam_cfg )              ! Namelist namclo in configuration namelist : Lateral momentum boundary condition
84      READ  ( numnam_cfg, namclo, IOSTAT = ios, ERR = 902 )
85902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namclo in configuration namelist')
86      IF(lwm) WRITE ( numond, namclo )
87      !!
88      IF(lwp) WRITE(numout,*)
89      IF(lwp) WRITE(numout,*)'dom_clo : read in masks to define closed seas '
90      IF(lwp) WRITE(numout,*)'~~~~~~~'
91      IF(lwp) WRITE(numout,*)
92      !!
93      !! check option compatibility
94      IF( .NOT. ln_read_cfg ) THEN
95         CALL ctl_stop('Suppression of closed seas does not work with ln_read_cfg = .true. . Set ln_closea = .false. .')
96      ENDIF
97      !!
98      IF( (.NOT. ln_maskcs) .AND. ln_diurnal_only ) THEN
99         CALL ctl_stop('Special handling of freshwater fluxes over closed seas not compatible with ln_diurnal_only.')
100      END IF
101      !
102      ! read the closed seas masks (if they exist) from domain_cfg file (if it exists)
103      ! ------------------------------------------------------------------------------
104      !
105      ! load mask of open sea
106      CALL alloc_csmask( mask_opnsea )
107      CALL read_csmask( cn_domcfg, 'mask_opensea' , mask_opnsea  )
108      !
109      IF ( ln_maskcs ) THEN
110         ! closed sea are masked
111         IF(lwp) WRITE(numout,*)'          ln_maskcs = T : all closed seas are masked'
112         IF(lwp) WRITE(numout,*)
113         ! no special treatment of closed sea
114         ! no redistribution of emp unbalance over closed sea into river mouth/open ocean
115         l_sbc_clo = .false. ; l_clo_rnf = .false.
116      ELSE
117         ! redistribution of emp unbalance over closed sea into river mouth/open ocean
118         IF(lwp) WRITE(numout,*)'          ln_maskcs = F : net emp is corrected over defined closed seas'
119         !
120         l_sbc_clo = .true.
121         !
122         ! river mouth from lakes added to rnf mask for special treatment
123         IF ( ln_clo_rnf) l_clo_rnf = .true.
124         !
125         IF ( ln_mask_csundef) THEN
126            ! closed sea not defined (ie not in the domcfg namelist used to build the domcfg.nc file) are masked
127            IF(lwp) WRITE(numout,*)'          ln_mask_csundef = T : all undefined closed seas are masked'
128            !
129            CALL alloc_csmask( mask_csundef )
130            CALL read_csmask( cn_domcfg, 'mask_csundef', mask_csundef )
131            ! revert the mask for masking of undefined closed seas in domzgr
132            ! (0 over the undefined closed sea and 1 elsewhere)
133            mask_csundef(:,:) = 1 - mask_csundef(:,:)
134         END IF
135         IF(lwp) WRITE(numout,*)
136         !
137         ! allocate source mask for each cases
138         CALL alloc_csmask( mask_csglo )
139         CALL alloc_csmask( mask_csrnf )
140         CALL alloc_csmask( mask_csemp )
141         !
142         ! load source mask of cs for each cases
143         CALL read_csmask( cn_domcfg, 'mask_csglo', mask_csglo )
144         CALL read_csmask( cn_domcfg, 'mask_csrnf', mask_csrnf )
145         CALL read_csmask( cn_domcfg, 'mask_csemp', mask_csemp )
146         !
147         ! compute number of cs for each cases
148         ncsg = MAXVAL( mask_csglo(:,:) ) ; CALL mpp_max( 'closea', ncsg )
149         ncsr = MAXVAL( mask_csrnf(:,:) ) ; CALL mpp_max( 'closea', ncsr )
150         ncse = MAXVAL( mask_csemp(:,:) ) ; CALL mpp_max( 'closea', ncse )
151         !
152         ! allocate closed sea group masks
153         !(used to defined the target area in case multiple lakes have the same river mouth (great lakes for example))
154         CALL alloc_csmask( mask_csgrpglo )
155         CALL alloc_csmask( mask_csgrprnf )
156         CALL alloc_csmask( mask_csgrpemp )
157
158         ! load mask of cs group for each cases
159         CALL read_csmask( cn_domcfg, 'mask_csgrpglo', mask_csgrpglo )
160         CALL read_csmask( cn_domcfg, 'mask_csgrprnf', mask_csgrprnf )
161         CALL read_csmask( cn_domcfg, 'mask_csgrpemp', mask_csgrpemp )
162         !
163      END IF
164   END SUBROUTINE dom_clo
165
166   SUBROUTINE clo_rnf( p_rnfmsk )
167      !!---------------------------------------------------------------------
168      !!                  ***  ROUTINE clo_rnf  ***
169      !!                   
170      !! ** Purpose :   allow the treatment of closed sea outflow grid-points
171      !!                to be the same as river mouth grid-points
172      !!
173      !! ** Method  :   set to 1 the runoff mask (mskrnf, see sbcrnf module)
174      !!                at the closed sea outflow grid-point.
175      !!
176      !! ** Action  :   update (p_)mskrnf (set 1 at closed sea outflow)
177      !!----------------------------------------------------------------------
178      !! subroutine parameter
179      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   p_rnfmsk   ! river runoff mask (rnfmsk array)
180      !!
181      !! local variables
182      REAL(wp), DIMENSION(jpi,jpj) :: zmsk
183      !!----------------------------------------------------------------------
184      !
185      ! zmsk > 0 where cs river mouth defined (case rnf and emp)
186      zmsk(:,:) = ( mask_csgrprnf (:,:) + mask_csgrpemp(:,:) ) * mask_opnsea(:,:)
187      WHERE( zmsk(:,:) > 0 )
188         p_rnfmsk(:,:) = 1.0_wp
189      END WHERE
190      !
191   END SUBROUTINE clo_rnf
192     
193   SUBROUTINE clo_msk( k_top, k_bot, k_mask, cd_prt )
194      !!---------------------------------------------------------------------
195      !!                  ***  ROUTINE clo_msk  ***
196      !!                   
197      !! ** Purpose :   Suppress closed sea from the domain
198      !!
199      !! ** Method  :   Where closea_mask > 0 set first and last ocean level to 0
200      !!                (As currently coded you can't define a closea_mask field in
201      !!                usr_def_zgr).
202      !!
203      !! ** Action  :   set k_top=0 and k_bot=0 over closed seas
204      !!----------------------------------------------------------------------
205      !! subroutine parameter
206      INTEGER, DIMENSION(:,:), INTENT(inout) ::   k_top, k_bot   ! ocean first and last level indices
207      INTEGER, DIMENSION(:,:), INTENT(in   ) ::   k_mask         ! mask used to mask ktop and k_bot
208      CHARACTER(256),          INTENT(in   ) ::   cd_prt         ! text for control print
209      !!
210      !! local variables
211      !!----------------------------------------------------------------------
212      !!
213      IF ( lwp ) THEN
214         WRITE(numout,*)
215         WRITE(numout,*) 'clo_msk : Suppression closed seas based on ',TRIM(cd_prt),' field.'
216         WRITE(numout,*) '~~~~~~~'
217         WRITE(numout,*)
218      ENDIF
219      !!
220      k_top(:,:) = k_top(:,:) * k_mask(:,:)
221      k_bot(:,:) = k_bot(:,:) * k_mask(:,:)
222      !!
223   END SUBROUTINE clo_msk
224
225   SUBROUTINE read_csmask(cd_file, cd_var, k_mskout)
226      !!---------------------------------------------------------------------
227      !!                  ***  ROUTINE read_csmask  ***
228      !!                   
229      !! ** Purpose : read mask in cd_filec file
230      !!----------------------------------------------------------------------
231      ! subroutine parameter
232      CHARACTER(256),          INTENT(in   ) :: cd_file, cd_var     ! netcdf file and variable name
233      INTEGER, DIMENSION(:,:), INTENT(  out) :: k_mskout            ! output mask variable
234      !
235      ! local variables
236      INTEGER :: ics                       ! netcdf id
237      REAL(wp), DIMENSION(jpi,jpj) :: zdta ! netcdf data
238      !!----------------------------------------------------------------------
239      !
240      CALL iom_open ( cd_file, ics )
241      CALL iom_get  ( ics, jpdom_data, TRIM(cd_var), zdta )
242      CALL iom_close( ics )
243      k_mskout(:,:) = NINT(zdta(:,:))
244      !
245   END SUBROUTINE read_csmask
246
247   SUBROUTINE alloc_csmask( kmask )
248      !!---------------------------------------------------------------------
249      !!                  ***  ROUTINE alloc_csmask  ***
250      !!                   
251      !! ** Purpose : allocated cs mask
252      !!----------------------------------------------------------------------
253      ! subroutine parameter
254      INTEGER, ALLOCATABLE, DIMENSION(:,:), INTENT(inout) :: kmask
255      !
256      ! local variables
257      INTEGER :: ierr
258      !!----------------------------------------------------------------------
259      !
260      ALLOCATE( kmask(jpi,jpj) , STAT=ierr )
261      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'alloc_csmask: failed to allocate surf array')
262      !
263   END SUBROUTINE
264
265END MODULE closea
Note: See TracBrowser for help on using the repository browser.