source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/TOP/PISCES/P4Z/p5zmicro.F90 @ 12257

Last change on this file since 12257 was 12257, checked in by cetlod, 11 months ago

dev_r12072_MERGE_OPTION2_2019: Cleaning PISCES diagnostics output ; fully sette tested

  • Property svn:keywords set to Id
File size: 22.0 KB
Line 
1MODULE p5zmicro
2   !!======================================================================
3   !!                         ***  MODULE p5zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11   !!   p5z_micro       :   Compute the sources/sinks for microzooplankton
12   !!   p5z_micro_init  :   Initialize and read the appropriate namelist
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zlim
18   USE p5zlim          !  Phytoplankton limitation terms
19   USE iom             !  I/O manager
20   USE prtctl_trc      !  print control for debugging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p5z_micro         ! called in p5zbio.F90
26   PUBLIC   p5z_micro_init    ! called in trcsms_pisces.F90
27
28   !! * Shared module variables
29   REAL(wp), PUBLIC ::  part        !: part of calcite not dissolved in microzoo guts
30   REAL(wp), PUBLIC ::  xprefc     !: microzoo preference for POC
31   REAL(wp), PUBLIC ::  xprefn     !: microzoo preference for nanophyto
32   REAL(wp), PUBLIC ::  xprefp     !: microzoo preference for picophyto
33   REAL(wp), PUBLIC ::  xprefd     !: microzoo preference for diatoms
34   REAL(wp), PUBLIC ::  xprefz     !: microzoo preference for microzoo
35   REAL(wp), PUBLIC ::  xthreshdia  !: diatoms feeding threshold for microzooplankton
36   REAL(wp), PUBLIC ::  xthreshpic  !: picophyto feeding threshold for microzooplankton
37   REAL(wp), PUBLIC ::  xthreshphy  !: nanophyto threshold for microzooplankton
38   REAL(wp), PUBLIC ::  xthreshzoo  !: microzoo threshold for microzooplankton
39   REAL(wp), PUBLIC ::  xthreshpoc  !: poc threshold for microzooplankton
40   REAL(wp), PUBLIC ::  xthresh     !: feeding threshold for microzooplankton
41   REAL(wp), PUBLIC ::  resrat      !: exsudation rate of microzooplankton
42   REAL(wp), PUBLIC ::  mzrat       !: microzooplankton mortality rate
43   REAL(wp), PUBLIC ::  grazrat     !: maximal microzoo grazing rate
44   REAL(wp), PUBLIC ::  xkgraz      !: Half-saturation constant of assimilation
45   REAL(wp), PUBLIC ::  unassc      !: Non-assimilated part of food
46   REAL(wp), PUBLIC ::  unassn      !: Non-assimilated part of food
47   REAL(wp), PUBLIC ::  unassp      !: Non-assimilated part of food
48   REAL(wp), PUBLIC ::  epsher      !: Growth efficiency for microzoo
49   REAL(wp), PUBLIC ::  epshermin   !: Minimum growth efficiency for microzoo
50   REAL(wp), PUBLIC ::  srespir     !: half sturation constant for grazing 1
51   REAL(wp), PUBLIC ::  ssigma      !: Fraction excreted as semi-labile DOM
52   LOGICAL,  PUBLIC ::  bmetexc     !: Use of excess carbon for respiration
53
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
56   !! $Id$
57   !! Software governed by the CeCILL license (see ./LICENSE)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE p5z_micro( kt, knt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p5z_micro  ***
65      !!
66      !! ** Purpose :   Compute the sources/sinks for microzooplankton
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      INTEGER, INTENT(in) ::  kt  ! ocean time step
71      INTEGER, INTENT(in) ::  knt 
72      !
73      INTEGER  :: ji, jj, jk
74      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc, zcompapon, zcompapop
75      REAL(wp) :: zcompapi, zgraze  , zdenom, zfact, zfood, zfoodlim
76      REAL(wp) :: ztmp1, ztmp2, ztmp3, ztmp4, ztmp5, ztmptot
77      REAL(wp) :: zepsherf, zepshert, zepsherv, zrespirc, zrespirn, zrespirp, zbasresb, zbasresi
78      REAL(wp) :: zgraztotc, zgraztotn, zgraztotp, zgraztotf, zbasresn, zbasresp, zbasresf
79      REAL(wp) :: zgradoc, zgradon, zgradop, zgraref, zgradoct, zgradont, zgradopt, zgrareft
80      REAL(wp) :: zexcess, zgraren, zgrarep, zgrarem
81      REAL(wp) :: zgrapoc, zgrapon, zgrapop, zgrapof, zprcaca, zmortz
82      REAL(wp) :: zrespz, ztortz, zgrasratf, zgrasratn, zgrasratp
83      REAL(wp) :: zgraznc, zgraznn, zgraznp, zgrazpoc, zgrazpon, zgrazpop, zgrazpof
84      REAL(wp) :: zgrazdc, zgrazdn, zgrazdp, zgrazdf, zgraznf, zgrazz
85      REAL(wp) :: zgrazpc, zgrazpn, zgrazpp, zgrazpf, zbeta, zrfact2, zmetexcess
86      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo, zzligprod
87      CHARACTER (len=25) :: charout
88      !!---------------------------------------------------------------------
89      !
90      IF( ln_timing )   CALL timing_start('p5z_micro')
91      !
92      zmetexcess = 0.0
93      IF ( bmetexc ) zmetexcess = 1.0
94      !
95      DO jk = 1, jpkm1
96         DO jj = 1, jpj
97            DO ji = 1, jpi
98               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
99               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
100
101               !   Michaelis-Menten mortality rates of microzooplankton
102               !   -----------------------------------------------------
103               zrespz = resrat * zfact * ( trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
104               &        + 3. * nitrfac(ji,jj,jk) )
105
106               !   Zooplankton mortality. A square function has been selected with
107               !   no real reason except that it seems to be more stable and may mimic predation.
108               !   ------------------------------------------------------------------------------
109               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
110
111               !   Computation of the abundance of the preys
112               !   A threshold can be specified in the namelist
113               !   --------------------------------------------
114               zcompadi  = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia )
115               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
116               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthreshzoo ), 0.e0 )
117               zcompapi  = MAX( ( trb(ji,jj,jk,jppic) - xthreshpic ), 0.e0 )
118               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
119               
120               !   Microzooplankton grazing
121               !   ------------------------
122               zfood     = xprefn * zcompaph + xprefc * zcompapoc + xprefd * zcompadi   &
123               &           + xprefz * zcompaz + xprefp * zcompapi
124               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
125               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
126               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk)) 
127
128               !   An active switching parameterization is used here.
129               !   We don't use the KTW parameterization proposed by
130               !   Vallina et al. because it tends to produce to steady biomass
131               !   composition and the variance of Chl is too low as it grazes
132               !   too strongly on winning organisms. Thus, instead of a square
133               !   a 1.5 power value is used which decreases the pressure on the
134               !   most abundant species
135               !   ------------------------------------------------------------ 
136               ztmp1 = xprefn * zcompaph**1.5
137               ztmp2 = xprefp * zcompapi**1.5
138               ztmp3 = xprefc * zcompapoc**1.5
139               ztmp4 = xprefd * zcompadi**1.5
140               ztmp5 = xprefz * zcompaz**1.5
141               ztmptot = ztmp1 + ztmp2 + ztmp3 + ztmp4 + ztmp5 + rtrn
142               ztmp1 = ztmp1 / ztmptot
143               ztmp2 = ztmp2 / ztmptot
144               ztmp3 = ztmp3 / ztmptot
145               ztmp4 = ztmp4 / ztmptot
146               ztmp5 = ztmp5 / ztmptot
147
148               !   Microzooplankton regular grazing on the different preys
149               !   -------------------------------------------------------
150               zgraznc   = zgraze  * ztmp1  * zdenom
151               zgraznn   = zgraznc * trb(ji,jj,jk,jpnph) / (trb(ji,jj,jk,jpphy) + rtrn)
152               zgraznp   = zgraznc * trb(ji,jj,jk,jppph) / (trb(ji,jj,jk,jpphy) + rtrn)
153               zgraznf   = zgraznc * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
154               zgrazpc   = zgraze  * ztmp2  * zdenom
155               zgrazpn   = zgrazpc * trb(ji,jj,jk,jpnpi) / (trb(ji,jj,jk,jppic) + rtrn)
156               zgrazpp   = zgrazpc * trb(ji,jj,jk,jpppi) / (trb(ji,jj,jk,jppic) + rtrn)
157               zgrazpf   = zgrazpc * trb(ji,jj,jk,jppfe) / (trb(ji,jj,jk,jppic) + rtrn)
158               zgrazz    = zgraze  * ztmp5   * zdenom
159               zgrazpoc  = zgraze  * ztmp3   * zdenom
160               zgrazpon  = zgrazpoc * trb(ji,jj,jk,jppon) / ( trb(ji,jj,jk,jppoc) + rtrn )
161               zgrazpop  = zgrazpoc * trb(ji,jj,jk,jppop) / ( trb(ji,jj,jk,jppoc) + rtrn )
162               zgrazpof  = zgrazpoc* trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
163               zgrazdc   = zgraze  * ztmp4  * zdenom
164               zgrazdn   = zgrazdc * trb(ji,jj,jk,jpndi) / (trb(ji,jj,jk,jpdia) + rtrn)
165               zgrazdp   = zgrazdc * trb(ji,jj,jk,jppdi) / (trb(ji,jj,jk,jpdia) + rtrn)
166               zgrazdf   = zgrazdc * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
167               !
168               zgraztotc = zgraznc + zgrazpoc + zgrazdc + zgrazz + zgrazpc
169               zgraztotn = zgraznn + zgrazpn + zgrazpon + zgrazdn + zgrazz * no3rat3
170               zgraztotp = zgraznp + zgrazpp + zgrazpop + zgrazdp + zgrazz * po4rat3
171               zgraztotf = zgraznf + zgrazpf + zgrazpof + zgrazdf + zgrazz * ferat3
172               !
173               ! Grazing by microzooplankton
174               zgrazing(ji,jj,jk) = zgraztotc
175
176               !   Stoichiometruc ratios of the food ingested by zooplanton
177               !   --------------------------------------------------------
178               zgrasratf =  (zgraztotf + rtrn) / ( zgraztotc + rtrn )
179               zgrasratn =  (zgraztotn + rtrn) / ( zgraztotc + rtrn )
180               zgrasratp =  (zgraztotp + rtrn) / ( zgraztotc + rtrn )
181
182               !   Growth efficiency is made a function of the quality
183               !   and the quantity of the preys
184               !   ---------------------------------------------------
185               zepshert  = MIN( 1., zgrasratn/ no3rat3, zgrasratp/ po4rat3, zgrasratf / ferat3)
186               zbeta     = MAX( 0., (epsher - epshermin) )
187               zepsherf  = epshermin + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta )
188               zepsherv  = zepsherf * zepshert
189
190               !   Respiration of microzooplankton
191               !   Excess carbon in the food is used preferentially
192               !   ------------------------------------------------
193               zexcess  = zgraztotc * zepsherf * (1.0 - zepshert) * zmetexcess
194               zbasresb = MAX(0., zrespz - zexcess)
195               zbasresi = zexcess + MIN(0., zrespz - zexcess) 
196               zrespirc = srespir * zepsherv * zgraztotc + zbasresb
197               
198               !   When excess carbon is used, the other elements in excess
199               !   are also used proportionally to their abundance
200               !   --------------------------------------------------------
201               zexcess  = ( zgrasratn/ no3rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
202               zbasresn = zbasresi * zexcess * zgrasratn 
203               zexcess  = ( zgrasratp/ po4rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
204               zbasresp = zbasresi * zexcess * zgrasratp
205               zexcess  = ( zgrasratf/ ferat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
206               zbasresf = zbasresi * zexcess * zgrasratf
207
208               !   Voiding of the excessive elements as DOM
209               !   ----------------------------------------
210               zgradoct   = (1. - unassc - zepsherv) * zgraztotc - zbasresi 
211               zgradont   = (1. - unassn) * zgraztotn - zepsherv * no3rat3 * zgraztotc - zbasresn
212               zgradopt   = (1. - unassp) * zgraztotp - zepsherv * po4rat3 * zgraztotc - zbasresp
213               zgrareft   = (1. - unassc) * zgraztotf - zepsherv * ferat3 * zgraztotc - zbasresf
214
215               !  Since only semilabile DOM is represented in PISCES
216               !  part of DOM is in fact labile and is then released
217               !  as dissolved inorganic compounds (ssigma)
218               !  --------------------------------------------------
219               zgradoc =  zgradoct * ssigma
220               zgradon =  zgradont * ssigma
221               zgradop =  zgradopt * ssigma
222               zgrarem = (1.0 - ssigma) * zgradoct
223               zgraren = (1.0 - ssigma) * zgradont
224               zgrarep = (1.0 - ssigma) * zgradopt
225               zgraref = zgrareft
226
227               !   Defecation as a result of non assimilated products
228               !   --------------------------------------------------
229               zgrapoc   = zgraztotc * unassc
230               zgrapon   = zgraztotn * unassn
231               zgrapop   = zgraztotp * unassp
232               zgrapof   = zgraztotf * unassc
233
234               !  Addition of respiration to the release of inorganic nutrients
235               !  -------------------------------------------------------------
236               zgrarem = zgrarem + zbasresi + zrespirc
237               zgraren = zgraren + zbasresn + zrespirc * no3rat3
238               zgrarep = zgrarep + zbasresp + zrespirc * po4rat3
239               zgraref = zgraref + zbasresf + zrespirc * ferat3
240
241               !   Update of the TRA arrays
242               !   ------------------------
243               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarep
244               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgraren
245               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgradoc
246               !
247               IF( ln_ligand ) THEN
248                  tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zgradoc * ldocz
249                  zzligprod(ji,jj,jk) = zgradoc * ldocz
250               ENDIF
251               !
252               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zgradon
253               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + zgradop
254               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarem 
255               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgraref
256               zfezoo(ji,jj,jk)    = zgraref
257               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) + zepsherv * zgraztotc - zrespirc - ztortz - zgrazz
258               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgraznc
259               tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) - zgraznn
260               tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) - zgraznp
261               tra(ji,jj,jk,jppic) = tra(ji,jj,jk,jppic) - zgrazpc
262               tra(ji,jj,jk,jpnpi) = tra(ji,jj,jk,jpnpi) - zgrazpn
263               tra(ji,jj,jk,jpppi) = tra(ji,jj,jk,jpppi) - zgrazpp
264               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazdc
265               tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) - zgrazdn
266               tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) - zgrazdp
267               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgraznc * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
268               tra(ji,jj,jk,jppch) = tra(ji,jj,jk,jppch) - zgrazpc * trb(ji,jj,jk,jppch)/(trb(ji,jj,jk,jppic)+rtrn)
269               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazdc * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
270               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazdc * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
271               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazdc * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
272               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
273               tra(ji,jj,jk,jppfe) = tra(ji,jj,jk,jppfe) - zgrazpf
274               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazdf
275               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + ztortz + zgrapoc - zgrazpoc 
276               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + ztortz + zgrapoc
277               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc
278               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + no3rat3 * ztortz + zgrapon - zgrazpon
279               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + po4rat3 * ztortz + zgrapop - zgrazpop
280               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * ztortz  + zgrapof - zgrazpof
281               !
282               ! calcite production
283               zprcaca = xfracal(ji,jj,jk) * zgraznc
284               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
285               !
286               zprcaca = part * zprcaca
287               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarem - zprcaca
288               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca     &
289               &                     + rno3 * zgraren
290               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
291            END DO
292         END DO
293      END DO
294      !
295      IF( lk_iomput .AND. knt == nrdttrc ) THEN
296        IF( iom_use("GRAZ1") ) THEN  !   Total grazing of phyto by zooplankton
297           zgrazing(:,:,jpk) = 0._wp   ; CALL iom_put( "GRAZ1" , zgrazing(:,:,:) * 1.e+3  * rfact2r * tmask(:,:,:) ) 
298         ENDIF
299         IF( iom_use("FEZOO") ) THEN 
300           zfezoo (:,:,jpk) = 0._wp    ; CALL iom_put( "FEZOO" , zfezoo(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) )
301         ENDIF
302         IF( ln_ligand ) THEN
303            zzligprod(:,:,jpk) = 0._wp ; CALL iom_put( "LPRODZ", zzligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:))
304         ENDIF
305      ENDIF
306      !
307      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
308         WRITE(charout, FMT="('micro')")
309         CALL prt_ctl_trc_info(charout)
310         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
311      ENDIF
312      !
313      IF( ln_timing )   CALL timing_stop('p5z_micro')
314      !
315   END SUBROUTINE p5z_micro
316
317
318   SUBROUTINE p5z_micro_init
319      !!----------------------------------------------------------------------
320      !!                  ***  ROUTINE p5z_micro_init  ***
321      !!
322      !! ** Purpose :   Initialization of microzooplankton parameters
323      !!
324      !! ** Method  :   Read the nampiszoo namelist and check the parameters
325      !!                called at the first timestep (nittrc000)
326      !!
327      !! ** input   :   Namelist nampiszoo
328      !!
329      !!----------------------------------------------------------------------
330      INTEGER ::   ios   ! Local integer
331      !!
332      NAMELIST/namp5zzoo/ part, grazrat, bmetexc, resrat, mzrat, xprefc, xprefn, &
333         &                xprefp, xprefd, xprefz, xthreshdia, xthreshphy, &
334         &                xthreshpic, xthreshpoc, xthreshzoo, xthresh, xkgraz, &
335         &                epsher, epshermin, ssigma, srespir, unassc, unassn, unassp
336      !!----------------------------------------------------------------------
337      !
338      READ  ( numnatp_ref, namp5zzoo, IOSTAT = ios, ERR = 901)
339901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zzoo in reference namelist' )
340      !
341      READ  ( numnatp_cfg, namp5zzoo, IOSTAT = ios, ERR = 902 )
342902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp5zzoo in configuration namelist' )
343      IF(lwm) WRITE ( numonp, namp5zzoo )
344      !
345      IF(lwp) THEN                         ! control print
346         WRITE(numout,*) ' '
347         WRITE(numout,*) ' Namelist parameters for microzooplankton, nampiszooq'
348         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
349         WRITE(numout,*) '    part of calcite not dissolved in microzoo guts  part        =', part
350         WRITE(numout,*) '    microzoo preference for POC                     xprefc     =', xprefc
351         WRITE(numout,*) '    microzoo preference for nano                    xprefn     =', xprefn
352         WRITE(numout,*) '    microzoo preference for pico                    xprefp     =', xprefp
353         WRITE(numout,*) '    microzoo preference for diatoms                 xprefd     =', xprefd
354         WRITE(numout,*) '    microzoo preference for microzoo                xprefz     =', xprefz
355         WRITE(numout,*) '    diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
356         WRITE(numout,*) '    nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
357         WRITE(numout,*) '    picophyto feeding threshold for microzoo        xthreshpic  =', xthreshpic
358         WRITE(numout,*) '    poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
359         WRITE(numout,*) '    microzoo feeding threshold for microzoo         xthreshzoo  =', xthreshzoo
360         WRITE(numout,*) '    feeding threshold for microzooplankton          xthresh     =', xthresh
361         WRITE(numout,*) '    exsudation rate of microzooplankton             resrat      =', resrat
362         WRITE(numout,*) '    microzooplankton mortality rate                 mzrat       =', mzrat
363         WRITE(numout,*) '    maximal microzoo grazing rate                   grazrat     =', grazrat
364         WRITE(numout,*) '    C egested fraction of fodd by microzoo          unassc      =', unassc
365         WRITE(numout,*) '    N egested fraction of fodd by microzoo          unassn      =', unassn
366         WRITE(numout,*) '    P egested fraction of fodd by microzoo          unassp      =', unassp
367         WRITE(numout,*) '    Efficicency of microzoo growth                  epsher      =', epsher
368         WRITE(numout,*) '    Minimum Efficiency of Microzoo growth           epshermin   =', epshermin
369         WRITE(numout,*) '    Fraction excreted as semi-labile DOM            ssigma      =', ssigma
370         WRITE(numout,*) '    Active respiration                              srespir     =', srespir
371         WRITE(numout,*) '    half sturation constant for grazing 1           xkgraz      =', xkgraz
372         WRITE(numout,*) '    Use of excess carbon for respiration            bmetexc     =', bmetexc
373      ENDIF
374      !
375   END SUBROUTINE p5z_micro_init
376
377   !!======================================================================
378END MODULE p5zmicro
Note: See TracBrowser for help on using the repository browser.