New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trazdf.F90 in NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/TRA/trazdf.F90 @ 12590

Last change on this file since 12590 was 12590, checked in by techene, 4 years ago

all: add e3 substitute, OCE/DOM/domzgr_substitute.h90: correct a bug for e3f
  • Property svn:keywords set to Id
File size: 12.9 KB
Line 
1MODULE trazdf
2   !!==============================================================================
3   !!                 ***  MODULE  trazdf  ***
4   !! Ocean active tracers:  vertical component of the tracer mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!            4.0  !  2017-06  (G. Madec)  remove explict time-stepping option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_zdf       : Update the tracer trend with the vertical diffusion
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE domvvl         ! variable volume
17   USE phycst         ! physical constant
18   USE zdf_oce        ! ocean vertical physics variables
19   USE sbc_oce        ! surface boundary condition: ocean
20   USE ldftra         ! lateral diffusion: eddy diffusivity
21   USE ldfslp         ! lateral diffusion: iso-neutral slope
22   USE trd_oce        ! trends: ocean variables
23   USE trdtra         ! trends: tracer trend manager
24   !
25   USE in_out_manager ! I/O manager
26   USE prtctl         ! Print control
27   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
28   USE lib_mpp        ! MPP library
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_zdf       ! called by step.F90
35   PUBLIC   tra_zdf_imp   ! called by trczdf.F90
36
37   !! * Substitutions
38#  include "do_loop_substitute.h90"
39#  include "domzgr_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE tra_zdf( kt, Kbb, Kmm, Krhs, pts, Kaa )
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE tra_zdf  ***
50      !!
51      !! ** Purpose :   compute the vertical ocean tracer physics.
52      !!---------------------------------------------------------------------
53      INTEGER                                  , INTENT(in)    :: kt                  ! ocean time-step index
54      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs, Kaa ! time level indices
55      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts                 ! active tracers and RHS of tracer equation
56      !
57      INTEGER  ::   jk   ! Dummy loop indices
58      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdt, ztrds   ! 3D workspace
59      !!---------------------------------------------------------------------
60      !
61      IF( ln_timing )   CALL timing_start('tra_zdf')
62      !
63      IF( kt == nit000 )  THEN
64         IF(lwp)WRITE(numout,*)
65         IF(lwp)WRITE(numout,*) 'tra_zdf : implicit vertical mixing on T & S'
66         IF(lwp)WRITE(numout,*) '~~~~~~~ '
67      ENDIF
68      !
69      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   r2dt =      rdt   ! at nit000, =   rdt (restarting with Euler time stepping)
70      ELSEIF( kt <= nit000 + 1           ) THEN   ;   r2dt = 2. * rdt   ! otherwise, = 2 rdt (leapfrog)
71      ENDIF
72      !
73      IF( l_trdtra )   THEN                  !* Save ta and sa trends
74         ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) )
75         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kaa)
76         ztrds(:,:,:) = pts(:,:,:,jp_sal,Kaa)
77      ENDIF
78      !
79      !                                      !* compute lateral mixing trend and add it to the general trend
80      CALL tra_zdf_imp( kt, nit000, 'TRA', r2dt, Kbb, Kmm, Krhs, pts, Kaa, jpts )
81
82!!gm WHY here !   and I don't like that !
83      ! DRAKKAR SSS control {
84      ! JMM avoid negative salinities near river outlet ! Ugly fix
85      ! JMM : restore negative salinities to small salinities:
86      WHERE( pts(:,:,:,jp_sal,Kaa) < 0._wp )   pts(:,:,:,jp_sal,Kaa) = 0.1_wp
87!!gm
88
89      IF( l_trdtra )   THEN                      ! save the vertical diffusive trends for further diagnostics
90         DO jk = 1, jpkm1
91            ztrdt(:,:,jk) = ( ( pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa)    &
92               &              - pts(:,:,jk,jp_tem,Kbb)*e3t(:,:,jk,Kbb) )  &
93               &             / (e3t(:,:,jk,Kmm)*r2dt) ) - ztrdt(:,:,jk)
94            ztrds(:,:,jk) = ( ( pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa)    &
95               &              - pts(:,:,jk,jp_sal,Kbb)*e3t(:,:,jk,Kbb) ) &
96               &             / (e3t(:,:,jk,Kmm)*r2dt) ) - ztrds(:,:,jk)
97         END DO
98!!gm this should be moved in trdtra.F90 and done on all trends
99         CALL lbc_lnk_multi( 'trazdf', ztrdt, 'T', 1. , ztrds, 'T', 1. )
100!!gm
101         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_zdf, ztrdt )
102         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_zdf, ztrds )
103         DEALLOCATE( ztrdt , ztrds )
104      ENDIF
105      !                                          ! print mean trends (used for debugging)
106      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kaa), clinfo1=' zdf  - Ta: ', mask1=tmask,               &
107         &                                  tab3d_2=pts(:,:,:,jp_sal,Kaa), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
108      !
109      IF( ln_timing )   CALL timing_stop('tra_zdf')
110      !
111   END SUBROUTINE tra_zdf
112
113
114   SUBROUTINE tra_zdf_imp( kt, kit000, cdtype, p2dt, Kbb, Kmm, Krhs, pt, Kaa, kjpt )
115      !!----------------------------------------------------------------------
116      !!                  ***  ROUTINE tra_zdf_imp  ***
117      !!
118      !! ** Purpose :   Compute the after tracer through a implicit computation
119      !!     of the vertical tracer diffusion (including the vertical component
120      !!     of lateral mixing (only for 2nd order operator, for fourth order
121      !!     it is already computed and add to the general trend in traldf)
122      !!
123      !! ** Method  :  The vertical diffusion of a tracer ,t , is given by:
124      !!          difft = dz( avt dz(t) ) = 1/e3t dk+1( avt/e3w dk(t) )
125      !!      It is computed using a backward time scheme (t=after field)
126      !!      which provide directly the after tracer field.
127      !!      If ln_zdfddm=T, use avs for salinity or for passive tracers
128      !!      Surface and bottom boundary conditions: no diffusive flux on
129      !!      both tracers (bottom, applied through the masked field avt).
130      !!      If iso-neutral mixing, add to avt the contribution due to lateral mixing.
131      !!
132      !! ** Action  : - pt(:,:,:,:,Kaa)  becomes the after tracer
133      !!---------------------------------------------------------------------
134      INTEGER                                  , INTENT(in   ) ::   kt       ! ocean time-step index
135      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs, Kaa  ! ocean time level indices
136      INTEGER                                  , INTENT(in   ) ::   kit000   ! first time step index
137      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
138      INTEGER                                  , INTENT(in   ) ::   kjpt     ! number of tracers
139      REAL(wp)                                 , INTENT(in   ) ::   p2dt     ! tracer time-step
140      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt       ! tracers and RHS of tracer equation
141      !
142      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
143      REAL(wp) ::  zrhs, zzwi, zzws ! local scalars
144      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zwi, zwt, zwd, zws
145      !!---------------------------------------------------------------------
146      !
147      !                                               ! ============= !
148      DO jn = 1, kjpt                                 !  tracer loop  !
149         !                                            ! ============= !
150         !  Matrix construction
151         ! --------------------
152         ! Build matrix if temperature or salinity (only in double diffusion case) or first passive tracer
153         !
154         IF(  ( cdtype == 'TRA' .AND. ( jn == jp_tem .OR. ( jn == jp_sal .AND. ln_zdfddm ) ) ) .OR.   &
155            & ( cdtype == 'TRC' .AND. jn == 1 )  )  THEN
156            !
157            ! vertical mixing coef.: avt for temperature, avs for salinity and passive tracers
158            IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN   ;   zwt(:,:,2:jpk) = avt(:,:,2:jpk)
159            ELSE                                            ;   zwt(:,:,2:jpk) = avs(:,:,2:jpk)
160            ENDIF
161            zwt(:,:,1) = 0._wp
162            !
163            IF( l_ldfslp ) THEN            ! isoneutral diffusion: add the contribution
164               IF( ln_traldf_msc  ) THEN     ! MSC iso-neutral operator
165                  DO_3D_00_00( 2, jpkm1 )
166                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + akz(ji,jj,jk)
167                  END_3D
168               ELSE                          ! standard or triad iso-neutral operator
169                  DO_3D_00_00( 2, jpkm1 )
170                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + ah_wslp2(ji,jj,jk)
171                  END_3D
172               ENDIF
173            ENDIF
174            !
175            ! Diagonal, lower (i), upper (s)  (including the bottom boundary condition since avt is masked)
176            IF( ln_zad_Aimp ) THEN         ! Adaptive implicit vertical advection
177               DO_3D_00_00( 1, jpkm1 )
178                  zzwi = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk  ,Kmm)
179                  zzws = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
180                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zzwi - zzws   &
181                     &                 + p2dt * ( MAX( wi(ji,jj,jk  ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )
182                  zwi(ji,jj,jk) = zzwi + p2dt *   MIN( wi(ji,jj,jk  ) , 0._wp )
183                  zws(ji,jj,jk) = zzws - p2dt *   MAX( wi(ji,jj,jk+1) , 0._wp )
184               END_3D
185            ELSE
186               DO_3D_00_00( 1, jpkm1 )
187                  zwi(ji,jj,jk) = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk,Kmm)
188                  zws(ji,jj,jk) = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
189                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zwi(ji,jj,jk) - zws(ji,jj,jk)
190               END_3D
191            ENDIF
192            !
193            !! Matrix inversion from the first level
194            !!----------------------------------------------------------------------
195            !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
196            !
197            !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
198            !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
199            !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
200            !        (        ...               )( ...  ) ( ...  )
201            !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
202            !
203            !   m is decomposed in the product of an upper and lower triangular matrix.
204            !   The 3 diagonal terms are in 3d arrays: zwd, zws, zwi.
205            !   Suffices i,s and d indicate "inferior" (below diagonal), diagonal
206            !   and "superior" (above diagonal) components of the tridiagonal system.
207            !   The solution will be in the 4d array pta.
208            !   The 3d array zwt is used as a work space array.
209            !   En route to the solution pt(:,:,:,:,Kaa) is used a to evaluate the rhs and then
210            !   used as a work space array: its value is modified.
211            !
212            DO_2D_00_00
213               zwt(ji,jj,1) = zwd(ji,jj,1)
214            END_2D
215            DO_3D_00_00( 2, jpkm1 )
216               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwt(ji,jj,jk-1)
217            END_3D
218            !
219         ENDIF
220         !
221         DO_2D_00_00
222            pt(ji,jj,1,jn,Kaa) =        e3t(ji,jj,1,Kbb) * pt(ji,jj,1,jn,Kbb)    &
223               &               + p2dt * e3t(ji,jj,1,Kmm) * pt(ji,jj,1,jn,Krhs)
224         END_2D
225         DO_3D_00_00( 2, jpkm1 )
226            zrhs =        e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb)    & 
227               & + p2dt * e3t(ji,jj,jk,Kmm) * pt(ji,jj,jk,jn,Krhs)   ! zrhs=right hand side
228            pt(ji,jj,jk,jn,Kaa) = zrhs - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) * pt(ji,jj,jk-1,jn,Kaa)
229         END_3D
230         !
231         DO_2D_00_00
232            pt(ji,jj,jpkm1,jn,Kaa) = pt(ji,jj,jpkm1,jn,Kaa) / zwt(ji,jj,jpkm1) * tmask(ji,jj,jpkm1)
233         END_2D
234         DO_3DS_00_00( jpk-2, 1, -1 )
235            pt(ji,jj,jk,jn,Kaa) = ( pt(ji,jj,jk,jn,Kaa) - zws(ji,jj,jk) * pt(ji,jj,jk+1,jn,Kaa) )   &
236               &             / zwt(ji,jj,jk) * tmask(ji,jj,jk)
237         END_3D
238         !                                            ! ================= !
239      END DO                                          !  end tracer loop  !
240      !                                               ! ================= !
241   END SUBROUTINE tra_zdf_imp
242
243   !!==============================================================================
244END MODULE trazdf
Note: See TracBrowser for help on using the repository browser.