New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynatfQCO.F90 in NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/DYN – NEMO

source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/DYN/dynatfQCO.F90 @ 12656

Last change on this file since 12656 was 12656, checked in by techene, 4 years ago

change key_QCO into key_qco, stepLF & traatf: add substitute, dynatfQCO: remove pe3 arguments
  • Property svn:keywords set to Id
File size: 14.9 KB
Line 
1MODULE dynatfqco
2   !!=========================================================================
3   !!                       ***  MODULE  dynatfqco  ***
4   !! Ocean dynamics: time filtering
5   !!=========================================================================
6   !! History :  OPA  !  1987-02  (P. Andrich, D. L Hostis)  Original code
7   !!                 !  1990-10  (C. Levy, G. Madec)
8   !!            7.0  !  1993-03  (M. Guyon)  symetrical conditions
9   !!            8.0  !  1997-02  (G. Madec & M. Imbard)  opa, release 8.0
10   !!            8.2  !  1997-04  (A. Weaver)  Euler forward step
11   !!             -   !  1997-06  (G. Madec)  lateral boudary cond., lbc routine
12   !!    NEMO    1.0  !  2002-08  (G. Madec)  F90: Free form and module
13   !!             -   !  2002-10  (C. Talandier, A-M. Treguier) Open boundary cond.
14   !!            2.0  !  2005-11  (V. Garnier) Surface pressure gradient organization
15   !!            2.3  !  2007-07  (D. Storkey) Calls to BDY routines.
16   !!            3.2  !  2009-06  (G. Madec, R.Benshila)  re-introduce the vvl option
17   !!            3.3  !  2010-09  (D. Storkey, E.O'Dea) Bug fix for BDY module
18   !!            3.3  !  2011-03  (P. Oddo) Bug fix for time-splitting+(BDY-OBC) and not VVL
19   !!            3.5  !  2013-07  (J. Chanut) Compliant with time splitting changes
20   !!            3.6  !  2014-04  (G. Madec) add the diagnostic of the time filter trends
21   !!            3.7  !  2015-11  (J. Chanut) Free surface simplification
22   !!            4.1  !  2019-08  (A. Coward, D. Storkey) Rename dynnxt.F90 -> dynatfLF.F90. Now just does time filtering.
23   !!-------------------------------------------------------------------------
24
25   !!----------------------------------------------------------------------------------------------
26   !!   dyn_atf_qco       : apply Asselin time filtering to "now" velocities and vertical scale factors
27   !!----------------------------------------------------------------------------------------------
28   USE oce            ! ocean dynamics and tracers
29   USE dom_oce        ! ocean space and time domain
30   USE sbc_oce        ! Surface boundary condition: ocean fields
31   USE sbcrnf         ! river runoffs
32   USE phycst         ! physical constants
33   USE dynadv         ! dynamics: vector invariant versus flux form
34   USE dynspg_ts      ! surface pressure gradient: split-explicit scheme
35   USE domvvl         ! variable volume
36   USE bdy_oce   , ONLY: ln_bdy
37   USE bdydta         ! ocean open boundary conditions
38   USE bdydyn         ! ocean open boundary conditions
39   USE bdyvol         ! ocean open boundary condition (bdy_vol routines)
40   USE trd_oce        ! trends: ocean variables
41   USE trddyn         ! trend manager: dynamics
42   USE trdken         ! trend manager: kinetic energy
43   USE isf_oce   , ONLY: ln_isf     ! ice shelf
44   USE isfdynatf , ONLY: isf_dynatf ! ice shelf volume filter correction subroutine
45   !
46   USE in_out_manager ! I/O manager
47   USE iom            ! I/O manager library
48   USE lbclnk         ! lateral boundary condition (or mpp link)
49   USE lib_mpp        ! MPP library
50   USE prtctl         ! Print control
51   USE timing         ! Timing
52#if defined key_agrif
53   USE agrif_oce_interp
54#endif
55
56   IMPLICIT NONE
57   PRIVATE
58
59   PUBLIC    dyn_atf_qco   ! routine called by step.F90
60
61   !! * Substitutions
62#  include "do_loop_substitute.h90"
63#  include "domzgr_substitute.h90"
64   !!----------------------------------------------------------------------
65   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
66   !! $Id$
67   !! Software governed by the CeCILL license (see ./LICENSE)
68   !!----------------------------------------------------------------------
69CONTAINS
70
71   SUBROUTINE dyn_atf_qco ( kt, Kbb, Kmm, Kaa, puu, pvv )
72      !!----------------------------------------------------------------------
73      !!                  ***  ROUTINE dyn_atf_qco  ***
74      !!
75      !! ** Purpose :   Finalize after horizontal velocity. Apply the boundary
76      !!             condition on the after velocity and apply the Asselin time
77      !!             filter to the now fields.
78      !!
79      !! ** Method  : * Ensure after velocities transport matches time splitting
80      !!             estimate (ln_dynspg_ts=T)
81      !!
82      !!              * Apply lateral boundary conditions on after velocity
83      !!             at the local domain boundaries through lbc_lnk call,
84      !!             at the one-way open boundaries (ln_bdy=T),
85      !!             at the AGRIF zoom   boundaries (lk_agrif=T)
86      !!
87      !!              * Apply the Asselin time filter to the now fields
88      !!             arrays to start the next time step:
89      !!                (puu(Kmm),pvv(Kmm)) = (puu(Kmm),pvv(Kmm))
90      !!                                    + atfp [ (puu(Kbb),pvv(Kbb)) + (puu(Kaa),pvv(Kaa)) - 2 (puu(Kmm),pvv(Kmm)) ]
91      !!             Note that with flux form advection and non linear free surface,
92      !!             the time filter is applied on thickness weighted velocity.
93      !!             As a result, dyn_atf_lf MUST be called after tra_atf.
94      !!
95      !! ** Action :   puu(Kmm),pvv(Kmm)   filtered now horizontal velocity
96      !!----------------------------------------------------------------------
97      INTEGER                             , INTENT(in   ) :: kt               ! ocean time-step index
98      INTEGER                             , INTENT(in   ) :: Kbb, Kmm, Kaa    ! before and after time level indices
99      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv         ! velocities to be time filtered
100      !
101      INTEGER  ::   ji, jj, jk   ! dummy loop indices
102      REAL(wp) ::   zue3a, zue3n, zue3b, zcoef    ! local scalars
103      REAL(wp) ::   zve3a, zve3n, zve3b, z1_2dt   !   -      -
104      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   zue, zve
105      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zua, zva
106      !!----------------------------------------------------------------------
107      !
108      IF( ln_timing    )   CALL timing_start('dyn_atf_qco')
109      IF( ln_dynspg_ts )   ALLOCATE( zue(jpi,jpj)     , zve(jpi,jpj)     )
110      IF( l_trddyn     )   ALLOCATE( zua(jpi,jpj,jpk) , zva(jpi,jpj,jpk) )
111      !
112      IF( kt == nit000 ) THEN
113         IF(lwp) WRITE(numout,*)
114         IF(lwp) WRITE(numout,*) 'dyn_atf_qco : Asselin time filtering'
115         IF(lwp) WRITE(numout,*) '~~~~~~~'
116      ENDIF
117      !
118      IF( l_trddyn ) THEN             ! prepare the atf trend computation + some diagnostics
119         z1_2dt = 1._wp / (2. * rdt)        ! Euler or leap-frog time step
120         IF( neuler == 0 .AND. kt == nit000 )   z1_2dt = 1._wp / rdt
121         !
122         !                                  ! Kinetic energy and Conversion
123         IF( ln_KE_trd  )   CALL trd_dyn( puu(:,:,:,Kaa), pvv(:,:,:,Kaa), jpdyn_ken, kt, Kmm )
124         !
125         IF( ln_dyn_trd ) THEN              ! 3D output: total momentum trends
126            zua(:,:,:) = ( puu(:,:,:,Kaa) - puu(:,:,:,Kbb) ) * z1_2dt
127            zva(:,:,:) = ( pvv(:,:,:,Kaa) - pvv(:,:,:,Kbb) ) * z1_2dt
128            CALL iom_put( "utrd_tot", zua )        ! total momentum trends, except the asselin time filter
129            CALL iom_put( "vtrd_tot", zva )
130         ENDIF
131         !
132         zua(:,:,:) = puu(:,:,:,Kmm)             ! save the now velocity before the asselin filter
133         zva(:,:,:) = pvv(:,:,:,Kmm)             ! (caution: there will be a shift by 1 timestep in the
134         !                                  !  computation of the asselin filter trends)
135      ENDIF
136
137      ! Time filter and swap of dynamics arrays
138      ! ------------------------------------------
139
140      IF( .NOT.( neuler == 0 .AND. kt == nit000 ) ) THEN    !* Leap-Frog : Asselin time filter
141         !                                ! =============!
142         IF( ln_linssh ) THEN             ! Fixed volume !
143            !                             ! =============!
144            DO_3D_11_11( 1, jpkm1 )
145               puu(ji,jj,jk,Kmm) = puu(ji,jj,jk,Kmm) + atfp * ( puu(ji,jj,jk,Kbb) - 2._wp * puu(ji,jj,jk,Kmm) + puu(ji,jj,jk,Kaa) )
146               pvv(ji,jj,jk,Kmm) = pvv(ji,jj,jk,Kmm) + atfp * ( pvv(ji,jj,jk,Kbb) - 2._wp * pvv(ji,jj,jk,Kmm) + pvv(ji,jj,jk,Kaa) )
147            END_3D
148            !                             ! ================!
149         ELSE                             ! Variable volume !
150            !                             ! ================!
151            ! Time-filtered scale factor at t-points
152            ! ----------------------------------------------------
153            ! DO jk = 1, jpk                                          ! filtered scale factor at T-points
154            !    pe3t(:,:,jk,Kmm) = e3t_0(:,:,jk) * ( 1._wp + r3t_f(:,:) * tmask(:,:,jk) )
155            ! END DO
156            !
157            !
158            IF( ln_dynadv_vec ) THEN      ! Asselin filter applied on velocity
159               ! Before filtered scale factor at (u/v)-points
160               ! DO jk = 1, jpk
161               !    pe3u(:,:,jk,Kmm) = e3u_0(:,:,jk) * ( 1._wp + r3u_f(:,:) * umask(:,:,jk) )
162               !    pe3v(:,:,jk,Kmm) = e3v_0(:,:,jk) * ( 1._wp + r3v_f(:,:) * vmask(:,:,jk) )
163               ! END DO
164               !
165               DO_3D_11_11( 1, jpkm1 )
166                  puu(ji,jj,jk,Kmm) = puu(ji,jj,jk,Kmm) + atfp * ( puu(ji,jj,jk,Kbb) - 2._wp * puu(ji,jj,jk,Kmm) + puu(ji,jj,jk,Kaa) )
167                  pvv(ji,jj,jk,Kmm) = pvv(ji,jj,jk,Kmm) + atfp * ( pvv(ji,jj,jk,Kbb) - 2._wp * pvv(ji,jj,jk,Kmm) + pvv(ji,jj,jk,Kaa) )
168               END_3D
169               !
170            ELSE                          ! Asselin filter applied on thickness weighted velocity
171               !
172               DO_3D_11_11( 1, jpkm1 )
173                  ! zue3a = pe3u(ji,jj,jk,Kaa) * puu(ji,jj,jk,Kaa)
174                  ! zve3a = pe3v(ji,jj,jk,Kaa) * pvv(ji,jj,jk,Kaa)
175                  ! zue3n = pe3u(ji,jj,jk,Kmm) * puu(ji,jj,jk,Kmm)
176                  ! zve3n = pe3v(ji,jj,jk,Kmm) * pvv(ji,jj,jk,Kmm)
177                  ! zue3b = pe3u(ji,jj,jk,Kbb) * puu(ji,jj,jk,Kbb)
178                  ! zve3b = pe3v(ji,jj,jk,Kbb) * pvv(ji,jj,jk,Kbb)
179                  !
180                  zue3a = ( 1._wp + r3u(ji,jj,Kaa) * umask(ji,jj,jk) ) * puu(ji,jj,jk,Kaa)
181                  zve3a = ( 1._wp + r3v(ji,jj,Kaa) * vmask(ji,jj,jk) ) * pvv(ji,jj,jk,Kaa)
182                  zue3n = ( 1._wp + r3u(ji,jj,Kmm) * umask(ji,jj,jk) ) * puu(ji,jj,jk,Kmm)
183                  zve3n = ( 1._wp + r3v(ji,jj,Kmm) * vmask(ji,jj,jk) ) * pvv(ji,jj,jk,Kmm)
184                  zue3b = ( 1._wp + r3u(ji,jj,Kbb) * umask(ji,jj,jk) ) * puu(ji,jj,jk,Kbb)
185                  zve3b = ( 1._wp + r3v(ji,jj,Kbb) * vmask(ji,jj,jk) ) * pvv(ji,jj,jk,Kbb)
186                  !                                                 ! filtered scale factor at U-,V-points
187                  ! pe3u(ji,jj,jk,Kmm) = e3u_0(ji,jj,jk) * ( 1._wp + r3u_f(ji,jj) * umask(ji,jj,jk) )
188                  ! pe3v(ji,jj,jk,Kmm) = e3v_0(ji,jj,jk) * ( 1._wp + r3v_f(ji,jj) * vmask(ji,jj,jk) )
189                  !
190                  puu(ji,jj,jk,Kmm) = ( zue3n + atfp * ( zue3b - 2._wp * zue3n  + zue3a ) ) / ( 1._wp + r3u_f(ji,jj)*umask(ji,jj,jk) ) !!st ze3u_f(ji,jj,jk)
191                  pvv(ji,jj,jk,Kmm) = ( zve3n + atfp * ( zve3b - 2._wp * zve3n  + zve3a ) ) / ( 1._wp + r3v_f(ji,jj)*vmask(ji,jj,jk) ) !!st ze3v_f(ji,jj,jk)
192               END_3D
193               !
194            ENDIF
195            !
196         ENDIF
197         !
198         IF( ln_dynspg_ts .AND. ln_bt_fw ) THEN
199            ! Revert filtered "now" velocities to time split estimate
200            ! Doing it here also means that asselin filter contribution is removed
201            ! zue(:,:) = pe3u(:,:,1,Kmm) * puu(:,:,1,Kmm) * umask(:,:,1)
202            ! zve(:,:) = pe3v(:,:,1,Kmm) * pvv(:,:,1,Kmm) * vmask(:,:,1)
203            ! DO jk = 2, jpkm1
204            !    zue(:,:) = zue(:,:) + pe3u(:,:,jk,Kmm) * puu(:,:,jk,Kmm) * umask(:,:,jk)
205            !    zve(:,:) = zve(:,:) + pe3v(:,:,jk,Kmm) * pvv(:,:,jk,Kmm) * vmask(:,:,jk)
206            ! END DO
207            zue(:,:) = e3u(:,:,1,Kmm) * puu(:,:,1,Kmm) * umask(:,:,1)
208            zve(:,:) = e3v(:,:,1,Kmm) * pvv(:,:,1,Kmm) * vmask(:,:,1)
209            DO jk = 2, jpkm1
210               zue(:,:) = zue(:,:) + e3u(:,:,jk,Kmm) * puu(:,:,jk,Kmm) * umask(:,:,jk)
211               zve(:,:) = zve(:,:) + e3v(:,:,jk,Kmm) * pvv(:,:,jk,Kmm) * vmask(:,:,jk)
212            END DO
213            DO jk = 1, jpkm1
214               puu(:,:,jk,Kmm) = puu(:,:,jk,Kmm) - (zue(:,:) * r1_hu(:,:,Kmm) - uu_b(:,:,Kmm)) * umask(:,:,jk)
215               pvv(:,:,jk,Kmm) = pvv(:,:,jk,Kmm) - (zve(:,:) * r1_hv(:,:,Kmm) - vv_b(:,:,Kmm)) * vmask(:,:,jk)
216            END DO
217         ENDIF
218         !
219      ENDIF ! neuler /= 0
220      !
221      ! Set "now" and "before" barotropic velocities for next time step:
222      ! JC: Would be more clever to swap variables than to make a full vertical
223      ! integration
224      !
225      IF(.NOT.ln_linssh ) THEN
226         hu(:,:,Kmm) = e3u(:,:,1,Kmm ) * umask(:,:,1)
227         hv(:,:,Kmm) = e3v(:,:,1,Kmm ) * vmask(:,:,1)
228         DO jk = 2, jpkm1
229            hu(:,:,Kmm) = hu(:,:,Kmm) + e3u(:,:,jk,Kmm ) * umask(:,:,jk)
230            hv(:,:,Kmm) = hv(:,:,Kmm) + e3v(:,:,jk,Kmm ) * vmask(:,:,jk)
231         END DO
232         r1_hu(:,:,Kmm) = ssumask(:,:) / ( hu(:,:,Kmm) + 1._wp - ssumask(:,:) )
233         r1_hv(:,:,Kmm) = ssvmask(:,:) / ( hv(:,:,Kmm) + 1._wp - ssvmask(:,:) )
234      ENDIF
235      !
236      uu_b(:,:,Kaa) = e3u(:,:,1,Kaa) * puu(:,:,1,Kaa) * umask(:,:,1)
237      uu_b(:,:,Kmm) = e3u(:,:,1,Kmm) * puu(:,:,1,Kmm) * umask(:,:,1)
238      vv_b(:,:,Kaa) = e3v(:,:,1,Kaa) * pvv(:,:,1,Kaa) * vmask(:,:,1)
239      vv_b(:,:,Kmm) = e3v(:,:,1,Kmm) * pvv(:,:,1,Kmm) * vmask(:,:,1)
240      DO jk = 2, jpkm1
241         uu_b(:,:,Kaa) = uu_b(:,:,Kaa) + e3u(:,:,jk,Kaa) * puu(:,:,jk,Kaa) * umask(:,:,jk)
242         uu_b(:,:,Kmm) = uu_b(:,:,Kmm) + e3u(:,:,jk,Kmm) * puu(:,:,jk,Kmm) * umask(:,:,jk)
243         vv_b(:,:,Kaa) = vv_b(:,:,Kaa) + e3v(:,:,jk,Kaa) * pvv(:,:,jk,Kaa) * vmask(:,:,jk)
244         vv_b(:,:,Kmm) = vv_b(:,:,Kmm) + e3v(:,:,jk,Kmm) * pvv(:,:,jk,Kmm) * vmask(:,:,jk)
245      END DO
246      uu_b(:,:,Kaa) = uu_b(:,:,Kaa) * r1_hu(:,:,Kaa)
247      vv_b(:,:,Kaa) = vv_b(:,:,Kaa) * r1_hv(:,:,Kaa)
248      uu_b(:,:,Kmm) = uu_b(:,:,Kmm) * r1_hu(:,:,Kmm)
249      vv_b(:,:,Kmm) = vv_b(:,:,Kmm) * r1_hv(:,:,Kmm)
250      !
251      IF( .NOT.ln_dynspg_ts ) THEN        ! output the barotropic currents
252         CALL iom_put(  "ubar", uu_b(:,:,Kmm) )
253         CALL iom_put(  "vbar", vv_b(:,:,Kmm) )
254      ENDIF
255      IF( l_trddyn ) THEN                ! 3D output: asselin filter trends on momentum
256         zua(:,:,:) = ( puu(:,:,:,Kmm) - zua(:,:,:) ) * z1_2dt
257         zva(:,:,:) = ( pvv(:,:,:,Kmm) - zva(:,:,:) ) * z1_2dt
258         CALL trd_dyn( zua, zva, jpdyn_atf, kt, Kmm )
259      ENDIF
260      !
261      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Kaa), clinfo1=' nxt  - puu(:,:,:,Kaa): ', mask1=umask,   &
262         &                                  tab3d_2=pvv(:,:,:,Kaa), clinfo2=' pvv(:,:,:,Kaa): '       , mask2=vmask )
263      !
264      IF( ln_dynspg_ts )   DEALLOCATE( zue, zve )
265      IF( l_trddyn     )   DEALLOCATE( zua, zva )
266      IF( ln_timing    )   CALL timing_stop('dyn_atf_qco')
267      !
268   END SUBROUTINE dyn_atf_qco
269
270   !!=========================================================================
271END MODULE dynatfqco
Note: See TracBrowser for help on using the repository browser.