New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in NEMO/branches/2020/dev_12905_xios_restart/src/OCE/IOM – NEMO

source: NEMO/branches/2020/dev_12905_xios_restart/src/OCE/IOM/restart.F90 @ 12957

Last change on this file since 12957 was 12957, checked in by andmirek, 4 years ago

Ticket #2462: write/read SI3 restart with XIOS (has debug print statements)
  • Property svn:keywords set to Id
File size: 15.6 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_si3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diu_bulk
30   USE lib_mpp         ! distribued memory computing library
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   rst_opn         ! routine called by step module
36   PUBLIC   rst_write       ! routine called by step module
37   PUBLIC   rst_read        ! routine called by istate module
38   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
39
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE rst_opn( kt )
48      !!---------------------------------------------------------------------
49      !!                   ***  ROUTINE rst_opn  ***
50      !!                     
51      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
52      !!              + open the restart when we are one time step before nitrst
53      !!                   - restart header is defined when kt = nitrst-1
54      !!                   - restart data  are written when kt = nitrst
55      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
56      !!----------------------------------------------------------------------
57      INTEGER, INTENT(in) ::   kt     ! ocean time-step
58      !!
59      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
60      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
61      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
62      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
63      CHARACTER(LEN=256)  ::   clinfo    ! info character
64      !!----------------------------------------------------------------------
65      !
66      IF( kt == nit000 ) THEN   ! default definitions
67         lrst_oce = .FALSE.   
68         IF( ln_rst_list ) THEN
69            nrst_lst = 1
70            nitrst = nn_stocklist( nrst_lst )
71         ELSE
72            nitrst = nitend
73         ENDIF
74      ENDIF
75     
76      IF( .NOT. ln_rst_list .AND. nn_stock == -1 )   RETURN   ! we will never do any restart
77
78      ! frequency-based restart dumping (nn_stock)
79      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nn_stock ) == 0 ) THEN   
80         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
81         nitrst = kt + nn_stock - 1                  ! define the next value of nitrst for restart writing
82         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
83      ENDIF
84      ! to get better performances with NetCDF format:
85      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
86      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
87      IF( kt == nitrst - 1 .OR. nn_stock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
88         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
89            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
90            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
91            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
92            ENDIF
93            ! create the file
94            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
95            clpath = TRIM(cn_ocerst_outdir)
96            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
97            IF(lwp) THEN
98               WRITE(numout,*)
99               IF(.NOT.lwxios) THEN
100                  WRITE(numout,*) '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
101                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
102                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
103                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
104                  ENDIF
105               ENDIF
106            ENDIF
107            !
108            IF(.NOT.lwxios) THEN
109               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE. )
110            ELSE
111#if defined key_iomput
112               cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
113               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
114                  clpname = clname
115               ELSE
116                  clpname = TRIM(Agrif_CFixed())//"_"//clname   
117               ENDIF
118               CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname), .false., ld_closedef = .FALSE. )
119               CALL iom_swap(      cxios_context          )
120#else
121               clinfo = 'Can not use XIOS in rst_opn'
122               CALL ctl_stop(TRIM(clinfo))
123#endif
124            ENDIF
125            lrst_oce = .TRUE.
126         ENDIF
127      ENDIF
128      !
129   END SUBROUTINE rst_opn
130
131
132   SUBROUTINE rst_write( kt, Kbb, Kmm )
133      !!---------------------------------------------------------------------
134      !!                   ***  ROUTINE rstwrite  ***
135      !!                     
136      !! ** Purpose :   Write restart fields in NetCDF format
137      !!
138      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
139      !!              file, save fields which are necessary for restart
140      !!----------------------------------------------------------------------
141      INTEGER, INTENT(in) ::   kt         ! ocean time-step
142      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
143      !!----------------------------------------------------------------------
144                     IF(lwxios) CALL iom_swap(      cwxios_context          )
145                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rn_Dt       , ldxios = lwxios)   ! dynamics time step
146                     CALL iom_delay_rst( 'WRITE', 'OCE', numrow )   ! save only ocean delayed global communication variables
147
148      IF ( .NOT. ln_diurnal_only ) THEN
149                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , uu(:,:,:       ,Kbb), ldxios = lwxios        )     ! before fields
150                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vv(:,:,:       ,Kbb), ldxios = lwxios        )
151                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , ts(:,:,:,jp_tem,Kbb), ldxios = lwxios )
152                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , ts(:,:,:,jp_sal,Kbb), ldxios = lwxios )
153                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   ,ssh(:,:         ,Kbb), ldxios = lwxios      )
154                     !
155                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , uu(:,:,:       ,Kmm), ldxios = lwxios        )     ! now fields
156                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vv(:,:,:       ,Kmm), ldxios = lwxios        )
157                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , ts(:,:,:,jp_tem,Kmm), ldxios = lwxios )
158                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , ts(:,:,:,jp_sal,Kmm), ldxios = lwxios )
159                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   ,ssh(:,:         ,Kmm), ldxios = lwxios      )
160                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop, ldxios = lwxios      )
161      ENDIF
162     
163      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, ldxios = lwxios ) 
164      IF(lwxios) CALL iom_swap(      cxios_context          )
165      IF( kt == nitrst ) THEN
166         IF(.NOT.lwxios) THEN
167            CALL iom_close( numrow )     ! close the restart file (only at last time step)
168         ELSE
169            CALL iom_context_finalize(      cwxios_context          )
170         ENDIF
171!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
172!!gm  not sure what to do here   ===>>>  ask to Sebastian
173         lrst_oce = .FALSE.
174            IF( ln_rst_list ) THEN
175               nrst_lst = MIN(nrst_lst + 1, SIZE(nn_stocklist,1))
176               nitrst = nn_stocklist( nrst_lst )
177            ENDIF
178      ENDIF
179      !
180   END SUBROUTINE rst_write
181
182
183   SUBROUTINE rst_read_open
184      !!----------------------------------------------------------------------
185      !!                   ***  ROUTINE rst_read_open  ***
186      !!
187      !! ** Purpose :   Open read files for NetCDF restart
188      !!
189      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
190      !!                the file has already been opened
191      !!----------------------------------------------------------------------
192      LOGICAL         ::   llok
193      CHARACTER(lc)   ::   clpath   ! full path to ocean output restart file
194      CHARACTER(lc+2) ::   clpname  ! file name including agrif prefix
195      !!----------------------------------------------------------------------
196      !
197      IF( numror <= 0 ) THEN
198         IF(lwp) THEN                                             ! Contol prints
199            WRITE(numout,*)
200            WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
201            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
202            WRITE(numout,*) '~~~~~~~~'
203         ENDIF
204         lxios_sini = .FALSE.
205         clpath = TRIM(cn_ocerst_indir)
206         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
207         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror )
208! are we using XIOS to read the data? Part above will have to modified once XIOS
209! can handle checking if variable is in the restart file (there will be no need to open
210! restart)
211         IF(.NOT.lxios_set) lrxios = lrxios.AND.lxios_sini
212
213         IF( lrxios) THEN
214             crxios_context = 'oce_rst'
215             IF( .NOT.lxios_set ) THEN
216                 IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
217                 IF( TRIM(Agrif_CFixed()) == '0' ) THEN
218                    clpname = cn_ocerst_in
219                 ELSE
220                    clpname = TRIM(Agrif_CFixed())//"_"//cn_ocerst_in   
221                 ENDIF
222                 CALL iom_init( crxios_context, fname = TRIM(clpath)//TRIM(clpname), ld_tmppatch = .TRUE. )
223                 lxios_set = .TRUE.
224             ENDIF
225         ENDIF
226
227      ENDIF
228
229   END SUBROUTINE rst_read_open
230
231
232   SUBROUTINE rst_read( Kbb, Kmm )
233      !!----------------------------------------------------------------------
234      !!                   ***  ROUTINE rst_read  ***
235      !!
236      !! ** Purpose :   Read files for NetCDF restart
237      !!
238      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
239      !!----------------------------------------------------------------------
240      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
241      REAL(wp) ::   zrdt
242      INTEGER  ::   jk
243      REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
244      !!----------------------------------------------------------------------
245
246      CALL rst_read_open           ! open restart for reading (if not already opened)
247
248      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
249      IF( lrxios ) CALL iom_swap( TRIM(crxios_context) )
250      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
251         CALL iom_get( numror, 'rdt', zrdt, ldxios = lrxios )
252         IF( zrdt /= rn_Dt ) THEN
253            IF(lwp) WRITE( numout,*)
254            IF(lwp) WRITE( numout,*) 'rst_read:  rdt not equal to the read one'
255            IF(lwp) WRITE( numout,*)
256            IF(lwp) WRITE( numout,*) '      ==>>>   forced euler first time-step'
257            l_1st_euler =  .TRUE.
258         ENDIF
259      ENDIF
260
261      CALL iom_delay_rst( 'READ', 'OCE', numror )   ! read only ocean delayed global communication variables
262     
263      ! Diurnal DSST
264      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst, ldxios = lrxios ) 
265      IF ( ln_diurnal_only ) THEN
266         IF(lwp) WRITE( numout, * ) &
267         &   "rst_read:- ln_diurnal_only set, setting rhop=rho0" 
268         rhop = rho0
269         CALL iom_get( numror, jpdom_autoglo, 'tn'     , w3d, ldxios = lrxios ) 
270         ts(:,:,1,jp_tem,Kmm) = w3d(:,:,1)
271         RETURN
272      ENDIF 
273
274      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
275         CALL iom_get( numror, jpdom_autoglo, 'ub'     , uu(:,:,:       ,Kbb), ldxios = lrxios )   ! before fields
276         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vv(:,:,:       ,Kbb), ldxios = lrxios )
277         CALL iom_get( numror, jpdom_autoglo, 'tb'     , ts(:,:,:,jp_tem,Kbb), ldxios = lrxios )
278         CALL iom_get( numror, jpdom_autoglo, 'sb'     , ts(:,:,:,jp_sal,Kbb), ldxios = lrxios )
279         CALL iom_get( numror, jpdom_autoglo, 'sshb'   ,ssh(:,:         ,Kbb), ldxios = lrxios )
280      ELSE
281         l_1st_euler =  .TRUE.      ! before field not found, forced euler 1st time-step
282      ENDIF
283      !
284      CALL iom_get( numror, jpdom_autoglo, 'un'     , uu(:,:,:       ,Kmm), ldxios = lrxios )       ! now    fields
285      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vv(:,:,:       ,Kmm), ldxios = lrxios )
286      CALL iom_get( numror, jpdom_autoglo, 'tn'     , ts(:,:,:,jp_tem,Kmm), ldxios = lrxios )
287      CALL iom_get( numror, jpdom_autoglo, 'sn'     , ts(:,:,:,jp_sal,Kmm), ldxios = lrxios )
288      CALL iom_get( numror, jpdom_autoglo, 'sshn'   ,ssh(:,:         ,Kmm), ldxios = lrxios )
289      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
290         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop, ldxios = lrxios )   ! now    potential density
291      ELSE
292         CALL eos( ts(:,:,:,:,Kmm), rhd, rhop, gdept(:,:,:,Kmm) )   
293      ENDIF
294      IF( lrxios ) CALL iom_swap( TRIM(cxios_context) )
295      !
296      IF( l_1st_euler ) THEN                                  ! Euler restart
297         ts   (:,:,:,:,Kbb) = ts   (:,:,:,:,Kmm)              ! all before fields set to now values
298         uu   (:,:,:  ,Kbb) = uu   (:,:,:  ,Kmm)
299         vv   (:,:,:  ,Kbb) = vv   (:,:,:  ,Kmm)
300         ssh  (:,:    ,Kbb) = ssh  (:,:    ,Kmm)
301         !
302         IF( .NOT.ln_linssh ) THEN
303            DO jk = 1, jpk
304               e3t(:,:,jk,Kbb) = e3t(:,:,jk,Kmm)
305            END DO
306         ENDIF
307         !
308      ENDIF
309      !
310   END SUBROUTINE rst_read
311
312   !!=====================================================================
313END MODULE restart
Note: See TracBrowser for help on using the repository browser.