New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zflx.F90 in NEMO/branches/2019/fix_sn_cfctl_ticket2328/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/fix_sn_cfctl_ticket2328/src/TOP/PISCES/P4Z/p4zflx.F90 @ 11869

Last change on this file since 11869 was 11869, checked in by acc, 4 years ago

Branch 2019/fix_sn_cfctl_ticket2328. Changes to enable correct functionality for the sn_cfctl%l_mppout and sn_cfctl%l_mpptop options. These changes also introduce a sn_cfctl%l_oasout option to toggle the OASIS setup information (sbccpl.F90, only) which was yet another misuse of ln_ctl. The next step may be to remove most references to ln_ctl altogether and provide a single control mechanism. TBD. See ticket #2328

  • Property svn:keywords set to Id
File size: 18.6 KB
RevLine 
[3443]1MODULE p4zflx
2   !!======================================================================
3   !!                         ***  MODULE p4zflx  ***
4   !! TOP :   PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
5   !!======================================================================
[9169]6   !! History :   -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!             -   !  1998     (O. Aumont) additions
8   !!             -   !  1999     (C. Le Quere) modifications
9   !!            1.0  !  2004     (O. Aumont) modifications
10   !!            2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                 !  2011-02  (J. Simeon, J. Orr) Include total atm P correction
[3443]12   !!----------------------------------------------------------------------
13   !!   p4z_flx       :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
14   !!   p4z_flx_init  :   Read the namelist
15   !!   p4z_patm      :   Read sfc atm pressure [atm] for each grid cell
16   !!----------------------------------------------------------------------
[9169]17   USE oce_trc        !  shared variables between ocean and passive tracers
18   USE trc            !  passive tracers common variables
19   USE sms_pisces     !  PISCES Source Minus Sink variables
20   USE p4zche         !  Chemical model
21   USE prtctl_trc     !  print control for debugging
22   USE iom            !  I/O manager
23   USE fldread        !  read input fields
[3443]24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_flx 
29   PUBLIC   p4z_flx_init 
30   PUBLIC   p4z_flx_alloc 
31
[9169]32   !                                 !!** Namelist  nampisext  **
33   REAL(wp)          ::   atcco2      !: pre-industrial atmospheric [co2] (ppm) 
34   LOGICAL           ::   ln_co2int   !: flag to read in a file and interpolate atmospheric pco2 or not
35   CHARACTER(len=34) ::   clname      !: filename of pco2 values
36   INTEGER           ::   nn_offset   !: Offset model-data start year (default = 0)
[3443]37
38   !!  Variables related to reading atmospheric CO2 time history   
[9169]39   INTEGER                                   ::   nmaxrec, numco2   !
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) ::   atcco2h, years    !
[3443]41
[9169]42   !                                  !!* nampisatm namelist (Atmospheric PRessure) *
[7646]43   LOGICAL, PUBLIC ::   ln_presatm     !: ref. pressure: global mean Patm (F) or a constant (F)
44   LOGICAL, PUBLIC ::   ln_presatmco2  !: accounting for spatial atm CO2 in the compuation of carbon flux (T) or not (F)
[3443]45
[9169]46   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:) ::   patm      ! atmospheric pressure at kt                 [N/m2]
47   TYPE(FLD), ALLOCATABLE,       DIMENSION(:)   ::   sf_patm   ! structure of input fields (file informations, fields read)
48   TYPE(FLD), ALLOCATABLE,       DIMENSION(:)   ::   sf_atmco2 ! structure of input fields (file informations, fields read)
[3443]49
[9169]50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::  satmco2   !: atmospheric pco2
[3443]51
[9169]52   REAL(wp) ::   xconv  = 0.01_wp / 3600._wp   !: coefficients for conversion
[3443]53
54   !!----------------------------------------------------------------------
[10067]55   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
[7753]56   !! $Id$
[10068]57   !! Software governed by the CeCILL license (see ./LICENSE)
[3443]58   !!----------------------------------------------------------------------
59CONTAINS
60
[5385]61   SUBROUTINE p4z_flx ( kt, knt )
[3443]62      !!---------------------------------------------------------------------
63      !!                     ***  ROUTINE p4z_flx  ***
64      !!
65      !! ** Purpose :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
66      !!
67      !! ** Method  :
68      !!              - Include total atm P correction via Esbensen & Kushnir (1981)
69      !!              - Remove Wanninkhof chemical enhancement;
70      !!              - Add option for time-interpolation of atcco2.txt 
71      !!---------------------------------------------------------------------
[5385]72      INTEGER, INTENT(in) ::   kt, knt   !
[3443]73      !
74      INTEGER  ::   ji, jj, jm, iind, iindm1
[6291]75      REAL(wp) ::   ztc, ztc2, ztc3, ztc4, zws, zkgwan
[3443]76      REAL(wp) ::   zfld, zflu, zfld16, zflu16, zfact
[6945]77      REAL(wp) ::   zvapsw, zsal, zfco2, zxc2, xCO2approx, ztkel, zfugcoeff
[7646]78      REAL(wp) ::   zph, zdic, zsch_o2, zsch_co2
[3443]79      REAL(wp) ::   zyr_dec, zdco2dt
[9169]80      CHARACTER (len=25) ::   charout
81      REAL(wp), DIMENSION(jpi,jpj) ::   zkgco2, zkgo2, zh2co3, zoflx,  zpco2atm 
82      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zw2d
[3443]83      !!---------------------------------------------------------------------
84      !
[9124]85      IF( ln_timing )   CALL timing_start('p4z_flx')
[3443]86      !
87      ! SURFACE CHEMISTRY (PCO2 AND [H+] IN
88      !     SURFACE LAYER); THE RESULT OF THIS CALCULATION
89      !     IS USED TO COMPUTE AIR-SEA FLUX OF CO2
90
[9169]91      IF( kt /= nit000 .AND. .NOT.l_co2cpl .AND. knt == 1 )   CALL p4z_patm( kt )   ! Get sea-level pressure (E&K [1981] climatology) for use in flux calcs
[3443]92
[7646]93      IF( ln_co2int .AND. .NOT.ln_presatmco2 .AND. .NOT.l_co2cpl ) THEN 
[3443]94         ! Linear temporal interpolation  of atmospheric pco2.  atcco2.txt has annual values.
95         ! Caveats: First column of .txt must be in years, decimal  years preferably.
96         ! For nn_offset, if your model year is iyy, nn_offset=(years(1)-iyy)
97         ! then the first atmospheric CO2 record read is at years(1)
98         zyr_dec = REAL( nyear + nn_offset, wp ) + REAL( nday_year, wp ) / REAL( nyear_len(1), wp )
[4148]99         jm = 1
100         DO WHILE( jm <= nmaxrec .AND. years(jm) < zyr_dec ) ;  jm = jm + 1 ;  END DO
[3443]101         iind = jm  ;   iindm1 = jm - 1
102         zdco2dt = ( atcco2h(iind) - atcco2h(iindm1) ) / ( years(iind) - years(iindm1) + rtrn )
103         atcco2  = zdco2dt * ( zyr_dec - years(iindm1) ) + atcco2h(iindm1)
[7753]104         satmco2(:,:) = atcco2 
[3443]105      ENDIF
106
[7753]107      IF( l_co2cpl )   satmco2(:,:) = atm_co2(:,:)
[3443]108
[7646]109      DO jj = 1, jpj
110         DO ji = 1, jpi
111            ! DUMMY VARIABLES FOR DIC, H+, AND BORATE
112            zfact = rhop(ji,jj,1) / 1000. + rtrn
113            zdic  = trb(ji,jj,1,jpdic)
114            zph   = MAX( hi(ji,jj,1), 1.e-10 ) / zfact
115            ! CALCULATE [H2CO3]
116            zh2co3(ji,jj) = zdic/(1. + ak13(ji,jj,1)/zph + ak13(ji,jj,1)*ak23(ji,jj,1)/zph**2)
[3443]117         END DO
118      END DO
119
120      ! --------------
121      ! COMPUTE FLUXES
122      ! --------------
123
124      ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS
125      ! -------------------------------------------
126
127      DO jj = 1, jpj
128         DO ji = 1, jpi
129            ztc  = MIN( 35., tsn(ji,jj,1,jp_tem) )
130            ztc2 = ztc * ztc
131            ztc3 = ztc * ztc2 
[6291]132            ztc4 = ztc2 * ztc2 
[3443]133            ! Compute the schmidt Number both O2 and CO2
[6291]134            zsch_co2 = 2116.8 - 136.25 * ztc + 4.7353 * ztc2 - 0.092307 * ztc3 + 0.0007555 * ztc4
135            zsch_o2  = 1920.4 - 135.6  * ztc + 5.2122 * ztc2 - 0.109390 * ztc3 + 0.0009377 * ztc4
[3443]136            !  wind speed
137            zws  = wndm(ji,jj) * wndm(ji,jj)
138            ! Compute the piston velocity for O2 and CO2
[6291]139            zkgwan = 0.251 * zws
[3443]140            zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1)
141            ! compute gas exchange for CO2 and O2
142            zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 )
143            zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 )
144         END DO
145      END DO
146
[7646]147
[3443]148      DO jj = 1, jpj
149         DO ji = 1, jpi
[7646]150            ztkel = tempis(ji,jj,1) + 273.15
151            zsal  = salinprac(ji,jj,1) + ( 1.- tmask(ji,jj,1) ) * 35.
[6945]152            zvapsw    = EXP(24.4543 - 67.4509*(100.0/ztkel) - 4.8489*LOG(ztkel/100) - 0.000544*zsal)
153            zpco2atm(ji,jj) = satmco2(ji,jj) * ( patm(ji,jj) - zvapsw )
154            zxc2      = ( 1.0 - zpco2atm(ji,jj) * 1E-6 )**2
155            zfugcoeff = EXP( patm(ji,jj) * (chemc(ji,jj,2) + 2.0 * zxc2 * chemc(ji,jj,3) )   &
156            &           / ( 82.05736 * ztkel ))
157            zfco2 = zpco2atm(ji,jj) * zfugcoeff
158
[3443]159            ! Compute CO2 flux for the sea and air
[6945]160            zfld = zfco2 * chemc(ji,jj,1) * zkgco2(ji,jj)  ! (mol/L) * (m/s)
161            zflu = zh2co3(ji,jj) * zkgco2(ji,jj)                                   ! (mol/L) (m/s) ?
[5385]162            oce_co2(ji,jj) = ( zfld - zflu ) * rfact2 * e1e2t(ji,jj) * tmask(ji,jj,1) * 1000.
[3443]163            ! compute the trend
[6945]164            tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) * rfact2 / e3t_n(ji,jj,1) * tmask(ji,jj,1)
[3443]165
166            ! Compute O2 flux
[6945]167            zfld16 = patm(ji,jj) * chemo2(ji,jj,1) * zkgo2(ji,jj)          ! (mol/L) * (m/s)
168            zflu16 = trb(ji,jj,1,jpoxy) * zkgo2(ji,jj)
169            zoflx(ji,jj) = ( zfld16 - zflu16 ) * tmask(ji,jj,1)
[6140]170            tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + zoflx(ji,jj) * rfact2 / e3t_n(ji,jj,1)
[3443]171         END DO
172      END DO
173
[10425]174      IF( iom_use("tcflx") .OR. iom_use("tcflxcum") .OR. kt == nitrst   &
175         &                 .OR. (ln_check_mass .AND. kt == nitend) )    &
176         t_oce_co2_flx  = glob_sum( 'p4zflx', oce_co2(:,:) )                    !  Total Flux of Carbon
[4996]177      t_oce_co2_flx_cum = t_oce_co2_flx_cum + t_oce_co2_flx       !  Cumulative Total Flux of Carbon
[10425]178!      t_atm_co2_flx     = glob_sum( 'p4zflx', satmco2(:,:) * e1e2t(:,:) )       ! Total atmospheric pCO2
[4996]179      t_atm_co2_flx     =  atcco2      ! Total atmospheric pCO2
180 
[11869]181      IF(ln_ctl .OR. sn_cfctl%l_mpptop)   THEN  ! print mean trends (used for debugging)
[3443]182         WRITE(charout, FMT="('flx ')")
183         CALL prt_ctl_trc_info(charout)
184         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
185      ENDIF
186
[5385]187      IF( lk_iomput .AND. knt == nrdttrc ) THEN
[9125]188         ALLOCATE( zw2d(jpi,jpj) ) 
[4996]189         IF( iom_use( "Cflx"  ) )  THEN
[7753]190            zw2d(:,:) = oce_co2(:,:) / e1e2t(:,:) * rfact2r
[4996]191            CALL iom_put( "Cflx"     , zw2d ) 
192         ENDIF
193         IF( iom_use( "Oflx"  ) )  THEN
[7753]194            zw2d(:,:) =  zoflx(:,:) * 1000 * tmask(:,:,1)
[4996]195            CALL iom_put( "Oflx" , zw2d )
196         ENDIF
197         IF( iom_use( "Kg"    ) )  THEN
[7753]198            zw2d(:,:) =  zkgco2(:,:) * tmask(:,:,1)
[4996]199            CALL iom_put( "Kg"   , zw2d )
200         ENDIF
201         IF( iom_use( "Dpco2" ) ) THEN
[7753]202           zw2d(:,:) = ( zpco2atm(:,:) - zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1)
[4996]203           CALL iom_put( "Dpco2" ,  zw2d )
204         ENDIF
205         IF( iom_use( "Dpo2" ) )  THEN
[7753]206           zw2d(:,:) = ( atcox * patm(:,:) - atcox * trb(:,:,1,jpoxy) / ( chemo2(:,:,1) + rtrn ) ) * tmask(:,:,1)
[4996]207           CALL iom_put( "Dpo2"  , zw2d )
208         ENDIF
[10425]209         CALL iom_put( "tcflx"    , t_oce_co2_flx * rfact2r )   ! molC/s
210         CALL iom_put( "tcflxcum" , t_oce_co2_flx_cum       )   ! molC
[4996]211         !
[9125]212         DEALLOCATE( zw2d )
[3443]213      ENDIF
214      !
[9124]215      IF( ln_timing )   CALL timing_stop('p4z_flx')
[3443]216      !
217   END SUBROUTINE p4z_flx
218
219
220   SUBROUTINE p4z_flx_init
221      !!----------------------------------------------------------------------
222      !!                  ***  ROUTINE p4z_flx_init  ***
223      !!
224      !! ** Purpose :   Initialization of atmospheric conditions
225      !!
226      !! ** Method  :   Read the nampisext namelist and check the parameters
227      !!      called at the first timestep (nittrc000)
[9169]228      !!
[3443]229      !! ** input   :   Namelist nampisext
230      !!----------------------------------------------------------------------
[9169]231      INTEGER ::   jm, ios   ! Local integer
232      !!
[3443]233      NAMELIST/nampisext/ln_co2int, atcco2, clname, nn_offset
234      !!----------------------------------------------------------------------
[9169]235      IF(lwp) THEN
236         WRITE(numout,*)
237         WRITE(numout,*) ' p4z_flx_init : atmospheric conditions for air-sea flux calculation'
238         WRITE(numout,*) ' ~~~~~~~~~~~~'
239      ENDIF
[3443]240      !
[4147]241      REWIND( numnatp_ref )              ! Namelist nampisext in reference namelist : Pisces atm. conditions
242      READ  ( numnatp_ref, nampisext, IOSTAT = ios, ERR = 901)
[11536]243901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisext in reference namelist' )
[4147]244      REWIND( numnatp_cfg )              ! Namelist nampisext in configuration namelist : Pisces atm. conditions
245      READ  ( numnatp_cfg, nampisext, IOSTAT = ios, ERR = 902 )
[11536]246902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisext in configuration namelist' )
[4624]247      IF(lwm) WRITE ( numonp, nampisext )
[3443]248      !
249      IF(lwp) THEN                         ! control print
[9169]250         WRITE(numout,*) '   Namelist : nampisext --- parameters for air-sea exchange'
251         WRITE(numout,*) '      reading in the atm pCO2 file or constant value   ln_co2int =', ln_co2int
[3443]252      ENDIF
[9248]253      !
254      CALL p4z_patm( nit000 )
255      !
256      IF( .NOT.ln_co2int .AND. .NOT.ln_presatmco2 ) THEN
[3443]257         IF(lwp) THEN                         ! control print
[9169]258            WRITE(numout,*) '         Constant Atmospheric pCO2 value               atcco2    =', atcco2
[3443]259         ENDIF
[7753]260         satmco2(:,:)  = atcco2      ! Initialisation of atmospheric pco2
[7646]261      ELSEIF( ln_co2int .AND. .NOT.ln_presatmco2 ) THEN
[3443]262         IF(lwp)  THEN
[9169]263            WRITE(numout,*) '         Constant Atmospheric pCO2 value               atcco2    =', atcco2
264            WRITE(numout,*) '         Atmospheric pCO2 value  from file             clname    =', TRIM( clname )
265            WRITE(numout,*) '         Offset model-data start year                  nn_offset =', nn_offset
[3443]266         ENDIF
267         CALL ctl_opn( numco2, TRIM( clname) , 'OLD', 'FORMATTED', 'SEQUENTIAL', -1 , numout, lwp )
268         jm = 0                      ! Count the number of record in co2 file
269         DO
270           READ(numco2,*,END=100) 
271           jm = jm + 1
272         END DO
273 100     nmaxrec = jm - 1 
[9169]274         ALLOCATE( years  (nmaxrec) )   ;   years  (:) = 0._wp
275         ALLOCATE( atcco2h(nmaxrec) )   ;   atcco2h(:) = 0._wp
276         !
[3443]277         REWIND(numco2)
278         DO jm = 1, nmaxrec          ! get  xCO2 data
279            READ(numco2, *)  years(jm), atcco2h(jm)
280            IF(lwp) WRITE(numout, '(f6.0,f7.2)')  years(jm), atcco2h(jm)
281         END DO
282         CLOSE(numco2)
[7646]283      ELSEIF( .NOT.ln_co2int .AND. ln_presatmco2 ) THEN
[9248]284         IF(lwp) WRITE(numout,*) '    Spatialized Atmospheric pCO2 from an external file'
[7646]285      ELSE
[9248]286         IF(lwp) WRITE(numout,*) '    Spatialized Atmospheric pCO2 from an external file'
[3443]287      ENDIF
288      !
[7753]289      oce_co2(:,:)  = 0._wp                ! Initialization of Flux of Carbon
[4996]290      t_oce_co2_flx = 0._wp
[3443]291      t_atm_co2_flx = 0._wp
292      !
293   END SUBROUTINE p4z_flx_init
294
[9124]295
[3443]296   SUBROUTINE p4z_patm( kt )
297      !!----------------------------------------------------------------------
298      !!                  ***  ROUTINE p4z_atm  ***
299      !!
[9169]300      !! ** Purpose :   Read and interpolate the external atmospheric sea-level pressure
[3443]301      !! ** Method  :   Read the files and interpolate the appropriate variables
302      !!
303      !!----------------------------------------------------------------------
[9169]304      INTEGER, INTENT(in) ::   kt   ! ocean time step
[3443]305      !
[9169]306      INTEGER            ::   ierr, ios   ! Local integer
307      CHARACTER(len=100) ::   cn_dir      ! Root directory for location of ssr files
308      TYPE(FLD_N)        ::   sn_patm     ! informations about the fields to be read
309      TYPE(FLD_N)        ::   sn_atmco2   ! informations about the fields to be read
[3443]310      !!
[7646]311      NAMELIST/nampisatm/ ln_presatm, ln_presatmco2, sn_patm, sn_atmco2, cn_dir
[9124]312      !!----------------------------------------------------------------------
[9169]313      !
314      IF( kt == nit000 ) THEN    !==  First call kt=nittrc000  ==!
315         !
316         IF(lwp) THEN
317            WRITE(numout,*)
318            WRITE(numout,*) ' p4z_patm : sea-level atmospheric pressure'
319            WRITE(numout,*) ' ~~~~~~~~'
320         ENDIF
321         !
[4147]322         REWIND( numnatp_ref )              ! Namelist nampisatm in reference namelist : Pisces atm. sea level pressure file
323         READ  ( numnatp_ref, nampisatm, IOSTAT = ios, ERR = 901)
[11536]324901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in reference namelist' )
[4147]325         REWIND( numnatp_cfg )              ! Namelist nampisatm in configuration namelist : Pisces atm. sea level pressure file
326         READ  ( numnatp_cfg, nampisatm, IOSTAT = ios, ERR = 902 )
[11536]327902      IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisatm in configuration namelist' )
[4624]328         IF(lwm) WRITE ( numonp, nampisatm )
[3443]329         !
330         !
331         IF(lwp) THEN                                 !* control print
[9169]332            WRITE(numout,*) '   Namelist : nampisatm --- Atmospheric Pressure as external forcing'
333            WRITE(numout,*) '      constant atmopsheric pressure (F) or from a file (T)  ln_presatm    = ', ln_presatm
334            WRITE(numout,*) '      spatial atmopsheric CO2 for flux calcs                ln_presatmco2 = ', ln_presatmco2
[3443]335         ENDIF
336         !
337         IF( ln_presatm ) THEN
338            ALLOCATE( sf_patm(1), STAT=ierr )           !* allocate and fill sf_patm (forcing structure) with sn_patm
339            IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_patm structure' )
340            !
341            CALL fld_fill( sf_patm, (/ sn_patm /), cn_dir, 'p4z_flx', 'Atmospheric pressure ', 'nampisatm' )
342                                   ALLOCATE( sf_patm(1)%fnow(jpi,jpj,1)   )
343            IF( sn_patm%ln_tint )  ALLOCATE( sf_patm(1)%fdta(jpi,jpj,1,2) )
344         ENDIF
345         !                                         
[7646]346         IF( ln_presatmco2 ) THEN
347            ALLOCATE( sf_atmco2(1), STAT=ierr )           !* allocate and fill sf_atmco2 (forcing structure) with sn_atmco2
348            IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_atmco2 structure' )
349            !
350            CALL fld_fill( sf_atmco2, (/ sn_atmco2 /), cn_dir, 'p4z_flx', 'Atmospheric co2 partial pressure ', 'nampisatm' )
351                                   ALLOCATE( sf_atmco2(1)%fnow(jpi,jpj,1)   )
352            IF( sn_atmco2%ln_tint )  ALLOCATE( sf_atmco2(1)%fdta(jpi,jpj,1,2) )
353         ENDIF
354         !
[9169]355         IF( .NOT.ln_presatm )   patm(:,:) = 1._wp    ! Initialize patm if no reading from a file
[3443]356         !
357      ENDIF
358      !
359      IF( ln_presatm ) THEN
360         CALL fld_read( kt, 1, sf_patm )               !* input Patm provided at kt + 1/2
[7753]361         patm(:,:) = sf_patm(1)%fnow(:,:,1)                        ! atmospheric pressure
[3443]362      ENDIF
363      !
[7646]364      IF( ln_presatmco2 ) THEN
365         CALL fld_read( kt, 1, sf_atmco2 )               !* input atmco2 provided at kt + 1/2
[7753]366         satmco2(:,:) = sf_atmco2(1)%fnow(:,:,1)                        ! atmospheric pressure
[7646]367      ELSE
[7753]368         satmco2(:,:) = atcco2    ! Initialize atmco2 if no reading from a file
[7646]369      ENDIF
370      !
[3443]371   END SUBROUTINE p4z_patm
372
[7646]373
[3443]374   INTEGER FUNCTION p4z_flx_alloc()
375      !!----------------------------------------------------------------------
376      !!                     ***  ROUTINE p4z_flx_alloc  ***
377      !!----------------------------------------------------------------------
[7646]378      ALLOCATE( satmco2(jpi,jpj), patm(jpi,jpj), STAT=p4z_flx_alloc )
[3443]379      !
[10425]380      IF( p4z_flx_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_flx_alloc : failed to allocate arrays' )
[3443]381      !
382   END FUNCTION p4z_flx_alloc
383
384   !!======================================================================
[5656]385END MODULE p4zflx
Note: See TracBrowser for help on using the repository browser.