source: NEMO/branches/2019/fix_sn_cfctl_ticket2328/src/OCE/DYN/dynkeg.F90 @ 11872

Last change on this file since 11872 was 11872, checked in by acc, 11 months ago

Branch 2019/fix_sn_cfctl_ticket2328. See #2328. Replacement of ln_ctl and activation of full functionality with
sn_cfctl structure. These changes rename structure components l_mppout and l_mpptop as l_prtctl and l_prttrc
and introduce l_glochk to activate former ln_ctl code in stpctl.F90 to perform global location of min and max
checks. Also added is l_allon which can be used to activate all output (much like the former ln_ctl). If l_allon
is .false. then l_config decides whether or not the suboptions are used.

   sn_cfctl%l_glochk = .FALSE.    ! Range sanity checks are local (F) or global (T). Set T for debugging only
   sn_cfctl%l_allon  = .FALSE.    ! IF T activate all options. If F deactivate all unless l_config is T
   sn_cfctl%l_config = .TRUE.     ! IF .true. then control which reports are written with the remaining options

Note, these changes pass SETTE tests but all references to ln_ctl need to be removed from the sette scripts.

  • Property svn:keywords set to Id
File size: 7.4 KB
Line 
1MODULE dynkeg
2   !!======================================================================
3   !!                       ***  MODULE  dynkeg  ***
4   !! Ocean dynamics:  kinetic energy gradient trend
5   !!======================================================================
6   !! History :  1.0  !  1987-09  (P. Andrich, M.-A. Foujols)  Original code
7   !!            7.0  !  1997-05  (G. Madec)  Split dynber into dynkeg and dynhpg
8   !!  NEMO      1.0  !  2002-07  (G. Madec)  F90: Free form and module
9   !!            3.6  !  2015-05  (N. Ducousso, G. Madec)  add Hollingsworth scheme as an option
10   !!----------------------------------------------------------------------
11   
12   !!----------------------------------------------------------------------
13   !!   dyn_keg      : update the momentum trend with the horizontal tke
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE trd_oce         ! trends: ocean variables
18   USE trddyn          ! trend manager: dynamics
19   !
20   USE in_out_manager  ! I/O manager
21   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
22   USE lib_mpp         ! MPP library
23   USE prtctl          ! Print control
24   USE timing          ! Timing
25   USE bdy_oce         ! ocean open boundary conditions
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   dyn_keg    ! routine called by step module
31   
32   INTEGER, PARAMETER, PUBLIC  ::   nkeg_C2  = 0   !: 2nd order centered scheme (standard scheme)
33   INTEGER, PARAMETER, PUBLIC  ::   nkeg_HW  = 1   !: Hollingsworth et al., QJRMS, 1983
34   !
35   REAL(wp) ::   r1_48 = 1._wp / 48._wp   !: =1/(4*2*6)
36   
37   !! * Substitutions
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
41   !! $Id$
42   !! Software governed by the CeCILL license (see ./LICENSE)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE dyn_keg( kt, kscheme )
47      !!----------------------------------------------------------------------
48      !!                  ***  ROUTINE dyn_keg  ***
49      !!
50      !! ** Purpose :   Compute the now momentum trend due to the horizontal
51      !!      gradient of the horizontal kinetic energy and add it to the
52      !!      general momentum trend.
53      !!
54      !! ** Method  : * kscheme = nkeg_C2 : 2nd order centered scheme that
55      !!      conserve kinetic energy. Compute the now horizontal kinetic energy
56      !!         zhke = 1/2 [ mi-1( un^2 ) + mj-1( vn^2 ) ]
57      !!              * kscheme = nkeg_HW : Hollingsworth correction following
58      !!      Arakawa (2001). The now horizontal kinetic energy is given by:
59      !!         zhke = 1/6 [ mi-1(  2 * un^2 + ((un(j+1)+un(j-1))/2)^2  )
60      !!                    + mj-1(  2 * vn^2 + ((vn(i+1)+vn(i-1))/2)^2  ) ]
61      !!     
62      !!      Take its horizontal gradient and add it to the general momentum
63      !!      trend (ua,va).
64      !!         ua = ua - 1/e1u di[ zhke ]
65      !!         va = va - 1/e2v dj[ zhke ]
66      !!
67      !! ** Action : - Update the (ua, va) with the hor. ke gradient trend
68      !!             - send this trends to trd_dyn (l_trddyn=T) for post-processing
69      !!
70      !! ** References : Arakawa, A., International Geophysics 2001.
71      !!                 Hollingsworth et al., Quart. J. Roy. Meteor. Soc., 1983.
72      !!----------------------------------------------------------------------
73      INTEGER, INTENT( in ) ::   kt        ! ocean time-step index
74      INTEGER, INTENT( in ) ::   kscheme   ! =0/1   type of KEG scheme
75      !
76      INTEGER  ::   ji, jj, jk             ! dummy loop indices
77      REAL(wp) ::   zu, zv                   ! local scalars
78      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::   zhke
79      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv 
80      !!----------------------------------------------------------------------
81      !
82      IF( ln_timing )   CALL timing_start('dyn_keg')
83      !
84      IF( kt == nit000 ) THEN
85         IF(lwp) WRITE(numout,*)
86         IF(lwp) WRITE(numout,*) 'dyn_keg : kinetic energy gradient trend, scheme number=', kscheme
87         IF(lwp) WRITE(numout,*) '~~~~~~~'
88      ENDIF
89
90      IF( l_trddyn ) THEN           ! Save the input trends
91         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
92         ztrdu(:,:,:) = ua(:,:,:) 
93         ztrdv(:,:,:) = va(:,:,:) 
94      ENDIF
95     
96      zhke(:,:,jpk) = 0._wp
97
98      SELECT CASE ( kscheme )             !== Horizontal kinetic energy at T-point  ==!
99      !
100      CASE ( nkeg_C2 )                          !--  Standard scheme  --!
101         DO jk = 1, jpkm1
102            DO jj = 2, jpj
103               DO ji = fs_2, jpi   ! vector opt.
104                  zu =    un(ji-1,jj  ,jk) * un(ji-1,jj  ,jk)   &
105                     &  + un(ji  ,jj  ,jk) * un(ji  ,jj  ,jk)
106                  zv =    vn(ji  ,jj-1,jk) * vn(ji  ,jj-1,jk)   &
107                     &  + vn(ji  ,jj  ,jk) * vn(ji  ,jj  ,jk)
108                  zhke(ji,jj,jk) = 0.25_wp * ( zv + zu )
109               END DO 
110            END DO
111         END DO
112      CASE ( nkeg_HW )                          !--  Hollingsworth scheme  --!
113         DO jk = 1, jpkm1
114            DO jj = 2, jpjm1       
115               DO ji = fs_2, jpim1   ! vector opt.
116                  zu = 8._wp * ( un(ji-1,jj  ,jk) * un(ji-1,jj  ,jk)    &
117                     &         + un(ji  ,jj  ,jk) * un(ji  ,jj  ,jk) )  &
118                     &   +     ( un(ji-1,jj-1,jk) + un(ji-1,jj+1,jk) ) * ( un(ji-1,jj-1,jk) + un(ji-1,jj+1,jk) )   &
119                     &   +     ( un(ji  ,jj-1,jk) + un(ji  ,jj+1,jk) ) * ( un(ji  ,jj-1,jk) + un(ji  ,jj+1,jk) )
120                     !
121                  zv = 8._wp * ( vn(ji  ,jj-1,jk) * vn(ji  ,jj-1,jk)    &
122                     &         + vn(ji  ,jj  ,jk) * vn(ji  ,jj  ,jk) )  &
123                     &  +      ( vn(ji-1,jj-1,jk) + vn(ji+1,jj-1,jk) ) * ( vn(ji-1,jj-1,jk) + vn(ji+1,jj-1,jk) )   &
124                     &  +      ( vn(ji-1,jj  ,jk) + vn(ji+1,jj  ,jk) ) * ( vn(ji-1,jj  ,jk) + vn(ji+1,jj  ,jk) )
125                  zhke(ji,jj,jk) = r1_48 * ( zv + zu )
126               END DO 
127            END DO
128         END DO
129         CALL lbc_lnk( 'dynkeg', zhke, 'T', 1. )
130         !
131      END SELECT 
132      !
133      DO jk = 1, jpkm1                    !==  grad( KE ) added to the general momentum trends  ==!
134         DO jj = 2, jpjm1
135            DO ji = fs_2, fs_jpim1   ! vector opt.
136               ua(ji,jj,jk) = ua(ji,jj,jk) - ( zhke(ji+1,jj  ,jk) - zhke(ji,jj,jk) ) / e1u(ji,jj)
137               va(ji,jj,jk) = va(ji,jj,jk) - ( zhke(ji  ,jj+1,jk) - zhke(ji,jj,jk) ) / e2v(ji,jj)
138            END DO
139         END DO
140      END DO
141      !
142      IF( l_trddyn ) THEN                 ! save the Kinetic Energy trends for diagnostic
143         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
144         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
145         CALL trd_dyn( ztrdu, ztrdv, jpdyn_keg, kt )
146         DEALLOCATE( ztrdu , ztrdv )
147      ENDIF
148      !
149      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' keg  - Ua: ', mask1=umask,   &
150         &                                  tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
151      !
152      IF( ln_timing )   CALL timing_stop('dyn_keg')
153      !
154   END SUBROUTINE dyn_keg
155
156   !!======================================================================
157END MODULE dynkeg
Note: See TracBrowser for help on using the repository browser.