source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/DYN/dynatf.F90 @ 12680

Last change on this file since 12680 was 12680, checked in by techene, 8 months ago

dynatfQCO.F90, stepLF.F90 : fixed (remove pe3. from dyn_atf_qco input arguments), all : remove e3. tables and include gurvan's feedbacks

  • Property svn:keywords set to Id
File size: 18.0 KB
Line 
1MODULE dynatf
2   !!=========================================================================
3   !!                       ***  MODULE  dynatf  ***
4   !! Ocean dynamics: time filtering
5   !!=========================================================================
6   !! History :  OPA  !  1987-02  (P. Andrich, D. L Hostis)  Original code
7   !!                 !  1990-10  (C. Levy, G. Madec)
8   !!            7.0  !  1993-03  (M. Guyon)  symetrical conditions
9   !!            8.0  !  1997-02  (G. Madec & M. Imbard)  opa, release 8.0
10   !!            8.2  !  1997-04  (A. Weaver)  Euler forward step
11   !!             -   !  1997-06  (G. Madec)  lateral boudary cond., lbc routine
12   !!    NEMO    1.0  !  2002-08  (G. Madec)  F90: Free form and module
13   !!             -   !  2002-10  (C. Talandier, A-M. Treguier) Open boundary cond.
14   !!            2.0  !  2005-11  (V. Garnier) Surface pressure gradient organization
15   !!            2.3  !  2007-07  (D. Storkey) Calls to BDY routines.
16   !!            3.2  !  2009-06  (G. Madec, R.Benshila)  re-introduce the vvl option
17   !!            3.3  !  2010-09  (D. Storkey, E.O'Dea) Bug fix for BDY module
18   !!            3.3  !  2011-03  (P. Oddo) Bug fix for time-splitting+(BDY-OBC) and not VVL
19   !!            3.5  !  2013-07  (J. Chanut) Compliant with time splitting changes
20   !!            3.6  !  2014-04  (G. Madec) add the diagnostic of the time filter trends
21   !!            3.7  !  2015-11  (J. Chanut) Free surface simplification
22   !!            4.1  !  2019-08  (A. Coward, D. Storkey) Rename dynnxt.F90 -> dynatf.F90. Now just does time filtering.
23   !!-------------------------------------------------------------------------
24
25   !!----------------------------------------------------------------------------------------------
26   !!   dyn_atf       : apply Asselin time filtering to "now" velocities and vertical scale factors
27   !!----------------------------------------------------------------------------------------------
28   USE oce            ! ocean dynamics and tracers
29   USE dom_oce        ! ocean space and time domain
30   USE sbc_oce        ! Surface boundary condition: ocean fields
31   USE sbcrnf         ! river runoffs
32   USE phycst         ! physical constants
33   USE dynadv         ! dynamics: vector invariant versus flux form
34   USE dynspg_ts      ! surface pressure gradient: split-explicit scheme
35   USE domvvl         ! variable volume
36   USE bdy_oce   , ONLY: ln_bdy
37   USE bdydta         ! ocean open boundary conditions
38   USE bdydyn         ! ocean open boundary conditions
39   USE bdyvol         ! ocean open boundary condition (bdy_vol routines)
40   USE trd_oce        ! trends: ocean variables
41   USE trddyn         ! trend manager: dynamics
42   USE trdken         ! trend manager: kinetic energy
43   USE isf_oce   , ONLY: ln_isf     ! ice shelf
44   USE isfdynatf , ONLY: isf_dynatf ! ice shelf volume filter correction subroutine
45   !
46   USE in_out_manager ! I/O manager
47   USE iom            ! I/O manager library
48   USE lbclnk         ! lateral boundary condition (or mpp link)
49   USE lib_mpp        ! MPP library
50   USE prtctl         ! Print control
51   USE timing         ! Timing
52#if defined key_agrif
53   USE agrif_oce_interp
54#endif
55
56   IMPLICIT NONE
57   PRIVATE
58
59   PUBLIC    dyn_atf   ! routine called by step.F90
60
61#if defined key_qco
62   !!----------------------------------------------------------------------
63   !!   'key_qco'      EMPTY ROUTINE     Quasi-Eulerian vertical coordonate
64   !!----------------------------------------------------------------------
65CONTAINS
66
67   SUBROUTINE dyn_atf ( kt, Kbb, Kmm, Kaa, puu, pvv, pe3t, pe3u, pe3v )
68      INTEGER                             , INTENT(in   ) :: kt               ! ocean time-step index
69      INTEGER                             , INTENT(in   ) :: Kbb, Kmm, Kaa    ! before and after time level indices
70      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv         ! velocities to be time filtered
71      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: pe3t, pe3u, pe3v ! scale factors to be time filtered
72
73      WRITE(*,*) 'dyn_atf: You should not have seen this print! error?', kt
74   END SUBROUTINE dyn_atf
75
76#else
77
78   !! * Substitutions
79#  include "do_loop_substitute.h90"
80   !!----------------------------------------------------------------------
81   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
82   !! $Id$
83   !! Software governed by the CeCILL license (see ./LICENSE)
84   !!----------------------------------------------------------------------
85CONTAINS
86
87   SUBROUTINE dyn_atf ( kt, Kbb, Kmm, Kaa, puu, pvv, pe3t, pe3u, pe3v )
88      !!----------------------------------------------------------------------
89      !!                  ***  ROUTINE dyn_atf  ***
90      !!
91      !! ** Purpose :   Finalize after horizontal velocity. Apply the boundary
92      !!             condition on the after velocity and apply the Asselin time
93      !!             filter to the now fields.
94      !!
95      !! ** Method  : * Ensure after velocities transport matches time splitting
96      !!             estimate (ln_dynspg_ts=T)
97      !!
98      !!              * Apply lateral boundary conditions on after velocity
99      !!             at the local domain boundaries through lbc_lnk call,
100      !!             at the one-way open boundaries (ln_bdy=T),
101      !!             at the AGRIF zoom   boundaries (lk_agrif=T)
102      !!
103      !!              * Apply the Asselin time filter to the now fields
104      !!             arrays to start the next time step:
105      !!                (puu(Kmm),pvv(Kmm)) = (puu(Kmm),pvv(Kmm))
106      !!                                    + atfp [ (puu(Kbb),pvv(Kbb)) + (puu(Kaa),pvv(Kaa)) - 2 (puu(Kmm),pvv(Kmm)) ]
107      !!             Note that with flux form advection and non linear free surface,
108      !!             the time filter is applied on thickness weighted velocity.
109      !!             As a result, dyn_atf MUST be called after tra_atf.
110      !!
111      !! ** Action :   puu(Kmm),pvv(Kmm)   filtered now horizontal velocity
112      !!----------------------------------------------------------------------
113      INTEGER                             , INTENT(in   ) :: kt               ! ocean time-step index
114      INTEGER                             , INTENT(in   ) :: Kbb, Kmm, Kaa    ! before and after time level indices
115      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv         ! velocities to be time filtered
116      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: pe3t, pe3u, pe3v ! scale factors to be time filtered
117      !
118      INTEGER  ::   ji, jj, jk   ! dummy loop indices
119      REAL(wp) ::   zue3a, zue3n, zue3b, zcoef    ! local scalars
120      REAL(wp) ::   zve3a, zve3n, zve3b, z1_2dt   !   -      -
121      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   zue, zve, zwfld
122      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ze3t_f, ze3u_f, ze3v_f, zua, zva
123      !!----------------------------------------------------------------------
124      !
125      IF( ln_timing    )   CALL timing_start('dyn_atf')
126      IF( ln_dynspg_ts )   ALLOCATE( zue(jpi,jpj)     , zve(jpi,jpj)     )
127      IF( l_trddyn     )   ALLOCATE( zua(jpi,jpj,jpk) , zva(jpi,jpj,jpk) )
128      !
129      IF( kt == nit000 ) THEN
130         IF(lwp) WRITE(numout,*)
131         IF(lwp) WRITE(numout,*) 'dyn_atf : Asselin time filtering'
132         IF(lwp) WRITE(numout,*) '~~~~~~~'
133      ENDIF
134
135      IF ( ln_dynspg_ts ) THEN
136         ! Ensure below that barotropic velocities match time splitting estimate
137         ! Compute actual transport and replace it with ts estimate at "after" time step
138         zue(:,:) = pe3u(:,:,1,Kaa) * puu(:,:,1,Kaa) * umask(:,:,1)
139         zve(:,:) = pe3v(:,:,1,Kaa) * pvv(:,:,1,Kaa) * vmask(:,:,1)
140         DO jk = 2, jpkm1
141            zue(:,:) = zue(:,:) + pe3u(:,:,jk,Kaa) * puu(:,:,jk,Kaa) * umask(:,:,jk)
142            zve(:,:) = zve(:,:) + pe3v(:,:,jk,Kaa) * pvv(:,:,jk,Kaa) * vmask(:,:,jk)
143         END DO
144         DO jk = 1, jpkm1
145            puu(:,:,jk,Kaa) = ( puu(:,:,jk,Kaa) - zue(:,:) * r1_hu(:,:,Kaa) + uu_b(:,:,Kaa) ) * umask(:,:,jk)
146            pvv(:,:,jk,Kaa) = ( pvv(:,:,jk,Kaa) - zve(:,:) * r1_hv(:,:,Kaa) + vv_b(:,:,Kaa) ) * vmask(:,:,jk)
147         END DO
148         !
149         IF( .NOT.ln_bt_fw ) THEN
150            ! Remove advective velocity from "now velocities"
151            ! prior to asselin filtering
152            ! In the forward case, this is done below after asselin filtering
153            ! so that asselin contribution is removed at the same time
154            DO jk = 1, jpkm1
155               puu(:,:,jk,Kmm) = ( puu(:,:,jk,Kmm) - un_adv(:,:)*r1_hu(:,:,Kmm) + uu_b(:,:,Kmm) )*umask(:,:,jk)
156               pvv(:,:,jk,Kmm) = ( pvv(:,:,jk,Kmm) - vn_adv(:,:)*r1_hv(:,:,Kmm) + vv_b(:,:,Kmm) )*vmask(:,:,jk)
157            END DO
158         ENDIF
159      ENDIF
160
161      ! Update after velocity on domain lateral boundaries
162      ! --------------------------------------------------
163# if defined key_agrif
164      CALL Agrif_dyn( kt )             !* AGRIF zoom boundaries
165# endif
166      !
167      CALL lbc_lnk_multi( 'dynatf', puu(:,:,:,Kaa), 'U', -1., pvv(:,:,:,Kaa), 'V', -1. )     !* local domain boundaries
168      !
169      !                                !* BDY open boundaries
170      IF( ln_bdy .AND. ln_dynspg_exp )   CALL bdy_dyn( kt, Kbb, puu, pvv, Kaa )
171      IF( ln_bdy .AND. ln_dynspg_ts  )   CALL bdy_dyn( kt, Kbb, puu, pvv, Kaa, dyn3d_only=.true. )
172
173!!$   Do we need a call to bdy_vol here??
174      !
175      IF( l_trddyn ) THEN             ! prepare the atf trend computation + some diagnostics
176         z1_2dt = 1._wp / (2. * rdt)        ! Euler or leap-frog time step
177         IF( neuler == 0 .AND. kt == nit000 )   z1_2dt = 1._wp / rdt
178         !
179         !                                  ! Kinetic energy and Conversion
180         IF( ln_KE_trd  )   CALL trd_dyn( puu(:,:,:,Kaa), pvv(:,:,:,Kaa), jpdyn_ken, kt, Kmm )
181         !
182         IF( ln_dyn_trd ) THEN              ! 3D output: total momentum trends
183            zua(:,:,:) = ( puu(:,:,:,Kaa) - puu(:,:,:,Kbb) ) * z1_2dt
184            zva(:,:,:) = ( pvv(:,:,:,Kaa) - pvv(:,:,:,Kbb) ) * z1_2dt
185            CALL iom_put( "utrd_tot", zua )        ! total momentum trends, except the asselin time filter
186            CALL iom_put( "vtrd_tot", zva )
187         ENDIF
188         !
189         zua(:,:,:) = puu(:,:,:,Kmm)             ! save the now velocity before the asselin filter
190         zva(:,:,:) = pvv(:,:,:,Kmm)             ! (caution: there will be a shift by 1 timestep in the
191         !                                  !  computation of the asselin filter trends)
192      ENDIF
193
194      ! Time filter and swap of dynamics arrays
195      ! ------------------------------------------
196
197      IF( .NOT.( neuler == 0 .AND. kt == nit000 ) ) THEN    !* Leap-Frog : Asselin time filter
198         !                                ! =============!
199         IF( ln_linssh ) THEN             ! Fixed volume !
200            !                             ! =============!
201            DO_3D_11_11( 1, jpkm1 )
202               puu(ji,jj,jk,Kmm) = puu(ji,jj,jk,Kmm) + atfp * ( puu(ji,jj,jk,Kbb) - 2._wp * puu(ji,jj,jk,Kmm) + puu(ji,jj,jk,Kaa) )
203               pvv(ji,jj,jk,Kmm) = pvv(ji,jj,jk,Kmm) + atfp * ( pvv(ji,jj,jk,Kbb) - 2._wp * pvv(ji,jj,jk,Kmm) + pvv(ji,jj,jk,Kaa) )
204            END_3D
205            !                             ! ================!
206         ELSE                             ! Variable volume !
207            !                             ! ================!
208            ! Time-filtered scale factor at t-points
209            ! ----------------------------------------------------
210            ALLOCATE( ze3t_f(jpi,jpj,jpk), zwfld(jpi,jpj) )
211            DO jk = 1, jpkm1
212               ze3t_f(:,:,jk) = pe3t(:,:,jk,Kmm) + atfp * ( pe3t(:,:,jk,Kbb) - 2._wp * pe3t(:,:,jk,Kmm) + pe3t(:,:,jk,Kaa) )
213            END DO
214            ! Add volume filter correction: compatibility with tracer advection scheme
215            ! => time filter + conservation correction
216            zcoef = atfp * rdt * r1_rau0
217            zwfld(:,:) = emp_b(:,:) - emp(:,:)
218            IF ( ln_rnf ) zwfld(:,:) =  zwfld(:,:) - ( rnf_b(:,:) - rnf(:,:) )
219            DO jk = 1, jpkm1
220               ze3t_f(:,:,jk) = ze3t_f(:,:,jk) - zcoef * zwfld(:,:) * tmask(:,:,jk) &
221                              &                        * pe3t(:,:,jk,Kmm) / ( ht(:,:) + 1._wp - ssmask(:,:) )
222            END DO
223            !
224            ! ice shelf melting (deal separately as it can be in depth)
225            ! PM: we could probably define a generic subroutine to do the in depth correction
226            !     to manage rnf, isf and possibly in the futur icb, tide water glacier (...)
227            !     ...(kt, coef, ktop, kbot, hz, fwf_b, fwf)
228            IF ( ln_isf ) CALL isf_dynatf( kt, Kmm, ze3t_f, atfp * rdt )
229            !
230            pe3t(:,:,1:jpkm1,Kmm) = ze3t_f(:,:,1:jpkm1)        ! filtered scale factor at T-points
231            !
232            IF( ln_dynadv_vec ) THEN      ! Asselin filter applied on velocity
233               ! Before filtered scale factor at (u/v)-points
234               CALL dom_vvl_interpol( pe3t(:,:,:,Kmm), pe3u(:,:,:,Kmm), 'U' )
235               CALL dom_vvl_interpol( pe3t(:,:,:,Kmm), pe3v(:,:,:,Kmm), 'V' )
236               DO_3D_11_11( 1, jpkm1 )
237                  puu(ji,jj,jk,Kmm) = puu(ji,jj,jk,Kmm) + atfp * ( puu(ji,jj,jk,Kbb) - 2._wp * puu(ji,jj,jk,Kmm) + puu(ji,jj,jk,Kaa) )
238                  pvv(ji,jj,jk,Kmm) = pvv(ji,jj,jk,Kmm) + atfp * ( pvv(ji,jj,jk,Kbb) - 2._wp * pvv(ji,jj,jk,Kmm) + pvv(ji,jj,jk,Kaa) )
239               END_3D
240               !
241            ELSE                          ! Asselin filter applied on thickness weighted velocity
242               !
243               ALLOCATE( ze3u_f(jpi,jpj,jpk) , ze3v_f(jpi,jpj,jpk) )
244               ! Now filtered scale factor at (u/v)-points stored in ze3u_f, ze3v_f
245               CALL dom_vvl_interpol( pe3t(:,:,:,Kmm), ze3u_f, 'U' )
246               CALL dom_vvl_interpol( pe3t(:,:,:,Kmm), ze3v_f, 'V' )
247               DO_3D_11_11( 1, jpkm1 )
248                  zue3a = pe3u(ji,jj,jk,Kaa) * puu(ji,jj,jk,Kaa)
249                  zve3a = pe3v(ji,jj,jk,Kaa) * pvv(ji,jj,jk,Kaa)
250                  zue3n = pe3u(ji,jj,jk,Kmm) * puu(ji,jj,jk,Kmm)
251                  zve3n = pe3v(ji,jj,jk,Kmm) * pvv(ji,jj,jk,Kmm)
252                  zue3b = pe3u(ji,jj,jk,Kbb) * puu(ji,jj,jk,Kbb)
253                  zve3b = pe3v(ji,jj,jk,Kbb) * pvv(ji,jj,jk,Kbb)
254                  !
255                  puu(ji,jj,jk,Kmm) = ( zue3n + atfp * ( zue3b - 2._wp * zue3n  + zue3a ) ) / ze3u_f(ji,jj,jk)
256                  pvv(ji,jj,jk,Kmm) = ( zve3n + atfp * ( zve3b - 2._wp * zve3n  + zve3a ) ) / ze3v_f(ji,jj,jk)
257               END_3D
258               pe3u(:,:,1:jpkm1,Kmm) = ze3u_f(:,:,1:jpkm1)
259               pe3v(:,:,1:jpkm1,Kmm) = ze3v_f(:,:,1:jpkm1)
260               !
261               DEALLOCATE( ze3u_f , ze3v_f )
262            ENDIF
263            !
264            DEALLOCATE( ze3t_f, zwfld )
265         ENDIF
266         !
267         IF( ln_dynspg_ts .AND. ln_bt_fw ) THEN
268            ! Revert filtered "now" velocities to time split estimate
269            ! Doing it here also means that asselin filter contribution is removed
270            zue(:,:) = pe3u(:,:,1,Kmm) * puu(:,:,1,Kmm) * umask(:,:,1)
271            zve(:,:) = pe3v(:,:,1,Kmm) * pvv(:,:,1,Kmm) * vmask(:,:,1)
272            DO jk = 2, jpkm1
273               zue(:,:) = zue(:,:) + pe3u(:,:,jk,Kmm) * puu(:,:,jk,Kmm) * umask(:,:,jk)
274               zve(:,:) = zve(:,:) + pe3v(:,:,jk,Kmm) * pvv(:,:,jk,Kmm) * vmask(:,:,jk)
275            END DO
276            DO jk = 1, jpkm1
277               puu(:,:,jk,Kmm) = puu(:,:,jk,Kmm) - (zue(:,:) * r1_hu(:,:,Kmm) - uu_b(:,:,Kmm)) * umask(:,:,jk)
278               pvv(:,:,jk,Kmm) = pvv(:,:,jk,Kmm) - (zve(:,:) * r1_hv(:,:,Kmm) - vv_b(:,:,Kmm)) * vmask(:,:,jk)
279            END DO
280         ENDIF
281         !
282      ENDIF ! neuler /= 0
283      !
284      ! Set "now" and "before" barotropic velocities for next time step:
285      ! JC: Would be more clever to swap variables than to make a full vertical
286      ! integration
287      !
288      IF(.NOT.ln_linssh ) THEN
289         hu(:,:,Kmm) = pe3u(:,:,1,Kmm ) * umask(:,:,1)
290         hv(:,:,Kmm) = pe3v(:,:,1,Kmm ) * vmask(:,:,1)
291         DO jk = 2, jpkm1
292            hu(:,:,Kmm) = hu(:,:,Kmm) + pe3u(:,:,jk,Kmm ) * umask(:,:,jk)
293            hv(:,:,Kmm) = hv(:,:,Kmm) + pe3v(:,:,jk,Kmm ) * vmask(:,:,jk)
294         END DO
295         r1_hu(:,:,Kmm) = ssumask(:,:) / ( hu(:,:,Kmm) + 1._wp - ssumask(:,:) )
296         r1_hv(:,:,Kmm) = ssvmask(:,:) / ( hv(:,:,Kmm) + 1._wp - ssvmask(:,:) )
297      ENDIF
298      !
299      uu_b(:,:,Kaa) = pe3u(:,:,1,Kaa) * puu(:,:,1,Kaa) * umask(:,:,1)
300      uu_b(:,:,Kmm) = pe3u(:,:,1,Kmm) * puu(:,:,1,Kmm) * umask(:,:,1)
301      vv_b(:,:,Kaa) = pe3v(:,:,1,Kaa) * pvv(:,:,1,Kaa) * vmask(:,:,1)
302      vv_b(:,:,Kmm) = pe3v(:,:,1,Kmm) * pvv(:,:,1,Kmm) * vmask(:,:,1)
303      DO jk = 2, jpkm1
304         uu_b(:,:,Kaa) = uu_b(:,:,Kaa) + pe3u(:,:,jk,Kaa) * puu(:,:,jk,Kaa) * umask(:,:,jk)
305         uu_b(:,:,Kmm) = uu_b(:,:,Kmm) + pe3u(:,:,jk,Kmm) * puu(:,:,jk,Kmm) * umask(:,:,jk)
306         vv_b(:,:,Kaa) = vv_b(:,:,Kaa) + pe3v(:,:,jk,Kaa) * pvv(:,:,jk,Kaa) * vmask(:,:,jk)
307         vv_b(:,:,Kmm) = vv_b(:,:,Kmm) + pe3v(:,:,jk,Kmm) * pvv(:,:,jk,Kmm) * vmask(:,:,jk)
308      END DO
309      uu_b(:,:,Kaa) = uu_b(:,:,Kaa) * r1_hu(:,:,Kaa)
310      vv_b(:,:,Kaa) = vv_b(:,:,Kaa) * r1_hv(:,:,Kaa)
311      uu_b(:,:,Kmm) = uu_b(:,:,Kmm) * r1_hu(:,:,Kmm)
312      vv_b(:,:,Kmm) = vv_b(:,:,Kmm) * r1_hv(:,:,Kmm)
313      !
314      IF( .NOT.ln_dynspg_ts ) THEN        ! output the barotropic currents
315         CALL iom_put(  "ubar", uu_b(:,:,Kmm) )
316         CALL iom_put(  "vbar", vv_b(:,:,Kmm) )
317      ENDIF
318      IF( l_trddyn ) THEN                ! 3D output: asselin filter trends on momentum
319         zua(:,:,:) = ( puu(:,:,:,Kmm) - zua(:,:,:) ) * z1_2dt
320         zva(:,:,:) = ( pvv(:,:,:,Kmm) - zva(:,:,:) ) * z1_2dt
321         CALL trd_dyn( zua, zva, jpdyn_atf, kt, Kmm )
322      ENDIF
323      !
324      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Kaa), clinfo1=' nxt  - puu(:,:,:,Kaa): ', mask1=umask,   &
325         &                                  tab3d_2=pvv(:,:,:,Kaa), clinfo2=' pvv(:,:,:,Kaa): '       , mask2=vmask )
326      !
327      IF( ln_dynspg_ts )   DEALLOCATE( zue, zve )
328      IF( l_trddyn     )   DEALLOCATE( zua, zva )
329      IF( ln_timing    )   CALL timing_stop('dyn_atf')
330      !
331   END SUBROUTINE dyn_atf
332
333#endif
334
335   !!=========================================================================
336END MODULE dynatf
Note: See TracBrowser for help on using the repository browser.