New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2019/fix_sn_cfctl_ticket2328/src/OFF – NEMO

source: NEMO/branches/2019/fix_sn_cfctl_ticket2328/src/OFF/nemogcm.F90 @ 11866

Last change on this file since 11866 was 11866, checked in by acc, 4 years ago

Branch 2019/fix_sn_cfctl_ticket2328. Changes to enable correct functionality for the sn_cfctl%l_oceout option. See #2328

  • Property svn:keywords set to Id
File size: 28.4 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            3.4  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!            4.0  ! 2016-10  (C. Ethe, G. Madec, S. Flavoni)  domain configuration / user defined interface
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   nemo_gcm      : off-line: solve ocean tracer only
13   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
14   !!   nemo_init     : initialization of the NEMO system
15   !!   nemo_ctl      : initialisation of the contol print
16   !!   nemo_closefile: close remaining open files
17   !!   nemo_alloc    : dynamical allocation
18   !!   istate_init   : simple initialization to zero of ocean fields
19   !!   stp_ctl       : reduced step control (no dynamics in off-line)
20   !!----------------------------------------------------------------------
21   USE dom_oce        ! ocean space domain variables
22   USE oce            ! dynamics and tracers variables
23   USE trc_oce        ! Shared ocean/passive tracers variables
24   USE c1d            ! 1D configuration
25   USE domain         ! domain initialization from coordinate & bathymetry (dom_init routine)
26   USE closea         ! treatment of closed seas (for ln_closea)
27   USE usrdef_nam     ! user defined configuration
28   USE eosbn2         ! equation of state            (eos bn2 routine)
29   !              ! ocean physics
30   USE ldftra         ! lateral diffusivity setting    (ldf_tra_init routine)
31   USE ldfslp         ! slopes of neutral surfaces     (ldf_slp_init routine)
32   USE traqsr         ! solar radiation penetration    (tra_qsr_init routine)
33   USE trabbl         ! bottom boundary layer          (tra_bbl_init routine)
34   USE traldf         ! lateral physics                (tra_ldf_init routine)
35   USE sbcmod         ! surface boundary condition     (sbc_init     routine)
36   USE phycst         ! physical constant                   (par_cst routine)
37   USE dtadyn         ! Lecture and Interpolation of the dynamical fields
38   USE trcini         ! Initilization of the passive tracers
39   USE daymod         ! calendar                            (day     routine)
40   USE trcstp         ! passive tracer time-stepping        (trc_stp routine)
41   USE dtadyn         ! Lecture and interpolation of the dynamical fields
42   !              ! Passive tracers needs
43   USE trc            ! passive tracer : variables
44   USE trcnam         ! passive tracer : namelist
45   USE trcrst         ! passive tracer restart
46   USE diaptr         ! Need to initialise this as some variables are used in if statements later
47   USE sbc_oce , ONLY : ln_rnf
48   USE sbcrnf         ! surface boundary condition : runoffs
49   !              ! I/O & MPP
50   USE iom            ! I/O library
51   USE in_out_manager ! I/O manager
52   USE mppini         ! shared/distributed memory setting (mpp_init routine)
53   USE lib_mpp        ! distributed memory computing
54#if defined key_iomput
55   USE xios           ! xIOserver
56#endif
57   USE prtctl         ! Print control                    (prt_ctl_init routine)
58   USE timing         ! Timing
59   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
60   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
61
62   IMPLICIT NONE
63   PRIVATE
64   
65   PUBLIC   nemo_gcm   ! called by nemo.F90
66
67   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
68
69   !!----------------------------------------------------------------------
70   !! NEMO/OFF 4.0 , NEMO Consortium (2018)
71   !! $Id$
72   !! Software governed by the CeCILL license (see ./LICENSE)
73   !!----------------------------------------------------------------------
74CONTAINS
75
76   SUBROUTINE nemo_gcm
77      !!----------------------------------------------------------------------
78      !!                     ***  ROUTINE nemo_gcm  ***
79      !!
80      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
81      !!              curvilinear mesh on the sphere.
82      !!
83      !! ** Method  : - model general initialization
84      !!              - launch the time-stepping (dta_dyn and trc_stp)
85      !!              - finalize the run by closing files and communications
86      !!
87      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
88      !!              Madec, 2008, internal report, IPSL.
89      !!----------------------------------------------------------------------
90      INTEGER :: istp, indic       ! time step index
91      !!----------------------------------------------------------------------
92
93      CALL nemo_init  ! Initializations
94
95      ! check that all process are still there... If some process have an error,
96      ! they will never enter in step and other processes will wait until the end of the cpu time!
97      CALL mpp_max( 'nemogcm', nstop )
98
99      !                            !-----------------------!
100      !                            !==   time stepping   ==!
101      !                            !-----------------------!
102      istp = nit000
103      !
104      IF( ln_rnf )   CALL sbc_rnf(istp)   ! runoffs initialization
105      !
106      CALL iom_init( cxios_context )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
107      !
108      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  OFF time-stepping  ==!
109         !
110         IF( istp /= nit000 )   CALL day        ( istp )         ! Calendar (day was already called at nit000 in day_init)
111                                CALL iom_setkt  ( istp - nit000 + 1, cxios_context )   ! say to iom that we are at time step kstp
112#if defined key_sed_off
113                                CALL dta_dyn_sed( istp )         ! Interpolation of the dynamical fields
114#else
115                                CALL dta_dyn    ( istp )         ! Interpolation of the dynamical fields
116         IF( .NOT.ln_linssh )   CALL dta_dyn_swp( istp )         ! swap of sea  surface height and vertical scale factors
117#endif
118                                CALL trc_stp    ( istp )         ! time-stepping
119                                CALL stp_ctl    ( istp, indic )  ! Time loop: control and print
120         istp = istp + 1
121      END DO
122      !
123#if defined key_iomput
124      CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
125#endif
126
127      !                            !------------------------!
128      !                            !==  finalize the run  ==!
129      !                            !------------------------!
130      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
131
132      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
133         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
134         CALL ctl_stop( ctmp1 )
135      ENDIF
136      !
137      IF( ln_timing )   CALL timing_finalize
138      !
139      CALL nemo_closefile
140      !
141#if defined key_iomput
142                     CALL xios_finalize   ! end mpp communications with xios
143#else
144      IF( lk_mpp )   CALL mppstop         ! end mpp communications
145#endif
146      !
147      IF(lwm) THEN
148         IF( nstop == 0 ) THEN   ;   STOP 0
149         ELSE                    ;   STOP 123
150         ENDIF
151      ENDIF
152      !
153   END SUBROUTINE nemo_gcm
154
155
156   SUBROUTINE nemo_init
157      !!----------------------------------------------------------------------
158      !!                     ***  ROUTINE nemo_init  ***
159      !!
160      !! ** Purpose :   initialization of the nemo model in off-line mode
161      !!----------------------------------------------------------------------
162      INTEGER ::   ios, ilocal_comm   ! local integers
163      !!
164      NAMELIST/namctl/ ln_ctl   , sn_cfctl, nn_print, nn_ictls, nn_ictle,   &
165         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
166         &             ln_timing, ln_diacfl
167      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
168      !!----------------------------------------------------------------------
169      !
170      cxios_context = 'nemo'
171      !
172      !                             !-------------------------------------------------!
173      !                             !     set communicator & select the local rank    !
174      !                             !  must be done as soon as possible to get narea  !
175      !                             !-------------------------------------------------!
176      !
177#if defined key_iomput
178      CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
179      CALL mpp_start( ilocal_comm )
180#else
181      CALL mpp_start( )
182#endif
183      !
184      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
185      lwm = (narea == 1)                ! control of output namelists
186      !
187      !                             !---------------------------------------------------------------!
188      !                             ! Open output files, reference and configuration namelist files !
189      !                             !---------------------------------------------------------------!
190      !
191      ! open ocean.output as soon as possible to get all output prints (including errors messages)
192      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
193      ! open reference and configuration namelist files
194                  CALL ctl_opn( numnam_ref,        'namelist_ref',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
195                  CALL ctl_opn( numnam_cfg,        'namelist_cfg',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
196      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
197      ! open /dev/null file to be able to supress output write easily
198                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
199      !
200      !                             !--------------------!
201      !                             ! Open listing units !  -> need ln_ctl from namctl to define lwp
202      !                             !--------------------!
203      !
204      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
205      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
206901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
207      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
208      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
209902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
210      !
211      ! finalize the definition of namctl variables
212      IF( sn_cfctl%l_config ) THEN
213         ! Activate finer control of report outputs
214         ! optionally switch off output from selected areas (note this only
215         ! applies to output which does not involve global communications)
216         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
217           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
218           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
219      ELSE
220         ! Use ln_ctl to turn on or off all options.
221         CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
222      ENDIF
223      !
224      lwp = (narea == 1) .OR. ln_ctl .OR. sn_cfctl%l_oceout    ! control of all listing output print
225      !
226      IF(lwp) THEN                            ! open listing units
227         !
228         IF( .NOT. lwm )   &           ! alreay opened for narea == 1
229            &     CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
230         !
231         WRITE(numout,*)
232         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
233         WRITE(numout,*) '                       NEMO team'
234         WRITE(numout,*) '                   Off-line TOP Model'
235         WRITE(numout,*) '                NEMO version 4.0  (2019) '
236         WRITE(numout,*)
237         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
238         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
239         WRITE(numout,*)
240         WRITE(numout,*) "           o         _,           _,             "
241         WRITE(numout,*) "            o      .' (        .-' /             "
242         WRITE(numout,*) "           o     _/..._'.    .'   /              "
243         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
244         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
245         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
246         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
247         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
248         WRITE(numout,*) "       )  )                        `     (   (   "
249         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
250         WRITE(numout,*)
251         !
252         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
253         !
254      ENDIF
255      !
256      IF(lwm) WRITE( numond, namctl )
257      !
258      !                             !------------------------------------!
259      !                             !  Set global domain size parameters !
260      !                             !------------------------------------!
261      !     
262      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
263      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
264903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
265      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
266      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
267904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
268      !
269      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
270         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
271      ELSE                                ! user-defined namelist
272         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
273      ENDIF
274      !
275      IF(lwm)   WRITE( numond, namcfg )
276      l_offline = .true.                  ! passive tracers are run offline
277      !
278      !                             !-----------------------------------------!
279      !                             ! mpp parameters and domain decomposition !
280      !                             !-----------------------------------------!
281      !
282      CALL mpp_init
283
284      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
285      CALL nemo_alloc()
286
287      !                             !-------------------------------!
288      !                             !  NEMO general initialization  !
289      !                             !-------------------------------!
290
291      CALL nemo_ctl                          ! Control prints
292      !
293      !                                      ! General initialization
294      IF( ln_timing    )   CALL timing_init
295      IF( ln_timing    )   CALL timing_start( 'nemo_init')
296      !
297                           CALL     phy_cst         ! Physical constants
298                           CALL     eos_init        ! Equation of state
299      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
300                           CALL     dom_init("OPA") ! Domain
301      IF( ln_ctl .OR. sn_cfctl%l_mppout )   &
302         &                 CALL prt_ctl_init        ! Print control
303
304                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
305
306                           CALL     sbc_init    ! Forcings : surface module
307
308      !                                      ! Tracer physics
309                           CALL ldf_tra_init    ! Lateral ocean tracer physics
310                           CALL ldf_eiv_init    ! Eddy induced velocity param
311                           CALL tra_ldf_init    ! lateral mixing
312      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
313      IF( ln_traqsr    )   CALL tra_qsr_init    ! penetrative solar radiation
314      IF( ln_trabbl    )   CALL tra_bbl_init    ! advective (and/or diffusive) bottom boundary layer scheme
315
316      !                                      ! Passive tracers
317                           CALL trc_nam_run    ! Needed to get restart parameters for passive tracers
318                           CALL trc_rst_cal( nit000, 'READ' )   ! calendar
319#if defined key_sed_off
320                           CALL dta_dyn_sed_init ! Initialization for the dynamics
321#else
322                           CALL dta_dyn_init   ! Initialization for the dynamics
323#endif
324
325                           CALL     trc_init   ! Passive tracers initialization
326                           CALL dia_ptr_init   ! Poleward TRansports initialization
327                           
328      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
329      !
330      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
331      !
332   END SUBROUTINE nemo_init
333
334
335   SUBROUTINE nemo_ctl
336      !!----------------------------------------------------------------------
337      !!                     ***  ROUTINE nemo_ctl  ***
338      !!
339      !! ** Purpose :   control print setting
340      !!
341      !! ** Method  : - print namctl information and check some consistencies
342      !!----------------------------------------------------------------------
343      !
344      IF(lwp) THEN                  ! control print
345         WRITE(numout,*)
346         WRITE(numout,*) 'nemo_ctl: Control prints'
347         WRITE(numout,*) '~~~~~~~~'
348         WRITE(numout,*) '   Namelist namctl'
349         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
350         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
351         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
352         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
353         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
354         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
355         WRITE(numout,*) '                              sn_cfctl%l_mppout  = ', sn_cfctl%l_mppout
356         WRITE(numout,*) '                              sn_cfctl%l_mpptop  = ', sn_cfctl%l_mpptop
357         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
358         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
359         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
360         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
361         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
362         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
363         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
364         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
365         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
366         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
367         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
368         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
369         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
370      ENDIF
371      !
372      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
373      nictls    = nn_ictls
374      nictle    = nn_ictle
375      njctls    = nn_jctls
376      njctle    = nn_jctle
377      isplt     = nn_isplt
378      jsplt     = nn_jsplt
379
380      IF(lwp) THEN                  ! control print
381         WRITE(numout,*)
382         WRITE(numout,*) '   Namelist namcfg'
383         WRITE(numout,*) '      read domain configuration file              ln_read_cfg      = ', ln_read_cfg
384         WRITE(numout,*) '         filename to be read                         cn_domcfg     = ', TRIM(cn_domcfg)
385         WRITE(numout,*) '         keep closed seas in the domain (if exist)   ln_closea     = ', ln_closea
386         WRITE(numout,*) '      create a configuration definition file      ln_write_cfg     = ', ln_write_cfg
387         WRITE(numout,*) '         filename to be written                      cn_domcfg_out = ', TRIM(cn_domcfg_out)
388         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr     = ', ln_use_jattr
389      ENDIF
390      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
391      !
392      !                             ! Parameter control
393      !
394      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
395         IF( lk_mpp .AND. jpnij > 1 ) THEN
396            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
397         ELSE
398            IF( isplt == 1 .AND. jsplt == 1  ) THEN
399               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
400                  &           ' - the print control will be done over the whole domain' )
401            ENDIF
402            ijsplt = isplt * jsplt            ! total number of processors ijsplt
403         ENDIF
404         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
405         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
406         !
407         !                              ! indices used for the SUM control
408         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
409            lsp_area = .FALSE.
410         ELSE                                             ! print control done over a specific  area
411            lsp_area = .TRUE.
412            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
413               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
414               nictls = 1
415            ENDIF
416            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
417               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
418               nictle = jpiglo
419            ENDIF
420            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
421               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
422               njctls = 1
423            ENDIF
424            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
425               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
426               njctle = jpjglo
427            ENDIF
428         ENDIF
429      ENDIF
430      !
431      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
432         &                                                'Compile with key_nosignedzero enabled' )
433      !
434   END SUBROUTINE nemo_ctl
435
436
437   SUBROUTINE nemo_closefile
438      !!----------------------------------------------------------------------
439      !!                     ***  ROUTINE nemo_closefile  ***
440      !!
441      !! ** Purpose :   Close the files
442      !!----------------------------------------------------------------------
443      !
444      IF( lk_mpp )   CALL mppsync
445      !
446      CALL iom_close                                 ! close all input/output files managed by iom_*
447      !
448      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
449      IF( numnam_ref /= -1 )   CLOSE( numnam_ref )   ! oce reference namelist
450      IF( numnam_cfg /= -1 )   CLOSE( numnam_cfg )   ! oce configuration namelist
451      IF( numout     /=  6 )   CLOSE( numout     )   ! standard model output file
452      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
453      !
454      numout = 6                                     ! redefine numout in case it is used after this point...
455      !
456   END SUBROUTINE nemo_closefile
457
458
459   SUBROUTINE nemo_alloc
460      !!----------------------------------------------------------------------
461      !!                     ***  ROUTINE nemo_alloc  ***
462      !!
463      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
464      !!
465      !! ** Method  :
466      !!----------------------------------------------------------------------
467      USE diawri ,   ONLY : dia_wri_alloc
468      USE dom_oce,   ONLY : dom_oce_alloc
469      USE zdf_oce,   ONLY : zdf_oce_alloc
470      USE trc_oce,   ONLY : trc_oce_alloc
471      !
472      INTEGER :: ierr
473      !!----------------------------------------------------------------------
474      !
475      ierr =        oce_alloc    ()          ! ocean
476      ierr = ierr + dia_wri_alloc()
477      ierr = ierr + dom_oce_alloc()          ! ocean domain
478      ierr = ierr + zdf_oce_alloc()          ! ocean vertical physics
479      ierr = ierr + trc_oce_alloc()          ! shared TRC / TRA arrays
480      !
481      CALL mpp_sum( 'nemogcm', ierr )
482      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
483      !
484   END SUBROUTINE nemo_alloc
485
486   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
487      !!----------------------------------------------------------------------
488      !!                     ***  ROUTINE nemo_set_cfctl  ***
489      !!
490      !! ** Purpose :   Set elements of the output control structure to setto.
491      !!                for_all should be .false. unless all areas are to be
492      !!                treated identically.
493      !!
494      !! ** Method  :   Note this routine can be used to switch on/off some
495      !!                types of output for selected areas but any output types
496      !!                that involve global communications (e.g. mpp_max, glob_sum)
497      !!                should be protected from selective switching by the
498      !!                for_all argument
499      !!----------------------------------------------------------------------
500      LOGICAL :: setto, for_all
501      TYPE(sn_ctl) :: sn_cfctl
502      !!----------------------------------------------------------------------
503      IF( for_all ) THEN
504         sn_cfctl%l_runstat = setto
505         sn_cfctl%l_trcstat = setto
506      ENDIF
507      sn_cfctl%l_oceout  = setto
508      sn_cfctl%l_layout  = setto
509      sn_cfctl%l_mppout  = setto
510      sn_cfctl%l_mpptop  = setto
511   END SUBROUTINE nemo_set_cfctl
512
513   SUBROUTINE istate_init
514      !!----------------------------------------------------------------------
515      !!                   ***  ROUTINE istate_init  ***
516      !!
517      !! ** Purpose :   Initialization to zero of the dynamics and tracers.
518      !!----------------------------------------------------------------------
519      !
520      !     now fields         !     after fields      !
521      un   (:,:,:)   = 0._wp   ;   ua(:,:,:) = 0._wp   !
522      vn   (:,:,:)   = 0._wp   ;   va(:,:,:) = 0._wp   !
523      wn   (:,:,:)   = 0._wp   !                       !
524      hdivn(:,:,:)   = 0._wp   !                       !
525      tsn  (:,:,:,:) = 0._wp   !                       !
526      !
527      rhd  (:,:,:) = 0.e0
528      rhop (:,:,:) = 0.e0
529      rn2  (:,:,:) = 0.e0
530      !
531   END SUBROUTINE istate_init
532
533
534   SUBROUTINE stp_ctl( kt, kindic )
535      !!----------------------------------------------------------------------
536      !!                    ***  ROUTINE stp_ctl  ***
537      !!
538      !! ** Purpose :   Control the run
539      !!
540      !! ** Method  : - Save the time step in numstp
541      !!
542      !! ** Actions :   'time.step' file containing the last ocean time-step
543      !!----------------------------------------------------------------------
544      INTEGER, INTENT(in   ) ::   kt      ! ocean time-step index
545      INTEGER, INTENT(inout) ::   kindic  ! indicator of solver convergence
546      !!----------------------------------------------------------------------
547      !
548      IF( kt == nit000 .AND. lwm ) THEN
549         WRITE(numout,*)
550         WRITE(numout,*) 'stp_ctl : time-stepping control'
551         WRITE(numout,*) '~~~~~~~'
552         ! open time.step file
553         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
554      ENDIF
555      !
556      IF(lwm) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
557      IF(lwm) REWIND( numstp )                       ! --------------------------
558      !
559   END SUBROUTINE stp_ctl
560   !!======================================================================
561END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.