source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/TOP/PISCES/P4Z/p4zbc.F90 @ 12202

Last change on this file since 12202 was 12202, checked in by cetlod, 11 months ago

dev_merge_option2 : merge in dev_r11613_ENHANCE-04_namelists_as_internalfiles

File size: 16.7 KB
Line 
1MODULE p4zbc
2   !!======================================================================
3   !!                         ***  MODULE p4sbc  ***
4   !! TOP :   PISCES surface boundary conditions of external inputs of nutrients
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, C. Ethe) Original code
7   !!----------------------------------------------------------------------
8   !!   p4z_bc        :  Read and interpolate time-varying nutrients fluxes
9   !!   p4z_bc_init   :  Initialization of p4z_bc
10   !!----------------------------------------------------------------------
11   USE oce_trc         !  shared variables between ocean and passive tracers
12   USE trc             !  passive tracers common variables
13   USE sms_pisces      !  PISCES Source Minus Sink variables
14   USE iom             !  I/O manager
15   USE fldread         !  time interpolation
16   USE trcbc
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   p4z_bc
22   PUBLIC   p4z_bc_init   
23
24   LOGICAL , PUBLIC ::   ln_ironsed   !: boolean for Fe input from sediments
25   LOGICAL , PUBLIC ::   ln_hydrofe   !: boolean for Fe input from hydrothermal vents
26   REAL(wp), PUBLIC ::   sedfeinput   !: Coastal release of Iron
27   REAL(wp), PUBLIC ::   icefeinput   !: Iron concentration in sea ice
28   REAL(wp), PUBLIC ::   wdust        !: Sinking speed of the dust
29   REAL(wp), PUBLIC ::   mfrac        !: Mineral Content of the dust
30   REAL(wp)         ::   hratio       !: Fe:3He ratio assumed for vent iron supply
31   REAL(wp)         ::   distcoast    !: Distance off the coast for Iron from sediments
32   REAL(wp), PUBLIC ::   lgw_rath     !: Weak ligand ratio from hydro sources
33
34   LOGICAL , PUBLIC ::   ll_bc
35   LOGICAL , PUBLIC ::   ll_dust      !: boolean for dust input from the atmosphere
36   LOGICAL , PUBLIC ::   ll_river     !: boolean for river input of nutrients
37   LOGICAL , PUBLIC ::   ll_ndepo     !: boolean for atmospheric deposition of N
38   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_dust      ! structure of input dust
39   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ironsed   ! structure of input iron from sediment
40   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_hydrofe   ! structure of input iron from sediment
41
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   dust    !: dust fields
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ironsed          !: Coastal supply of iron
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   hydrofe          !: Hydrothermal vent supply of iron
45
46   REAL(wp), PUBLIC :: sedsilfrac, sedcalfrac
47
48   !! * Substitutions
49#  include "vectopt_loop_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
52   !! $Id: p4zbc.F90 10869 2019-04-15 10:34:03Z cetlod $
53   !! Software governed by the CeCILL license (see ./LICENSE)
54   !!----------------------------------------------------------------------
55CONTAINS
56
57   SUBROUTINE p4z_bc( kt )
58      !!----------------------------------------------------------------------
59      !!                  ***  routine p4z_bc  ***
60      !!
61      !! ** purpose :   read and interpolate the external sources of nutrients
62      !!
63      !! ** method  :   read the files and interpolate the appropriate variables
64      !!
65      !! ** input   :   external netcdf files
66      !!
67      !!----------------------------------------------------------------------
68      INTEGER, INTENT(in) ::   kt   ! ocean time step
69      !
70      INTEGER  ::  ji, jj, jk, jl 
71      REAL(wp) ::  zcoef, zyyss
72      REAL(wp) ::  zdep, ztrfer, zwdust, zwflux, zrivdin
73      !
74      CHARACTER (len=25) :: charout
75      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zirondep
76      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zironice, zndep
77      !!---------------------------------------------------------------------
78      !
79      IF( ln_timing )   CALL timing_start('p4z_bc')
80      !
81      IF( ll_dust )  THEN
82         ALLOCATE(  zirondep(jpi,jpj,jpk) )
83         !
84         CALL fld_read( kt, 1, sf_dust )
85         dust(:,:) = MAX( rtrn, sf_dust(1)%fnow(:,:,1) )
86         !
87         jl = n_trc_indsbc(jpfer)
88         zirondep(:,:,1) = rf_trsfac(jl) * sf_trcsbc(jl)%fnow(:,:,1) / e3t_n(:,:,1) / rn_sbc_time
89         !                                              ! Iron solubilization of particles in the water column
90         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
91         zwdust = 0.03 / ( wdust / rday ) / ( 270. * rday )
92         DO jk = 2, jpkm1
93            zirondep(:,:,jk) = ( mfrac * dust(:,:) * zwdust / mMass_Fe ) * rfact * EXP( -gdept_n(:,:,jk) / 540. )
94            tra(:,:,jk,jpfer) = tra(:,:,jk,jpfer) + zirondep(:,:,jk)
95            tra(:,:,jk,jppo4) = tra(:,:,jk,jppo4) + zirondep(:,:,jk) * 0.023
96         ENDDO
97         !
98         IF( lk_iomput ) THEN
99           IF( iom_use( "Irondep" ) )   &
100             &  CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfactr * e3t_n(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
101           IF( iom_use( "pdust" ) )   &
102             &  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday ) * tmask(:,:,1) ) ! dust concentration at surface
103         ENDIF
104         DEALLOCATE( zirondep )
105      ENDIF
106
107      ! N/P and Si releases due to coastal rivers
108      ! Compute river at nit000 or only if there is more than 1 time record in river file
109      ! -----------------------------------------
110            ! Add the external input of nutrients from river
111      ! ----------------------------------------------------------
112      IF( ll_river ) THEN
113          jl = n_trc_indcbc(jpno3)
114          DO jj = 1, jpj
115             DO ji = 1, jpi
116                DO jk = 1, nk_rnf(ji,jj)
117                   zcoef = rn_rfact / ( e1e2t(ji,jj) * h_rnf(ji,jj) * rn_cbc_time ) * tmask(ji,jj,1)
118                   zrivdin = rf_trcfac(jl) * sf_trccbc(jl)%fnow(ji,jj,1) * zcoef
119                   tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - rno3 * zrivdin * rfact
120               ENDDO
121             END DO
122          END DO
123      ENDIF
124     
125      ! Add the external input of nutrients from nitrogen deposition
126      ! ----------------------------------------------------------
127      IF( ll_ndepo ) THEN
128         ALLOCATE( zndep(jpi,jpj) )
129         IF( ln_trc_sbc(jpno3) ) THEN
130            jl = n_trc_indsbc(jpno3)
131            zndep(:,:) = rf_trsfac(jl) * sf_trcsbc(jl)%fnow(:,:,1) / e3t_n(:,:,1) / rn_sbc_time
132            tra(:,:,1,jptal) = tra(:,:,1,jptal) - rno3 * zndep(:,:) * rfact
133         ENDIF
134         IF( ln_trc_sbc(jpnh4) ) THEN
135            jl = n_trc_indsbc(jpnh4)
136            zndep(:,:) = rf_trsfac(jl) * sf_trcsbc(jl)%fnow(:,:,1) / e3t_n(:,:,1) / rn_sbc_time
137            tra(:,:,1,jptal) = tra(:,:,1,jptal) - rno3 * zndep(:,:) * rfact
138         ENDIF
139         DEALLOCATE( zndep )
140      ENDIF
141      !
142      ! Iron input/uptake due to sea ice : Crude parameterization based on
143      ! Lancelot et al.
144      ! ----------------------------------------------------
145      IF( ln_ironice ) THEN
146         !
147         ALLOCATE( zironice(jpi,jpj) )
148         !
149         DO jj = 1, jpj
150            DO ji = 1, jpi
151               zdep    = rfact / e3t_n(ji,jj,1)
152               zwflux  = fmmflx(ji,jj) / 1000._wp
153               zironice(ji,jj) =  MAX( -0.99 * trb(ji,jj,1,jpfer), -zwflux * icefeinput * zdep )
154            END DO
155         END DO
156         !
157         tra(:,:,1,jpfer) = tra(:,:,1,jpfer) + zironice(:,:)
158         !
159         IF( lk_iomput .AND. iom_use( "Ironice" ) )   &
160            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfactr * e3t_n(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
161         !
162         DEALLOCATE( zironice )
163         !
164      ENDIF
165
166      ! Add the external input of iron from sediment mobilization
167      ! ------------------------------------------------------
168      IF( ln_ironsed .AND. .NOT.lk_sed ) THEN
169          tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + ironsed(:,:,:) * rfact
170          !
171          IF( lk_iomput .AND. iom_use( "Ironsed" ) )   &
172               &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) 
173      ENDIF
174
175      ! Add the external input of iron from hydrothermal vents
176      ! ------------------------------------------------------
177      IF( ln_hydrofe ) THEN
178         CALL fld_read( kt, 1, sf_hydrofe )
179         DO jk = 1, jpk
180            hydrofe(:,:,jk) = ( MAX( rtrn, sf_hydrofe(1)%fnow(:,:,jk) ) * hratio ) &
181              &              / ( e1e2t(:,:) * e3t_n(:,:,jk) * ryyss + rtrn ) / 1000._wp &
182              &              * tmask(:,:,jk)
183         ENDDO
184                         tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + hydrofe(:,:,:) * rfact
185         IF( ln_ligand ) tra(:,:,:,jplgw) = tra(:,:,:,jplgw) + ( hydrofe(:,:,:) * lgw_rath ) * rfact
186         !
187         IF( lk_iomput .AND. iom_use( "HYDR" ) )   &
188            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
189      ENDIF
190      IF( ln_timing )  CALL timing_stop('p4z_bc')
191      !
192   END SUBROUTINE p4z_bc
193
194
195   SUBROUTINE p4z_bc_init
196      !!----------------------------------------------------------------------
197      !!                  ***  routine p4z_bc_init  ***
198      !!
199      !! ** purpose :   initialization of the external sources of nutrients
200      !!
201      !! ** method  :   read the files and compute the budget
202      !!                called at the first timestep (nittrc000)
203      !!
204      !! ** input   :   external netcdf files
205      !!
206      !!----------------------------------------------------------------------
207      INTEGER  :: ji, jj, jk, jm
208      INTEGER  :: ii0, ii1, ij0, ij1
209      INTEGER  :: numiron
210      INTEGER  :: ierr, ierr1, ierr2, ierr3
211      INTEGER  :: ios                 ! Local integer output status for namelist read
212      INTEGER  :: ik50                !  last level where depth less than 50 m
213      REAL(wp) :: zexpide, zdenitide, zmaskt, zsurfc, zsurfp,ze3t, ze3t2, zcslp
214      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zriver, zcmask
215      !
216      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
217      TYPE(FLD_N) ::   sn_dust, sn_ironsed, sn_hydrofe   ! informations about the fields to be read
218      !!
219      NAMELIST/nampisbc/cn_dir, sn_dust, sn_ironsed, sn_hydrofe, &
220        &                ln_ironsed, ln_ironice, ln_hydrofe,    &
221        &                sedfeinput, distcoast, icefeinput, wdust, mfrac,  &
222        &                hratio, lgw_rath
223      !!----------------------------------------------------------------------
224      !
225      IF(lwp) THEN
226         WRITE(numout,*)
227         WRITE(numout,*) 'p4z_bc_init : initialization of the external sources of nutrients '
228         WRITE(numout,*) '~~~~~~~~~~~~ '
229      ENDIF
230      !                            !* set file information
231      READ  ( numnatp_ref, nampisbc, IOSTAT = ios, ERR = 901)
232901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisbc in reference namelist' )
233      READ  ( numnatp_cfg, nampisbc, IOSTAT = ios, ERR = 902 )
234902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisbc in configuration namelist' )
235      IF(lwm) WRITE ( numonp, nampisbc )
236
237
238      IF(lwp) THEN
239         WRITE(numout,*) '   Namelist : nampissbc '
240         WRITE(numout,*) '      Fe input from sediments                  ln_ironsed  = ', ln_ironsed
241         WRITE(numout,*) '      Fe input from seaice                     ln_ironice  = ', ln_ironice
242         WRITE(numout,*) '      fe input from hydrothermal vents         ln_hydrofe  = ', ln_hydrofe
243         IF( ln_ironsed ) THEN
244            WRITE(numout,*) '      coastal release of iron                  sedfeinput  = ', sedfeinput
245            WRITE(numout,*) '      distance off the coast                   distcoast   = ', distcoast
246         ENDIF
247         IF( ln_ligand ) THEN
248            WRITE(numout,*) '      Weak ligand ratio from sed hydro sources  lgw_rath   = ', lgw_rath
249         ENDIF
250         IF( ln_ironice ) THEN
251            WRITE(numout,*) '      Iron concentration in sea ice            icefeinput  = ', icefeinput
252         ENDIF
253         IF( ln_trc_sbc(jpfer) ) THEN
254            WRITE(numout,*) '      Mineral Fe content of the dust           mfrac       = ', mfrac
255            WRITE(numout,*) '      sinking speed of the dust                wdust       = ', wdust
256         ENDIF
257         IF( ln_hydrofe ) THEN
258            WRITE(numout,*) '      Fe to 3He ratio assumed for vent iron supply hratio  = ', hratio
259         ENDIF
260      END IF
261
262      ll_bc    = ( ln_trcbc .AND. lltrcbc )  .OR. ln_hydrofe .OR. ln_ironsed .OR. ln_ironice
263      ll_dust  =  ln_trc_sbc(jpfer)   
264      ll_ndepo =  ln_trc_sbc(jpno3) .OR. ln_trc_sbc(jpnh4)   
265      ll_river =  ln_trc_cbc(jpno3) 
266
267      ! dust input from the atmosphere
268      ! ------------------------------
269      IF( ll_dust ) THEN
270         !
271         IF(lwp) WRITE(numout,*) '    initialize dust input from atmosphere '
272         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
273         !
274         ALLOCATE( dust(jpi,jpj) ) 
275         !
276         ALLOCATE( sf_dust(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
277         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_dust structure' )
278         !
279         CALL fld_fill( sf_dust, (/ sn_dust /), cn_dir, 'p4z_sed_init', 'Atmospheric dust deposition', 'nampissed' )
280                                   ALLOCATE( sf_dust(1)%fnow(jpi,jpj,1)   )
281         IF( sn_dust%ln_tint )     ALLOCATE( sf_dust(1)%fdta(jpi,jpj,1,2) )
282         !
283      END IF
284
285      ! coastal and island masks
286      ! ------------------------
287      IF( ln_ironsed ) THEN     
288         !
289         IF(lwp) WRITE(numout,*)
290         IF(lwp) WRITE(numout,*) '   ==>>>   ln_ironsed=T , computation of an island mask to enhance coastal supply of iron'
291         !
292         ALLOCATE( ironsed(jpi,jpj,jpk) )    ! allocation
293         !
294         CALL iom_open ( TRIM( sn_ironsed%clname ), numiron )
295         ALLOCATE( zcmask(jpi,jpj,jpk) )
296         CALL iom_get  ( numiron, jpdom_data, TRIM( sn_ironsed%clvar ), zcmask(:,:,:), 1 )
297         CALL iom_close( numiron )
298         !
299         ik50 = 5        !  last level where depth less than 50 m
300         DO jk = jpkm1, 1, -1
301            IF( gdept_1d(jk) > 50. )   ik50 = jk - 1
302         END DO
303         IF(lwp) WRITE(numout,*)
304         IF(lwp) WRITE(numout,*) ' Level corresponding to 50m depth ',  ik50,' ', gdept_1d(ik50+1)
305         DO jk = 1, ik50
306            DO jj = 2, jpjm1
307               DO ji = fs_2, fs_jpim1
308                  ze3t   = e3t_0(ji,jj,jk)
309                  zsurfc =  e1u(ji,jj) * ( 1. - umask(ji  ,jj  ,jk) )   &
310                          + e1u(ji,jj) * ( 1. - umask(ji-1,jj  ,jk) )   &
311                          + e2v(ji,jj) * ( 1. - vmask(ji  ,jj  ,jk) )   &
312                          + e2v(ji,jj) * ( 1. - vmask(ji  ,jj-1,jk) )
313                  zsurfp = zsurfc * ze3t / e1e2t(ji,jj)
314                  ! estimation of the coastal slope : 5 km off the coast
315                  ze3t2 = ze3t * ze3t
316                  zcslp = SQRT( ( distcoast*distcoast + ze3t2 ) / ze3t2 )
317                  !
318                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) + zcslp * zsurfp
319               END DO
320            END DO
321         END DO
322         !
323         CALL lbc_lnk( 'p4zbc', zcmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
324         !
325         DO jk = 1, jpk
326            DO jj = 1, jpj
327               DO ji = 1, jpi
328                  zexpide   = MIN( 8.,( gdept_n(ji,jj,jk) / 500. )**(-1.5) )
329                  zdenitide = -0.9543 + 0.7662 * LOG( zexpide ) - 0.235 * LOG( zexpide )**2
330                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) * MIN( 1., EXP( zdenitide ) / 0.5 )
331               END DO
332            END DO
333         END DO
334         ! Coastal supply of iron
335         ! -------------------------
336         ironsed(:,:,jpk) = 0._wp
337         DO jk = 1, jpkm1
338            ironsed(:,:,jk) = sedfeinput * zcmask(:,:,jk) / ( e3t_0(:,:,jk) * rday )
339         END DO
340         DEALLOCATE( zcmask)
341      ENDIF
342      !
343      ! Iron from Hydrothermal vents
344      ! ------------------------
345      IF( ln_hydrofe ) THEN
346         !
347         IF(lwp) WRITE(numout,*)
348         IF(lwp) WRITE(numout,*) '   ==>>>   ln_hydrofe=T , Input of iron from hydrothermal vents'
349         !
350         ALLOCATE( hydrofe(jpi,jpj,jpk) )    ! allocation
351         !
352         ALLOCATE( sf_hydrofe(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
353         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_hydro structure' )
354         !
355         CALL fld_fill( sf_hydrofe, (/ sn_hydrofe /), cn_dir, 'p4z_sed_init', 'Input of iron from hydrothermal vents', 'nampisbc' )
356                                   ALLOCATE( sf_hydrofe(1)%fnow(jpi,jpj,jpk)   )
357         IF( sn_hydrofe%ln_tint )    ALLOCATE( sf_hydrofe(1)%fdta(jpi,jpj,jpk,2) )
358         !
359      ENDIF
360      !
361   END SUBROUTINE p4z_bc_init
362
363   !!======================================================================
364END MODULE p4zbc
Note: See TracBrowser for help on using the repository browser.