source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/TOP/PISCES/P4Z/p4zlys.F90 @ 12257

Last change on this file since 12257 was 12257, checked in by cetlod, 11 months ago

dev_r12072_MERGE_OPTION2_2019: Cleaning PISCES diagnostics output ; fully sette tested

  • Property svn:keywords set to Id
File size: 8.1 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr)  Calcon salinity dependence
12   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improvment of calcite dissolution
13   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
14   !!----------------------------------------------------------------------
15   !!   p4z_lys        :   Compute the CaCO3 dissolution
16   !!   p4z_lys_init   :   Read the namelist parameters
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zche          !  Chemical model
22   USE prtctl_trc      !  print control for debugging
23   USE iom             !  I/O manager
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
29   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
30
31   REAL(wp), PUBLIC ::   kdca   !: diss. rate constant calcite
32   REAL(wp), PUBLIC ::   nca    !: order of reaction for calcite dissolution
33
34   INTEGER  ::   rmtss              ! number of seconds per month
35   REAL(wp) ::   calcon = 1.03E-2   ! mean calcite concentration [Ca2+] in sea water [mole/kg solution]
36 
37   !!----------------------------------------------------------------------
38   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
39   !! $Id$
40   !! Software governed by the CeCILL license (see ./LICENSE)
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE p4z_lys( kt, knt )
46      !!---------------------------------------------------------------------
47      !!                     ***  ROUTINE p4z_lys  ***
48      !!
49      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
50      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
51      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
52      !!
53      !! ** Method  : - ???
54      !!---------------------------------------------------------------------
55      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step and ???
56      !
57      INTEGER  ::   ji, jj, jk, jn
58      REAL(wp) ::   zdispot, zfact, zcalcon
59      REAL(wp) ::   zomegaca, zexcess, zexcess0
60      CHARACTER (len=25) ::   charout
61      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zco3, zcaldiss, zhinit, zhi, zco3sat
62      !!---------------------------------------------------------------------
63      !
64      IF( ln_timing )  CALL timing_start('p4z_lys')
65      !
66      zhinit  (:,:,:) = hi(:,:,:) * 1000. / ( rhop(:,:,:) + rtrn )
67      !
68      !     -------------------------------------------
69      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
70      !     -------------------------------------------
71
72      CALL solve_at_general( zhinit, zhi )
73
74      DO jk = 1, jpkm1
75         DO jj = 1, jpj
76            DO ji = 1, jpi
77               zco3(ji,jj,jk) = trb(ji,jj,jk,jpdic) * ak13(ji,jj,jk) * ak23(ji,jj,jk) / (zhi(ji,jj,jk)**2   &
78                  &             + ak13(ji,jj,jk) * zhi(ji,jj,jk) + ak13(ji,jj,jk) * ak23(ji,jj,jk) + rtrn )
79               hi  (ji,jj,jk) = zhi(ji,jj,jk) * rhop(ji,jj,jk) / 1000.
80            END DO
81         END DO
82      END DO
83
84      !     ---------------------------------------------------------
85      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
86      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
87      !        MGCO3)
88      !     ---------------------------------------------------------
89
90      DO jk = 1, jpkm1
91         DO jj = 1, jpj
92            DO ji = 1, jpi
93
94               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
95               ! Salinity dependance in zomegaca and divide by rhop/1000 to have good units
96               zcalcon  = calcon * ( salinprac(ji,jj,jk) / 35._wp )
97               zfact    = rhop(ji,jj,jk) / 1000._wp
98               zomegaca = ( zcalcon * zco3(ji,jj,jk) ) / ( aksp(ji,jj,jk) * zfact + rtrn )
99               zco3sat(ji,jj,jk) = aksp(ji,jj,jk) * zfact / ( zcalcon + rtrn )
100
101               ! SET DEGREE OF UNDER-/SUPERSATURATION
102               excess(ji,jj,jk) = 1._wp - zomegaca
103               zexcess0 = MAX( 0., excess(ji,jj,jk) )
104               zexcess  = zexcess0**nca
105
106               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
107               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
108               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
109               zdispot = kdca * zexcess * trb(ji,jj,jk,jpcal)
110              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
111              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
112              zcaldiss(ji,jj,jk)  = zdispot * rfact2 / rmtss ! calcite dissolution
113              !
114              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zcaldiss(ji,jj,jk)
115              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zcaldiss(ji,jj,jk)
116              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zcaldiss(ji,jj,jk)
117            END DO
118         END DO
119      END DO
120      !
121
122      IF( lk_iomput .AND. knt == nrdttrc ) THEN
123         CALL iom_put( "PH"  , -1. * LOG10( MAX( hi(:,:,:), rtrn ) ) * tmask(:,:,:) )
124         IF( iom_use( "CO3" ) ) THEN
125            zco3(:,:,jpk) = 0.    ; CALL iom_put( "CO3"   , zco3(:,:,:)     * 1.e+3           * tmask(:,:,:) )
126         ENDIF
127         IF( iom_use( "CO3sat" ) ) THEN
128           zco3sat(:,:,jpk) = 0.  ; CALL iom_put( "CO3sat", zco3sat(:,:,:)  * 1.e+3           * tmask(:,:,:) )
129         ENDIF
130         IF( iom_use( "DCAL" ) ) THEN
131           zcaldiss(:,:,jpk) = 0. ; CALL iom_put( "DCAL"  , zcaldiss(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) )
132         ENDIF
133      ENDIF
134      !
135      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
136        WRITE(charout, FMT="('lys ')")
137        CALL prt_ctl_trc_info(charout)
138        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
139      ENDIF
140      !
141      IF( ln_timing )   CALL timing_stop('p4z_lys')
142      !
143   END SUBROUTINE p4z_lys
144
145
146   SUBROUTINE p4z_lys_init
147      !!----------------------------------------------------------------------
148      !!                  ***  ROUTINE p4z_lys_init  ***
149      !!
150      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
151      !!
152      !! ** Method  :   Read the nampiscal namelist and check the parameters
153      !!      called at the first timestep (nittrc000)
154      !!
155      !! ** input   :   Namelist nampiscal
156      !!
157      !!----------------------------------------------------------------------
158      INTEGER ::   ios   ! Local integer
159      !
160      NAMELIST/nampiscal/ kdca, nca
161      !!----------------------------------------------------------------------
162      IF(lwp) THEN
163         WRITE(numout,*)
164         WRITE(numout,*) 'p4z_lys_init : initialization of CaCO3 dissolution'
165         WRITE(numout,*) '~~~~~~~~~~~~'
166      ENDIF
167      !
168      READ  ( numnatp_ref, nampiscal, IOSTAT = ios, ERR = 901)
169901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampiscal in reference namelist' )
170      READ  ( numnatp_cfg, nampiscal, IOSTAT = ios, ERR = 902 )
171902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampiscal in configuration namelist' )
172      IF(lwm) WRITE( numonp, nampiscal )
173      !
174      IF(lwp) THEN                         ! control print
175         WRITE(numout,*) '   Namelist : nampiscal'
176         WRITE(numout,*) '      diss. rate constant calcite (per month)        kdca =', kdca
177         WRITE(numout,*) '      order of reaction for calcite dissolution      nca  =', nca
178      ENDIF
179      !
180      ! Number of seconds per month
181      rmtss =  nyear_len(1) * rday / raamo
182      !
183   END SUBROUTINE p4z_lys_init
184
185   !!======================================================================
186END MODULE p4zlys
Note: See TracBrowser for help on using the repository browser.