New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/OCE – NEMO

source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/OCE/nemogcm.F90 @ 12251

Last change on this file since 12251 was 12251, checked in by smasson, 4 years ago

rev12232_dev_r12072_MERGE_OPTION2_2019: merge trunk 12072:12248, all sette tests ok, GYRE_PISCES, AMM12, ISOMIP, VORTEX intentical to 12210

  • Property svn:keywords set to Id
File size: 35.8 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tide_mod, ONLY : tide_init ! tidal components initialization   (tide_init routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE diamlr         ! IOM context management for multiple-linear-regression analysis
62   USE step           ! NEMO time-stepping                 (stp     routine)
63   USE isfstp         ! ice shelf                     (isf_stp_init routine)
64   USE icbini         ! handle bergs, initialisation
65   USE icbstp         ! handle bergs, calving, themodynamics and transport
66   USE cpl_oasis3     ! OASIS3 coupling
67   USE c1d            ! 1D configuration
68   USE step_c1d       ! Time stepping loop for the 1D configuration
69   USE dyndmp         ! Momentum damping
70   USE stopar         ! Stochastic param.: ???
71   USE stopts         ! Stochastic param.: ???
72   USE diurnal_bulk   ! diurnal bulk SST
73   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
74   USE crsini         ! initialise grid coarsening utility
75   USE dia25h         ! 25h mean output
76   USE diadetide      ! Weights computation for daily detiding of model diagnostics
77   USE sbc_oce , ONLY : lk_oasis
78   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
79#if defined key_top
80   USE trcini         ! passive tracer initialisation
81#endif
82#if defined key_nemocice_decomp
83   USE ice_domain_size, only: nx_global, ny_global
84#endif
85   !
86   USE lib_mpp        ! distributed memory computing
87   USE mppini         ! shared/distributed memory setting (mpp_init routine)
88   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
89   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
90#if defined key_iomput
91   USE xios           ! xIOserver
92#endif
93#if defined key_agrif
94   USE agrif_all_update   ! Master Agrif update
95#endif
96
97   IMPLICIT NONE
98   PRIVATE
99
100   PUBLIC   nemo_gcm    ! called by model.F90
101   PUBLIC   nemo_init   ! needed by AGRIF
102   PUBLIC   nemo_alloc  ! needed by TAM
103
104   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
105
106#if defined key_mpp_mpi
107   ! need MPI_Wtime
108   INCLUDE 'mpif.h'
109#endif
110
111   !!----------------------------------------------------------------------
112   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
113   !! $Id$
114   !! Software governed by the CeCILL license (see ./LICENSE)
115   !!----------------------------------------------------------------------
116CONTAINS
117
118   SUBROUTINE nemo_gcm
119      !!----------------------------------------------------------------------
120      !!                     ***  ROUTINE nemo_gcm  ***
121      !!
122      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
123      !!              curvilinear mesh on the sphere.
124      !!
125      !! ** Method  : - model general initialization
126      !!              - launch the time-stepping (stp routine)
127      !!              - finalize the run by closing files and communications
128      !!
129      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
130      !!              Madec, 2008, internal report, IPSL.
131      !!----------------------------------------------------------------------
132      INTEGER ::   istp   ! time step index
133      REAL(wp)::   zstptiming   ! elapsed time for 1 time step
134      !!----------------------------------------------------------------------
135      !
136#if defined key_agrif
137      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
138#endif
139      !                            !-----------------------!
140      CALL nemo_init               !==  Initialisations  ==!
141      !                            !-----------------------!
142#if defined key_agrif
143      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
144      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
145# if defined key_top
146      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
147# endif
148# if defined key_si3
149      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
150# endif
151#endif
152      ! check that all process are still there... If some process have an error,
153      ! they will never enter in step and other processes will wait until the end of the cpu time!
154      CALL mpp_max( 'nemogcm', nstop )
155
156      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
157
158      !                            !-----------------------!
159      !                            !==   time stepping   ==!
160      !                            !-----------------------!
161      istp = nit000
162      !
163#if defined key_c1d
164      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
165         CALL stp_c1d( istp )
166         istp = istp + 1
167      END DO
168#else
169      !
170# if defined key_agrif
171      !                                               !==  AGRIF time-stepping  ==!
172      CALL Agrif_Regrid()
173      !
174      ! Recursive update from highest nested level to lowest:
175      CALL Agrif_step_child_adj(Agrif_Update_All)
176      !
177      DO WHILE( istp <= nitend .AND. nstop == 0 )
178         CALL stp
179         istp = istp + 1
180      END DO
181      !
182      IF( .NOT. Agrif_Root() ) THEN
183         CALL Agrif_ParentGrid_To_ChildGrid()
184         IF( ln_diaobs )   CALL dia_obs_wri
185         IF( ln_timing )   CALL timing_finalize
186         CALL Agrif_ChildGrid_To_ParentGrid()
187      ENDIF
188      !
189# else
190      !
191      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
192         !
193         DO WHILE( istp <= nitend .AND. nstop == 0 )
194
195            ncom_stp = istp
196            IF( ln_timing ) THEN
197               zstptiming = MPI_Wtime()
198               IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
199               IF ( istp ==         nitend ) elapsed_time = zstptiming - elapsed_time
200            ENDIF
201           
202            CALL stp        ( istp ) 
203            istp = istp + 1
204
205            IF( lwp .AND. ln_timing )   WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
206
207         END DO
208         !
209      ELSE                                            !==  diurnal SST time-steeping only  ==!
210         !
211         DO WHILE( istp <= nitend .AND. nstop == 0 )
212            CALL stp_diurnal( istp )   ! time step only the diurnal SST
213            istp = istp + 1
214         END DO
215         !
216      ENDIF
217      !
218# endif
219      !
220#endif
221      !
222      IF( ln_diaobs   )   CALL dia_obs_wri
223      !
224      IF( ln_icebergs )   CALL icb_end( nitend )
225
226      !                            !------------------------!
227      !                            !==  finalize the run  ==!
228      !                            !------------------------!
229      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
230      !
231      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
232         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
233         CALL ctl_stop( ctmp1 )
234      ENDIF
235      !
236      IF( ln_timing )   CALL timing_finalize
237      !
238      CALL nemo_closefile
239      !
240#if defined key_iomput
241                                    CALL xios_finalize  ! end mpp communications with xios
242      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
243#else
244      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
245      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop      ! end mpp communications
246      ENDIF
247#endif
248      !
249      IF(lwm) THEN
250         IF( nstop == 0 ) THEN   ;   STOP 0
251         ELSE                    ;   STOP 123
252         ENDIF
253      ENDIF
254      !
255   END SUBROUTINE nemo_gcm
256
257
258   SUBROUTINE nemo_init
259      !!----------------------------------------------------------------------
260      !!                     ***  ROUTINE nemo_init  ***
261      !!
262      !! ** Purpose :   initialization of the NEMO GCM
263      !!----------------------------------------------------------------------
264      INTEGER ::   ios, ilocal_comm   ! local integers
265      !!
266      NAMELIST/namctl/ sn_cfctl,  nn_print, nn_ictls, nn_ictle,             &
267         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
268         &             ln_timing, ln_diacfl
269      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
270      !!----------------------------------------------------------------------
271      !
272      cxios_context = 'nemo'
273      !
274      !                             !-------------------------------------------------!
275      !                             !     set communicator & select the local rank    !
276      !                             !  must be done as soon as possible to get narea  !
277      !                             !-------------------------------------------------!
278      !
279#if defined key_iomput
280      IF( Agrif_Root() ) THEN
281         IF( lk_oasis ) THEN
282            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
283            CALL xios_initialize( "not used"       , local_comm =ilocal_comm )   ! send nemo communicator to xios
284         ELSE
285            CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
286         ENDIF
287      ENDIF
288      CALL mpp_start( ilocal_comm )
289#else
290      IF( lk_oasis ) THEN
291         IF( Agrif_Root() ) THEN
292            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
293         ENDIF
294         CALL mpp_start( ilocal_comm )
295      ELSE
296         CALL mpp_start( )
297      ENDIF
298#endif
299      !
300      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
301      lwm = (narea == 1)                ! control of output namelists
302      !
303      !                             !---------------------------------------------------------------!
304      !                             ! Open output files, reference and configuration namelist files !
305      !                             !---------------------------------------------------------------!
306      !
307      ! open ocean.output as soon as possible to get all output prints (including errors messages)
308      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
309      ! open reference and configuration namelist files
310                  CALL load_nml( numnam_ref,        'namelist_ref',                                           -1, lwm )
311                  CALL load_nml( numnam_cfg,        'namelist_cfg',                                           -1, lwm )
312      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
313      ! open /dev/null file to be able to supress output write easily
314                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
315      !
316      !                             !--------------------!
317      !                             ! Open listing units !  -> need sn_cfctl from namctl to define lwp
318      !                             !--------------------!
319      !
320      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
321901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
322      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
323902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
324      !
325      ! finalize the definition of namctl variables
326      IF( sn_cfctl%l_allon ) THEN
327         ! Turn on all options.
328         CALL nemo_set_cfctl( sn_cfctl, .TRUE., .TRUE. )
329         ! Ensure all processors are active
330         sn_cfctl%procmin = 0 ; sn_cfctl%procmax = 1000000 ; sn_cfctl%procincr = 1
331      ELSEIF( sn_cfctl%l_config ) THEN
332         ! Activate finer control of report outputs
333         ! optionally switch off output from selected areas (note this only
334         ! applies to output which does not involve global communications)
335         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
336           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
337           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
338      ELSE
339         ! turn off all options.
340         CALL nemo_set_cfctl( sn_cfctl, .FALSE., .TRUE. )
341      ENDIF
342      !
343      lwp = (narea == 1) .OR. sn_cfctl%l_oceout    ! control of all listing output print
344      !
345      IF(lwp) THEN                      ! open listing units
346         !
347         IF( .NOT. lwm )   &            ! alreay opened for narea == 1
348            &            CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
349         !
350         WRITE(numout,*)
351         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
352         WRITE(numout,*) '                       NEMO team'
353         WRITE(numout,*) '            Ocean General Circulation Model'
354         WRITE(numout,*) '                NEMO version 4.0  (2019) '
355         WRITE(numout,*)
356         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
357         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
358         WRITE(numout,*)
359         WRITE(numout,*) "           o         _,           _,             "
360         WRITE(numout,*) "            o      .' (        .-' /             "
361         WRITE(numout,*) "           o     _/..._'.    .'   /              "
362         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
363         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
364         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
365         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
366         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
367         WRITE(numout,*) "       )  ) jgs                     `    (   (   "
368         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
369         WRITE(numout,*)
370         !
371         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
372         !
373      ENDIF
374      !
375      IF(lwm) WRITE( numond, namctl )
376      !
377      !                             !------------------------------------!
378      !                             !  Set global domain size parameters !
379      !                             !------------------------------------!
380      !
381      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
382903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
383      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
384904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
385      !
386      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
387         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
388      ELSE                              ! user-defined namelist
389         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
390      ENDIF
391      !
392      IF(lwm)   WRITE( numond, namcfg )
393      !
394      !                             !-----------------------------------------!
395      !                             ! mpp parameters and domain decomposition !
396      !                             !-----------------------------------------!
397      CALL mpp_init
398
399      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
400      CALL nemo_alloc()
401
402      !                             !-------------------------------!
403      !                             !  NEMO general initialization  !
404      !                             !-------------------------------!
405
406      CALL nemo_ctl                          ! Control prints
407      !
408      !                                      ! General initialization
409      IF( ln_timing    )   CALL timing_init     ! timing
410      IF( ln_timing    )   CALL timing_start( 'nemo_init')
411      !
412                           CALL     phy_cst         ! Physical constants
413                           CALL     eos_init        ! Equation of state
414      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
415                           CALL     wad_init        ! Wetting and drying options
416                           CALL     dom_init("OPA") ! Domain
417      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
418      IF( sn_cfctl%l_prtctl )   &
419         &                 CALL prt_ctl_init        ! Print control
420     
421                           CALL diurnal_sst_bulk_init       ! diurnal sst
422      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
423      !                           
424                           IF( ln_diurnal_only ) THEN                    ! diurnal only: a subset of the initialisation routines
425                              CALL  istate_init                          ! ocean initial state (Dynamics and tracers)
426                              CALL     sbc_init                          ! Forcings : surface module
427                              CALL tra_qsr_init                          ! penetrative solar radiation qsr
428                              IF( ln_diaobs ) THEN                       ! Observation & model comparison
429                                 CALL dia_obs_init                       ! Initialize observational data
430                                 CALL dia_obs( nit000 - 1 )              ! Observation operator for restart
431                              ENDIF     
432                              IF( lk_asminc )   CALL asm_inc_init        ! Assimilation increments
433                              !
434                              RETURN                                     ! end of diurnal_only initialization
435                           ENDIF
436      !
437     
438                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
439
440      !                                      ! external forcing
441                           CALL    tide_init    ! tidal harmonics
442                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
443                           CALL     bdy_init    ! Open boundaries initialisation
444
445      !                                      ! Ocean physics
446                           CALL zdf_phy_init    ! Vertical physics
447                                     
448      !                                         ! Lateral physics
449                           CALL ldf_tra_init      ! Lateral ocean tracer physics
450                           CALL ldf_eiv_init      ! eddy induced velocity param.
451                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
452
453      !                                      ! Active tracers
454      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
455                           CALL tra_bbc_init      ! bottom heat flux
456                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
457                           CALL tra_dmp_init      ! internal tracer damping
458                           CALL tra_adv_init      ! horizontal & vertical advection
459                           CALL tra_ldf_init      ! lateral mixing
460
461      !                                      ! Dynamics
462      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
463                           CALL dyn_adv_init      ! advection (vector or flux form)
464                           CALL dyn_vor_init      ! vorticity term including Coriolis
465                           CALL dyn_ldf_init      ! lateral mixing
466                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
467                           CALL dyn_spg_init      ! surface pressure gradient
468
469#if defined key_top
470      !                                      ! Passive tracers
471                           CALL     trc_init
472#endif
473      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
474
475      !                                      ! Icebergs
476                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
477
478                                                ! ice shelf
479                           CALL isf_init
480
481      !                                      ! Misc. options
482                           CALL sto_par_init    ! Stochastic parametrization
483      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
484     
485      !                                      ! Diagnostics
486                           CALL     flo_init    ! drifting Floats
487      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
488!                           CALL dia_ptr_init    ! Poleward TRansports initialization
489                           CALL dia_dct_init    ! Sections tranports
490                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
491                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
492                           CALL dia_obs_init    ! Initialize observational data
493                           CALL dia_25h_init    ! 25h mean  outputs
494                           CALL dia_detide_init ! Weights computation for daily detiding of model diagnostics
495     IF( ln_diaobs    )    CALL dia_obs( nit000-1 )   ! Observation operator for restart
496                           CALL dia_mlr_init    ! Initialisation of IOM context management for multiple-linear-regression analysis
497
498      !                                      ! Assimilation increments
499      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
500      !
501      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
502      !
503      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
504      !
505   END SUBROUTINE nemo_init
506
507
508   SUBROUTINE nemo_ctl
509      !!----------------------------------------------------------------------
510      !!                     ***  ROUTINE nemo_ctl  ***
511      !!
512      !! ** Purpose :   control print setting
513      !!
514      !! ** Method  : - print namctl and namcfg information and check some consistencies
515      !!----------------------------------------------------------------------
516      !
517      IF(lwp) THEN                  ! control print
518         WRITE(numout,*)
519         WRITE(numout,*) 'nemo_ctl: Control prints'
520         WRITE(numout,*) '~~~~~~~~'
521         WRITE(numout,*) '   Namelist namctl'
522         WRITE(numout,*) '                              sn_cfctl%l_glochk  = ', sn_cfctl%l_glochk
523         WRITE(numout,*) '                              sn_cfctl%l_allon   = ', sn_cfctl%l_allon
524         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
525         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
526         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
527         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
528         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
529         WRITE(numout,*) '                              sn_cfctl%l_prtctl  = ', sn_cfctl%l_prtctl
530         WRITE(numout,*) '                              sn_cfctl%l_prttrc  = ', sn_cfctl%l_prttrc
531         WRITE(numout,*) '                              sn_cfctl%l_oasout  = ', sn_cfctl%l_oasout
532         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
533         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
534         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
535         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
536         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
537         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
538         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
539         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
540         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
541         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
542         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
543         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
544         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
545      ENDIF
546      !
547      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
548      nictls    = nn_ictls
549      nictle    = nn_ictle
550      njctls    = nn_jctls
551      njctle    = nn_jctle
552      isplt     = nn_isplt
553      jsplt     = nn_jsplt
554
555      IF(lwp) THEN                  ! control print
556         WRITE(numout,*)
557         WRITE(numout,*) '   Namelist namcfg'
558         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
559         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
560         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
561         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
562         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
563         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
564      ENDIF
565      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
566      !
567      !                             ! Parameter control
568      !
569      IF( sn_cfctl%l_prtctl .OR. sn_cfctl%l_prttrc ) THEN              ! sub-domain area indices for the control prints
570         IF( lk_mpp .AND. jpnij > 1 ) THEN
571            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
572         ELSE
573            IF( isplt == 1 .AND. jsplt == 1  ) THEN
574               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
575                  &           ' - the print control will be done over the whole domain' )
576            ENDIF
577            ijsplt = isplt * jsplt            ! total number of processors ijsplt
578         ENDIF
579         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
580         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
581         !
582         !                              ! indices used for the SUM control
583         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
584            lsp_area = .FALSE.
585         ELSE                                             ! print control done over a specific  area
586            lsp_area = .TRUE.
587            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
588               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
589               nictls = 1
590            ENDIF
591            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
592               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
593               nictle = jpiglo
594            ENDIF
595            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
596               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
597               njctls = 1
598            ENDIF
599            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
600               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
601               njctle = jpjglo
602            ENDIF
603         ENDIF
604      ENDIF
605      !
606      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
607         &                                                'Compile with key_nosignedzero enabled:',   &
608         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
609      !
610#if defined key_agrif
611      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
612#endif
613      !
614   END SUBROUTINE nemo_ctl
615
616
617   SUBROUTINE nemo_closefile
618      !!----------------------------------------------------------------------
619      !!                     ***  ROUTINE nemo_closefile  ***
620      !!
621      !! ** Purpose :   Close the files
622      !!----------------------------------------------------------------------
623      !
624      IF( lk_mpp )   CALL mppsync
625      !
626      CALL iom_close                                 ! close all input/output files managed by iom_*
627      !
628      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
629      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
630      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
631      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
632      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
633      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
634      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
635      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
636      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
637      !
638      numout = 6                                     ! redefine numout in case it is used after this point...
639      !
640   END SUBROUTINE nemo_closefile
641
642
643   SUBROUTINE nemo_alloc
644      !!----------------------------------------------------------------------
645      !!                     ***  ROUTINE nemo_alloc  ***
646      !!
647      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
648      !!
649      !! ** Method  :
650      !!----------------------------------------------------------------------
651      USE diawri    , ONLY : dia_wri_alloc
652      USE dom_oce   , ONLY : dom_oce_alloc
653      USE trc_oce   , ONLY : trc_oce_alloc
654      USE bdy_oce   , ONLY : bdy_oce_alloc
655      !
656      INTEGER :: ierr
657      !!----------------------------------------------------------------------
658      !
659      ierr =        oce_alloc    ()    ! ocean
660      ierr = ierr + dia_wri_alloc()
661      ierr = ierr + dom_oce_alloc()    ! ocean domain
662      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
663      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
664      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
665      !
666      CALL mpp_sum( 'nemogcm', ierr )
667      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
668      !
669   END SUBROUTINE nemo_alloc
670
671   
672   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
673      !!----------------------------------------------------------------------
674      !!                     ***  ROUTINE nemo_set_cfctl  ***
675      !!
676      !! ** Purpose :   Set elements of the output control structure to setto.
677      !!                for_all should be .false. unless all areas are to be
678      !!                treated identically.
679      !!
680      !! ** Method  :   Note this routine can be used to switch on/off some
681      !!                types of output for selected areas but any output types
682      !!                that involve global communications (e.g. mpp_max, glob_sum)
683      !!                should be protected from selective switching by the
684      !!                for_all argument
685      !!----------------------------------------------------------------------
686      LOGICAL :: setto, for_all
687      TYPE(sn_ctl) :: sn_cfctl
688      !!----------------------------------------------------------------------
689      IF( for_all ) THEN
690         sn_cfctl%l_runstat = setto
691         sn_cfctl%l_trcstat = setto
692      ENDIF
693      sn_cfctl%l_oceout  = setto
694      sn_cfctl%l_layout  = setto
695      sn_cfctl%l_prtctl  = setto
696      sn_cfctl%l_prttrc  = setto
697      sn_cfctl%l_oasout  = setto
698   END SUBROUTINE nemo_set_cfctl
699
700   !!======================================================================
701END MODULE nemogcm
702
Note: See TracBrowser for help on using the repository browser.