source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/TOP/PISCES/P4Z/p4zopt.F90 @ 12257

Last change on this file since 12257 was 12257, checked in by cetlod, 11 months ago

dev_r12072_MERGE_OPTION2_2019: Cleaning PISCES diagnostics output ; fully sette tested

  • Property svn:keywords set to Id
File size: 19.7 KB
Line 
1MODULE p4zopt
2   !!======================================================================
3   !!                         ***  MODULE p4zopt  ***
4   !! TOP - PISCES : Compute the light availability in the water column
5   !!======================================================================
6   !! History :  1.0  !  2004     (O. Aumont) Original code
7   !!            2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!            3.2  !  2009-04  (C. Ethe, G. Madec)  optimisation
9   !!            3.4  !  2011-06  (O. Aumont, C. Ethe) Improve light availability of nano & diat
10   !!----------------------------------------------------------------------
11   !!   p4z_opt       : light availability in the water column
12   !!----------------------------------------------------------------------
13   USE trc            ! tracer variables
14   USE oce_trc        ! tracer-ocean share variables
15   USE sms_pisces     ! Source Minus Sink of PISCES
16   USE iom            ! I/O manager
17   USE fldread        !  time interpolation
18   USE prtctl_trc     !  print control for debugging
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p4z_opt        ! called in p4zbio.F90 module
24   PUBLIC   p4z_opt_init   ! called in trcsms_pisces.F90 module
25   PUBLIC   p4z_opt_alloc
26
27   !! * Shared module variables
28
29   LOGICAL  ::   ln_varpar   ! boolean for variable PAR fraction
30   REAL(wp) ::   parlux      ! Fraction of shortwave as PAR
31   REAL(wp) ::   xparsw      ! parlux/3
32   REAL(wp) ::   xsi0r       ! 1. /rn_si0
33
34   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_par      ! structure of input par
35   INTEGER , PARAMETER :: nbtimes = 366  !: maximum number of times record in a file
36   INTEGER  :: ntimes_par                ! number of time steps in a file
37   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   par_varsw      ! PAR fraction of shortwave
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ekb, ekg, ekr  ! wavelength (Red-Green-Blue)
39
40   INTEGER  ::   nksrp   ! levels below which the light cannot penetrate ( depth larger than 391 m)
41
42   REAL(wp), DIMENSION(3,61) ::   xkrgb   ! tabulated attenuation coefficients for RGB absorption
43   
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE p4z_opt( kt, knt )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_opt  ***
54      !!
55      !! ** Purpose :   Compute the light availability in the water column
56      !!              depending on the depth and the chlorophyll concentration
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step
61      !
62      INTEGER  ::   ji, jj, jk
63      INTEGER  ::   irgb
64      REAL(wp) ::   zchl
65      REAL(wp) ::   zc0 , zc1 , zc2, zc3, z1_dep
66      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zetmp5
67      REAL(wp), DIMENSION(jpi,jpj    ) :: zdepmoy, zetmp1, zetmp2, zetmp3, zetmp4
68      REAL(wp), DIMENSION(jpi,jpj    ) :: zqsr100, zqsr_corr
69      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpar, ze0, ze1, ze2, ze3, zchl3d
70      !!---------------------------------------------------------------------
71      !
72      IF( ln_timing )   CALL timing_start('p4z_opt')
73
74      IF( knt == 1 .AND. ln_varpar )   CALL p4z_opt_sbc( kt )
75
76      !     Initialisation of variables used to compute PAR
77      !     -----------------------------------------------
78      ze1(:,:,:) = 0._wp
79      ze2(:,:,:) = 0._wp
80      ze3(:,:,:) = 0._wp
81      !
82      !                                        !* attenuation coef. function of Chlorophyll and wavelength (Red-Green-Blue)
83      !                                        !  --------------------------------------------------------
84                     zchl3d(:,:,:) = trb(:,:,:,jpnch) + trb(:,:,:,jpdch)
85      IF( ln_p5z )   zchl3d(:,:,:) = zchl3d(:,:,:)    + trb(:,:,:,jppch)
86      !
87      DO jk = 1, jpkm1   
88         DO jj = 1, jpj
89            DO ji = 1, jpi
90               zchl = ( zchl3d(ji,jj,jk) + rtrn ) * 1.e6
91               zchl = MIN(  10. , MAX( 0.05, zchl )  )
92               irgb = NINT( 41 + 20.* LOG10( zchl ) + rtrn )
93               !                                                         
94               ekb(ji,jj,jk) = xkrgb(1,irgb) * e3t_n(ji,jj,jk)
95               ekg(ji,jj,jk) = xkrgb(2,irgb) * e3t_n(ji,jj,jk)
96               ekr(ji,jj,jk) = xkrgb(3,irgb) * e3t_n(ji,jj,jk)
97            END DO
98         END DO
99      END DO
100      !                                        !* Photosynthetically Available Radiation (PAR)
101      !                                        !  --------------------------------------
102      IF( l_trcdm2dc ) THEN                     !  diurnal cycle
103         !
104         zqsr_corr(:,:) = qsr_mean(:,:) / ( 1.-fr_i(:,:) + rtrn )
105         !
106         CALL p4z_opt_par( kt, zqsr_corr, ze1, ze2, ze3, pqsr100 = zqsr100 ) 
107         !
108         DO jk = 1, nksrp     
109            etot_ndcy(:,:,jk) =        ze1(:,:,jk) +        ze2(:,:,jk) +       ze3(:,:,jk)
110            enano    (:,:,jk) =  1.85 * ze1(:,:,jk) + 0.69 * ze2(:,:,jk) + 0.46 * ze3(:,:,jk)
111            ediat    (:,:,jk) =  1.62 * ze1(:,:,jk) + 0.74 * ze2(:,:,jk) + 0.63 * ze3(:,:,jk)
112         END DO
113         IF( ln_p5z ) THEN
114            DO jk = 1, nksrp     
115              epico  (:,:,jk) =  1.94 * ze1(:,:,jk) + 0.66 * ze2(:,:,jk) + 0.4 * ze3(:,:,jk)
116            END DO
117         ENDIF
118         !
119         zqsr_corr(:,:) = qsr(:,:) / ( 1.-fr_i(:,:) + rtrn )
120         !
121         CALL p4z_opt_par( kt, zqsr_corr, ze1, ze2, ze3 ) 
122         !
123         DO jk = 1, nksrp     
124            etot(:,:,jk) =  ze1(:,:,jk) + ze2(:,:,jk) + ze3(:,:,jk)
125         END DO
126         !
127      ELSE
128         !
129         zqsr_corr(:,:) = qsr(:,:) / ( 1.-fr_i(:,:) + rtrn )
130         !
131         CALL p4z_opt_par( kt, zqsr_corr, ze1, ze2, ze3, pqsr100 = zqsr100  ) 
132         !
133         DO jk = 1, nksrp     
134            etot (:,:,jk) =         ze1(:,:,jk) +        ze2(:,:,jk) +       ze3(:,:,jk)
135            enano(:,:,jk) =  1.85 * ze1(:,:,jk) + 0.69 * ze2(:,:,jk) + 0.46 * ze3(:,:,jk)
136            ediat(:,:,jk) =  1.62 * ze1(:,:,jk) + 0.74 * ze2(:,:,jk) + 0.63 * ze3(:,:,jk)
137         END DO
138         IF( ln_p5z ) THEN
139            DO jk = 1, nksrp     
140              epico(:,:,jk) =  1.94 * ze1(:,:,jk) + 0.66 * ze2(:,:,jk) + 0.4 * ze3(:,:,jk)
141            END DO
142         ENDIF
143         etot_ndcy(:,:,:) =  etot(:,:,:) 
144      ENDIF
145
146
147      IF( ln_qsr_bio ) THEN                    !* heat flux accros w-level (used in the dynamics)
148         !                                     !  ------------------------
149         CALL p4z_opt_par( kt, qsr, ze1, ze2, ze3, pe0=ze0 )
150         !
151         etot3(:,:,1) =  qsr(:,:) * tmask(:,:,1)
152         DO jk = 2, nksrp + 1
153            etot3(:,:,jk) =  ( ze0(:,:,jk) + ze1(:,:,jk) + ze2(:,:,jk) + ze3(:,:,jk) ) * tmask(:,:,jk)
154         END DO
155         !                                     !  ------------------------
156      ENDIF
157      !                                        !* Euphotic depth and level
158      neln   (:,:) = 1                            !  ------------------------
159      heup   (:,:) = gdepw_n(:,:,2)
160      heup_01(:,:) = gdepw_n(:,:,2)
161
162      DO jk = 2, nksrp
163         DO jj = 1, jpj
164           DO ji = 1, jpi
165              IF( etot_ndcy(ji,jj,jk) * tmask(ji,jj,jk) >=  zqsr100(ji,jj) )  THEN
166                 neln(ji,jj) = jk+1                    ! Euphotic level : 1rst T-level strictly below Euphotic layer
167                 !                                     ! nb: ensure the compatibility with nmld_trc definition in trd_mld_trc_zint
168                 heup(ji,jj) = gdepw_n(ji,jj,jk+1)     ! Euphotic layer depth
169              ENDIF
170              IF( etot_ndcy(ji,jj,jk) * tmask(ji,jj,jk) >= 0.50 )  THEN
171                 heup_01(ji,jj) = gdepw_n(ji,jj,jk+1)  ! Euphotic layer depth (light level definition)
172              ENDIF
173           END DO
174        END DO
175      END DO
176      !
177      heup   (:,:) = MIN( 300., heup   (:,:) )
178      heup_01(:,:) = MIN( 300., heup_01(:,:) )
179      !                                        !* mean light over the mixed layer
180      zdepmoy(:,:)   = 0.e0                    !  -------------------------------
181      zetmp1 (:,:)   = 0.e0
182      zetmp2 (:,:)   = 0.e0
183
184      DO jk = 1, nksrp
185         DO jj = 1, jpj
186            DO ji = 1, jpi
187               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
188                  zetmp1 (ji,jj) = zetmp1 (ji,jj) + etot     (ji,jj,jk) * e3t_n(ji,jj,jk) ! remineralisation
189                  zetmp2 (ji,jj) = zetmp2 (ji,jj) + etot_ndcy(ji,jj,jk) * e3t_n(ji,jj,jk) ! production
190                  zdepmoy(ji,jj) = zdepmoy(ji,jj) +                       e3t_n(ji,jj,jk)
191               ENDIF
192            END DO
193         END DO
194      END DO
195      !
196      emoy(:,:,:) = etot(:,:,:)       ! remineralisation
197      zpar(:,:,:) = etot_ndcy(:,:,:)  ! diagnostic : PAR with no diurnal cycle
198      !
199      DO jk = 1, nksrp
200         DO jj = 1, jpj
201            DO ji = 1, jpi
202               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
203                  z1_dep = 1. / ( zdepmoy(ji,jj) + rtrn )
204                  emoy (ji,jj,jk) = zetmp1(ji,jj) * z1_dep
205                  zpar (ji,jj,jk) = zetmp2(ji,jj) * z1_dep
206               ENDIF
207            END DO
208         END DO
209      END DO
210      !
211      zdepmoy(:,:)   = 0.e0
212      zetmp3 (:,:)   = 0.e0
213      zetmp4 (:,:)   = 0.e0
214      !
215      DO jk = 1, nksrp
216         DO jj = 1, jpj
217            DO ji = 1, jpi
218               IF( gdepw_n(ji,jj,jk+1) <= MIN(hmld(ji,jj), heup_01(ji,jj)) ) THEN
219                  zetmp3 (ji,jj) = zetmp3 (ji,jj) + enano    (ji,jj,jk) * e3t_n(ji,jj,jk) ! production
220                  zetmp4 (ji,jj) = zetmp4 (ji,jj) + ediat    (ji,jj,jk) * e3t_n(ji,jj,jk) ! production
221                  zdepmoy(ji,jj) = zdepmoy(ji,jj) +                       e3t_n(ji,jj,jk)
222               ENDIF
223            END DO
224         END DO
225      END DO
226      enanom(:,:,:) = enano(:,:,:)
227      ediatm(:,:,:) = ediat(:,:,:)
228      !
229      DO jk = 1, nksrp
230         DO jj = 1, jpj
231            DO ji = 1, jpi
232               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
233                  z1_dep = 1. / ( zdepmoy(ji,jj) + rtrn )
234                  enanom(ji,jj,jk) = zetmp3(ji,jj) * z1_dep
235                  ediatm(ji,jj,jk) = zetmp4(ji,jj) * z1_dep
236               ENDIF
237            END DO
238         END DO
239      END DO
240      !
241      IF( ln_p5z ) THEN
242         ALLOCATE( zetmp5(jpi,jpj) )  ;   zetmp5 (:,:) = 0.e0
243         DO jk = 1, nksrp
244            DO jj = 1, jpj
245               DO ji = 1, jpi
246                  IF( gdepw_n(ji,jj,jk+1) <= MIN(hmld(ji,jj), heup_01(ji,jj)) ) THEN
247                     zetmp5(ji,jj)  = zetmp5 (ji,jj) + epico(ji,jj,jk) * e3t_n(ji,jj,jk) ! production
248                  ENDIF
249               END DO
250            END DO
251         END DO
252         !
253         epicom(:,:,:) = epico(:,:,:)
254         !
255         DO jk = 1, nksrp
256            DO jj = 1, jpj
257               DO ji = 1, jpi
258                  IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
259                     z1_dep = 1. / ( zdepmoy(ji,jj) + rtrn )
260                     epicom(ji,jj,jk) = zetmp5(ji,jj) * z1_dep
261                  ENDIF
262               END DO
263            END DO
264         END DO
265         DEALLOCATE( zetmp5 )
266      ENDIF
267      !
268      IF( lk_iomput .AND.  knt == nrdttrc ) THEN
269         CALL iom_put( "Heup" , heup(:,:  ) * tmask(:,:,1) )  ! euphotic layer deptht
270         CALL iom_put( "PARDM", zpar(:,:,:) * tmask(:,:,:) )  ! Photosynthetically Available Radiation
271         CALL iom_put( "PAR"  , emoy(:,:,:) * tmask(:,:,:) )  ! Photosynthetically Available Radiation
272      ENDIF
273      !
274      IF( ln_timing )   CALL timing_stop('p4z_opt')
275      !
276   END SUBROUTINE p4z_opt
277
278
279   SUBROUTINE p4z_opt_par( kt, pqsr, pe1, pe2, pe3, pe0, pqsr100 ) 
280      !!----------------------------------------------------------------------
281      !!                  ***  routine p4z_opt_par  ***
282      !!
283      !! ** purpose :   compute PAR of each wavelength (Red-Green-Blue)
284      !!                for a given shortwave radiation
285      !!
286      !!----------------------------------------------------------------------
287      INTEGER                         , INTENT(in)              ::   kt                ! ocean time-step
288      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   )           ::   pqsr              ! shortwave
289      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout)           ::   pe1 , pe2 , pe3   ! PAR ( R-G-B)
290      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout), OPTIONAL ::   pe0               !
291      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(  out), OPTIONAL ::   pqsr100           !
292      !
293      INTEGER    ::   ji, jj, jk     ! dummy loop indices
294      REAL(wp), DIMENSION(jpi,jpj) ::  zqsr   ! shortwave
295      !!----------------------------------------------------------------------
296
297      !  Real shortwave
298      IF( ln_varpar ) THEN  ;  zqsr(:,:) = par_varsw(:,:) * pqsr(:,:)
299      ELSE                  ;  zqsr(:,:) = xparsw         * pqsr(:,:)
300      ENDIF
301     
302      !  Light at the euphotic depth
303      IF( PRESENT( pqsr100 ) )   pqsr100(:,:) = 0.01 * 3. * zqsr(:,:)
304
305      IF( PRESENT( pe0 ) ) THEN     !  W-level
306         !
307         pe0(:,:,1) = pqsr(:,:) - 3. * zqsr(:,:)    !   ( 1 - 3 * alpha ) * q
308         pe1(:,:,1) = zqsr(:,:)         
309         pe2(:,:,1) = zqsr(:,:)
310         pe3(:,:,1) = zqsr(:,:)
311         !
312         DO jk = 2, nksrp + 1
313            DO jj = 1, jpj
314               DO ji = 1, jpi
315                  pe0(ji,jj,jk) = pe0(ji,jj,jk-1) * EXP( -e3t_n(ji,jj,jk-1) * xsi0r )
316                  pe1(ji,jj,jk) = pe1(ji,jj,jk-1) * EXP( -ekb  (ji,jj,jk-1 )        )
317                  pe2(ji,jj,jk) = pe2(ji,jj,jk-1) * EXP( -ekg  (ji,jj,jk-1 )        )
318                  pe3(ji,jj,jk) = pe3(ji,jj,jk-1) * EXP( -ekr  (ji,jj,jk-1 )        )
319               END DO
320              !
321            END DO
322            !
323         END DO
324        !
325      ELSE   ! T- level
326        !
327        pe1(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekb(:,:,1) )
328        pe2(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekg(:,:,1) )
329        pe3(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekr(:,:,1) )
330        !
331        DO jk = 2, nksrp     
332           DO jj = 1, jpj
333              DO ji = 1, jpi
334                 pe1(ji,jj,jk) = pe1(ji,jj,jk-1) * EXP( -0.5 * ( ekb(ji,jj,jk-1) + ekb(ji,jj,jk) ) )
335                 pe2(ji,jj,jk) = pe2(ji,jj,jk-1) * EXP( -0.5 * ( ekg(ji,jj,jk-1) + ekg(ji,jj,jk) ) )
336                 pe3(ji,jj,jk) = pe3(ji,jj,jk-1) * EXP( -0.5 * ( ekr(ji,jj,jk-1) + ekr(ji,jj,jk) ) )
337              END DO
338           END DO
339        END DO   
340        !
341      ENDIF
342      !
343   END SUBROUTINE p4z_opt_par
344
345
346   SUBROUTINE p4z_opt_sbc( kt )
347      !!----------------------------------------------------------------------
348      !!                  ***  routine p4z_opt_sbc  ***
349      !!
350      !! ** purpose :   read and interpolate the variable PAR fraction
351      !!                of shortwave radiation
352      !!
353      !! ** method  :   read the files and interpolate the appropriate variables
354      !!
355      !! ** input   :   external netcdf files
356      !!
357      !!----------------------------------------------------------------------
358      INTEGER, INTENT(in) ::   kt   ! ocean time step
359      !
360      INTEGER  :: ji,jj
361      REAL(wp) :: zcoef
362      !!---------------------------------------------------------------------
363      !
364      IF( ln_timing )  CALL timing_start('p4z_optsbc')
365      !
366      ! Compute par_varsw at nit000 or only if there is more than 1 time record in par coefficient file
367      IF( ln_varpar ) THEN
368         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_par > 1 ) ) THEN
369            CALL fld_read( kt, 1, sf_par )
370            par_varsw(:,:) = ( sf_par(1)%fnow(:,:,1) ) / 3.0
371         ENDIF
372      ENDIF
373      !
374      IF( ln_timing )  CALL timing_stop('p4z_optsbc')
375      !
376   END SUBROUTINE p4z_opt_sbc
377
378
379   SUBROUTINE p4z_opt_init
380      !!----------------------------------------------------------------------
381      !!                  ***  ROUTINE p4z_opt_init  ***
382      !!
383      !! ** Purpose :   Initialization of tabulated attenuation coef
384      !!                and of the percentage of PAR in Shortwave
385      !!
386      !! ** Input   :   external ascii and netcdf files
387      !!----------------------------------------------------------------------
388      INTEGER :: numpar, ierr, ios   ! Local integer
389      !
390      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
391      TYPE(FLD_N) ::   sn_par                ! informations about the fields to be read
392      !
393      NAMELIST/nampisopt/cn_dir, sn_par, ln_varpar, parlux
394      !!----------------------------------------------------------------------
395      IF(lwp) THEN
396         WRITE(numout,*)
397         WRITE(numout,*) 'p4z_opt_init : '
398         WRITE(numout,*) '~~~~~~~~~~~~ '
399      ENDIF
400      READ  ( numnatp_ref, nampisopt, IOSTAT = ios, ERR = 901)
401901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisopt in reference namelist' )
402      READ  ( numnatp_cfg, nampisopt, IOSTAT = ios, ERR = 902 )
403902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisopt in configuration namelist' )
404      IF(lwm) WRITE ( numonp, nampisopt )
405
406      IF(lwp) THEN
407         WRITE(numout,*) '   Namelist : nampisopt '
408         WRITE(numout,*) '      PAR as a variable fraction of SW     ln_varpar      = ', ln_varpar
409         WRITE(numout,*) '      Default value for the PAR fraction   parlux         = ', parlux
410      ENDIF
411      !
412      xparsw = parlux / 3.0
413      xsi0r  = 1.e0 / rn_si0
414      !
415      ! Variable PAR at the surface of the ocean
416      ! ----------------------------------------
417      IF( ln_varpar ) THEN
418         IF(lwp) WRITE(numout,*)
419         IF(lwp) WRITE(numout,*) '   ==>>>   initialize variable par fraction (ln_varpar=T)'
420         !
421         ALLOCATE( par_varsw(jpi,jpj) )
422         !
423         ALLOCATE( sf_par(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
424         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_opt_init: unable to allocate sf_par structure' )
425         !
426         CALL fld_fill( sf_par, (/ sn_par /), cn_dir, 'p4z_opt_init', 'Variable PAR fraction ', 'nampisopt' )
427                                   ALLOCATE( sf_par(1)%fnow(jpi,jpj,1)   )
428         IF( sn_par%ln_tint )      ALLOCATE( sf_par(1)%fdta(jpi,jpj,1,2) )
429
430         CALL iom_open (  TRIM( sn_par%clname ) , numpar )
431         ntimes_par = iom_getszuld( numpar )   ! get number of record in file
432      ENDIF
433      !
434      CALL trc_oce_rgb( xkrgb )                  ! tabulated attenuation coefficients
435      nksrp = trc_oce_ext_lev( r_si2, 0.33e2 )     ! max level of light extinction (Blue Chl=0.01)
436      !
437      IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksrp, ' ref depth = ', gdepw_1d(nksrp+1), ' m'
438      !
439                         ekr      (:,:,:) = 0._wp
440                         ekb      (:,:,:) = 0._wp
441                         ekg      (:,:,:) = 0._wp
442                         etot     (:,:,:) = 0._wp
443                         etot_ndcy(:,:,:) = 0._wp
444                         enano    (:,:,:) = 0._wp
445                         ediat    (:,:,:) = 0._wp
446      IF( ln_p5z     )   epico    (:,:,:) = 0._wp
447      IF( ln_qsr_bio )   etot3    (:,:,:) = 0._wp
448      !
449   END SUBROUTINE p4z_opt_init
450
451
452   INTEGER FUNCTION p4z_opt_alloc()
453      !!----------------------------------------------------------------------
454      !!                     ***  ROUTINE p4z_opt_alloc  ***
455      !!----------------------------------------------------------------------
456      !
457      ALLOCATE( ekb(jpi,jpj,jpk), ekr(jpi,jpj,jpk),  &
458                ekg(jpi,jpj,jpk), STAT= p4z_opt_alloc  ) 
459      !
460      IF( p4z_opt_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p4z_opt_alloc : failed to allocate arrays.' )
461      !
462   END FUNCTION p4z_opt_alloc
463
464   !!======================================================================
465END MODULE p4zopt
Note: See TracBrowser for help on using the repository browser.