New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icbutl.F90 in NEMO/branches/2019/fix_ticket2238_solution1/src/OCE/ICB – NEMO

source: NEMO/branches/2019/fix_ticket2238_solution1/src/OCE/ICB/icbutl.F90 @ 10696

Last change on this file since 10696 was 10696, checked in by mathiot, 5 years ago

move extended array tt_e,uo_e (...) initialisation to 0. in icbini.F90 and chnage hicth name to hi_e

  • Property svn:keywords set to Id
File size: 34.1 KB
Line 
1MODULE icbutl
2   !!======================================================================
3   !!                       ***  MODULE  icbutl  ***
4   !! Icebergs:  various iceberg utility routines
5   !!======================================================================
6   !! History : 3.3.1 !  2010-01  (Martin&Adcroft) Original code
7   !!            -    !  2011-03  (Madec)          Part conversion to NEMO form
8   !!            -    !                            Removal of mapping from another grid
9   !!            -    !  2011-04  (Alderson)       Split into separate modules
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   icb_utl_interp   :
14   !!   icb_utl_bilin    :
15   !!   icb_utl_bilin_e  :
16   !!----------------------------------------------------------------------
17   USE par_oce                             ! ocean parameters
18   USE dom_oce                             ! ocean domain
19   USE in_out_manager                      ! IO parameters
20   USE lbclnk                              ! lateral boundary condition
21   USE lib_mpp                             ! MPI code and lk_mpp in particular
22   USE icb_oce                             ! define iceberg arrays
23   USE sbc_oce                             ! ocean surface boundary conditions
24#if defined key_si3
25   USE ice,    ONLY: u_ice, v_ice, hm_i    ! SI3 variables
26   USE icevar                              ! ice_var_sshdyn
27   USE sbc_ice, ONLY: snwice_mass, snwice_mass_b
28#endif
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   icb_utl_copy          ! routine called in icbstp module
34   PUBLIC   icb_utl_interp        ! routine called in icbdyn, icbthm modules
35   PUBLIC   icb_utl_bilin         ! routine called in icbini, icbdyn modules
36   PUBLIC   icb_utl_bilin_x       ! routine called in icbdyn module
37   PUBLIC   icb_utl_add           ! routine called in icbini.F90, icbclv, icblbc and icbrst modules
38   PUBLIC   icb_utl_delete        ! routine called in icblbc, icbthm modules
39   PUBLIC   icb_utl_destroy       ! routine called in icbstp module
40   PUBLIC   icb_utl_track         ! routine not currently used, retain just in case
41   PUBLIC   icb_utl_print_berg    ! routine called in icbthm module
42   PUBLIC   icb_utl_print         ! routine called in icbini, icbstp module
43   PUBLIC   icb_utl_count         ! routine called in icbdia, icbini, icblbc, icbrst modules
44   PUBLIC   icb_utl_incr          ! routine called in icbini, icbclv modules
45   PUBLIC   icb_utl_yearday       ! routine called in icbclv, icbstp module
46   PUBLIC   icb_utl_mass          ! routine called in icbdia module
47   PUBLIC   icb_utl_heat          ! routine called in icbdia module
48
49   !!----------------------------------------------------------------------
50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE icb_utl_copy()
57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE icb_utl_copy  ***
59      !!
60      !! ** Purpose :   iceberg initialization.
61      !!
62      !! ** Method  : - blah blah
63      !!----------------------------------------------------------------------
64#if defined key_si3
65      REAL(wp), DIMENSION(jpi,jpj) :: zssh_lead_m    !    ocean surface (ssh_m) if ice is not embedded
66      !                                              !    ocean surface in leads if ice is embedded   
67#endif
68      ! copy nemo forcing arrays into iceberg versions with extra halo
69      ! only necessary for variables not on T points
70      ! and ssh which is used to calculate gradients
71
72      uo_e(1:jpi,1:jpj) = ssu_m(:,:) * umask(:,:,1)
73      vo_e(1:jpi,1:jpj) = ssv_m(:,:) * vmask(:,:,1)
74      ff_e(1:jpi,1:jpj) = ff_f (:,:) 
75      tt_e(1:jpi,1:jpj) = sst_m(:,:)
76      fr_e(1:jpi,1:jpj) = fr_i (:,:)
77      ua_e(1:jpi,1:jpj) = utau (:,:) * umask(:,:,1) ! maybe mask useless because mask applied in sbcblk
78      va_e(1:jpi,1:jpj) = vtau (:,:) * vmask(:,:,1) ! maybe mask useless because mask applied in sbcblk
79      !
80      CALL lbc_lnk_icb( 'icbutl', uo_e, 'U', -1._wp, 1, 1 )
81      CALL lbc_lnk_icb( 'icbutl', vo_e, 'V', -1._wp, 1, 1 )
82      CALL lbc_lnk_icb( 'icbutl', ff_e, 'F', +1._wp, 1, 1 )
83      CALL lbc_lnk_icb( 'icbutl', ua_e, 'U', -1._wp, 1, 1 )
84      CALL lbc_lnk_icb( 'icbutl', va_e, 'V', -1._wp, 1, 1 )
85      CALL lbc_lnk_icb( 'icbutl', fr_e, 'T', +1._wp, 1, 1 )
86      CALL lbc_lnk_icb( 'icbutl', tt_e, 'T', +1._wp, 1, 1 )
87#if defined key_si3
88      hi_e(1:jpi, 1:jpj) = hm_i (:,:) 
89      ui_e(1:jpi, 1:jpj) = u_ice(:,:)
90      vi_e(1:jpi, 1:jpj) = v_ice(:,:)
91      !     
92      ! compute ssh slope using ssh_lead if embedded
93      zssh_lead_m(:,:) = ice_var_sshdyn(ssh_m, snwice_mass, snwice_mass_b)
94      ssh_e(1:jpi, 1:jpj) = zssh_lead_m(:,:) * tmask(:,:,1)
95      !
96      CALL lbc_lnk_icb( 'icbutl', hi_e , 'T', +1._wp, 1, 1 )
97      CALL lbc_lnk_icb( 'icbutl', ui_e , 'U', -1._wp, 1, 1 )
98      CALL lbc_lnk_icb( 'icbutl', vi_e , 'V', -1._wp, 1, 1 )
99#else
100      ssh_e(1:jpi, 1:jpj) = ssh_m(:,:) * tmask(:,:,1)
101#endif
102      CALL lbc_lnk_icb( 'icbutl', ssh_e, 'T', +1._wp, 1, 1 )
103      !
104   END SUBROUTINE icb_utl_copy
105
106
107   SUBROUTINE icb_utl_interp( pi, pe1, puo, pui, pua, pssh_i,   &
108      &                       pj, pe2, pvo, pvi, pva, pssh_j,   &
109      &                       psst, pcn, phi, pff            )
110      !!----------------------------------------------------------------------
111      !!                  ***  ROUTINE icb_utl_interp  ***
112      !!
113      !! ** Purpose :   interpolation
114      !!
115      !! ** Method  : - interpolate from various ocean arrays onto iceberg position
116      !!
117      !!       !!gm  CAUTION here I do not care of the slip/no-slip conditions
118      !!             this can be done later (not that easy to do...)
119      !!             right now, U is 0 in land so that the coastal value of velocity parallel to the coast
120      !!             is half the off shore value, wile the normal-to-the-coast value is zero.
121      !!             This is OK as a starting point.
122      !!
123      !!----------------------------------------------------------------------
124      REAL(wp), INTENT(in   ) ::   pi , pj                        ! position in (i,j) referential
125      REAL(wp), INTENT(  out) ::   pe1, pe2                       ! i- and j scale factors
126      REAL(wp), INTENT(  out) ::   puo, pvo, pui, pvi, pua, pva   ! ocean, ice and wind speeds
127      REAL(wp), INTENT(  out) ::   pssh_i, pssh_j                 ! ssh i- & j-gradients
128      REAL(wp), INTENT(  out) ::   psst, pcn, phi, pff            ! SST, ice concentration, ice thickness, Coriolis
129      !
130      REAL(wp) ::   zcd, zmod       ! local scalars
131      !!----------------------------------------------------------------------
132
133      pe1 = icb_utl_bilin_e( e1t, e1u, e1v, e1f, pi, pj )     ! scale factors
134      pe2 = icb_utl_bilin_e( e2t, e2u, e2v, e2f, pi, pj )
135      !
136      puo  = icb_utl_bilin_h( uo_e, pi, pj, 'U' )             ! ocean velocities
137      pvo  = icb_utl_bilin_h( vo_e, pi, pj, 'V' )
138      psst = icb_utl_bilin_h( tt_e, pi, pj, 'T' )             ! SST
139      pcn  = icb_utl_bilin_h( fr_e , pi, pj, 'T' )            ! ice concentration
140      pff  = icb_utl_bilin_h( ff_e , pi, pj, 'F' )            ! Coriolis parameter
141      !
142      pua  = icb_utl_bilin_h( ua_e , pi, pj, 'U' )            ! 10m wind
143      pva  = icb_utl_bilin_h( va_e , pi, pj, 'V' )            ! here (ua,va) are stress => rough conversion from stress to speed
144      zcd  = 1.22_wp * 1.5e-3_wp                              ! air density * drag coefficient
145      zmod = 1._wp / MAX(  1.e-20, SQRT(  zcd * SQRT( pua*pua + pva*pva)  )  )
146      pua  = pua * zmod                                       ! note: stress module=0 necessarly implies ua=va=0
147      pva  = pva * zmod
148
149#if defined key_si3
150      pui = icb_utl_bilin_h( ui_e , pi, pj, 'U' )              ! sea-ice velocities
151      pvi = icb_utl_bilin_h( vi_e , pi, pj, 'V' )
152      phi = icb_utl_bilin_h( hi_e , pi, pj, 'T' )              ! ice thickness
153#else
154      pui = 0._wp
155      pvi = 0._wp
156      phi = 0._wp
157#endif
158
159      ! Estimate SSH gradient in i- and j-direction (centred evaluation)
160      pssh_i = ( icb_utl_bilin_h( ssh_e, pi+0.1_wp, pj, 'T' ) -   &
161         &       icb_utl_bilin_h( ssh_e, pi-0.1_wp, pj, 'T' )  ) / ( 0.2_wp * pe1 )
162      pssh_j = ( icb_utl_bilin_h( ssh_e, pi, pj+0.1_wp, 'T' ) -   &
163         &       icb_utl_bilin_h( ssh_e, pi, pj-0.1_wp, 'T' )  ) / ( 0.2_wp * pe2 )
164      !
165   END SUBROUTINE icb_utl_interp
166
167
168   REAL(wp) FUNCTION icb_utl_bilin_h( pfld, pi, pj, cd_type )
169      !!----------------------------------------------------------------------
170      !!                  ***  FUNCTION icb_utl_bilin  ***
171      !!
172      !! ** Purpose :   bilinear interpolation at berg location depending on the grid-point type
173      !!                this version deals with extra halo points
174      !!
175      !!       !!gm  CAUTION an optional argument should be added to handle
176      !!             the slip/no-slip conditions  ==>>> to be done later
177      !!
178      !!----------------------------------------------------------------------
179      REAL(wp), DIMENSION(0:jpi+1,0:jpj+1), INTENT(in) ::   pfld      ! field to be interpolated
180      REAL(wp)                            , INTENT(in) ::   pi, pj    ! targeted coordinates in (i,j) referential
181      CHARACTER(len=1)                    , INTENT(in) ::   cd_type   ! type of pfld array grid-points: = T , U , V or F points
182      !
183      INTEGER  ::   ii, ij   ! local integer
184      REAL(wp) ::   zi, zj   ! local real
185      !!----------------------------------------------------------------------
186      !
187      SELECT CASE ( cd_type )
188      CASE ( 'T' )
189         ! note that here there is no +0.5 added
190         ! since we're looking for four T points containing quadrant we're in of
191         ! current T cell
192         ii = MAX(0, INT( pi     ))
193         ij = MAX(0, INT( pj     ))    ! T-point
194         zi = pi - REAL(ii,wp)
195         zj = pj - REAL(ij,wp)
196      CASE ( 'U' )
197         ii = MAX(0, INT( pi-0.5_wp ))
198         ij = MAX(0, INT( pj     ))    ! U-point
199         zi = pi - 0.5_wp - REAL(ii,wp)
200         zj = pj - REAL(ij,wp)
201      CASE ( 'V' )
202         ii = MAX(0, INT( pi     ))
203         ij = MAX(0, INT( pj-0.5_wp ))    ! V-point
204         zi = pi - REAL(ii,wp)
205         zj = pj - 0.5_wp - REAL(ij,wp)
206      CASE ( 'F' )
207         ii = MAX(0, INT( pi-0.5_wp ))
208         ij = MAX(0, INT( pj-0.5_wp ))    ! F-point
209         zi = pi - 0.5_wp - REAL(ii,wp)
210         zj = pj - 0.5_wp - REAL(ij,wp)
211      END SELECT
212      !
213      ! find position in this processor. Prevent near edge problems (see #1389)
214      ! (PM) will be useless if extra halo is used in NEMO
215      !
216      IF    ( ii <= mig(1)-1 ) THEN   ;   ii = 0
217      ELSEIF( ii  > mig(jpi) ) THEN   ;   ii = jpi
218      ELSE                            ;   ii = mi1(ii)
219      ENDIF
220      IF    ( ij <= mjg(1)-1 ) THEN   ;   ij = 0
221      ELSEIF( ij  > mjg(jpj) ) THEN   ;   ij = jpj
222      ELSE                            ;   ij = mj1(ij)
223      ENDIF
224      !
225      !
226      icb_utl_bilin_h = ( pfld(ii,ij  ) * (1._wp-zi) + pfld(ii+1,ij  ) * zi ) * (1._wp-zj)   &
227         &            + ( pfld(ii,ij+1) * (1._wp-zi) + pfld(ii+1,ij+1) * zi ) *        zj
228      !
229   END FUNCTION icb_utl_bilin_h
230
231
232   REAL(wp) FUNCTION icb_utl_bilin( pfld, pi, pj, cd_type )
233      !!----------------------------------------------------------------------
234      !!                  ***  FUNCTION icb_utl_bilin  ***
235      !!
236      !! ** Purpose :   bilinear interpolation at berg location depending on the grid-point type
237      !!
238      !!       !!gm  CAUTION an optional argument should be added to handle
239      !!             the slip/no-slip conditions  ==>>> to be done later
240      !!
241      !!----------------------------------------------------------------------
242      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pfld      ! field to be interpolated
243      REAL(wp)                    , INTENT(in) ::   pi, pj    ! targeted coordinates in (i,j) referential
244      CHARACTER(len=1)            , INTENT(in) ::   cd_type   ! type of pfld array grid-points: = T , U , V or F points
245      !
246      INTEGER  ::   ii, ij   ! local integer
247      REAL(wp) ::   zi, zj   ! local real
248      !!----------------------------------------------------------------------
249      !
250      SELECT CASE ( cd_type )
251         CASE ( 'T' )
252            ! note that here there is no +0.5 added
253            ! since we're looking for four T points containing quadrant we're in of
254            ! current T cell
255            ii = MAX(1, INT( pi     ))
256            ij = MAX(1, INT( pj     ))    ! T-point
257            zi = pi - REAL(ii,wp)
258            zj = pj - REAL(ij,wp)
259         CASE ( 'U' )
260            ii = MAX(1, INT( pi-0.5 ))
261            ij = MAX(1, INT( pj     ))    ! U-point
262            zi = pi - 0.5 - REAL(ii,wp)
263            zj = pj - REAL(ij,wp)
264         CASE ( 'V' )
265            ii = MAX(1, INT( pi     ))
266            ij = MAX(1, INT( pj-0.5 ))    ! V-point
267            zi = pi - REAL(ii,wp)
268            zj = pj - 0.5 - REAL(ij,wp)
269         CASE ( 'F' )
270            ii = MAX(1, INT( pi-0.5 ))
271            ij = MAX(1, INT( pj-0.5 ))    ! F-point
272            zi = pi - 0.5 - REAL(ii,wp)
273            zj = pj - 0.5 - REAL(ij,wp)
274      END SELECT
275      !
276      ! find position in this processor. Prevent near edge problems (see #1389)
277      IF    ( ii < mig( 1 ) ) THEN   ;   ii = 1
278      ELSEIF( ii > mig(jpi) ) THEN   ;   ii = jpi
279      ELSE                           ;   ii = mi1(ii)
280      ENDIF
281      IF    ( ij < mjg( 1 ) ) THEN   ;   ij = 1
282      ELSEIF( ij > mjg(jpj) ) THEN   ;   ij = jpj
283      ELSE                           ;   ij  = mj1(ij)
284      ENDIF
285      !
286      IF( ii == jpi )   ii = ii-1     
287      IF( ij == jpj )   ij = ij-1
288      !
289      icb_utl_bilin = ( pfld(ii,ij  ) * (1.-zi) + pfld(ii+1,ij  ) * zi ) * (1.-zj)   &
290         &          + ( pfld(ii,ij+1) * (1.-zi) + pfld(ii+1,ij+1) * zi ) *     zj
291      !
292   END FUNCTION icb_utl_bilin
293
294
295   REAL(wp) FUNCTION icb_utl_bilin_x( pfld, pi, pj )
296      !!----------------------------------------------------------------------
297      !!                  ***  FUNCTION icb_utl_bilin_x  ***
298      !!
299      !! ** Purpose :   bilinear interpolation at berg location depending on the grid-point type
300      !!                Special case for interpolating longitude
301      !!
302      !!       !!gm  CAUTION an optional argument should be added to handle
303      !!             the slip/no-slip conditions  ==>>> to be done later
304      !!
305      !!----------------------------------------------------------------------
306      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pfld      ! field to be interpolated
307      REAL(wp)                    , INTENT(in) ::   pi, pj    ! targeted coordinates in (i,j) referential
308      !
309      INTEGER                                  ::   ii, ij   ! local integer
310      REAL(wp)                                 ::   zi, zj   ! local real
311      REAL(wp)                                 ::   zret     ! local real
312      REAL(wp), DIMENSION(4)                   ::   z4
313      !!----------------------------------------------------------------------
314      !
315      ! note that here there is no +0.5 added
316      ! since we're looking for four T points containing quadrant we're in of
317      ! current T cell
318      ii = MAX(1, INT( pi     ))
319      ij = MAX(1, INT( pj     ))    ! T-point
320      zi = pi - REAL(ii,wp)
321      zj = pj - REAL(ij,wp)
322      !
323      ! find position in this processor. Prevent near edge problems (see #1389)
324      IF    ( ii < mig( 1 ) ) THEN   ;   ii = 1
325      ELSEIF( ii > mig(jpi) ) THEN   ;   ii = jpi
326      ELSE                           ;   ii = mi1(ii)
327      ENDIF
328      IF    ( ij < mjg( 1 ) ) THEN   ;   ij = 1
329      ELSEIF( ij > mjg(jpj) ) THEN   ;   ij = jpj
330      ELSE                           ;   ij  = mj1(ij)
331      ENDIF
332      !
333      IF( ii == jpi )   ii = ii-1     
334      IF( ij == jpj )   ij = ij-1
335      !
336      z4(1) = pfld(ii  ,ij  )
337      z4(2) = pfld(ii+1,ij  )
338      z4(3) = pfld(ii  ,ij+1)
339      z4(4) = pfld(ii+1,ij+1)
340      IF( MAXVAL(z4) - MINVAL(z4) > 90._wp ) THEN
341         WHERE( z4 < 0._wp ) z4 = z4 + 360._wp
342      ENDIF
343      !
344      zret = (z4(1) * (1.-zi) + z4(2) * zi) * (1.-zj) + (z4(3) * (1.-zi) + z4(4) * zi) * zj
345      IF( zret > 180._wp ) zret = zret - 360._wp
346      icb_utl_bilin_x = zret
347      !
348   END FUNCTION icb_utl_bilin_x
349
350
351   REAL(wp) FUNCTION icb_utl_bilin_e( pet, peu, pev, pef, pi, pj )
352      !!----------------------------------------------------------------------
353      !!                  ***  FUNCTION dom_init  ***
354      !!
355      !! ** Purpose :   bilinear interpolation at berg location of horizontal scale factor
356      !! ** Method  :   interpolation done using the 4 nearest grid points among
357      !!                t-, u-, v-, and f-points.
358      !!----------------------------------------------------------------------
359      REAL(wp), DIMENSION(:,:), INTENT(in) ::   pet, peu, pev, pef   ! horizontal scale factor to be interpolated at t-,u-,v- & f-pts
360      REAL(wp)                , INTENT(in) ::   pi, pj               ! targeted coordinates in (i,j) referential
361      !
362      INTEGER  ::   ii, ij, icase, ierr   ! local integer
363      !
364      ! weights corresponding to corner points of a T cell quadrant
365      REAL(wp) ::   zi, zj          ! local real
366      !
367      ! values at corner points of a T cell quadrant
368      ! 00 = bottom left, 10 = bottom right, 01 = top left, 11 = top right
369      REAL(wp) ::   ze00, ze10, ze01, ze11
370      !!----------------------------------------------------------------------
371      !
372      ii = MAX(1, INT( pi ))   ;   ij = MAX(1, INT( pj ))            ! left bottom T-point (i,j) indices
373
374      ! fractional box spacing
375      ! 0   <= zi < 0.5, 0   <= zj < 0.5   -->  NW quadrant of current T cell
376      ! 0.5 <= zi < 1  , 0   <= zj < 0.5   -->  NE quadrant
377      ! 0   <= zi < 0.5, 0.5 <= zj < 1     -->  SE quadrant
378      ! 0.5 <= zi < 1  , 0.5 <= zj < 1     -->  SW quadrant
379
380      zi = pi - REAL(ii,wp)          !!gm use here mig, mjg arrays
381      zj = pj - REAL(ij,wp)
382
383      ! find position in this processor. Prevent near edge problems (see #1389)
384      !
385      ierr = 0
386      IF    ( ii < mig( 1 ) ) THEN   ;   ii = 1       ; ierr = ierr + 1
387      ELSEIF( ii > mig(jpi) ) THEN   ;   ii = jpi     ; ierr = ierr + 1
388      ELSE                           ;   ii = mi1(ii)
389      ENDIF
390      IF    ( ij < mjg( 1 ) ) THEN   ;   ij = 1       ; ierr = ierr + 1
391      ELSEIF( ij > mjg(jpj) ) THEN   ;   ij = jpj     ; ierr = ierr + 1
392      ELSE                           ;   ij  = mj1(ij)
393      ENDIF
394      !
395      IF( ii == jpi ) THEN ; ii = ii-1 ; ierr = ierr + 1 ; END IF     
396      IF( ij == jpj ) THEN ; ij = ij-1 ; ierr = ierr + 1 ; END IF
397      !
398      IF ( ierr > 0 ) CALL ctl_stop('STOP','icb_utl_bilin_e: an icebergs coordinates is out of valid range (out of bound error)')
399      !
400      IF(    0.0_wp <= zi .AND. zi < 0.5_wp   ) THEN
401         IF( 0.0_wp <= zj .AND. zj < 0.5_wp        )   THEN        !  NE quadrant
402            !                                                      !             i=I       i=I+1/2
403            ze01 = pev(ii  ,ij  )   ;   ze11 = pef(ii  ,ij  )      !   j=J+1/2    V ------- F
404            ze00 = pet(ii  ,ij  )   ;   ze10 = peu(ii  ,ij  )      !   j=J        T ------- U
405            zi = 2._wp * zi
406            zj = 2._wp * zj
407         ELSE                                                      !  SE quadrant
408            !                                                                    !             i=I       i=I+1/2
409            ze01 = pet(ii  ,ij+1)   ;   ze11 = peu(ii  ,ij+1)      !   j=J+1      T ------- U
410            ze00 = pev(ii  ,ij  )   ;   ze10 = pef(ii  ,ij  )      !   j=J+1/2    V ------- F
411            zi = 2._wp *  zi
412            zj = 2._wp * (zj-0.5_wp)
413         ENDIF
414      ELSE
415         IF( 0.0_wp <= zj .AND. zj < 0.5_wp        )   THEN        !  NW quadrant
416            !                                                                    !             i=I       i=I+1/2
417            ze01 = pef(ii  ,ij  )   ;   ze11 = pev(ii+1,ij)        !   j=J+1/2    F ------- V
418            ze00 = peu(ii  ,ij  )   ;   ze10 = pet(ii+1,ij)        !   j=J        U ------- T
419            zi = 2._wp * (zi-0.5_wp)
420            zj = 2._wp *  zj
421         ELSE                                                      !  SW quadrant
422            !                                                                    !             i=I+1/2   i=I+1
423            ze01 = peu(ii  ,ij+1)   ;   ze11 = pet(ii+1,ij+1)      !   j=J+1      U ------- T
424            ze00 = pef(ii  ,ij  )   ;   ze10 = pev(ii+1,ij  )      !   j=J+1/2    F ------- V
425            zi = 2._wp * (zi-0.5_wp)
426            zj = 2._wp * (zj-0.5_wp)
427         ENDIF
428      ENDIF
429      !
430      icb_utl_bilin_e = ( ze01 * (1._wp-zi) + ze11 * zi ) *        zj    &
431         &            + ( ze00 * (1._wp-zi) + ze10 * zi ) * (1._wp-zj)
432      !
433   END FUNCTION icb_utl_bilin_e
434
435
436   SUBROUTINE icb_utl_add( bergvals, ptvals )
437      !!----------------------------------------------------------------------
438      !!                ***  ROUTINE icb_utl_add           ***
439      !!
440      !! ** Purpose :   add a new berg to the iceberg list
441      !!
442      !!----------------------------------------------------------------------
443      TYPE(iceberg), INTENT(in)           ::   bergvals
444      TYPE(point)  , INTENT(in)           ::   ptvals
445      !
446      TYPE(iceberg), POINTER ::   new => NULL()
447      !!----------------------------------------------------------------------
448      !
449      new => NULL()
450      CALL icb_utl_create( new, bergvals, ptvals )
451      CALL icb_utl_insert( new )
452      new => NULL()     ! Clear new
453      !
454   END SUBROUTINE icb_utl_add         
455
456
457   SUBROUTINE icb_utl_create( berg, bergvals, ptvals )
458      !!----------------------------------------------------------------------
459      !!                ***  ROUTINE icb_utl_create  ***
460      !!
461      !! ** Purpose :   add a new berg to the iceberg list
462      !!
463      !!----------------------------------------------------------------------
464      TYPE(iceberg), INTENT(in) ::   bergvals
465      TYPE(point)  , INTENT(in) ::   ptvals
466      TYPE(iceberg), POINTER    ::   berg
467      !
468      TYPE(point)  , POINTER    ::   pt
469      INTEGER                   ::   istat
470      !!----------------------------------------------------------------------
471      !
472      IF( ASSOCIATED(berg) )   CALL ctl_stop( 'icebergs, icb_utl_create: berg already associated' )
473      ALLOCATE(berg, STAT=istat)
474      IF( istat /= 0 ) CALL ctl_stop( 'failed to allocate iceberg' )
475      berg%number(:) = bergvals%number(:)
476      berg%mass_scaling = bergvals%mass_scaling
477      berg%prev => NULL()
478      berg%next => NULL()
479      !
480      ALLOCATE(pt, STAT=istat)
481      IF( istat /= 0 ) CALL ctl_stop( 'failed to allocate first iceberg point' )
482      pt = ptvals
483      berg%current_point => pt
484      !
485   END SUBROUTINE icb_utl_create
486
487
488   SUBROUTINE icb_utl_insert( newberg )
489      !!----------------------------------------------------------------------
490      !!                 ***  ROUTINE icb_utl_insert  ***
491      !!
492      !! ** Purpose :   add a new berg to the iceberg list
493      !!
494      !!----------------------------------------------------------------------
495      TYPE(iceberg), POINTER  ::   newberg
496      !
497      TYPE(iceberg), POINTER  ::   this, prev, last
498      !!----------------------------------------------------------------------
499      !
500      IF( ASSOCIATED( first_berg ) ) THEN
501         last => first_berg
502         DO WHILE (ASSOCIATED(last%next))
503            last => last%next
504         ENDDO
505         newberg%prev => last
506         last%next    => newberg
507         last         => newberg
508      ELSE                       ! list is empty so create it
509         first_berg => newberg
510      ENDIF
511      !
512   END SUBROUTINE icb_utl_insert
513
514
515   REAL(wp) FUNCTION icb_utl_yearday(kmon, kday, khr, kmin, ksec)
516      !!----------------------------------------------------------------------
517      !!                 ***  FUNCTION icb_utl_yearday  ***
518      !!
519      !! ** Purpose :   
520      !!
521      ! sga - improved but still only applies to 365 day year, need to do this properly
522      !
523      !!gm  all these info are already known in daymod, no???
524      !!
525      !!----------------------------------------------------------------------
526      INTEGER, INTENT(in)     :: kmon, kday, khr, kmin, ksec
527      !
528      INTEGER, DIMENSION(12)  :: imonths = (/ 0,31,28,31,30,31,30,31,31,30,31,30 /)
529      !!----------------------------------------------------------------------
530      !
531      icb_utl_yearday = REAL( SUM( imonths(1:kmon) ), wp )
532      icb_utl_yearday = icb_utl_yearday + REAL(kday-1,wp) + (REAL(khr,wp) + (REAL(kmin,wp) + REAL(ksec,wp)/60.)/60.)/24.
533      !
534   END FUNCTION icb_utl_yearday
535
536   !!-------------------------------------------------------------------------
537
538   SUBROUTINE icb_utl_delete( first, berg )
539      !!----------------------------------------------------------------------
540      !!                 ***  ROUTINE icb_utl_delete  ***
541      !!
542      !! ** Purpose :   
543      !!
544      !!----------------------------------------------------------------------
545      TYPE(iceberg), POINTER :: first, berg
546      !!----------------------------------------------------------------------
547      ! Connect neighbors to each other
548      IF ( ASSOCIATED(berg%prev) ) THEN
549        berg%prev%next => berg%next
550      ELSE
551        first => berg%next
552      ENDIF
553      IF (ASSOCIATED(berg%next)) berg%next%prev => berg%prev
554      !
555      CALL icb_utl_destroy(berg)
556      !
557   END SUBROUTINE icb_utl_delete
558
559
560   SUBROUTINE icb_utl_destroy( berg )
561      !!----------------------------------------------------------------------
562      !!                 ***  ROUTINE icb_utl_destroy  ***
563      !!
564      !! ** Purpose :   remove a single iceberg instance
565      !!
566      !!----------------------------------------------------------------------
567      TYPE(iceberg), POINTER :: berg
568      !!----------------------------------------------------------------------
569      !
570      ! Remove any points
571      IF( ASSOCIATED( berg%current_point ) )   DEALLOCATE( berg%current_point )
572      !
573      DEALLOCATE(berg)
574      !
575   END SUBROUTINE icb_utl_destroy
576
577
578   SUBROUTINE icb_utl_track( knum, cd_label, kt )
579      !!----------------------------------------------------------------------
580      !!                 ***  ROUTINE icb_utl_track  ***
581      !!
582      !! ** Purpose :   
583      !!
584      !!----------------------------------------------------------------------
585      INTEGER, DIMENSION(nkounts)    :: knum       ! iceberg number
586      CHARACTER(len=*)               :: cd_label   !
587      INTEGER                        :: kt         ! timestep number
588      !
589      TYPE(iceberg), POINTER         :: this
590      LOGICAL                        :: match
591      INTEGER                        :: k
592      !!----------------------------------------------------------------------
593      !
594      this => first_berg
595      DO WHILE( ASSOCIATED(this) )
596         match = .TRUE.
597         DO k = 1, nkounts
598            IF( this%number(k) /= knum(k) ) match = .FALSE.
599         END DO
600         IF( match )   CALL icb_utl_print_berg(this, kt)
601         this => this%next
602      END DO
603      !
604   END SUBROUTINE icb_utl_track
605
606
607   SUBROUTINE icb_utl_print_berg( berg, kt )
608      !!----------------------------------------------------------------------
609      !!                 ***  ROUTINE icb_utl_print_berg  ***
610      !!
611      !! ** Purpose :   print one
612      !!
613      !!----------------------------------------------------------------------
614      TYPE(iceberg), POINTER :: berg
615      TYPE(point)  , POINTER :: pt
616      INTEGER                :: kt      ! timestep number
617      !!----------------------------------------------------------------------
618      !
619      IF (nn_verbose_level == 0) RETURN
620      pt => berg%current_point
621      WRITE(numicb, 9200) kt, berg%number(1), &
622                   pt%xi, pt%yj, pt%lon, pt%lat, pt%uvel, pt%vvel,  &
623                   pt%uo, pt%vo, pt%ua, pt%va, pt%ui, pt%vi
624      CALL flush( numicb )
625 9200 FORMAT(5x,i5,2x,i10,6(2x,2f10.4))
626      !
627   END SUBROUTINE icb_utl_print_berg
628
629
630   SUBROUTINE icb_utl_print( cd_label, kt )
631      !!----------------------------------------------------------------------
632      !!                 ***  ROUTINE icb_utl_print  ***
633      !!
634      !! ** Purpose :   print many
635      !!
636      !!----------------------------------------------------------------------
637      CHARACTER(len=*)       :: cd_label
638      INTEGER                :: kt             ! timestep number
639      !
640      INTEGER                :: ibergs, inbergs
641      TYPE(iceberg), POINTER :: this
642      !!----------------------------------------------------------------------
643      !
644      IF (nn_verbose_level == 0) RETURN
645      this => first_berg
646      IF( ASSOCIATED(this) ) THEN
647         WRITE(numicb,'(a," pe=(",i3,")")' ) cd_label, narea
648         WRITE(numicb,'(a8,4x,a6,12x,a5,15x,a7,19x,a3,17x,a5,17x,a5,17x,a5)' )   &
649            &         'timestep', 'number', 'xi,yj','lon,lat','u,v','uo,vo','ua,va','ui,vi'
650      ENDIF
651      DO WHILE( ASSOCIATED(this) )
652        CALL icb_utl_print_berg(this, kt)
653        this => this%next
654      END DO
655      ibergs = icb_utl_count()
656      inbergs = ibergs
657      CALL mpp_sum('icbutl', inbergs)
658      IF( ibergs > 0 )   WRITE(numicb,'(a," there are",i5," bergs out of",i6," on PE ",i4)')   &
659         &                                  cd_label, ibergs, inbergs, narea
660      !
661   END SUBROUTINE icb_utl_print
662
663
664   SUBROUTINE icb_utl_incr()
665      !!----------------------------------------------------------------------
666      !!                 ***  ROUTINE icb_utl_incr  ***
667      !!
668      !! ** Purpose :   
669      !!
670      ! Small routine for coping with very large integer values labelling icebergs
671      ! num_bergs is a array of integers
672      ! the first member is incremented in steps of jpnij starting from narea
673      ! this means each iceberg is labelled with a unique number
674      ! when this gets to the maximum allowed integer the second and subsequent members are
675      ! used to count how many times the member before cycles
676      !!----------------------------------------------------------------------
677      INTEGER ::   ii, ibig
678      !!----------------------------------------------------------------------
679
680      ibig = HUGE(num_bergs(1))
681      IF( ibig-jpnij < num_bergs(1) ) THEN
682         num_bergs(1) = narea
683         DO ii = 2,nkounts
684            IF( num_bergs(ii) == ibig ) THEN
685               num_bergs(ii) = 0
686               IF( ii == nkounts ) CALL ctl_stop('Sorry, run out of iceberg number space')
687            ELSE
688               num_bergs(ii) = num_bergs(ii) + 1
689               EXIT
690            ENDIF
691         END DO
692      ELSE
693         num_bergs(1) = num_bergs(1) + jpnij
694      ENDIF
695      !
696   END SUBROUTINE icb_utl_incr
697
698
699   INTEGER FUNCTION icb_utl_count()
700      !!----------------------------------------------------------------------
701      !!                 ***  FUNCTION icb_utl_count  ***
702      !!
703      !! ** Purpose :   
704      !!----------------------------------------------------------------------
705      TYPE(iceberg), POINTER :: this
706      !!----------------------------------------------------------------------
707      !
708      icb_utl_count = 0
709      this => first_berg
710      DO WHILE( ASSOCIATED(this) )
711         icb_utl_count = icb_utl_count+1
712         this => this%next
713      END DO
714      !
715   END FUNCTION icb_utl_count
716
717
718   REAL(wp) FUNCTION icb_utl_mass( first, justbits, justbergs )
719      !!----------------------------------------------------------------------
720      !!                 ***  FUNCTION icb_utl_mass  ***
721      !!
722      !! ** Purpose :   compute the mass all iceberg, all berg bits or all bergs.
723      !!----------------------------------------------------------------------
724      TYPE(iceberg)      , POINTER  ::   first
725      TYPE(point)        , POINTER  ::   pt
726      LOGICAL, INTENT(in), OPTIONAL ::   justbits, justbergs
727      !
728      TYPE(iceberg), POINTER ::   this
729      !!----------------------------------------------------------------------
730      icb_utl_mass = 0._wp
731      this => first
732      !
733      IF( PRESENT( justbergs  ) ) THEN
734         DO WHILE( ASSOCIATED( this ) )
735            pt => this%current_point
736            icb_utl_mass = icb_utl_mass + pt%mass         * this%mass_scaling
737            this => this%next
738         END DO
739      ELSEIF( PRESENT(justbits) ) THEN
740         DO WHILE( ASSOCIATED( this ) )
741            pt => this%current_point
742            icb_utl_mass = icb_utl_mass + pt%mass_of_bits * this%mass_scaling
743            this => this%next
744         END DO
745      ELSE
746         DO WHILE( ASSOCIATED( this ) )
747            pt => this%current_point
748            icb_utl_mass = icb_utl_mass + ( pt%mass + pt%mass_of_bits ) * this%mass_scaling
749            this => this%next
750         END DO
751      ENDIF
752      !
753   END FUNCTION icb_utl_mass
754
755
756   REAL(wp) FUNCTION icb_utl_heat( first, justbits, justbergs )
757      !!----------------------------------------------------------------------
758      !!                 ***  FUNCTION icb_utl_heat  ***
759      !!
760      !! ** Purpose :   compute the heat in all iceberg, all bergies or all bergs.
761      !!----------------------------------------------------------------------
762      TYPE(iceberg)      , POINTER  ::   first
763      LOGICAL, INTENT(in), OPTIONAL ::   justbits, justbergs
764      !
765      TYPE(iceberg)      , POINTER  ::   this
766      TYPE(point)        , POINTER  ::   pt
767      !!----------------------------------------------------------------------
768      icb_utl_heat = 0._wp
769      this => first
770      !
771      IF( PRESENT( justbergs  ) ) THEN
772         DO WHILE( ASSOCIATED( this ) )
773            pt => this%current_point
774            icb_utl_heat = icb_utl_heat + pt%mass         * this%mass_scaling * pt%heat_density
775            this => this%next
776         END DO
777      ELSEIF( PRESENT(justbits) ) THEN
778         DO WHILE( ASSOCIATED( this ) )
779            pt => this%current_point
780            icb_utl_heat = icb_utl_heat + pt%mass_of_bits * this%mass_scaling * pt%heat_density
781            this => this%next
782         END DO
783      ELSE
784         DO WHILE( ASSOCIATED( this ) )
785            pt => this%current_point
786            icb_utl_heat = icb_utl_heat + ( pt%mass + pt%mass_of_bits ) * this%mass_scaling * pt%heat_density
787            this => this%next
788         END DO
789      ENDIF
790      !
791   END FUNCTION icb_utl_heat
792
793   !!======================================================================
794END MODULE icbutl
Note: See TracBrowser for help on using the repository browser.