New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcdta.F90 in NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/TOP – NEMO

source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/TOP/trcdta.F90 @ 12202

Last change on this file since 12202 was 12202, checked in by cetlod, 4 years ago

dev_merge_option2 : merge in dev_r11613_ENHANCE-04_namelists_as_internalfiles
  • Property svn:keywords set to Id
File size: 12.5 KB
Line 
1MODULE trcdta
2   !!======================================================================
3   !!                     ***  MODULE  trcdta  ***
4   !! TOP :  reads passive tracer data
5   !!=====================================================================
6   !! History :   1.0  !  2002-04  (O. Aumont)  original code
7   !!              -   !  2004-03  (C. Ethe)  module
8   !!              -   !  2005-03  (O. Aumont, A. El Moussaoui) F90
9   !!            3.4   !  2010-11  (C. Ethe, G. Madec)  use of fldread + dynamical allocation
10   !!            3.5   !  2013-08  (M. Vichi)  generalization for other BGC models
11   !!            3.6   !  2015-03  (T. Lovato) revisit code I/O
12   !!----------------------------------------------------------------------
13#if defined key_top 
14   !!----------------------------------------------------------------------
15   !!   'key_top'                                                TOP model
16   !!----------------------------------------------------------------------
17   !!   trc_dta    : read and time interpolated passive tracer data
18   !!----------------------------------------------------------------------
19   USE par_trc       !  passive tracers parameters
20   USE oce_trc       !  shared variables between ocean and passive tracers
21   USE trc           !  passive tracers common variables
22   !
23   USE iom           !  I/O manager
24   USE lib_mpp       !  MPP library
25   USE fldread       !  read input fields
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   trc_dta         ! called in trcini.F90 and trcdmp.F90
31   PUBLIC   trc_dta_ini     ! called in trcini.F90
32
33   INTEGER  , SAVE, PUBLIC                             :: nb_trcdta   ! number of tracers to be initialised with data
34   INTEGER  , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: n_trc_index ! indice of tracer which is initialised with data
35   INTEGER  , SAVE, PUBLIC                             :: ntra        ! MAX( 1, nb_trcdta ) to avoid compilation error with bounds checking
36   REAL(wp) , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: rf_trfac    ! multiplicative factor for tracer values
37!$AGRIF_DO_NOT_TREAT
38   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: sf_trcdta   ! structure of input SST (file informations, fields read)
39!$AGRIF_END_DO_NOT_TREAT
40
41   !!----------------------------------------------------------------------
42   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE trc_dta_ini(ntrc)
49      !!----------------------------------------------------------------------
50      !!                   ***  ROUTINE trc_dta_ini  ***
51      !!                   
52      !! ** Purpose :   initialisation of passive tracer input data
53      !!
54      !! ** Method  : - Read namtsd namelist
55      !!              - allocates passive tracer data structure
56      !!----------------------------------------------------------------------
57      INTEGER,INTENT(in) ::   ntrc   ! number of tracers
58      !
59      INTEGER ::   jl, jn                            ! dummy loop indices
60      INTEGER ::   ios, ierr0, ierr1, ierr2, ierr3   ! local integers
61      REAL(wp) ::   zfact
62      CHARACTER(len=100) ::   clndta, clntrc
63      !
64      CHARACTER(len=100) ::   cn_dir
65      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: slf_i ! array of namelist informations on the fields to read
66      TYPE(FLD_N), DIMENSION(jpmaxtrc) :: sn_trcdta
67      REAL(wp)   , DIMENSION(jpmaxtrc) :: rn_trfac    ! multiplicative factor for tracer values
68      !!
69      NAMELIST/namtrc_dta/ sn_trcdta, cn_dir, rn_trfac 
70      !!----------------------------------------------------------------------
71      !
72      IF( lwp ) THEN
73         WRITE(numout,*)
74         WRITE(numout,*) 'trc_dta_ini : Tracers Initial Conditions (IC)'
75         WRITE(numout,*) '~~~~~~~~~~~ '
76      ENDIF
77      !
78      !  Initialisation
79      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0 
80      ! Compute the number of tracers to be initialised with data
81      ALLOCATE( n_trc_index(ntrc), slf_i(ntrc), STAT=ierr0 )
82      IF( ierr0 > 0 ) THEN
83         CALL ctl_stop( 'trc_dta_ini: unable to allocate n_trc_index' )   ;   RETURN
84      ENDIF
85      nb_trcdta      = 0
86      n_trc_index(:) = 0
87      DO jn = 1, ntrc
88         IF( ln_trc_ini(jn) ) THEN
89             nb_trcdta       = nb_trcdta + 1 
90             n_trc_index(jn) = nb_trcdta 
91         ENDIF
92      END DO
93      !
94      ntra = MAX( 1, nb_trcdta )   ! To avoid compilation error with bounds checking
95      IF(lwp) THEN
96         WRITE(numout,*)
97         WRITE(numout,*) '   number of passive tracers to be initialize by data :', ntra
98      ENDIF
99      !
100      READ  ( numnat_ref, namtrc_dta, IOSTAT = ios, ERR = 901)
101901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_dta_ini in reference namelist' )
102      READ  ( numnat_cfg, namtrc_dta, IOSTAT = ios, ERR = 902 )
103902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtrc_dta_ini in configuration namelist' )
104      IF(lwm) WRITE ( numont, namtrc_dta )
105
106      IF( lwp ) THEN
107         DO jn = 1, ntrc
108            IF( ln_trc_ini(jn) )  THEN    ! open input file only if ln_trc_ini(jn) is true
109               clndta = TRIM( sn_trcdta(jn)%clvar ) 
110               clntrc = TRIM( ctrcnm   (jn)       ) 
111               if (jn > jptra) clntrc='Dummy' ! By pass weird formats in ocean.output if ntrc > jptra
112               zfact  = rn_trfac(jn)
113               IF( clndta /=  clntrc ) THEN
114                  CALL ctl_warn( 'trc_dta_ini: passive tracer data initialisation    ',   &
115                  &              'Input name of data file : '//TRIM(clndta)//   &
116                  &              ' differs from that of tracer : '//TRIM(clntrc)//' ')
117               ENDIF
118               WRITE(numout,*)
119               WRITE(numout,'(a, i4,3a,e11.3)') '   Read IC file for tracer number :', &
120               &            jn, ', name : ', TRIM(clndta), ', Multiplicative Scaling factor : ', zfact
121            ENDIF
122         END DO
123      ENDIF
124      !
125      IF( nb_trcdta > 0 ) THEN       !  allocate only if the number of tracer to initialise is greater than zero
126         ALLOCATE( sf_trcdta(nb_trcdta), rf_trfac(nb_trcdta), STAT=ierr1 )
127         IF( ierr1 > 0 ) THEN
128            CALL ctl_stop( 'trc_dta_ini: unable to allocate  sf_trcdta structure' )   ;   RETURN
129         ENDIF
130         !
131         DO jn = 1, ntrc
132            IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
133               jl = n_trc_index(jn)
134               slf_i(jl)    = sn_trcdta(jn)
135               rf_trfac(jl) = rn_trfac(jn)
136                                            ALLOCATE( sf_trcdta(jl)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
137               IF( sn_trcdta(jn)%ln_tint )  ALLOCATE( sf_trcdta(jl)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
138               IF( ierr2 + ierr3 > 0 ) THEN
139                 CALL ctl_stop( 'trc_dta_ini : unable to allocate passive tracer data arrays' )   ;   RETURN
140               ENDIF
141            ENDIF
142            !   
143         ENDDO
144         !                         ! fill sf_trcdta with slf_i and control print
145         CALL fld_fill( sf_trcdta, slf_i, cn_dir, 'trc_dta_ini', 'Passive tracer data', 'namtrc' )
146         !
147      ENDIF
148      !
149      DEALLOCATE( slf_i )          ! deallocate local field structure
150      !
151   END SUBROUTINE trc_dta_ini
152
153
154   SUBROUTINE trc_dta( kt, sf_trcdta, ptrcfac, ptrcdta)
155      !!----------------------------------------------------------------------
156      !!                   ***  ROUTINE trc_dta  ***
157      !!                   
158      !! ** Purpose :   provides passive tracer data at kt
159      !!
160      !! ** Method  : - call fldread routine
161      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
162      !!              - ln_trcdmp=F: deallocates the data structure as they are not used
163      !!
164      !! ** Action  :   sf_trcdta   passive tracer data on meld mesh and interpolated at time-step kt
165      !!----------------------------------------------------------------------
166      INTEGER                          , INTENT(in   )   ::   kt         ! ocean time-step
167      TYPE(FLD), DIMENSION(1)          , INTENT(inout)   ::   sf_trcdta  ! array of information on the field to read
168      REAL(wp)                         , INTENT(in   )   ::   ptrcfac    ! multiplication factor
169      REAL(wp),  DIMENSION(jpi,jpj,jpk), INTENT(inout  ) ::   ptrcdta    ! 3D data array
170      !
171      INTEGER ::   ji, jj, jk, jl, jkk, ik    ! dummy loop indices
172      REAL(wp)::   zl, zi
173      REAL(wp), DIMENSION(jpk) ::  ztp                ! 1D workspace
174      CHARACTER(len=100) :: clndta
175      !!----------------------------------------------------------------------
176      !
177      IF( ln_timing )   CALL timing_start('trc_dta')
178      !
179      IF( kt == nit000 .AND. lwp) THEN
180         WRITE(numout,*)
181         WRITE(numout,*) 'trc_dta : passive tracers data for IC'
182         WRITE(numout,*) '~~~~~~~ '
183      ENDIF
184      !
185      IF( nb_trcdta > 0 ) THEN
186         !
187         ! read data at kt time step
188         CALL fld_read( kt, 1, sf_trcdta )
189         ptrcdta(:,:,:) = sf_trcdta(1)%fnow(:,:,:) * tmask(:,:,:)
190         !
191         IF( ln_sco ) THEN                !== s- or mixed s-zps-coordinate  ==!
192            !
193            IF( kt == nit000 .AND. lwp )THEN
194               WRITE(numout,*)
195               WRITE(numout,*) 'trc_dta: interpolates passive tracer data onto the s- or mixed s-z-coordinate mesh'
196            ENDIF
197            DO jj = 1, jpj                         ! vertical interpolation of T & S
198               DO ji = 1, jpi
199                  DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
200                     zl = gdept_n(ji,jj,jk)
201                     IF(     zl < gdept_1d(1  ) ) THEN         ! above the first level of data
202                        ztp(jk) = ptrcdta(ji,jj,1)
203                     ELSEIF( zl > gdept_1d(jpk) ) THEN         ! below the last level of data
204                        ztp(jk) = ptrcdta(ji,jj,jpkm1)
205                     ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
206                        DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
207                           IF( (zl-gdept_1d(jkk)) * (zl-gdept_1d(jkk+1)) <= 0._wp ) THEN
208                              zi = ( zl - gdept_1d(jkk) ) / (gdept_1d(jkk+1)-gdept_1d(jkk))
209                              ztp(jk) = ptrcdta(ji,jj,jkk) + ( ptrcdta(ji,jj,jkk+1) - ptrcdta(ji,jj,jkk) ) * zi
210                           ENDIF
211                        END DO
212                     ENDIF
213                  END DO
214                  DO jk = 1, jpkm1
215                     ptrcdta(ji,jj,jk) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
216                  END DO
217                  ptrcdta(ji,jj,jpk) = 0._wp
218                END DO
219            END DO
220            !
221         ELSE                                !==   z- or zps- coordinate   ==!
222            ! zps-coordinate (partial steps) interpolation at the last ocean level
223!            IF( ln_zps ) THEN
224!               DO jj = 1, jpj
225!                  DO ji = 1, jpi
226!                     ik = mbkt(ji,jj)
227!                     IF( ik > 1 ) THEN
228!                        zl = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
229!                        ptrcdta(ji,jj,ik) = (1.-zl) * ptrcdta(ji,jj,ik) + zl * ptrcdta(ji,jj,ik-1)
230!                     ENDIF
231!                     ik = mikt(ji,jj)
232!                     IF( ik > 1 ) THEN
233!                        zl = ( gdept_0(ji,jj,ik) - gdept_1d(ik) ) / ( gdept_1d(ik+1) - gdept_1d(ik) )
234!                        ptrcdta(ji,jj,ik) = (1.-zl) * ptrcdta(ji,jj,ik) + zl * ptrcdta(ji,jj,ik+1)
235!                     ENDIF
236!                  END DO
237!              END DO
238!            ENDIF
239            !
240         ENDIF
241         !
242         ! Scale by multiplicative factor
243         ptrcdta(:,:,:) = ptrcdta(:,:,:) * ptrcfac
244         !
245      ENDIF
246      !
247      IF( ln_timing )  CALL timing_stop('trc_dta')
248      !
249   END SUBROUTINE trc_dta
250
251#else
252   !!----------------------------------------------------------------------
253   !!   Dummy module                              NO 3D passive tracer data
254   !!----------------------------------------------------------------------
255CONTAINS
256   SUBROUTINE trc_dta( kt, sf_trcdta, ptrcfac, ptrcdta)        ! Empty routine
257      WRITE(*,*) 'trc_dta: You should not have seen this print! error?', kt
258   END SUBROUTINE trc_dta
259#endif
260
261   !!======================================================================
262END MODULE trcdta
Note: See TracBrowser for help on using the repository browser.