source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/TOP/PISCES/P4Z/p4zflx.F90 @ 12257

Last change on this file since 12257 was 12257, checked in by cetlod, 10 months ago

dev_r12072_MERGE_OPTION2_2019: Cleaning PISCES diagnostics output ; fully sette tested

  • Property svn:keywords set to Id
File size: 17.7 KB
Line 
1MODULE p4zflx
2   !!======================================================================
3   !!                         ***  MODULE p4zflx  ***
4   !! TOP :   PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
5   !!======================================================================
6   !! History :   -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!             -   !  1998     (O. Aumont) additions
8   !!             -   !  1999     (C. Le Quere) modifications
9   !!            1.0  !  2004     (O. Aumont) modifications
10   !!            2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                 !  2011-02  (J. Simeon, J. Orr) Include total atm P correction
12   !!----------------------------------------------------------------------
13   !!   p4z_flx       :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
14   !!   p4z_flx_init  :   Read the namelist
15   !!   p4z_patm      :   Read sfc atm pressure [atm] for each grid cell
16   !!----------------------------------------------------------------------
17   USE oce_trc        !  shared variables between ocean and passive tracers
18   USE trc            !  passive tracers common variables
19   USE sms_pisces     !  PISCES Source Minus Sink variables
20   USE p4zche         !  Chemical model
21   USE prtctl_trc     !  print control for debugging
22   USE iom            !  I/O manager
23   USE fldread        !  read input fields
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_flx 
29   PUBLIC   p4z_flx_init 
30   PUBLIC   p4z_flx_alloc 
31
32   !                                 !!** Namelist  nampisext  **
33   REAL(wp)          ::   atcco2      !: pre-industrial atmospheric [co2] (ppm) 
34   LOGICAL           ::   ln_co2int   !: flag to read in a file and interpolate atmospheric pco2 or not
35   CHARACTER(len=34) ::   clname      !: filename of pco2 values
36   INTEGER           ::   nn_offset   !: Offset model-data start year (default = 0)
37
38   !!  Variables related to reading atmospheric CO2 time history   
39   INTEGER                                   ::   nmaxrec, numco2   !
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) ::   atcco2h, years    !
41
42   !                                  !!* nampisatm namelist (Atmospheric PRessure) *
43   LOGICAL, PUBLIC ::   ln_presatm     !: ref. pressure: global mean Patm (F) or a constant (F)
44   LOGICAL, PUBLIC ::   ln_presatmco2  !: accounting for spatial atm CO2 in the compuation of carbon flux (T) or not (F)
45
46   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:) ::   patm      ! atmospheric pressure at kt                 [N/m2]
47   TYPE(FLD), ALLOCATABLE,       DIMENSION(:)   ::   sf_patm   ! structure of input fields (file informations, fields read)
48   TYPE(FLD), ALLOCATABLE,       DIMENSION(:)   ::   sf_atmco2 ! structure of input fields (file informations, fields read)
49
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::  satmco2   !: atmospheric pco2
51
52   REAL(wp) ::   xconv  = 0.01_wp / 3600._wp   !: coefficients for conversion
53
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
56   !! $Id$
57   !! Software governed by the CeCILL license (see ./LICENSE)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   SUBROUTINE p4z_flx ( kt, knt )
62      !!---------------------------------------------------------------------
63      !!                     ***  ROUTINE p4z_flx  ***
64      !!
65      !! ** Purpose :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
66      !!
67      !! ** Method  :
68      !!              - Include total atm P correction via Esbensen & Kushnir (1981)
69      !!              - Remove Wanninkhof chemical enhancement;
70      !!              - Add option for time-interpolation of atcco2.txt 
71      !!---------------------------------------------------------------------
72      INTEGER, INTENT(in) ::   kt, knt   !
73      !
74      INTEGER  ::   ji, jj, jm, iind, iindm1
75      REAL(wp) ::   ztc, ztc2, ztc3, ztc4, zws, zkgwan
76      REAL(wp) ::   zfld, zflu, zfld16, zflu16, zfact
77      REAL(wp) ::   zvapsw, zsal, zfco2, zxc2, xCO2approx, ztkel, zfugcoeff
78      REAL(wp) ::   zph, zdic, zsch_o2, zsch_co2
79      REAL(wp) ::   zyr_dec, zdco2dt
80      CHARACTER (len=25) ::   charout
81      REAL(wp), DIMENSION(jpi,jpj) ::   zkgco2, zkgo2, zh2co3, zoflx,  zpco2atm 
82      !!---------------------------------------------------------------------
83      !
84      IF( ln_timing )   CALL timing_start('p4z_flx')
85      !
86      ! SURFACE CHEMISTRY (PCO2 AND [H+] IN
87      !     SURFACE LAYER); THE RESULT OF THIS CALCULATION
88      !     IS USED TO COMPUTE AIR-SEA FLUX OF CO2
89
90      IF( kt /= nit000 .AND. .NOT.l_co2cpl .AND. knt == 1 )   CALL p4z_patm( kt )   ! Get sea-level pressure (E&K [1981] climatology) for use in flux calcs
91
92      IF( ln_co2int .AND. .NOT.ln_presatmco2 .AND. .NOT.l_co2cpl ) THEN 
93         ! Linear temporal interpolation  of atmospheric pco2.  atcco2.txt has annual values.
94         ! Caveats: First column of .txt must be in years, decimal  years preferably.
95         ! For nn_offset, if your model year is iyy, nn_offset=(years(1)-iyy)
96         ! then the first atmospheric CO2 record read is at years(1)
97         zyr_dec = REAL( nyear + nn_offset, wp ) + REAL( nday_year, wp ) / REAL( nyear_len(1), wp )
98         jm = 1
99         DO WHILE( jm <= nmaxrec .AND. years(jm) < zyr_dec ) ;  jm = jm + 1 ;  END DO
100         iind = jm  ;   iindm1 = jm - 1
101         zdco2dt = ( atcco2h(iind) - atcco2h(iindm1) ) / ( years(iind) - years(iindm1) + rtrn )
102         atcco2  = zdco2dt * ( zyr_dec - years(iindm1) ) + atcco2h(iindm1)
103         satmco2(:,:) = atcco2 
104      ENDIF
105
106      IF( l_co2cpl )   satmco2(:,:) = atm_co2(:,:)
107
108      DO jj = 1, jpj
109         DO ji = 1, jpi
110            ! DUMMY VARIABLES FOR DIC, H+, AND BORATE
111            zfact = rhop(ji,jj,1) / 1000. + rtrn
112            zdic  = trb(ji,jj,1,jpdic)
113            zph   = MAX( hi(ji,jj,1), 1.e-10 ) / zfact
114            ! CALCULATE [H2CO3]
115            zh2co3(ji,jj) = zdic/(1. + ak13(ji,jj,1)/zph + ak13(ji,jj,1)*ak23(ji,jj,1)/zph**2)
116         END DO
117      END DO
118
119      ! --------------
120      ! COMPUTE FLUXES
121      ! --------------
122
123      ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS
124      ! -------------------------------------------
125
126      DO jj = 1, jpj
127         DO ji = 1, jpi
128            ztc  = MIN( 35., tsn(ji,jj,1,jp_tem) )
129            ztc2 = ztc * ztc
130            ztc3 = ztc * ztc2 
131            ztc4 = ztc2 * ztc2 
132            ! Compute the schmidt Number both O2 and CO2
133            zsch_co2 = 2116.8 - 136.25 * ztc + 4.7353 * ztc2 - 0.092307 * ztc3 + 0.0007555 * ztc4
134            zsch_o2  = 1920.4 - 135.6  * ztc + 5.2122 * ztc2 - 0.109390 * ztc3 + 0.0009377 * ztc4
135            !  wind speed
136            zws  = wndm(ji,jj) * wndm(ji,jj)
137            ! Compute the piston velocity for O2 and CO2
138            zkgwan = 0.251 * zws
139            zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1)
140            ! compute gas exchange for CO2 and O2
141            zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 )
142            zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 )
143         END DO
144      END DO
145
146
147      DO jj = 1, jpj
148         DO ji = 1, jpi
149            ztkel = tempis(ji,jj,1) + 273.15
150            zsal  = salinprac(ji,jj,1) + ( 1.- tmask(ji,jj,1) ) * 35.
151            zvapsw    = EXP(24.4543 - 67.4509*(100.0/ztkel) - 4.8489*LOG(ztkel/100) - 0.000544*zsal)
152            zpco2atm(ji,jj) = satmco2(ji,jj) * ( patm(ji,jj) - zvapsw )
153            zxc2      = ( 1.0 - zpco2atm(ji,jj) * 1E-6 )**2
154            zfugcoeff = EXP( patm(ji,jj) * (chemc(ji,jj,2) + 2.0 * zxc2 * chemc(ji,jj,3) )   &
155            &           / ( 82.05736 * ztkel ))
156            zfco2 = zpco2atm(ji,jj) * zfugcoeff
157
158            ! Compute CO2 flux for the sea and air
159            zfld = zfco2 * chemc(ji,jj,1) * zkgco2(ji,jj)  ! (mol/L) * (m/s)
160            zflu = zh2co3(ji,jj) * zkgco2(ji,jj)                                   ! (mol/L) (m/s) ?
161            oce_co2(ji,jj) = ( zfld - zflu ) * tmask(ji,jj,1) 
162            ! compute the trend
163            tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + oce_co2(ji,jj) * rfact2 / e3t_n(ji,jj,1)
164
165            ! Compute O2 flux
166            zfld16 = patm(ji,jj) * chemo2(ji,jj,1) * zkgo2(ji,jj)          ! (mol/L) * (m/s)
167            zflu16 = trb(ji,jj,1,jpoxy) * zkgo2(ji,jj)
168            zoflx(ji,jj) = ( zfld16 - zflu16 ) * tmask(ji,jj,1)
169            tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + zoflx(ji,jj) * rfact2 / e3t_n(ji,jj,1)
170         END DO
171      END DO
172
173      IF( iom_use("tcflx") .OR. iom_use("tcflxcum") .OR. kt == nitrst   &
174         &                 .OR. (ln_check_mass .AND. kt == nitend) )    &
175         t_oce_co2_flx  = glob_sum( 'p4zflx', oce_co2(:,:) * e1e2t(:,:) * 1000. )                    !  Total Flux of Carbon
176      t_oce_co2_flx_cum = t_oce_co2_flx_cum + t_oce_co2_flx       !  Cumulative Total Flux of Carbon
177!      t_atm_co2_flx     = glob_sum( 'p4zflx', satmco2(:,:) * e1e2t(:,:) )       ! Total atmospheric pCO2
178      t_atm_co2_flx     =  atcco2      ! Total atmospheric pCO2
179 
180      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
181         WRITE(charout, FMT="('flx ')")
182         CALL prt_ctl_trc_info(charout)
183         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
184      ENDIF
185
186      IF( lk_iomput .AND. knt == nrdttrc ) THEN
187         CALL iom_put( "AtmCo2"  , satmco2(:,:) * tmask(:,:,1) )   ! Atmospheric CO2 concentration
188         CALL iom_put( "Cflx"    , oce_co2(:,:) * 1000. ) 
189         CALL iom_put( "Oflx"    , zoflx(:,:) * 1000.  )
190         CALL iom_put( "Kg"      , zkgco2(:,:) * tmask(:,:,1)  )
191         CALL iom_put( "Dpco2"   , ( zpco2atm(:,:) - zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1) )
192         CALL iom_put( "pCO2sea" , ( zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1) )
193         CALL iom_put( "Dpo2"    , ( atcox * patm(:,:) - atcox * trb(:,:,1,jpoxy) / ( chemo2(:,:,1) + rtrn ) ) * tmask(:,:,1) )
194         CALL iom_put( "tcflx"   , t_oce_co2_flx     )   ! molC/s
195         CALL iom_put( "tcflxcum", t_oce_co2_flx_cum )   ! molC
196      ENDIF
197      !
198      IF( ln_timing )   CALL timing_stop('p4z_flx')
199      !
200   END SUBROUTINE p4z_flx
201
202
203   SUBROUTINE p4z_flx_init
204      !!----------------------------------------------------------------------
205      !!                  ***  ROUTINE p4z_flx_init  ***
206      !!
207      !! ** Purpose :   Initialization of atmospheric conditions
208      !!
209      !! ** Method  :   Read the nampisext namelist and check the parameters
210      !!      called at the first timestep (nittrc000)
211      !!
212      !! ** input   :   Namelist nampisext
213      !!----------------------------------------------------------------------
214      INTEGER ::   jm, ios   ! Local integer
215      !!
216      NAMELIST/nampisext/ln_co2int, atcco2, clname, nn_offset
217      !!----------------------------------------------------------------------
218      IF(lwp) THEN
219         WRITE(numout,*)
220         WRITE(numout,*) ' p4z_flx_init : atmospheric conditions for air-sea flux calculation'
221         WRITE(numout,*) ' ~~~~~~~~~~~~'
222      ENDIF
223      !
224      READ  ( numnatp_ref, nampisext, IOSTAT = ios, ERR = 901)
225901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisext in reference namelist' )
226      READ  ( numnatp_cfg, nampisext, IOSTAT = ios, ERR = 902 )
227902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisext in configuration namelist' )
228      IF(lwm) WRITE ( numonp, nampisext )
229      !
230      IF(lwp) THEN                         ! control print
231         WRITE(numout,*) '   Namelist : nampisext --- parameters for air-sea exchange'
232         WRITE(numout,*) '      reading in the atm pCO2 file or constant value   ln_co2int =', ln_co2int
233      ENDIF
234      !
235      CALL p4z_patm( nit000 )
236      !
237      IF( .NOT.ln_co2int .AND. .NOT.ln_presatmco2 ) THEN
238         IF(lwp) THEN                         ! control print
239            WRITE(numout,*) '         Constant Atmospheric pCO2 value               atcco2    =', atcco2
240         ENDIF
241         satmco2(:,:)  = atcco2      ! Initialisation of atmospheric pco2
242      ELSEIF( ln_co2int .AND. .NOT.ln_presatmco2 ) THEN
243         IF(lwp)  THEN
244            WRITE(numout,*) '         Constant Atmospheric pCO2 value               atcco2    =', atcco2
245            WRITE(numout,*) '         Atmospheric pCO2 value  from file             clname    =', TRIM( clname )
246            WRITE(numout,*) '         Offset model-data start year                  nn_offset =', nn_offset
247         ENDIF
248         CALL ctl_opn( numco2, TRIM( clname) , 'OLD', 'FORMATTED', 'SEQUENTIAL', -1 , numout, lwp )
249         jm = 0                      ! Count the number of record in co2 file
250         DO
251           READ(numco2,*,END=100) 
252           jm = jm + 1
253         END DO
254 100     nmaxrec = jm - 1 
255         ALLOCATE( years  (nmaxrec) )   ;   years  (:) = 0._wp
256         ALLOCATE( atcco2h(nmaxrec) )   ;   atcco2h(:) = 0._wp
257         !
258         REWIND(numco2)
259         DO jm = 1, nmaxrec          ! get  xCO2 data
260            READ(numco2, *)  years(jm), atcco2h(jm)
261            IF(lwp) WRITE(numout, '(f6.0,f7.2)')  years(jm), atcco2h(jm)
262         END DO
263         CLOSE(numco2)
264      ELSEIF( .NOT.ln_co2int .AND. ln_presatmco2 ) THEN
265         IF(lwp) WRITE(numout,*) '    Spatialized Atmospheric pCO2 from an external file'
266      ELSE
267         IF(lwp) WRITE(numout,*) '    Spatialized Atmospheric pCO2 from an external file'
268      ENDIF
269      !
270      oce_co2(:,:)  = 0._wp                ! Initialization of Flux of Carbon
271      t_oce_co2_flx = 0._wp
272      t_atm_co2_flx = 0._wp
273      !
274   END SUBROUTINE p4z_flx_init
275
276
277   SUBROUTINE p4z_patm( kt )
278      !!----------------------------------------------------------------------
279      !!                  ***  ROUTINE p4z_atm  ***
280      !!
281      !! ** Purpose :   Read and interpolate the external atmospheric sea-level pressure
282      !! ** Method  :   Read the files and interpolate the appropriate variables
283      !!
284      !!----------------------------------------------------------------------
285      INTEGER, INTENT(in) ::   kt   ! ocean time step
286      !
287      INTEGER            ::   ierr, ios   ! Local integer
288      CHARACTER(len=100) ::   cn_dir      ! Root directory for location of ssr files
289      TYPE(FLD_N)        ::   sn_patm     ! informations about the fields to be read
290      TYPE(FLD_N)        ::   sn_atmco2   ! informations about the fields to be read
291      !!
292      NAMELIST/nampisatm/ ln_presatm, ln_presatmco2, sn_patm, sn_atmco2, cn_dir
293      !!----------------------------------------------------------------------
294      !
295      IF( kt == nit000 ) THEN    !==  First call kt=nittrc000  ==!
296         !
297         IF(lwp) THEN
298            WRITE(numout,*)
299            WRITE(numout,*) ' p4z_patm : sea-level atmospheric pressure'
300            WRITE(numout,*) ' ~~~~~~~~'
301         ENDIF
302         !
303         READ  ( numnatp_ref, nampisatm, IOSTAT = ios, ERR = 901)
304901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in reference namelist' )
305         READ  ( numnatp_cfg, nampisatm, IOSTAT = ios, ERR = 902 )
306902      IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisatm in configuration namelist' )
307         IF(lwm) WRITE ( numonp, nampisatm )
308         !
309         !
310         IF(lwp) THEN                                 !* control print
311            WRITE(numout,*) '   Namelist : nampisatm --- Atmospheric Pressure as external forcing'
312            WRITE(numout,*) '      constant atmopsheric pressure (F) or from a file (T)  ln_presatm    = ', ln_presatm
313            WRITE(numout,*) '      spatial atmopsheric CO2 for flux calcs                ln_presatmco2 = ', ln_presatmco2
314         ENDIF
315         !
316         IF( ln_presatm ) THEN
317            ALLOCATE( sf_patm(1), STAT=ierr )           !* allocate and fill sf_patm (forcing structure) with sn_patm
318            IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_patm structure' )
319            !
320            CALL fld_fill( sf_patm, (/ sn_patm /), cn_dir, 'p4z_flx', 'Atmospheric pressure ', 'nampisatm' )
321                                   ALLOCATE( sf_patm(1)%fnow(jpi,jpj,1)   )
322            IF( sn_patm%ln_tint )  ALLOCATE( sf_patm(1)%fdta(jpi,jpj,1,2) )
323         ENDIF
324         !                                         
325         IF( ln_presatmco2 ) THEN
326            ALLOCATE( sf_atmco2(1), STAT=ierr )           !* allocate and fill sf_atmco2 (forcing structure) with sn_atmco2
327            IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_atmco2 structure' )
328            !
329            CALL fld_fill( sf_atmco2, (/ sn_atmco2 /), cn_dir, 'p4z_flx', 'Atmospheric co2 partial pressure ', 'nampisatm' )
330                                   ALLOCATE( sf_atmco2(1)%fnow(jpi,jpj,1)   )
331            IF( sn_atmco2%ln_tint )  ALLOCATE( sf_atmco2(1)%fdta(jpi,jpj,1,2) )
332         ENDIF
333         !
334         IF( .NOT.ln_presatm )   patm(:,:) = 1._wp    ! Initialize patm if no reading from a file
335         !
336      ENDIF
337      !
338      IF( ln_presatm ) THEN
339         CALL fld_read( kt, 1, sf_patm )               !* input Patm provided at kt + 1/2
340         patm(:,:) = sf_patm(1)%fnow(:,:,1)                        ! atmospheric pressure
341      ENDIF
342      !
343      IF( ln_presatmco2 ) THEN
344         CALL fld_read( kt, 1, sf_atmco2 )               !* input atmco2 provided at kt + 1/2
345         satmco2(:,:) = sf_atmco2(1)%fnow(:,:,1)                        ! atmospheric pressure
346      ELSE
347         satmco2(:,:) = atcco2    ! Initialize atmco2 if no reading from a file
348      ENDIF
349      !
350   END SUBROUTINE p4z_patm
351
352
353   INTEGER FUNCTION p4z_flx_alloc()
354      !!----------------------------------------------------------------------
355      !!                     ***  ROUTINE p4z_flx_alloc  ***
356      !!----------------------------------------------------------------------
357      ALLOCATE( satmco2(jpi,jpj), patm(jpi,jpj), STAT=p4z_flx_alloc )
358      !
359      IF( p4z_flx_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_flx_alloc : failed to allocate arrays' )
360      !
361   END FUNCTION p4z_flx_alloc
362
363   !!======================================================================
364END MODULE p4zflx
Note: See TracBrowser for help on using the repository browser.