New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in NEMO/branches/2020/KERNEL-03_Storkey_Coward_RK3_stage2/tests/ISOMIP+/MY_SRC – NEMO

source: NEMO/branches/2020/KERNEL-03_Storkey_Coward_RK3_stage2/tests/ISOMIP+/MY_SRC/sbcfwb.F90 @ 12406

Last change on this file since 12406 was 12406, checked in by davestorkey, 4 years ago
  1. Rename the namelist timestep parameter: rn_rdt -> rn_Dt
  2. Use the namelist parameter instead of the non-DOCTOR parameter: rdt -> rn_Dt

This version has same SETTE results as the last version. Passes all tests but some
tests don't bit compare with the trunk.

File size: 14.2 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!            3.6  ! 2014-11  (P. Mathiot  ) add ice shelf melting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_fwb       : freshwater budget for global ocean configurations (free surface & forced mode)
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE sbc_oce        ! surface ocean boundary condition
19   USE isf_oce        ! ice shelf melting contribution
20   USE sbc_ice , ONLY : snwice_mass, snwice_mass_b, snwice_fmass
21   USE phycst         ! physical constants
22   USE sbcrnf         ! ocean runoffs
23   USE sbcssr         ! Sea-Surface damping terms
24   !
25   USE in_out_manager ! I/O manager
26   USE lib_mpp        ! distribued memory computing library
27   USE timing         ! Timing
28   USE lbclnk         ! ocean lateral boundary conditions
29   USE lib_fortran    !
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   sbc_fwb    ! routine called by step
35
36   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
37   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
38   REAL(wp) ::   fwfold    ! fwfold to be suppressed
39   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
40
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id: sbcfwb.F90 11395 2019-08-02 14:19:00Z mathiot $
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc, Kmm )
49      !!---------------------------------------------------------------------
50      !!                  ***  ROUTINE sbc_fwb  ***
51      !!
52      !! ** Purpose :   Control the mean sea surface drift
53      !!
54      !! ** Method  :   several ways  depending on kn_fwb
55      !!                =0 no control
56      !!                =1 global mean of emp set to zero at each nn_fsbc time step
57      !!                =2 annual global mean corrected from previous year
58      !!                =3 global mean of emp set to zero at each nn_fsbc time step
59      !!                   & spread out over erp area depending its sign
60      !! Note: if sea ice is embedded it is taken into account when computing the budget
61      !!----------------------------------------------------------------------
62      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
63      INTEGER, INTENT( in ) ::   kn_fsbc  !
64      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
65      INTEGER, INTENT( in ) ::   Kmm      ! ocean time level index
66      !
67      INTEGER  ::   inum, ikty, iyear     ! local integers
68      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
69      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
70      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
71      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
72      REAL(wp)   ,DIMENSION(1) ::   z_fwfprv 
73      COMPLEX(wp),DIMENSION(1) ::   y_fwfnow 
74      !!----------------------------------------------------------------------
75      !
76      IF( kt == nit000 ) THEN
77         IF(lwp) THEN
78            WRITE(numout,*)
79            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
80            WRITE(numout,*) '~~~~~~~'
81            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
82            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
83            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
84            IF( kn_fwb == 4 )   WRITE(numout,*) '          instantaneously set to zero with heat and salt flux correction (ISOMIP+)'
85         ENDIF
86         !
87         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
88         IF( kn_fwb == 3 .AND. ln_isfcav    )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' )
89         !
90         area = glob_sum( 'sbcfwb', e1e2t(:,:) * tmask(:,:,1))           ! interior global domain surface
91         ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes
92         ! and in case of no melt, it can generate HSSW.
93         !
94#if ! defined key_si3 && ! defined key_cice
95         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
96         snwice_mass  (:,:) = 0.e0
97#endif
98         !
99      ENDIF
100
101      SELECT CASE ( kn_fwb )
102      !
103      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
104         !
105         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
106            y_fwfnow(1) = local_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) )
107            CALL mpp_delay_sum( 'sbcfwb', 'fwb', y_fwfnow(:), z_fwfprv(:), kt == nitend - nn_fsbc + 1 )
108            z_fwfprv(1) = z_fwfprv(1) / area
109            zcoef = z_fwfprv(1) * rcp
110            emp(:,:) = emp(:,:) - z_fwfprv(1)        * tmask(:,:,1)
111            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
112         ENDIF
113         !
114      CASE ( 4 )                             !==  global mean fwf set to zero (ISOMIP case) ==!
115         !
116         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
117            z_fwf = glob_sum( 'sbcfwb',  e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) )
118            !
119            ! correction for ice sheet coupling testing (ie remove the excess through the surface)
120            ! test impact on the melt as conservation correction made in depth
121            ! test conservation level as sbcfwb is conserving
122            ! avoid the model to blow up for large ssh drop (isomip OCEAN3 with melt switch off and uniform T/S)
123            IF (ln_isfcpl .AND. ln_isfcpl_cons) THEN
124               z_fwf = z_fwf + glob_sum( 'sbcfwb',  e1e2t(:,:) * risfcpl_cons_ssh(:,:) * rau0 )
125            END IF
126            !
127            z_fwf = z_fwf / area
128            zcoef = z_fwf * rcp
129            emp(:,:) = emp(:,:) - z_fwf              * tmask(:,:,1) ! (Eq. 34 AD2015)
130            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! (Eq. 35 AD2015) ! use sst_m to avoid generation of any bouyancy fluxes
131            sfx(:,:) = sfx(:,:) + z_fwf * sss_m(:,:) * tmask(:,:,1) ! (Eq. 36 AD2015) ! use sss_m to avoid generation of any bouyancy fluxes
132            !qns(:,:) = qns(:,:) + zcoef * ( -1.9 ) * tmask(:,:,1) ! (Eq. 35 AD2015) ! could be sst_m if we don't want any bouyancy fluxes
133            !sfx(:,:) = sfx(:,:) + z_fwf * ( 33.8 ) * tmask(:,:,1) ! (Eq. 36 AD2015) ! could be sss_m if we don't want any bouyancy fluxes
134            !qns(:,:) = qns(:,:) + zcoef * ( -1.0 ) * tmask(:,:,1) ! use for ISOMIP+ coupling sanity check (keep ssh cst while playing with cpl conservation option)
135            !sfx(:,:) = sfx(:,:) + z_fwf * ( 34.2 ) * tmask(:,:,1) ! use for ISOMIP+ coupling sanity check (keep ssh cst while playing with cpl conservation option)
136         ENDIF
137         !
138      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
139         !
140         IF( kt == nit000 ) THEN                      ! initialisation
141            !                                         ! Read the corrective factor on precipitations (fwfold)
142            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
143            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
144            CLOSE( inum )
145            fwfold = a_fwb                            ! current year freshwater budget correction
146            !                                         ! estimate from the previous year budget
147            IF(lwp)WRITE(numout,*)
148            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
149            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
150            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
151         ENDIF   
152         !                                         ! Update fwfold if new year start
153         ikty = 365 * 86400 / rn_Dt               !!bug  use of 365 days leap year or 360d year !!!!!!!
154         IF( MOD( kt, ikty ) == 0 ) THEN
155            a_fwb_b = a_fwb                           ! mean sea level taking into account the ice+snow
156                                                      ! sum over the global domain
157            a_fwb   = glob_sum( 'sbcfwb', e1e2t(:,:) * ( ssh(:,:,Kmm) + snwice_mass(:,:) * r1_rau0 ) )
158            a_fwb   = a_fwb * 1.e+3 / ( area * rday * 365. )     ! convert in Kg/m3/s = mm/s
159!!gm        !                                                      !!bug 365d year
160            fwfold =  a_fwb                           ! current year freshwater budget correction
161            !                                         ! estimate from the previous year budget
162         ENDIF
163         !
164         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes
165            zcoef = fwfold * rcp
166            emp(:,:) = emp(:,:) + fwfold             * tmask(:,:,1)
167            qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
168         ENDIF
169         !
170         IF( kt == nitend .AND. lwm ) THEN            ! save fwfold value in a file (only one required)
171            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
172            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
173            CLOSE( inum )
174         ENDIF
175         !
176      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
177         !
178         ALLOCATE( ztmsk_neg(jpi,jpj) , ztmsk_pos(jpi,jpj) , ztmsk_tospread(jpi,jpj) , z_wgt(jpi,jpj) , zerp_cor(jpi,jpj) )
179         !
180         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
181            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
182            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
183            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
184            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
185            z_fwf     = glob_sum( 'sbcfwb', e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) ) / area
186            !           
187            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
188               zsurf_pos = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_pos(:,:) )
189               zsurf_tospread      = zsurf_pos
190               ztmsk_tospread(:,:) = ztmsk_pos(:,:)
191            ELSE                             ! spread out over <0 erp area to increase precipitation
192               zsurf_neg = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
193               zsurf_tospread      = zsurf_neg
194               ztmsk_tospread(:,:) = ztmsk_neg(:,:)
195            ENDIF
196            !
197            zsum_fwf   = glob_sum( 'sbcfwb', e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
198!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
199            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
200            !                                                  ! weight to respect erp field 2D structure
201            zsum_erp   = glob_sum( 'sbcfwb', ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
202            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
203            !                                                  ! final correction term to apply
204            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
205            !
206!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
207            CALL lbc_lnk( 'sbcfwb', zerp_cor, 'T', 1. )
208            !
209            emp(:,:) = emp(:,:) + zerp_cor(:,:)
210            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
211            erp(:,:) = erp(:,:) + zerp_cor(:,:)
212            !
213            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
214               IF( z_fwf < 0._wp ) THEN
215                  WRITE(numout,*)'   z_fwf < 0'
216                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
217               ELSE
218                  WRITE(numout,*)'   z_fwf >= 0'
219                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
220               ENDIF
221               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
222               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
223               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
224               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
225               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
226            ENDIF
227         ENDIF
228         DEALLOCATE( ztmsk_neg , ztmsk_pos , ztmsk_tospread , z_wgt , zerp_cor )
229         !
230      CASE DEFAULT                           !==  you should never be there  ==!
231         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
232         !
233      END SELECT
234      !
235   END SUBROUTINE sbc_fwb
236
237   !!======================================================================
238END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.