New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2019/fix_vvl_ticket1791/src/SAS – NEMO

source: NEMO/branches/2019/fix_vvl_ticket1791/src/SAS/nemogcm.F90 @ 11422

Last change on this file since 11422 was 11422, checked in by jchanut, 5 years ago

#1791, merge with trunk

  • Property svn:keywords set to Id
File size: 27.7 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! StandAlone Surface module : surface fluxes + sea-ice + iceberg floats
5   !!======================================================================
6   !! History :  3.6  ! 2011-11  (S. Alderson, G. Madec) original code
7   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
8   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
9   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
14   !!   nemo_init     : initialization of the NEMO system
15   !!   nemo_ctl      : initialisation of the contol print
16   !!   nemo_closefile: close remaining open files
17   !!   nemo_alloc    : dynamical allocation
18   !!----------------------------------------------------------------------
19   USE step_oce       ! module used in the ocean time stepping module
20   USE sbc_oce        ! surface boundary condition: ocean
21   USE phycst         ! physical constant                  (par_cst routine)
22   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
23   USE closea         ! treatment of closed seas (for ln_closea)
24   USE usrdef_nam     ! user defined configuration
25   USE daymod         ! calendar
26   USE restart        ! open  restart file
27   USE step           ! NEMO time-stepping                 (stp     routine)
28   USE cpl_oasis3     !
29   USE sbcssm         !
30   USE icbini         ! handle bergs, initialisation
31   USE icbstp         ! handle bergs, calving, themodynamics and transport
32   USE bdyini         ! open boundary cond. setting       (bdy_init routine). mandatory for sea-ice
33   USE bdydta         ! open boundary cond. setting   (bdy_dta_init routine). mandatory for sea-ice
34   !
35   USE lib_mpp        ! distributed memory computing
36   USE mppini         ! shared/distributed memory setting (mpp_init routine)
37   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
38   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
39#if defined key_iomput
40   USE xios           ! xIOserver
41#endif
42#if defined key_agrif && defined key_si3
43   USE agrif_ice_update ! ice update
44#endif
45
46   IMPLICIT NONE
47   PRIVATE
48
49   PUBLIC   nemo_gcm    ! called by model.F90
50   PUBLIC   nemo_init   ! needed by AGRIF
51
52   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
53
54   !!----------------------------------------------------------------------
55   !! NEMO/SAS 4.0 , NEMO Consortium (2018)
56   !! $Id$
57   !! Software governed by the CeCILL license (see ./LICENSE)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   SUBROUTINE nemo_gcm
62      !!----------------------------------------------------------------------
63      !!                     ***  ROUTINE nemo_gcm  ***
64      !!
65      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
66      !!              curvilinear mesh on the sphere.
67      !!
68      !! ** Method  : - model general initialization
69      !!              - launch the time-stepping (stp routine)
70      !!              - finalize the run by closing files and communications
71      !!
72      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
73      !!              Madec, 2008, internal report, IPSL.
74      !!----------------------------------------------------------------------
75      INTEGER ::   istp   ! time step index
76      !!----------------------------------------------------------------------
77      !
78#if defined key_agrif
79      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
80#endif
81      !                            !-----------------------!
82      CALL nemo_init               !==  Initialisations  ==!
83      !                            !-----------------------!
84#if defined key_agrif
85      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
86      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
87# if defined key_top
88      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
89# endif
90# if defined key_si3
91      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
92# endif
93#endif
94      ! check that all process are still there... If some process have an error,
95      ! they will never enter in step and other processes will wait until the end of the cpu time!
96      CALL mpp_max( 'nemogcm', nstop )
97
98      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
99
100      !                            !-----------------------!
101      !                            !==   time stepping   ==!
102      !                            !-----------------------!
103      istp = nit000
104      !
105#if defined key_agrif
106      !                                               !==  AGRIF time-stepping  ==!
107      CALL Agrif_Regrid()
108      !
109#if defined key_si3
110      ! Recursive update from highest nested level to lowest:
111      CALL Agrif_step_child_adj(Agrif_update_ice)
112#endif
113      !
114      DO WHILE( istp <= nitend .AND. nstop == 0 )
115         CALL stp
116         istp = istp + 1
117      END DO
118      !
119      IF( .NOT. Agrif_Root() ) THEN
120         CALL Agrif_ParentGrid_To_ChildGrid()
121         IF( ln_timing )   CALL timing_finalize
122         CALL Agrif_ChildGrid_To_ParentGrid()
123      ENDIF
124      !
125#else
126      !
127      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
128         !
129         DO WHILE( istp <= nitend .AND. nstop == 0 )
130            CALL stp        ( istp ) 
131            istp = istp + 1
132         END DO
133         !
134      ELSE                                            !==  diurnal SST time-steeping only  ==!
135         !
136         DO WHILE( istp <= nitend .AND. nstop == 0 )
137            CALL stp_diurnal( istp )   ! time step only the diurnal SST
138            istp = istp + 1
139         END DO
140         !
141      ENDIF
142      !
143#endif
144      !
145      IF( ln_icebergs )   CALL icb_end( nitend )
146
147      !                            !------------------------!
148      !                            !==  finalize the run  ==!
149      !                            !------------------------!
150      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
151      !
152      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
153         WRITE(numout,cform_err)
154         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
155         WRITE(numout,*)
156      ENDIF
157      !
158      IF( ln_timing )   CALL timing_finalize
159      !
160      CALL nemo_closefile
161      !
162#if defined key_iomput
163                                    CALL xios_finalize  ! end mpp communications with xios
164      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
165#else
166      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
167      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop( ldfinal = .TRUE. )   ! end mpp communications
168      ENDIF
169#endif
170      !
171      IF(lwm) THEN
172         IF( nstop == 0 ) THEN   ;   STOP 0
173         ELSE                    ;   STOP 999
174         ENDIF
175      ENDIF
176      !
177   END SUBROUTINE nemo_gcm
178
179
180   SUBROUTINE nemo_init
181      !!----------------------------------------------------------------------
182      !!                     ***  ROUTINE nemo_init  ***
183      !!
184      !! ** Purpose :   initialization of the NEMO GCM
185      !!----------------------------------------------------------------------
186      INTEGER  ::   ji                 ! dummy loop indices
187      INTEGER  ::   ios, ilocal_comm   ! local integers
188      CHARACTER(len=120), DIMENSION(30) ::   cltxt, cltxt2, clnam
189      CHARACTER(len=80)                 ::   clname
190      !!
191      NAMELIST/namctl/ ln_ctl   , sn_cfctl, nn_print, nn_ictls, nn_ictle,   &
192         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
193         &             ln_timing, ln_diacfl
194      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
195      !!----------------------------------------------------------------------
196      !
197      cltxt  = ''
198      cltxt2 = ''
199      clnam  = '' 
200      cxios_context = 'nemo'
201      !
202      !                             ! Open reference namelist and configuration namelist files
203      IF( lk_oasis ) THEN
204         CALL ctl_opn( numnam_ref, 'namelist_sas_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
205         CALL ctl_opn( numnam_cfg, 'namelist_sas_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
206         cxios_context = 'sas'
207         clname = 'output.namelist_sas.dyn'
208      ELSE
209         CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
210         CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
211         cxios_context = 'nemo'
212         clname = 'output.namelist.dyn'
213   ENDIF
214      !
215      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
216      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
217901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
218      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
219      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
220902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
221      !
222      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
223      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
224903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
225      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
226      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
227904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
228
229      !                             !--------------------------!
230      !                             !  Set global domain size  !   (control print return in cltxt2)
231      !                             !--------------------------!
232      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
233         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
234         !
235      ELSE                                ! user-defined namelist
236         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
237      ENDIF
238      !
239      !
240      !                             !--------------------------------------------!
241      !                             !  set communicator & select the local node  !
242      !                             !  NB: mynode also opens output.namelist.dyn !
243      !                             !      on unit number numond on first proc   !
244      !                             !--------------------------------------------!
245#if defined key_iomput
246      IF( Agrif_Root() ) THEN
247         IF( lk_oasis ) THEN
248            CALL cpl_init( "sas", ilocal_comm )                          ! nemo local communicator given by oasis
249            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
250         ELSE
251            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
252         ENDIF
253      ENDIF
254      narea = mynode ( cltxt, clname, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )  ! Nodes selection
255#else
256      IF( lk_oasis ) THEN
257         IF( Agrif_Root() ) THEN
258            CALL cpl_init( "sas", ilocal_comm )                          ! nemo local communicator given by oasis
259         ENDIF
260         narea = mynode( cltxt, clname, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection (control print return in cltxt)
261      ELSE
262         ilocal_comm = 0
263         narea = mynode( cltxt, clname, numnam_ref, numnam_cfg, numond , nstop )                ! Nodes selection (control print return in cltxt)
264      ENDIF
265#endif
266
267      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
268
269      IF( sn_cfctl%l_config ) THEN
270         ! Activate finer control of report outputs
271         ! optionally switch off output from selected areas (note this only
272         ! applies to output which does not involve global communications)
273         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
274           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
275           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
276      ELSE
277         ! Use ln_ctl to turn on or off all options.
278         CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
279      ENDIF
280
281      lwm = (narea == 1)                                    ! control of output namelists
282      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
283
284      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
285         !                       ! now that the file has been opened in call to mynode.
286         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
287         WRITE( numond, namctl )
288         WRITE( numond, namcfg )
289         IF( .NOT.ln_read_cfg ) THEN
290            DO ji = 1, SIZE(clnam)
291               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
292            END DO
293         ENDIF
294      ENDIF
295
296      IF(lwp) THEN                            ! open listing units
297         !
298         IF( lk_oasis ) THEN   ;   CALL ctl_opn( numout,   'sas.output', 'REPLACE','FORMATTED','SEQUENTIAL', -1, 6, .FALSE., narea )
299         ELSE                  ;   CALL ctl_opn( numout, 'ocean.output', 'REPLACE','FORMATTED','SEQUENTIAL', -1, 6, .FALSE., narea )
300         ENDIF
301         !
302         WRITE(numout,*)
303         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
304         WRITE(numout,*) '                       NEMO team'
305         WRITE(numout,*) '            Ocean General Circulation Model'
306         WRITE(numout,*) '                NEMO version 4.0  (2019) '
307         WRITE(numout,*) '             StandAlone Surface version (SAS) '
308         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
309         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
310         WRITE(numout,*)
311         WRITE(numout,*) "           o         _,           _,             "
312         WRITE(numout,*) "            o      .' (        .-' /             "
313         WRITE(numout,*) "           o     _/..._'.    .'   /              "
314         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
315         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
316         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
317         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
318         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
319         WRITE(numout,*) "       )  ) jgs                    `     (   (   "
320         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
321         WRITE(numout,*)
322
323         DO ji = 1, SIZE(cltxt)
324            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) TRIM(cltxt(ji))    ! control print of mynode
325         END DO
326         WRITE(numout,*)
327         WRITE(numout,*)
328         DO ji = 1, SIZE(cltxt2)
329            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) TRIM(cltxt2(ji))   ! control print of domain size
330         END DO
331         !
332         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
333         !
334      ENDIF
335      ! open /dev/null file to be able to supress output write easily
336      CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
337      !
338      !                                      ! Domain decomposition
339      CALL mpp_init                          ! MPP
340
341      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
342      CALL nemo_alloc()
343
344      !                             !-------------------------------!
345      !                             !  NEMO general initialization  !
346      !                             !-------------------------------!
347
348      CALL nemo_ctl                          ! Control prints
349      !
350      !                                      ! General initialization
351      IF( ln_timing    )   CALL timing_init     ! timing
352      IF( ln_timing    )   CALL timing_start( 'nemo_init')
353
354                           CALL phy_cst         ! Physical constants
355                           CALL eos_init        ! Equation of seawater
356                           CALL dom_init('SAS') ! Domain
357      IF( ln_ctl      )    CALL prt_ctl_init    ! Print control
358     
359                           CALL day_init        ! model calendar (using both namelist and restart infos)
360      IF( ln_rstart )      CALL rst_read_open
361
362      !                                      ! external forcing
363                           CALL sbc_init        ! Forcings : surface module
364
365      ! ==> clem: open boundaries init. is mandatory for sea-ice because ice BDY is not decoupled from 
366      !           the environment of ocean BDY. Therefore bdy is called in both OPA and SAS modules.
367      !           This is not clean and should be changed in the future.
368                           CALL bdy_init
369      ! ==>
370                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
371      !
372      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
373      !
374      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
375      !
376   END SUBROUTINE nemo_init
377
378
379   SUBROUTINE nemo_ctl
380      !!----------------------------------------------------------------------
381      !!                     ***  ROUTINE nemo_ctl  ***
382      !!
383      !! ** Purpose :   control print setting
384      !!
385      !! ** Method  : - print namctl information and check some consistencies
386      !!----------------------------------------------------------------------
387      !
388      IF(lwp) THEN                  ! control print
389         WRITE(numout,*)
390         WRITE(numout,*) 'nemo_ctl: Control prints'
391         WRITE(numout,*) '~~~~~~~~'
392         WRITE(numout,*) '   Namelist namctl'
393         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
394         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
395         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
396         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
397         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
398         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
399         WRITE(numout,*) '                              sn_cfctl%l_mppout  = ', sn_cfctl%l_mppout
400         WRITE(numout,*) '                              sn_cfctl%l_mpptop  = ', sn_cfctl%l_mpptop
401         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
402         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
403         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
404         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
405         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
406         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
407         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
408         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
409         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
410         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
411         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
412         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
413         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
414      ENDIF
415      !
416      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
417      nictls    = nn_ictls
418      nictle    = nn_ictle
419      njctls    = nn_jctls
420      njctle    = nn_jctle
421      isplt     = nn_isplt
422      jsplt     = nn_jsplt
423
424      IF(lwp) THEN                  ! control print
425         WRITE(numout,*)
426         WRITE(numout,*) '   Namelist namcfg'
427         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
428         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
429         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
430         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
431         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
432         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
433      ENDIF
434      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
435      !
436      !                             ! Parameter control
437      !
438      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
439         IF( lk_mpp .AND. jpnij > 1 ) THEN
440            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
441         ELSE
442            IF( isplt == 1 .AND. jsplt == 1  ) THEN
443               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
444                  &           ' - the print control will be done over the whole domain' )
445            ENDIF
446            ijsplt = isplt * jsplt            ! total number of processors ijsplt
447         ENDIF
448         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
449         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
450         !
451         !                              ! indices used for the SUM control
452         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
453            lsp_area = .FALSE.
454         ELSE                                             ! print control done over a specific  area
455            lsp_area = .TRUE.
456            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
457               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
458               nictls = 1
459            ENDIF
460            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
461               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
462               nictle = jpiglo
463            ENDIF
464            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
465               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
466               njctls = 1
467            ENDIF
468            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
469               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
470               njctle = jpjglo
471            ENDIF
472         ENDIF
473      ENDIF
474      !
475      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
476         &                                                'Compile with key_nosignedzero enabled:',   &
477         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
478      !
479#if defined key_agrif
480      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
481#endif
482      !
483   END SUBROUTINE nemo_ctl
484
485
486   SUBROUTINE nemo_closefile
487      !!----------------------------------------------------------------------
488      !!                     ***  ROUTINE nemo_closefile  ***
489      !!
490      !! ** Purpose :   Close the files
491      !!----------------------------------------------------------------------
492      !
493      IF( lk_mpp )   CALL mppsync
494      !
495      CALL iom_close                                 ! close all input/output files managed by iom_*
496      !
497      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file     
498      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
499      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
500      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
501      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
502      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
503      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
504      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
505      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
506      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
507      !
508      numout = 6                                     ! redefine numout in case it is used after this point...
509      !
510   END SUBROUTINE nemo_closefile
511
512
513   SUBROUTINE nemo_alloc
514      !!----------------------------------------------------------------------
515      !!                     ***  ROUTINE nemo_alloc  ***
516      !!
517      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
518      !!
519      !! ** Method  :
520      !!----------------------------------------------------------------------
521      USE diawri    , ONLY : dia_wri_alloc
522      USE dom_oce   , ONLY : dom_oce_alloc
523      USE bdy_oce   , ONLY : ln_bdy, bdy_oce_alloc
524      USE oce       ! mandatory for sea-ice because needed for bdy arrays
525      !
526      INTEGER :: ierr
527      !!----------------------------------------------------------------------
528      !
529      ierr =        dia_wri_alloc()
530      ierr = ierr + dom_oce_alloc()          ! ocean domain
531      ierr = ierr + oce_alloc    ()          ! (tsn...) needed for agrif and/or SI3 and bdy
532      ierr = ierr + bdy_oce_alloc()          ! bdy masks (incl. initialization)
533      !
534      CALL mpp_sum( 'nemogcm', ierr )
535      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
536      !
537   END SUBROUTINE nemo_alloc
538
539   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
540      !!----------------------------------------------------------------------
541      !!                     ***  ROUTINE nemo_set_cfctl  ***
542      !!
543      !! ** Purpose :   Set elements of the output control structure to setto.
544      !!                for_all should be .false. unless all areas are to be
545      !!                treated identically.
546      !!
547      !! ** Method  :   Note this routine can be used to switch on/off some
548      !!                types of output for selected areas but any output types
549      !!                that involve global communications (e.g. mpp_max, glob_sum)
550      !!                should be protected from selective switching by the
551      !!                for_all argument
552      !!----------------------------------------------------------------------
553      LOGICAL :: setto, for_all
554      TYPE(sn_ctl) :: sn_cfctl
555      !!----------------------------------------------------------------------
556      IF( for_all ) THEN
557         sn_cfctl%l_runstat = setto
558         sn_cfctl%l_trcstat = setto
559      ENDIF
560      sn_cfctl%l_oceout  = setto
561      sn_cfctl%l_layout  = setto
562      sn_cfctl%l_mppout  = setto
563      sn_cfctl%l_mpptop  = setto
564   END SUBROUTINE nemo_set_cfctl
565
566   !!======================================================================
567END MODULE nemogcm
568
Note: See TracBrowser for help on using the repository browser.