| 1 | MODULE icbini |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE icbini *** |
|---|
| 4 | !! Icebergs: initialise variables for iceberg tracking |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2010-01 (T. Martin & A. Adcroft) Original code |
|---|
| 7 | !! 3.3 ! 2011-03 (G. Madec) Part conversion to NEMO form ; Removal of mapping from another grid |
|---|
| 8 | !! - ! 2011-04 (S. Alderson) Split into separate modules ; Restore restart routines |
|---|
| 9 | !! - ! 2011-05 (S. Alderson) generate_test_icebergs restored ; new forcing arrays with extra halo ; |
|---|
| 10 | !! - ! north fold exchange arrays added |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! icb_init : initialise icebergs |
|---|
| 14 | !! icb_ini_gen : generate test icebergs |
|---|
| 15 | !! icb_nam : read iceberg namelist |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE dom_oce ! ocean domain |
|---|
| 18 | USE in_out_manager ! IO routines and numout in particular |
|---|
| 19 | USE lib_mpp ! mpi library and lk_mpp in particular |
|---|
| 20 | USE sbc_oce ! ocean : surface boundary condition |
|---|
| 21 | USE sbc_ice ! sea-ice: surface boundary condition |
|---|
| 22 | USE iom ! IOM library |
|---|
| 23 | USE fldread ! field read |
|---|
| 24 | USE lbclnk ! lateral boundary condition - MPP link |
|---|
| 25 | ! |
|---|
| 26 | USE icb_oce ! define iceberg arrays |
|---|
| 27 | USE icbutl ! iceberg utility routines |
|---|
| 28 | USE icbrst ! iceberg restart routines |
|---|
| 29 | USE icbtrj ! iceberg trajectory I/O routines |
|---|
| 30 | USE icbdia ! iceberg budget routines |
|---|
| 31 | |
|---|
| 32 | IMPLICIT NONE |
|---|
| 33 | PRIVATE |
|---|
| 34 | |
|---|
| 35 | PUBLIC icb_init ! routine called in nemogcm.F90 module |
|---|
| 36 | |
|---|
| 37 | CHARACTER(len=100) :: cn_dir = './' !: Root directory for location of icb files |
|---|
| 38 | TYPE(FLD_N) :: sn_icb !: information about the calving file to be read |
|---|
| 39 | TYPE(FLD), PUBLIC, ALLOCATABLE , DIMENSION(:) :: sf_icb !: structure: file information, fields read |
|---|
| 40 | !: used in icbini and icbstp |
|---|
| 41 | !!---------------------------------------------------------------------- |
|---|
| 42 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 43 | !! $Id$ |
|---|
| 44 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 45 | !!---------------------------------------------------------------------- |
|---|
| 46 | CONTAINS |
|---|
| 47 | |
|---|
| 48 | SUBROUTINE icb_init( pdt, kt ) |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | !! *** ROUTINE dom_init *** |
|---|
| 51 | !! |
|---|
| 52 | !! ** Purpose : iceberg initialization. |
|---|
| 53 | !! |
|---|
| 54 | !! ** Method : - read the iceberg namelist |
|---|
| 55 | !! - find non-overlapping processor interior since we can only |
|---|
| 56 | !! have one instance of a particular iceberg |
|---|
| 57 | !! - calculate the destinations for north fold exchanges |
|---|
| 58 | !! - setup either test icebergs or calving file |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | REAL(wp), INTENT(in) :: pdt ! iceberg time-step (rdt*nn_fsbc) |
|---|
| 61 | INTEGER , INTENT(in) :: kt ! time step number |
|---|
| 62 | ! |
|---|
| 63 | INTEGER :: ji, jj, jn ! dummy loop indices |
|---|
| 64 | INTEGER :: i1, i2, i3 ! local integers |
|---|
| 65 | INTEGER :: ii, inum, ivar ! - - |
|---|
| 66 | INTEGER :: istat1, istat2, istat3 ! - - |
|---|
| 67 | CHARACTER(len=300) :: cl_sdist ! local character |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | ! |
|---|
| 70 | CALL icb_nam ! Read and print namelist parameters |
|---|
| 71 | ! |
|---|
| 72 | IF( .NOT. ln_icebergs ) RETURN |
|---|
| 73 | |
|---|
| 74 | ! ! allocate gridded fields |
|---|
| 75 | IF( icb_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'icb_alloc : unable to allocate arrays' ) |
|---|
| 76 | ! |
|---|
| 77 | ! ! initialised variable with extra haloes to zero |
|---|
| 78 | uo_e(:,:) = 0._wp ; vo_e(:,:) = 0._wp ; |
|---|
| 79 | ua_e(:,:) = 0._wp ; va_e(:,:) = 0._wp ; |
|---|
| 80 | ff_e(:,:) = 0._wp ; tt_e(:,:) = 0._wp ; |
|---|
| 81 | fr_e(:,:) = 0._wp ; hi_e(:,:) = 0._wp ; |
|---|
| 82 | #if defined key_si3 |
|---|
| 83 | ui_e(:,:) = 0._wp ; vi_e(:,:) = 0._wp ; |
|---|
| 84 | #endif |
|---|
| 85 | ssh_e(:,:) = 0._wp ; |
|---|
| 86 | ! |
|---|
| 87 | ! ! open ascii output file or files for iceberg status information |
|---|
| 88 | ! ! note that we choose to do this on all processors since we cannot |
|---|
| 89 | ! ! predict where icebergs will be ahead of time |
|---|
| 90 | IF( nn_verbose_level > 0) THEN |
|---|
| 91 | CALL ctl_opn( numicb, 'icebergs.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea ) |
|---|
| 92 | ENDIF |
|---|
| 93 | |
|---|
| 94 | ! set parameters (mostly from namelist) |
|---|
| 95 | ! |
|---|
| 96 | berg_dt = pdt |
|---|
| 97 | first_width (:) = SQRT( rn_initial_mass(:) / ( rn_LoW_ratio * rn_rho_bergs * rn_initial_thickness(:) ) ) |
|---|
| 98 | first_length(:) = rn_LoW_ratio * first_width(:) |
|---|
| 99 | |
|---|
| 100 | berg_grid%calving (:,:) = 0._wp |
|---|
| 101 | berg_grid%calving_hflx (:,:) = 0._wp |
|---|
| 102 | berg_grid%stored_heat (:,:) = 0._wp |
|---|
| 103 | berg_grid%floating_melt(:,:) = 0._wp |
|---|
| 104 | berg_grid%maxclass (:,:) = nclasses |
|---|
| 105 | berg_grid%stored_ice (:,:,:) = 0._wp |
|---|
| 106 | berg_grid%tmp (:,:) = 0._wp |
|---|
| 107 | src_calving (:,:) = 0._wp |
|---|
| 108 | src_calving_hflx (:,:) = 0._wp |
|---|
| 109 | |
|---|
| 110 | ! ! domain for icebergs |
|---|
| 111 | IF( lk_mpp .AND. jpni == 1 ) CALL ctl_stop( 'icbinit: having ONE processor in x currently does not work' ) |
|---|
| 112 | ! NB: the issue here is simply that cyclic east-west boundary condition have not been coded in mpp case |
|---|
| 113 | ! for the north fold we work out which points communicate by asking |
|---|
| 114 | ! lbc_lnk to pass processor number (valid even in single processor case) |
|---|
| 115 | ! borrow src_calving arrays for this |
|---|
| 116 | ! |
|---|
| 117 | ! pack i and j together using a scaling of a power of 10 |
|---|
| 118 | nicbpack = 10000 |
|---|
| 119 | IF( jpiglo >= nicbpack ) CALL ctl_stop( 'icbini: processor index packing failure' ) |
|---|
| 120 | nicbfldproc(:) = -1 |
|---|
| 121 | |
|---|
| 122 | DO jj = 1, jpj |
|---|
| 123 | DO ji = 1, jpi |
|---|
| 124 | src_calving_hflx(ji,jj) = narea |
|---|
| 125 | src_calving (ji,jj) = nicbpack * mjg(jj) + mig(ji) |
|---|
| 126 | END DO |
|---|
| 127 | END DO |
|---|
| 128 | CALL lbc_lnk( 'icbini', src_calving_hflx, 'T', 1._wp ) |
|---|
| 129 | CALL lbc_lnk( 'icbini', src_calving , 'T', 1._wp ) |
|---|
| 130 | |
|---|
| 131 | ! work out interior of processor from exchange array |
|---|
| 132 | ! first entry with narea for this processor is left hand interior index |
|---|
| 133 | ! last entry is right hand interior index |
|---|
| 134 | jj = nlcj/2 |
|---|
| 135 | nicbdi = -1 |
|---|
| 136 | nicbei = -1 |
|---|
| 137 | DO ji = 1, jpi |
|---|
| 138 | i3 = INT( src_calving(ji,jj) ) |
|---|
| 139 | i2 = INT( i3/nicbpack ) |
|---|
| 140 | i1 = i3 - i2*nicbpack |
|---|
| 141 | i3 = INT( src_calving_hflx(ji,jj) ) |
|---|
| 142 | IF( i1 == mig(ji) .AND. i3 == narea ) THEN |
|---|
| 143 | IF( nicbdi < 0 ) THEN ; nicbdi = ji |
|---|
| 144 | ELSE ; nicbei = ji |
|---|
| 145 | ENDIF |
|---|
| 146 | ENDIF |
|---|
| 147 | END DO |
|---|
| 148 | ! |
|---|
| 149 | ! repeat for j direction |
|---|
| 150 | ji = nlci/2 |
|---|
| 151 | nicbdj = -1 |
|---|
| 152 | nicbej = -1 |
|---|
| 153 | DO jj = 1, jpj |
|---|
| 154 | i3 = INT( src_calving(ji,jj) ) |
|---|
| 155 | i2 = INT( i3/nicbpack ) |
|---|
| 156 | i1 = i3 - i2*nicbpack |
|---|
| 157 | i3 = INT( src_calving_hflx(ji,jj) ) |
|---|
| 158 | IF( i2 == mjg(jj) .AND. i3 == narea ) THEN |
|---|
| 159 | IF( nicbdj < 0 ) THEN ; nicbdj = jj |
|---|
| 160 | ELSE ; nicbej = jj |
|---|
| 161 | ENDIF |
|---|
| 162 | ENDIF |
|---|
| 163 | END DO |
|---|
| 164 | ! |
|---|
| 165 | ! special for east-west boundary exchange we save the destination index |
|---|
| 166 | i1 = MAX( nicbdi-1, 1) |
|---|
| 167 | i3 = INT( src_calving(i1,nlcj/2) ) |
|---|
| 168 | jj = INT( i3/nicbpack ) |
|---|
| 169 | ricb_left = REAL( i3 - nicbpack*jj, wp ) |
|---|
| 170 | i1 = MIN( nicbei+1, jpi ) |
|---|
| 171 | i3 = INT( src_calving(i1,nlcj/2) ) |
|---|
| 172 | jj = INT( i3/nicbpack ) |
|---|
| 173 | ricb_right = REAL( i3 - nicbpack*jj, wp ) |
|---|
| 174 | |
|---|
| 175 | ! north fold |
|---|
| 176 | IF( npolj > 0 ) THEN |
|---|
| 177 | ! |
|---|
| 178 | ! icebergs in row nicbej+1 get passed across fold |
|---|
| 179 | nicbfldpts(:) = INT( src_calving(:,nicbej+1) ) |
|---|
| 180 | nicbflddest(:) = INT( src_calving_hflx(:,nicbej+1) ) |
|---|
| 181 | ! |
|---|
| 182 | ! work out list of unique processors to talk to |
|---|
| 183 | ! pack them into a fixed size array where empty slots are marked by a -1 |
|---|
| 184 | DO ji = nicbdi, nicbei |
|---|
| 185 | ii = nicbflddest(ji) |
|---|
| 186 | IF( ii .GT. 0 ) THEN ! Needed because land suppression can mean |
|---|
| 187 | ! that unused points are not set in edge haloes |
|---|
| 188 | DO jn = 1, jpni |
|---|
| 189 | ! work along array until we find an empty slot |
|---|
| 190 | IF( nicbfldproc(jn) == -1 ) THEN |
|---|
| 191 | nicbfldproc(jn) = ii |
|---|
| 192 | EXIT !!gm EXIT should be avoided: use DO WHILE expression instead |
|---|
| 193 | ENDIF |
|---|
| 194 | ! before we find an empty slot, we may find processor number is already here so we exit |
|---|
| 195 | IF( nicbfldproc(jn) == ii ) EXIT |
|---|
| 196 | END DO |
|---|
| 197 | ENDIF |
|---|
| 198 | END DO |
|---|
| 199 | ENDIF |
|---|
| 200 | ! |
|---|
| 201 | IF( nn_verbose_level > 0) THEN |
|---|
| 202 | WRITE(numicb,*) 'processor ', narea |
|---|
| 203 | WRITE(numicb,*) 'jpi, jpj ', jpi, jpj |
|---|
| 204 | WRITE(numicb,*) 'nldi, nlei ', nldi, nlei |
|---|
| 205 | WRITE(numicb,*) 'nldj, nlej ', nldj, nlej |
|---|
| 206 | WRITE(numicb,*) 'berg i interior ', nicbdi, nicbei |
|---|
| 207 | WRITE(numicb,*) 'berg j interior ', nicbdj, nicbej |
|---|
| 208 | WRITE(numicb,*) 'berg left ', ricb_left |
|---|
| 209 | WRITE(numicb,*) 'berg right ', ricb_right |
|---|
| 210 | jj = nlcj/2 |
|---|
| 211 | WRITE(numicb,*) "central j line:" |
|---|
| 212 | WRITE(numicb,*) "i processor" |
|---|
| 213 | WRITE(numicb,*) (INT(src_calving_hflx(ji,jj)), ji=1,jpi) |
|---|
| 214 | WRITE(numicb,*) "i point" |
|---|
| 215 | WRITE(numicb,*) (INT(src_calving(ji,jj)), ji=1,jpi) |
|---|
| 216 | ji = nlci/2 |
|---|
| 217 | WRITE(numicb,*) "central i line:" |
|---|
| 218 | WRITE(numicb,*) "j processor" |
|---|
| 219 | WRITE(numicb,*) (INT(src_calving_hflx(ji,jj)), jj=1,jpj) |
|---|
| 220 | WRITE(numicb,*) "j point" |
|---|
| 221 | WRITE(numicb,*) (INT(src_calving(ji,jj)), jj=1,jpj) |
|---|
| 222 | IF( npolj > 0 ) THEN |
|---|
| 223 | WRITE(numicb,*) 'north fold destination points ' |
|---|
| 224 | WRITE(numicb,*) nicbfldpts |
|---|
| 225 | WRITE(numicb,*) 'north fold destination procs ' |
|---|
| 226 | WRITE(numicb,*) nicbflddest |
|---|
| 227 | WRITE(numicb,*) 'north fold destination proclist ' |
|---|
| 228 | WRITE(numicb,*) nicbfldproc |
|---|
| 229 | ENDIF |
|---|
| 230 | CALL flush(numicb) |
|---|
| 231 | ENDIF |
|---|
| 232 | |
|---|
| 233 | src_calving (:,:) = 0._wp |
|---|
| 234 | src_calving_hflx(:,:) = 0._wp |
|---|
| 235 | |
|---|
| 236 | ! assign each new iceberg with a unique number constructed from the processor number |
|---|
| 237 | ! and incremented by the total number of processors |
|---|
| 238 | num_bergs(:) = 0 |
|---|
| 239 | num_bergs(1) = narea - jpnij |
|---|
| 240 | |
|---|
| 241 | ! when not generating test icebergs we need to setup calving file |
|---|
| 242 | IF( nn_test_icebergs < 0 .OR. ln_use_calving ) THEN |
|---|
| 243 | ! |
|---|
| 244 | ! maximum distribution class array does not change in time so read it once |
|---|
| 245 | cl_sdist = TRIM( cn_dir )//TRIM( sn_icb%clname ) |
|---|
| 246 | CALL iom_open ( cl_sdist, inum ) ! open file |
|---|
| 247 | ivar = iom_varid( inum, 'maxclass', ldstop=.FALSE. ) |
|---|
| 248 | IF( ivar > 0 ) THEN |
|---|
| 249 | CALL iom_get ( inum, jpdom_data, 'maxclass', src_calving ) ! read the max distribution array |
|---|
| 250 | berg_grid%maxclass(:,:) = INT( src_calving ) |
|---|
| 251 | src_calving(:,:) = 0._wp |
|---|
| 252 | ENDIF |
|---|
| 253 | CALL iom_close( inum ) ! close file |
|---|
| 254 | ! |
|---|
| 255 | IF( nn_verbose_level > 0) THEN |
|---|
| 256 | WRITE(numicb,*) |
|---|
| 257 | WRITE(numicb,*) ' calving read in a file' |
|---|
| 258 | ENDIF |
|---|
| 259 | ALLOCATE( sf_icb(1), STAT=istat1 ) ! Create sf_icb structure (calving) |
|---|
| 260 | ALLOCATE( sf_icb(1)%fnow(jpi,jpj,1), STAT=istat2 ) |
|---|
| 261 | ALLOCATE( sf_icb(1)%fdta(jpi,jpj,1,2), STAT=istat3 ) |
|---|
| 262 | IF( istat1+istat2+istat3 > 0 ) THEN |
|---|
| 263 | CALL ctl_stop( 'sbc_icb: unable to allocate sf_icb structure' ) ; RETURN |
|---|
| 264 | ENDIF |
|---|
| 265 | ! ! fill sf_icb with the namelist (sn_icb) and control print |
|---|
| 266 | CALL fld_fill( sf_icb, (/ sn_icb /), cn_dir, 'icb_init', 'read calving data', 'namicb' ) |
|---|
| 267 | ! |
|---|
| 268 | ENDIF |
|---|
| 269 | |
|---|
| 270 | IF( .NOT.ln_rstart ) THEN |
|---|
| 271 | IF( nn_test_icebergs > 0 ) CALL icb_ini_gen() |
|---|
| 272 | ELSE |
|---|
| 273 | IF( nn_test_icebergs > 0 ) THEN |
|---|
| 274 | CALL icb_ini_gen() |
|---|
| 275 | ELSE |
|---|
| 276 | CALL icb_rst_read() |
|---|
| 277 | l_restarted_bergs = .TRUE. |
|---|
| 278 | ENDIF |
|---|
| 279 | ENDIF |
|---|
| 280 | ! |
|---|
| 281 | IF( nn_sample_rate .GT. 0 ) CALL icb_trj_init( nitend ) |
|---|
| 282 | ! |
|---|
| 283 | CALL icb_dia_init() |
|---|
| 284 | ! |
|---|
| 285 | IF( nn_verbose_level >= 2 ) CALL icb_utl_print('icb_init, initial status', nit000-1) |
|---|
| 286 | ! |
|---|
| 287 | END SUBROUTINE icb_init |
|---|
| 288 | |
|---|
| 289 | |
|---|
| 290 | SUBROUTINE icb_ini_gen() |
|---|
| 291 | !!---------------------------------------------------------------------- |
|---|
| 292 | !! *** ROUTINE icb_ini_gen *** |
|---|
| 293 | !! |
|---|
| 294 | !! ** Purpose : iceberg generation |
|---|
| 295 | !! |
|---|
| 296 | !! ** Method : - at each grid point of the test box supplied in the namelist |
|---|
| 297 | !! generate an iceberg in one class determined by the value of |
|---|
| 298 | !! parameter nn_test_icebergs |
|---|
| 299 | !!---------------------------------------------------------------------- |
|---|
| 300 | INTEGER :: ji, jj, ibergs |
|---|
| 301 | TYPE(iceberg) :: localberg ! NOT a pointer but an actual local variable |
|---|
| 302 | TYPE(point) :: localpt |
|---|
| 303 | INTEGER :: iyr, imon, iday, ihr, imin, isec |
|---|
| 304 | INTEGER :: iberg |
|---|
| 305 | !!---------------------------------------------------------------------- |
|---|
| 306 | |
|---|
| 307 | ! For convenience |
|---|
| 308 | iberg = nn_test_icebergs |
|---|
| 309 | |
|---|
| 310 | ! call get_date(Time, iyr, imon, iday, ihr, imin, isec) |
|---|
| 311 | ! Convert nemo time variables from dom_oce into local versions |
|---|
| 312 | iyr = nyear |
|---|
| 313 | imon = nmonth |
|---|
| 314 | iday = nday |
|---|
| 315 | ihr = INT(nsec_day/3600) |
|---|
| 316 | imin = INT((nsec_day-ihr*3600)/60) |
|---|
| 317 | isec = nsec_day - ihr*3600 - imin*60 |
|---|
| 318 | |
|---|
| 319 | ! no overlap for icebergs since we want only one instance of each across the whole domain |
|---|
| 320 | ! so restrict area of interest |
|---|
| 321 | ! use tmask here because tmask_i has been doctored on one side of the north fold line |
|---|
| 322 | |
|---|
| 323 | DO jj = nicbdj, nicbej |
|---|
| 324 | DO ji = nicbdi, nicbei |
|---|
| 325 | IF( tmask(ji,jj,1) > 0._wp .AND. & |
|---|
| 326 | rn_test_box(1) < glamt(ji,jj) .AND. glamt(ji,jj) < rn_test_box(2) .AND. & |
|---|
| 327 | rn_test_box(3) < gphit(ji,jj) .AND. gphit(ji,jj) < rn_test_box(4) ) THEN |
|---|
| 328 | localberg%mass_scaling = rn_mass_scaling(iberg) |
|---|
| 329 | localpt%xi = REAL( mig(ji), wp ) |
|---|
| 330 | localpt%yj = REAL( mjg(jj), wp ) |
|---|
| 331 | localpt%lon = icb_utl_bilin(glamt, localpt%xi, localpt%yj, 'T' ) |
|---|
| 332 | localpt%lat = icb_utl_bilin(gphit, localpt%xi, localpt%yj, 'T' ) |
|---|
| 333 | localpt%mass = rn_initial_mass (iberg) |
|---|
| 334 | localpt%thickness = rn_initial_thickness(iberg) |
|---|
| 335 | localpt%width = first_width (iberg) |
|---|
| 336 | localpt%length = first_length(iberg) |
|---|
| 337 | localpt%year = iyr |
|---|
| 338 | localpt%day = REAL(iday,wp)+(REAL(ihr,wp)+REAL(imin,wp)/60._wp)/24._wp |
|---|
| 339 | localpt%mass_of_bits = 0._wp |
|---|
| 340 | localpt%heat_density = 0._wp |
|---|
| 341 | localpt%uvel = 0._wp |
|---|
| 342 | localpt%vvel = 0._wp |
|---|
| 343 | CALL icb_utl_incr() |
|---|
| 344 | localberg%number(:) = num_bergs(:) |
|---|
| 345 | call icb_utl_add(localberg, localpt) |
|---|
| 346 | ENDIF |
|---|
| 347 | END DO |
|---|
| 348 | END DO |
|---|
| 349 | ! |
|---|
| 350 | ibergs = icb_utl_count() |
|---|
| 351 | CALL mpp_sum('icbini', ibergs) |
|---|
| 352 | IF( nn_verbose_level > 0) THEN |
|---|
| 353 | WRITE(numicb,'(a,i6,a)') 'diamonds, icb_ini_gen: ',ibergs,' were generated' |
|---|
| 354 | ENDIF |
|---|
| 355 | ! |
|---|
| 356 | END SUBROUTINE icb_ini_gen |
|---|
| 357 | |
|---|
| 358 | |
|---|
| 359 | SUBROUTINE icb_nam |
|---|
| 360 | !!---------------------------------------------------------------------- |
|---|
| 361 | !! *** ROUTINE icb_nam *** |
|---|
| 362 | !! |
|---|
| 363 | !! ** Purpose : read iceberg namelist and print the variables. |
|---|
| 364 | !! |
|---|
| 365 | !! ** input : - namberg namelist |
|---|
| 366 | !!---------------------------------------------------------------------- |
|---|
| 367 | INTEGER :: jn ! dummy loop indices |
|---|
| 368 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 369 | REAL(wp) :: zfact ! local scalar |
|---|
| 370 | ! |
|---|
| 371 | NAMELIST/namberg/ ln_icebergs , ln_bergdia , nn_sample_rate , rn_initial_mass , & |
|---|
| 372 | & rn_distribution, rn_mass_scaling, rn_initial_thickness, nn_verbose_write , & |
|---|
| 373 | & rn_rho_bergs , rn_LoW_ratio , nn_verbose_level , ln_operator_splitting, & |
|---|
| 374 | & rn_bits_erosion_fraction , rn_sicn_shift , ln_passive_mode , & |
|---|
| 375 | & ln_time_average_weight , nn_test_icebergs , rn_test_box , & |
|---|
| 376 | & ln_use_calving , rn_speed_limit , cn_dir, sn_icb |
|---|
| 377 | !!---------------------------------------------------------------------- |
|---|
| 378 | |
|---|
| 379 | #if defined key_agrif |
|---|
| 380 | IF(lwp) THEN |
|---|
| 381 | WRITE(numout,*) |
|---|
| 382 | WRITE(numout,*) 'icb_nam : AGRIF is not compatible with namelist namberg : ' |
|---|
| 383 | WRITE(numout,*) '~~~~~~~ definition of rn_initial_mass(nclasses) with nclasses as PARAMETER ' |
|---|
| 384 | WRITE(numout,*) |
|---|
| 385 | WRITE(numout,*) ' ==>>> force NO icebergs used. The namelist namberg is not read' |
|---|
| 386 | ENDIF |
|---|
| 387 | ln_icebergs = .false. |
|---|
| 388 | RETURN |
|---|
| 389 | #else |
|---|
| 390 | IF(lwp) THEN |
|---|
| 391 | WRITE(numout,*) |
|---|
| 392 | WRITE(numout,*) 'icb_nam : iceberg initialization through namberg namelist read' |
|---|
| 393 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 394 | ENDIF |
|---|
| 395 | #endif |
|---|
| 396 | ! !== read namelist ==! |
|---|
| 397 | REWIND( numnam_ref ) ! Namelist namberg in reference namelist : Iceberg parameters |
|---|
| 398 | READ ( numnam_ref, namberg, IOSTAT = ios, ERR = 901) |
|---|
| 399 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namberg in reference namelist', lwp ) |
|---|
| 400 | REWIND( numnam_cfg ) ! Namelist namberg in configuration namelist : Iceberg parameters |
|---|
| 401 | READ ( numnam_cfg, namberg, IOSTAT = ios, ERR = 902 ) |
|---|
| 402 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namberg in configuration namelist', lwp ) |
|---|
| 403 | IF(lwm) WRITE ( numond, namberg ) |
|---|
| 404 | ! |
|---|
| 405 | IF(lwp) WRITE(numout,*) |
|---|
| 406 | IF( ln_icebergs ) THEN |
|---|
| 407 | IF(lwp) WRITE(numout,*) ' ==>>> icebergs are used' |
|---|
| 408 | ELSE |
|---|
| 409 | IF(lwp) WRITE(numout,*) ' ==>>> No icebergs used' |
|---|
| 410 | RETURN |
|---|
| 411 | ENDIF |
|---|
| 412 | ! |
|---|
| 413 | IF( nn_test_icebergs > nclasses ) THEN |
|---|
| 414 | IF(lwp) WRITE(numout,*) |
|---|
| 415 | IF(lwp) WRITE(numout,*) ' ==>>> Resetting of nn_test_icebergs to ', nclasses |
|---|
| 416 | nn_test_icebergs = nclasses |
|---|
| 417 | ENDIF |
|---|
| 418 | ! |
|---|
| 419 | IF( nn_test_icebergs < 0 .AND. .NOT. ln_use_calving ) THEN |
|---|
| 420 | IF(lwp) WRITE(numout,*) |
|---|
| 421 | IF(lwp) WRITE(numout,*) ' ==>>> Resetting ln_use_calving to .true. since we are not using test icebergs' |
|---|
| 422 | ln_use_calving = .true. |
|---|
| 423 | ENDIF |
|---|
| 424 | ! |
|---|
| 425 | IF(lwp) THEN ! control print |
|---|
| 426 | WRITE(numout,*) |
|---|
| 427 | WRITE(numout,*) 'icb_nam : iceberg initialization through namberg namelist read' |
|---|
| 428 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 429 | WRITE(numout,*) ' Calculate budgets ln_bergdia = ', ln_bergdia |
|---|
| 430 | WRITE(numout,*) ' Period between sampling of position for trajectory storage nn_sample_rate = ', nn_sample_rate |
|---|
| 431 | WRITE(numout,*) ' Mass thresholds between iceberg classes (kg) rn_initial_mass =' |
|---|
| 432 | DO jn = 1, nclasses |
|---|
| 433 | WRITE(numout,'(a,f15.2)') ' ', rn_initial_mass(jn) |
|---|
| 434 | ENDDO |
|---|
| 435 | WRITE(numout,*) ' Fraction of calving to apply to this class (non-dim) rn_distribution =' |
|---|
| 436 | DO jn = 1, nclasses |
|---|
| 437 | WRITE(numout,'(a,f10.4)') ' ', rn_distribution(jn) |
|---|
| 438 | END DO |
|---|
| 439 | WRITE(numout,*) ' Ratio between effective and real iceberg mass (non-dim) rn_mass_scaling = ' |
|---|
| 440 | DO jn = 1, nclasses |
|---|
| 441 | WRITE(numout,'(a,f10.2)') ' ', rn_mass_scaling(jn) |
|---|
| 442 | END DO |
|---|
| 443 | WRITE(numout,*) ' Total thickness of newly calved bergs (m) rn_initial_thickness = ' |
|---|
| 444 | DO jn = 1, nclasses |
|---|
| 445 | WRITE(numout,'(a,f10.2)') ' ', rn_initial_thickness(jn) |
|---|
| 446 | END DO |
|---|
| 447 | WRITE(numout,*) ' Timesteps between verbose messages nn_verbose_write = ', nn_verbose_write |
|---|
| 448 | |
|---|
| 449 | WRITE(numout,*) ' Density of icebergs rn_rho_bergs = ', rn_rho_bergs |
|---|
| 450 | WRITE(numout,*) ' Initial ratio L/W for newly calved icebergs rn_LoW_ratio = ', rn_LoW_ratio |
|---|
| 451 | WRITE(numout,*) ' Turn on more verbose output level = ', nn_verbose_level |
|---|
| 452 | WRITE(numout,*) ' Use first order operator splitting for thermodynamics ', & |
|---|
| 453 | & 'use_operator_splitting = ', ln_operator_splitting |
|---|
| 454 | WRITE(numout,*) ' Fraction of erosion melt flux to divert to bergy bits ', & |
|---|
| 455 | & 'bits_erosion_fraction = ', rn_bits_erosion_fraction |
|---|
| 456 | |
|---|
| 457 | WRITE(numout,*) ' Shift of sea-ice concentration in erosion flux modulation ', & |
|---|
| 458 | & '(0<sicn_shift<1) rn_sicn_shift = ', rn_sicn_shift |
|---|
| 459 | WRITE(numout,*) ' Do not add freshwater flux from icebergs to ocean ', & |
|---|
| 460 | & ' passive_mode = ', ln_passive_mode |
|---|
| 461 | WRITE(numout,*) ' Time average the weight on the ocean time_average_weight = ', ln_time_average_weight |
|---|
| 462 | WRITE(numout,*) ' Create icebergs in absence of a restart file nn_test_icebergs = ', nn_test_icebergs |
|---|
| 463 | WRITE(numout,*) ' in lon/lat box = ', rn_test_box |
|---|
| 464 | WRITE(numout,*) ' Use calving data even if nn_test_icebergs > 0 ln_use_calving = ', ln_use_calving |
|---|
| 465 | WRITE(numout,*) ' CFL speed limit for a berg speed_limit = ', rn_speed_limit |
|---|
| 466 | WRITE(numout,*) ' Writing Iceberg status information to icebergs.stat file ' |
|---|
| 467 | ENDIF |
|---|
| 468 | ! |
|---|
| 469 | ! ensure that the sum of berg input distribution is equal to one |
|---|
| 470 | zfact = SUM( rn_distribution ) |
|---|
| 471 | IF( zfact /= 1._wp .AND. 0_wp /= zfact ) THEN |
|---|
| 472 | rn_distribution(:) = rn_distribution(:) / zfact |
|---|
| 473 | IF(lwp) THEN |
|---|
| 474 | WRITE(numout,*) |
|---|
| 475 | WRITE(numout,*) ' ==>>> CAUTION: sum of berg input distribution = ', zfact |
|---|
| 476 | WRITE(numout,*) ' ******* redistribution has been rescaled' |
|---|
| 477 | WRITE(numout,*) ' updated berg distribution is :' |
|---|
| 478 | DO jn = 1, nclasses |
|---|
| 479 | WRITE(numout,'(a,f10.4)') ' ',rn_distribution(jn) |
|---|
| 480 | END DO |
|---|
| 481 | ENDIF |
|---|
| 482 | ENDIF |
|---|
| 483 | IF( MINVAL( rn_distribution(:) ) < 0._wp ) THEN |
|---|
| 484 | CALL ctl_stop( 'icb_nam: a negative rn_distribution value encountered ==>> change your namelist namberg' ) |
|---|
| 485 | ENDIF |
|---|
| 486 | ! |
|---|
| 487 | END SUBROUTINE icb_nam |
|---|
| 488 | |
|---|
| 489 | !!====================================================================== |
|---|
| 490 | END MODULE icbini |
|---|
