New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

icbini.F90 in NEMO/branches/2019/fix_ticket2238_solution1/src/OCE/ICB – NEMO

Context Navigation

source: NEMO/branches/2019/fix_ticket2238_solution1/src/OCE/ICB/icbini.F90 @ 10700

Last change on this file since 10700 was 10700, checked in by mathiot, 5 years ago
allocate/define/initialise hi_e only if key_si3 is define (ticket #2238)
Property svn:keywords set to `Id`
File size: 23.2 KB

Line
1	MODULE icbini
2	!!======================================================================
3	!! * MODULE icbini *
4	!! Icebergs: initialise variables for iceberg tracking
5	!!======================================================================
6	!! History : - ! 2010-01 (T. Martin & A. Adcroft) Original code
7	!! 3.3 ! 2011-03 (G. Madec) Part conversion to NEMO form ; Removal of mapping from another grid
8	!! - ! 2011-04 (S. Alderson) Split into separate modules ; Restore restart routines
9	!! - ! 2011-05 (S. Alderson) generate_test_icebergs restored ; new forcing arrays with extra halo ;
10	!! - ! north fold exchange arrays added
11	!!----------------------------------------------------------------------
12	!!----------------------------------------------------------------------
13	!! icb_init : initialise icebergs
14	!! icb_ini_gen : generate test icebergs
15	!! icb_nam : read iceberg namelist
16	!!----------------------------------------------------------------------
17	USE dom_oce ! ocean domain
18	USE in_out_manager ! IO routines and numout in particular
19	USE lib_mpp ! mpi library and lk_mpp in particular
20	USE sbc_oce ! ocean : surface boundary condition
21	USE sbc_ice ! sea-ice: surface boundary condition
22	USE iom ! IOM library
23	USE fldread ! field read
24	USE lbclnk ! lateral boundary condition - MPP link
25	!
26	USE icb_oce ! define iceberg arrays
27	USE icbutl ! iceberg utility routines
28	USE icbrst ! iceberg restart routines
29	USE icbtrj ! iceberg trajectory I/O routines
30	USE icbdia ! iceberg budget routines
31
32	IMPLICIT NONE
33	PRIVATE
34
35	PUBLIC icb_init ! routine called in nemogcm.F90 module
36
37	CHARACTER(len=100) :: cn_dir = './' !: Root directory for location of icb files
38	TYPE(FLD_N) :: sn_icb !: information about the calving file to be read
39	TYPE(FLD), PUBLIC, ALLOCATABLE , DIMENSION(:) :: sf_icb !: structure: file information, fields read
40	!: used in icbini and icbstp
41	!!----------------------------------------------------------------------
42	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
43	!! $Id$
44	!! Software governed by the CeCILL license (see ./LICENSE)
45	!!----------------------------------------------------------------------
46	CONTAINS
47
48	SUBROUTINE icb_init( pdt, kt )
49	!!----------------------------------------------------------------------
50	!! * ROUTINE dom_init *
51	!!
52	!! ** Purpose : iceberg initialization.
53	!!
54	!! ** Method : - read the iceberg namelist
55	!! - find non-overlapping processor interior since we can only
56	!! have one instance of a particular iceberg
57	!! - calculate the destinations for north fold exchanges
58	!! - setup either test icebergs or calving file
59	!!----------------------------------------------------------------------
60	REAL(wp), INTENT(in) :: pdt ! iceberg time-step (rdt*nn_fsbc)
61	INTEGER , INTENT(in) :: kt ! time step number
62	!
63	INTEGER :: ji, jj, jn ! dummy loop indices
64	INTEGER :: i1, i2, i3 ! local integers
65	INTEGER :: ii, inum, ivar ! - -
66	INTEGER :: istat1, istat2, istat3 ! - -
67	CHARACTER(len=300) :: cl_sdist ! local character
68	!!----------------------------------------------------------------------
69	!
70	CALL icb_nam ! Read and print namelist parameters
71	!
72	IF( .NOT. ln_icebergs ) RETURN
73
74	! ! allocate gridded fields
75	IF( icb_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'icb_alloc : unable to allocate arrays' )
76	!
77	! ! initialised variable with extra haloes to zero
78	uo_e(:,:) = 0._wp ; vo_e(:,:) = 0._wp ;
79	ua_e(:,:) = 0._wp ; va_e(:,:) = 0._wp ;
80	ff_e(:,:) = 0._wp ; tt_e(:,:) = 0._wp ;
81	fr_e(:,:) = 0._wp ;
82	#if defined key_si3
83	hi_e(:,:) = 0._wp ;
84	ui_e(:,:) = 0._wp ; vi_e(:,:) = 0._wp ;
85	#endif
86	ssh_e(:,:) = 0._wp ;
87	!
88	! ! open ascii output file or files for iceberg status information
89	! ! note that we choose to do this on all processors since we cannot
90	! ! predict where icebergs will be ahead of time
91	IF( nn_verbose_level > 0) THEN
92	CALL ctl_opn( numicb, 'icebergs.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
93	ENDIF
94
95	! set parameters (mostly from namelist)
96	!
97	berg_dt = pdt
98	first_width (:) = SQRT( rn_initial_mass(:) / ( rn_LoW_ratio * rn_rho_bergs * rn_initial_thickness(:) ) )
99	first_length(:) = rn_LoW_ratio * first_width(:)
100
101	berg_grid%calving (:,:) = 0._wp
102	berg_grid%calving_hflx (:,:) = 0._wp
103	berg_grid%stored_heat (:,:) = 0._wp
104	berg_grid%floating_melt(:,:) = 0._wp
105	berg_grid%maxclass (:,:) = nclasses
106	berg_grid%stored_ice (:,:,:) = 0._wp
107	berg_grid%tmp (:,:) = 0._wp
108	src_calving (:,:) = 0._wp
109	src_calving_hflx (:,:) = 0._wp
110
111	! ! domain for icebergs
112	IF( lk_mpp .AND. jpni == 1 ) CALL ctl_stop( 'icbinit: having ONE processor in x currently does not work' )
113	! NB: the issue here is simply that cyclic east-west boundary condition have not been coded in mpp case
114	! for the north fold we work out which points communicate by asking
115	! lbc_lnk to pass processor number (valid even in single processor case)
116	! borrow src_calving arrays for this
117	!
118	! pack i and j together using a scaling of a power of 10
119	nicbpack = 10000
120	IF( jpiglo >= nicbpack ) CALL ctl_stop( 'icbini: processor index packing failure' )
121	nicbfldproc(:) = -1
122
123	DO jj = 1, jpj
124	DO ji = 1, jpi
125	src_calving_hflx(ji,jj) = narea
126	src_calving (ji,jj) = nicbpack * mjg(jj) + mig(ji)
127	END DO
128	END DO
129	CALL lbc_lnk( 'icbini', src_calving_hflx, 'T', 1._wp )
130	CALL lbc_lnk( 'icbini', src_calving , 'T', 1._wp )
131
132	! work out interior of processor from exchange array
133	! first entry with narea for this processor is left hand interior index
134	! last entry is right hand interior index
135	jj = nlcj/2
136	nicbdi = -1
137	nicbei = -1
138	DO ji = 1, jpi
139	i3 = INT( src_calving(ji,jj) )
140	i2 = INT( i3/nicbpack )
141	i1 = i3 - i2*nicbpack
142	i3 = INT( src_calving_hflx(ji,jj) )
143	IF( i1 == mig(ji) .AND. i3 == narea ) THEN
144	IF( nicbdi < 0 ) THEN ; nicbdi = ji
145	ELSE ; nicbei = ji
146	ENDIF
147	ENDIF
148	END DO
149	!
150	! repeat for j direction
151	ji = nlci/2
152	nicbdj = -1
153	nicbej = -1
154	DO jj = 1, jpj
155	i3 = INT( src_calving(ji,jj) )
156	i2 = INT( i3/nicbpack )
157	i1 = i3 - i2*nicbpack
158	i3 = INT( src_calving_hflx(ji,jj) )
159	IF( i2 == mjg(jj) .AND. i3 == narea ) THEN
160	IF( nicbdj < 0 ) THEN ; nicbdj = jj
161	ELSE ; nicbej = jj
162	ENDIF
163	ENDIF
164	END DO
165	!
166	! special for east-west boundary exchange we save the destination index
167	i1 = MAX( nicbdi-1, 1)
168	i3 = INT( src_calving(i1,nlcj/2) )
169	jj = INT( i3/nicbpack )
170	ricb_left = REAL( i3 - nicbpack*jj, wp )
171	i1 = MIN( nicbei+1, jpi )
172	i3 = INT( src_calving(i1,nlcj/2) )
173	jj = INT( i3/nicbpack )
174	ricb_right = REAL( i3 - nicbpack*jj, wp )
175
176	! north fold
177	IF( npolj > 0 ) THEN
178	!
179	! icebergs in row nicbej+1 get passed across fold
180	nicbfldpts(:) = INT( src_calving(:,nicbej+1) )
181	nicbflddest(:) = INT( src_calving_hflx(:,nicbej+1) )
182	!
183	! work out list of unique processors to talk to
184	! pack them into a fixed size array where empty slots are marked by a -1
185	DO ji = nicbdi, nicbei
186	ii = nicbflddest(ji)
187	IF( ii .GT. 0 ) THEN ! Needed because land suppression can mean
188	! that unused points are not set in edge haloes
189	DO jn = 1, jpni
190	! work along array until we find an empty slot
191	IF( nicbfldproc(jn) == -1 ) THEN
192	nicbfldproc(jn) = ii
193	EXIT !!gm EXIT should be avoided: use DO WHILE expression instead
194	ENDIF
195	! before we find an empty slot, we may find processor number is already here so we exit
196	IF( nicbfldproc(jn) == ii ) EXIT
197	END DO
198	ENDIF
199	END DO
200	ENDIF
201	!
202	IF( nn_verbose_level > 0) THEN
203	WRITE(numicb,*) 'processor ', narea
204	WRITE(numicb,*) 'jpi, jpj ', jpi, jpj
205	WRITE(numicb,*) 'nldi, nlei ', nldi, nlei
206	WRITE(numicb,*) 'nldj, nlej ', nldj, nlej
207	WRITE(numicb,*) 'berg i interior ', nicbdi, nicbei
208	WRITE(numicb,*) 'berg j interior ', nicbdj, nicbej
209	WRITE(numicb,*) 'berg left ', ricb_left
210	WRITE(numicb,*) 'berg right ', ricb_right
211	jj = nlcj/2
212	WRITE(numicb,*) "central j line:"
213	WRITE(numicb,*) "i processor"
214	WRITE(numicb,*) (INT(src_calving_hflx(ji,jj)), ji=1,jpi)
215	WRITE(numicb,*) "i point"
216	WRITE(numicb,*) (INT(src_calving(ji,jj)), ji=1,jpi)
217	ji = nlci/2
218	WRITE(numicb,*) "central i line:"
219	WRITE(numicb,*) "j processor"
220	WRITE(numicb,*) (INT(src_calving_hflx(ji,jj)), jj=1,jpj)
221	WRITE(numicb,*) "j point"
222	WRITE(numicb,*) (INT(src_calving(ji,jj)), jj=1,jpj)
223	IF( npolj > 0 ) THEN
224	WRITE(numicb,*) 'north fold destination points '
225	WRITE(numicb,*) nicbfldpts
226	WRITE(numicb,*) 'north fold destination procs '
227	WRITE(numicb,*) nicbflddest
228	WRITE(numicb,*) 'north fold destination proclist '
229	WRITE(numicb,*) nicbfldproc
230	ENDIF
231	CALL flush(numicb)
232	ENDIF
233
234	src_calving (:,:) = 0._wp
235	src_calving_hflx(:,:) = 0._wp
236
237	! assign each new iceberg with a unique number constructed from the processor number
238	! and incremented by the total number of processors
239	num_bergs(:) = 0
240	num_bergs(1) = narea - jpnij
241
242	! when not generating test icebergs we need to setup calving file
243	IF( nn_test_icebergs < 0 .OR. ln_use_calving ) THEN
244	!
245	! maximum distribution class array does not change in time so read it once
246	cl_sdist = TRIM( cn_dir )//TRIM( sn_icb%clname )
247	CALL iom_open ( cl_sdist, inum ) ! open file
248	ivar = iom_varid( inum, 'maxclass', ldstop=.FALSE. )
249	IF( ivar > 0 ) THEN
250	CALL iom_get ( inum, jpdom_data, 'maxclass', src_calving ) ! read the max distribution array
251	berg_grid%maxclass(:,:) = INT( src_calving )
252	src_calving(:,:) = 0._wp
253	ENDIF
254	CALL iom_close( inum ) ! close file
255	!
256	IF( nn_verbose_level > 0) THEN
257	WRITE(numicb,*)
258	WRITE(numicb,*) ' calving read in a file'
259	ENDIF
260	ALLOCATE( sf_icb(1), STAT=istat1 ) ! Create sf_icb structure (calving)
261	ALLOCATE( sf_icb(1)%fnow(jpi,jpj,1), STAT=istat2 )
262	ALLOCATE( sf_icb(1)%fdta(jpi,jpj,1,2), STAT=istat3 )
263	IF( istat1+istat2+istat3 > 0 ) THEN
264	CALL ctl_stop( 'sbc_icb: unable to allocate sf_icb structure' ) ; RETURN
265	ENDIF
266	! ! fill sf_icb with the namelist (sn_icb) and control print
267	CALL fld_fill( sf_icb, (/ sn_icb /), cn_dir, 'icb_init', 'read calving data', 'namicb' )
268	!
269	ENDIF
270
271	IF( .NOT.ln_rstart ) THEN
272	IF( nn_test_icebergs > 0 ) CALL icb_ini_gen()
273	ELSE
274	IF( nn_test_icebergs > 0 ) THEN
275	CALL icb_ini_gen()
276	ELSE
277	CALL icb_rst_read()
278	l_restarted_bergs = .TRUE.
279	ENDIF
280	ENDIF
281	!
282	IF( nn_sample_rate .GT. 0 ) CALL icb_trj_init( nitend )
283	!
284	CALL icb_dia_init()
285	!
286	IF( nn_verbose_level >= 2 ) CALL icb_utl_print('icb_init, initial status', nit000-1)
287	!
288	END SUBROUTINE icb_init
289
290
291	SUBROUTINE icb_ini_gen()
292	!!----------------------------------------------------------------------
293	!! * ROUTINE icb_ini_gen *
294	!!
295	!! ** Purpose : iceberg generation
296	!!
297	!! ** Method : - at each grid point of the test box supplied in the namelist
298	!! generate an iceberg in one class determined by the value of
299	!! parameter nn_test_icebergs
300	!!----------------------------------------------------------------------
301	INTEGER :: ji, jj, ibergs
302	TYPE(iceberg) :: localberg ! NOT a pointer but an actual local variable
303	TYPE(point) :: localpt
304	INTEGER :: iyr, imon, iday, ihr, imin, isec
305	INTEGER :: iberg
306	!!----------------------------------------------------------------------
307
308	! For convenience
309	iberg = nn_test_icebergs
310
311	! call get_date(Time, iyr, imon, iday, ihr, imin, isec)
312	! Convert nemo time variables from dom_oce into local versions
313	iyr = nyear
314	imon = nmonth
315	iday = nday
316	ihr = INT(nsec_day/3600)
317	imin = INT((nsec_day-ihr*3600)/60)
318	isec = nsec_day - ihr3600 - imin60
319
320	! no overlap for icebergs since we want only one instance of each across the whole domain
321	! so restrict area of interest
322	! use tmask here because tmask_i has been doctored on one side of the north fold line
323
324	DO jj = nicbdj, nicbej
325	DO ji = nicbdi, nicbei
326	IF( tmask(ji,jj,1) > 0._wp .AND. &
327	rn_test_box(1) < glamt(ji,jj) .AND. glamt(ji,jj) < rn_test_box(2) .AND. &
328	rn_test_box(3) < gphit(ji,jj) .AND. gphit(ji,jj) < rn_test_box(4) ) THEN
329	localberg%mass_scaling = rn_mass_scaling(iberg)
330	localpt%xi = REAL( mig(ji), wp )
331	localpt%yj = REAL( mjg(jj), wp )
332	localpt%lon = icb_utl_bilin(glamt, localpt%xi, localpt%yj, 'T' )
333	localpt%lat = icb_utl_bilin(gphit, localpt%xi, localpt%yj, 'T' )
334	localpt%mass = rn_initial_mass (iberg)
335	localpt%thickness = rn_initial_thickness(iberg)
336	localpt%width = first_width (iberg)
337	localpt%length = first_length(iberg)
338	localpt%year = iyr
339	localpt%day = REAL(iday,wp)+(REAL(ihr,wp)+REAL(imin,wp)/60._wp)/24._wp
340	localpt%mass_of_bits = 0._wp
341	localpt%heat_density = 0._wp
342	localpt%uvel = 0._wp
343	localpt%vvel = 0._wp
344	CALL icb_utl_incr()
345	localberg%number(:) = num_bergs(:)
346	call icb_utl_add(localberg, localpt)
347	ENDIF
348	END DO
349	END DO
350	!
351	ibergs = icb_utl_count()
352	CALL mpp_sum('icbini', ibergs)
353	IF( nn_verbose_level > 0) THEN
354	WRITE(numicb,'(a,i6,a)') 'diamonds, icb_ini_gen: ',ibergs,' were generated'
355	ENDIF
356	!
357	END SUBROUTINE icb_ini_gen
358
359
360	SUBROUTINE icb_nam
361	!!----------------------------------------------------------------------
362	!! * ROUTINE icb_nam *
363	!!
364	!! ** Purpose : read iceberg namelist and print the variables.
365	!!
366	!! ** input : - namberg namelist
367	!!----------------------------------------------------------------------
368	INTEGER :: jn ! dummy loop indices
369	INTEGER :: ios ! Local integer output status for namelist read
370	REAL(wp) :: zfact ! local scalar
371	!
372	NAMELIST/namberg/ ln_icebergs , ln_bergdia , nn_sample_rate , rn_initial_mass , &
373	& rn_distribution, rn_mass_scaling, rn_initial_thickness, nn_verbose_write , &
374	& rn_rho_bergs , rn_LoW_ratio , nn_verbose_level , ln_operator_splitting, &
375	& rn_bits_erosion_fraction , rn_sicn_shift , ln_passive_mode , &
376	& ln_time_average_weight , nn_test_icebergs , rn_test_box , &
377	& ln_use_calving , rn_speed_limit , cn_dir, sn_icb
378	!!----------------------------------------------------------------------
379
380	#if defined key_agrif
381	IF(lwp) THEN
382	WRITE(numout,*)
383	WRITE(numout,*) 'icb_nam : AGRIF is not compatible with namelist namberg : '
384	WRITE(numout,*) '~~~~~~~ definition of rn_initial_mass(nclasses) with nclasses as PARAMETER '
385	WRITE(numout,*)
386	WRITE(numout,*) ' ==>>> force NO icebergs used. The namelist namberg is not read'
387	ENDIF
388	ln_icebergs = .false.
389	RETURN
390	#else
391	IF(lwp) THEN
392	WRITE(numout,*)
393	WRITE(numout,*) 'icb_nam : iceberg initialization through namberg namelist read'
394	WRITE(numout,*) '~~~~~~~~ '
395	ENDIF
396	#endif
397	! !== read namelist ==!
398	REWIND( numnam_ref ) ! Namelist namberg in reference namelist : Iceberg parameters
399	READ ( numnam_ref, namberg, IOSTAT = ios, ERR = 901)
400	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namberg in reference namelist', lwp )
401	REWIND( numnam_cfg ) ! Namelist namberg in configuration namelist : Iceberg parameters
402	READ ( numnam_cfg, namberg, IOSTAT = ios, ERR = 902 )
403	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namberg in configuration namelist', lwp )
404	IF(lwm) WRITE ( numond, namberg )
405	!
406	IF(lwp) WRITE(numout,*)
407	IF( ln_icebergs ) THEN
408	IF(lwp) WRITE(numout,*) ' ==>>> icebergs are used'
409	ELSE
410	IF(lwp) WRITE(numout,*) ' ==>>> No icebergs used'
411	RETURN
412	ENDIF
413	!
414	IF( nn_test_icebergs > nclasses ) THEN
415	IF(lwp) WRITE(numout,*)
416	IF(lwp) WRITE(numout,*) ' ==>>> Resetting of nn_test_icebergs to ', nclasses
417	nn_test_icebergs = nclasses
418	ENDIF
419	!
420	IF( nn_test_icebergs < 0 .AND. .NOT. ln_use_calving ) THEN
421	IF(lwp) WRITE(numout,*)
422	IF(lwp) WRITE(numout,*) ' ==>>> Resetting ln_use_calving to .true. since we are not using test icebergs'
423	ln_use_calving = .true.
424	ENDIF
425	!
426	IF(lwp) THEN ! control print
427	WRITE(numout,*)
428	WRITE(numout,*) 'icb_nam : iceberg initialization through namberg namelist read'
429	WRITE(numout,*) '~~~~~~~~ '
430	WRITE(numout,*) ' Calculate budgets ln_bergdia = ', ln_bergdia
431	WRITE(numout,*) ' Period between sampling of position for trajectory storage nn_sample_rate = ', nn_sample_rate
432	WRITE(numout,*) ' Mass thresholds between iceberg classes (kg) rn_initial_mass ='
433	DO jn = 1, nclasses
434	WRITE(numout,'(a,f15.2)') ' ', rn_initial_mass(jn)
435	ENDDO
436	WRITE(numout,*) ' Fraction of calving to apply to this class (non-dim) rn_distribution ='
437	DO jn = 1, nclasses
438	WRITE(numout,'(a,f10.4)') ' ', rn_distribution(jn)
439	END DO
440	WRITE(numout,*) ' Ratio between effective and real iceberg mass (non-dim) rn_mass_scaling = '
441	DO jn = 1, nclasses
442	WRITE(numout,'(a,f10.2)') ' ', rn_mass_scaling(jn)
443	END DO
444	WRITE(numout,*) ' Total thickness of newly calved bergs (m) rn_initial_thickness = '
445	DO jn = 1, nclasses
446	WRITE(numout,'(a,f10.2)') ' ', rn_initial_thickness(jn)
447	END DO
448	WRITE(numout,*) ' Timesteps between verbose messages nn_verbose_write = ', nn_verbose_write
449
450	WRITE(numout,*) ' Density of icebergs rn_rho_bergs = ', rn_rho_bergs
451	WRITE(numout,*) ' Initial ratio L/W for newly calved icebergs rn_LoW_ratio = ', rn_LoW_ratio
452	WRITE(numout,*) ' Turn on more verbose output level = ', nn_verbose_level
453	WRITE(numout,*) ' Use first order operator splitting for thermodynamics ', &
454	& 'use_operator_splitting = ', ln_operator_splitting
455	WRITE(numout,*) ' Fraction of erosion melt flux to divert to bergy bits ', &
456	& 'bits_erosion_fraction = ', rn_bits_erosion_fraction
457
458	WRITE(numout,*) ' Shift of sea-ice concentration in erosion flux modulation ', &
459	& '(0<sicn_shift<1) rn_sicn_shift = ', rn_sicn_shift
460	WRITE(numout,*) ' Do not add freshwater flux from icebergs to ocean ', &
461	& ' passive_mode = ', ln_passive_mode
462	WRITE(numout,*) ' Time average the weight on the ocean time_average_weight = ', ln_time_average_weight
463	WRITE(numout,*) ' Create icebergs in absence of a restart file nn_test_icebergs = ', nn_test_icebergs
464	WRITE(numout,*) ' in lon/lat box = ', rn_test_box
465	WRITE(numout,*) ' Use calving data even if nn_test_icebergs > 0 ln_use_calving = ', ln_use_calving
466	WRITE(numout,*) ' CFL speed limit for a berg speed_limit = ', rn_speed_limit
467	WRITE(numout,*) ' Writing Iceberg status information to icebergs.stat file '
468	ENDIF
469	!
470	! ensure that the sum of berg input distribution is equal to one
471	zfact = SUM( rn_distribution )
472	IF( zfact /= 1._wp .AND. 0_wp /= zfact ) THEN
473	rn_distribution(:) = rn_distribution(:) / zfact
474	IF(lwp) THEN
475	WRITE(numout,*)
476	WRITE(numout,*) ' ==>>> CAUTION: sum of berg input distribution = ', zfact
477	WRITE(numout,) ' ****** redistribution has been rescaled'
478	WRITE(numout,*) ' updated berg distribution is :'
479	DO jn = 1, nclasses
480	WRITE(numout,'(a,f10.4)') ' ',rn_distribution(jn)
481	END DO
482	ENDIF
483	ENDIF
484	IF( MINVAL( rn_distribution(:) ) < 0._wp ) THEN
485	CALL ctl_stop( 'icb_nam: a negative rn_distribution value encountered ==>> change your namelist namberg' )
486	ENDIF
487	!
488	END SUBROUTINE icb_nam
489
490	!!======================================================================
491	END MODULE icbini

Note: See TracBrowser for help on using the repository browser.

Download in other formats: