source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/TOP/PISCES/P4Z/p4zligand.F90 @ 12257

Last change on this file since 12257 was 12257, checked in by cetlod, 10 months ago

dev_r12072_MERGE_OPTION2_2019: Cleaning PISCES diagnostics output ; fully sette tested

  • Property svn:keywords set to Id
File size: 6.3 KB
Line 
1MODULE p4zligand
2   !!======================================================================
3   !!                         ***  MODULE p4zligand  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic ligands
5   !!=========================================================================
6   !! History :   3.6  !  2016-03  (O. Aumont, A. Tagliabue) Quota model and reorganization
7   !!----------------------------------------------------------------------
8   !!   p4z_ligand     :  Compute remineralization/dissolution of organic ligands
9   !!   p4z_ligand_init:  Initialisation of parameters for remineralisation
10   !!----------------------------------------------------------------------
11   USE oce_trc         ! shared variables between ocean and passive tracers
12   USE trc             ! passive tracers common variables
13   USE sms_pisces      ! PISCES Source Minus Sink variables
14   USE prtctl_trc      ! print control for debugging
15   USE iom             !  I/O manager
16
17   IMPLICIT NONE
18   PRIVATE
19
20   PUBLIC   p4z_ligand         ! called in p4zbio.F90
21   PUBLIC   p4z_ligand_init    ! called in trcsms_pisces.F90
22
23   REAL(wp), PUBLIC ::  rlgw     !: lifetime (years) of weak ligands
24   REAL(wp), PUBLIC ::  rlgs     !: lifetime (years) of strong ligands
25   REAL(wp), PUBLIC ::  rlig     !: Remin ligand production
26   REAL(wp), PUBLIC ::  prlgw    !: Photochemical of weak ligand
27
28   !!----------------------------------------------------------------------
29   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
30   !! $Id$
31   !! Software governed by the CeCILL license (see ./LICENSE)
32   !!----------------------------------------------------------------------
33CONTAINS
34
35   SUBROUTINE p4z_ligand( kt, knt )
36      !!---------------------------------------------------------------------
37      !!                     ***  ROUTINE p4z_ligand  ***
38      !!
39      !! ** Purpose :   Compute remineralization/scavenging of organic ligands
40      !!---------------------------------------------------------------------
41      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
42      !
43      INTEGER  ::   ji, jj, jk
44      REAL(wp) ::   zlgwp, zlgwpr, zlgwr, zlablgw
45      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zligrem, zligpr, zligprod
46      CHARACTER (len=25) ::   charout
47      !!---------------------------------------------------------------------
48      !
49      IF( ln_timing )   CALL timing_start('p4z_ligand')
50      !
51      DO jk = 1, jpkm1
52         DO jj = 1, jpj
53            DO ji = 1, jpi
54               !
55               ! ------------------------------------------------------------------
56               ! Remineralization of iron ligands
57               ! ------------------------------------------------------------------
58               ! production from remineralisation of organic matter
59               zlgwp = orem(ji,jj,jk) * rlig
60               ! decay of weak ligand
61               ! This is based on the idea that as LGW is lower
62               ! there is a larger fraction of refractory OM
63               zlgwr = max( rlgs , rlgw * exp( -2 * (trb(ji,jj,jk,jplgw)*1e9) ) ) ! years
64               zlgwr = 1. / zlgwr * tgfunc(ji,jj,jk) * ( xstep / nyear_len(1) ) * blim(ji,jj,jk) * trb(ji,jj,jk,jplgw)
65               ! photochem loss of weak ligand
66               zlgwpr = prlgw * xstep * etot(ji,jj,jk) * trb(ji,jj,jk,jplgw) * (1. - fr_i(ji,jj))
67               tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zlgwp - zlgwr - zlgwpr
68               zligrem(ji,jj,jk)   = zlgwr
69               zligpr(ji,jj,jk)    = zlgwpr
70               zligprod(ji,jj,jk)  = zlgwp
71               !
72            END DO
73         END DO
74      END DO
75      !
76      !  Output of some diagnostics variables
77      !     ---------------------------------
78      IF( lk_iomput .AND. knt == nrdttrc ) THEN
79         IF( iom_use( "LIGREM" ) ) THEN
80           zligrem(:,:,jpk) = 0.  ; CALL iom_put( "LIGREM", zligrem(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) )
81         ENDIF
82         IF( iom_use( "LIGPR" ) ) THEN
83           zligpr(:,:,jpk) = 0.   ; CALL iom_put( "LIGPR" , zligpr(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) )
84         ENDIF
85         IF( iom_use( "LPRODR" ) ) THEN
86           zligprod(:,:,jpk) = 0. ; CALL iom_put( "LPRODR", zligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) )
87         ENDIF
88      ENDIF
89      !
90      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
91         WRITE(charout, FMT="('ligand1')")
92         CALL prt_ctl_trc_info(charout)
93         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
94      ENDIF
95      !
96      IF( ln_timing )   CALL timing_stop('p4z_ligand')
97      !
98   END SUBROUTINE p4z_ligand
99
100
101   SUBROUTINE p4z_ligand_init
102      !!----------------------------------------------------------------------
103      !!                  ***  ROUTINE p4z_ligand_init  ***
104      !!
105      !! ** Purpose :   Initialization of remineralization parameters
106      !!
107      !! ** Method  :   Read the nampislig namelist and check the parameters
108      !!
109      !! ** input   :   Namelist nampislig
110      !!----------------------------------------------------------------------
111      INTEGER ::   ios   ! Local integer
112      !
113      NAMELIST/nampislig/ rlgw, prlgw, rlgs, rlig
114      !!----------------------------------------------------------------------
115      !
116      IF(lwp) THEN
117         WRITE(numout,*)
118         WRITE(numout,*) 'p4z_ligand_init : remineralization/scavenging of organic ligands'
119         WRITE(numout,*) '~~~~~~~~~~~~~~~'
120      ENDIF
121      READ  ( numnatp_ref, nampislig, IOSTAT = ios, ERR = 901)
122901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampislig in reference namelist' )
123      READ  ( numnatp_cfg, nampislig, IOSTAT = ios, ERR = 902 )
124902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampislig in configuration namelist' )
125      IF(lwm) WRITE ( numonp, nampislig )
126      !
127      IF(lwp) THEN                         ! control print
128         WRITE(numout,*) '   Namelist : nampislig'
129         WRITE(numout,*) '      Lifetime (years) of weak ligands             rlgw  =', rlgw
130         WRITE(numout,*) '      Remin ligand production per unit C           rlig  =', rlig
131         WRITE(numout,*) '      Photolysis of weak ligand                    prlgw =', prlgw
132         WRITE(numout,*) '      Lifetime (years) of strong ligands           rlgs  =', rlgs
133      ENDIF
134      !
135   END SUBROUTINE p4z_ligand_init
136
137   !!======================================================================
138END MODULE p4zligand
Note: See TracBrowser for help on using the repository browser.