New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OFF – NEMO

Context Navigation

source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OFF/nemogcm.F90 @ 12779

Last change on this file since 12779 was 12779, checked in by techene, 4 years ago
modify TOP to be able to run with key_qco i.e. remove e3. gdep. and use a substitute instead (# include "domzgr_substitute.h90")
Property svn:keywords set to `Id`
File size: 29.8 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Off-line Ocean : passive tracer evolution, dynamics read in files
5	!!======================================================================
6	!! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line
7	!! 3.4 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8	!! 4.0 ! 2016-10 (C. Ethe, G. Madec, S. Flavoni) domain configuration / user defined interface
9	!! 4.1 ! 2019-08 (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
10	!!----------------------------------------------------------------------
11
12	!!----------------------------------------------------------------------
13	!! nemo_gcm : off-line: solve ocean tracer only
14	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
15	!! nemo_init : initialization of the NEMO system
16	!! nemo_ctl : initialisation of the contol print
17	!! nemo_closefile: close remaining open files
18	!! nemo_alloc : dynamical allocation
19	!! istate_init : simple initialization to zero of ocean fields
20	!! stp_ctl : reduced step control (no dynamics in off-line)
21	!!----------------------------------------------------------------------
22	USE dom_oce ! ocean space domain variables
23	USE oce ! dynamics and tracers variables
24	USE trc_oce ! Shared ocean/passive tracers variables
25	USE c1d ! 1D configuration
26	USE domain ! domain initialization from coordinate & bathymetry (dom_init routine)
27	USE closea ! treatment of closed seas (for ln_closea)
28	USE usrdef_nam ! user defined configuration
29	USE eosbn2 ! equation of state (eos bn2 routine)
30	#if defined key_qco
31	USE domqco ! tools for scale factor (dom_qco_r3c routine)
32	#endif
33	! ! ocean physics
34	USE ldftra ! lateral diffusivity setting (ldf_tra_init routine)
35	USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine)
36	USE traqsr ! solar radiation penetration (tra_qsr_init routine)
37	USE trabbl ! bottom boundary layer (tra_bbl_init routine)
38	USE traldf ! lateral physics (tra_ldf_init routine)
39	USE sbcmod ! surface boundary condition (sbc_init routine)
40	USE phycst ! physical constant (par_cst routine)
41	USE dtadyn ! Lecture and Interpolation of the dynamical fields
42	USE trcini ! Initilization of the passive tracers
43	USE daymod ! calendar (day routine)
44	USE trcstp ! passive tracer time-stepping (trc_stp routine)
45	USE dtadyn ! Lecture and interpolation of the dynamical fields
46	! ! Passive tracers needs
47	USE trc ! passive tracer : variables
48	USE trcnam ! passive tracer : namelist
49	USE trcrst ! passive tracer restart
50	USE diaptr ! Need to initialise this as some variables are used in if statements later
51	USE sbc_oce , ONLY : ln_rnf
52	USE sbcrnf ! surface boundary condition : runoffs
53	! ! I/O & MPP
54	USE iom ! I/O library
55	USE in_out_manager ! I/O manager
56	USE mppini ! shared/distributed memory setting (mpp_init routine)
57	USE lib_mpp ! distributed memory computing
58	#if defined key_iomput
59	USE xios ! xIOserver
60	#endif
61	USE prtctl ! Print control (prt_ctl_init routine)
62	USE timing ! Timing
63	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
64	USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
65	USE step, ONLY : Nbb, Nnn, Naa, Nrhs ! time level indices
66
67	IMPLICIT NONE
68	PRIVATE
69
70	PUBLIC nemo_gcm ! called by nemo.F90
71
72	CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
73
74	!!----------------------------------------------------------------------
75	!! NEMO/OFF 4.0 , NEMO Consortium (2018)
76	!! $Id$
77	!! Software governed by the CeCILL license (see ./LICENSE)
78	!!----------------------------------------------------------------------
79	CONTAINS
80
81	SUBROUTINE nemo_gcm
82	!!----------------------------------------------------------------------
83	!! * ROUTINE nemo_gcm *
84	!!
85	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
86	!! curvilinear mesh on the sphere.
87	!!
88	!! ** Method : - model general initialization
89	!! - launch the time-stepping (dta_dyn and trc_stp)
90	!! - finalize the run by closing files and communications
91	!!
92	!! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL.
93	!! Madec, 2008, internal report, IPSL.
94	!!----------------------------------------------------------------------
95	INTEGER :: istp, indic ! time step index
96	!!----------------------------------------------------------------------
97
98	CALL nemo_init ! Initializations
99
100	! check that all process are still there... If some process have an error,
101	! they will never enter in step and other processes will wait until the end of the cpu time!
102	CALL mpp_max( 'nemogcm', nstop )
103
104	! !-----------------------!
105	! !== time stepping ==!
106	! !-----------------------!
107	istp = nit000
108	!
109	IF( ln_rnf ) CALL sbc_rnf(istp) ! runoffs initialization
110	!
111	CALL iom_init( cxios_context ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
112	!
113	DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== OFF time-stepping ==!
114	!
115	IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init)
116	CALL iom_setkt ( istp - nit000 + 1, cxios_context ) ! say to iom that we are at time step kstp
117	#if defined key_sed_off
118	CALL dta_dyn_sed( istp, Nnn ) ! Interpolation of the dynamical fields
119	#else
120	CALL dta_dyn ( istp, Nbb, Nnn, Naa ) ! Interpolation of the dynamical fields
121	#endif
122	#if ! defined key_sed_off
123	IF( .NOT.ln_linssh ) THEN
124	CALL dta_dyn_atf( istp, Nbb, Nnn, Naa ) ! time filter of sea surface height and vertical scale factors
125	# if defined key_qco
126	CALL dom_qco_r3c( ssh(:,:,Kmm), r3t_f, r3u_f, r3v_f )
127	# endif
128	ENDIF
129	CALL trc_stp ( istp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping
130	# if defined key_qco
131	!r3t(:,:,Kmm) = r3t_f(:,:) ! update ssh to h0 ratio
132	!r3u(:,:,Kmm) = r3u_f(:,:)
133	!r3v(:,:,Kmm) = r3v_f(:,:)
134	# endif
135	#endif
136	! Swap time levels
137	Nrhs = Nbb
138	Nbb = Nnn
139	Nnn = Naa
140	Naa = Nrhs
141	!
142	#if ! defined key_qco
143	# if ! defined key_sed_off
144	IF( .NOT.ln_linssh ) CALL dta_dyn_sf_interp( istp, Nnn ) ! calculate now grid parameters
145	# endif
146	#endif
147	CALL stp_ctl ( istp, indic ) ! Time loop: control and print
148	istp = istp + 1
149	END DO
150	!
151	#if defined key_iomput
152	CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
153	#endif
154
155	! !------------------------!
156	! !== finalize the run ==!
157	! !------------------------!
158	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
159
160	IF( nstop /= 0 .AND. lwp ) THEN ! error print
161	WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found'
162	CALL ctl_stop( ctmp1 )
163	ENDIF
164	!
165	IF( ln_timing ) CALL timing_finalize
166	!
167	CALL nemo_closefile
168	!
169	#if defined key_iomput
170	CALL xios_finalize ! end mpp communications with xios
171	#else
172	IF( lk_mpp ) CALL mppstop ! end mpp communications
173	#endif
174	!
175	IF(lwm) THEN
176	IF( nstop == 0 ) THEN ; STOP 0
177	ELSE ; STOP 123
178	ENDIF
179	ENDIF
180	!
181	END SUBROUTINE nemo_gcm
182
183
184	SUBROUTINE nemo_init
185	!!----------------------------------------------------------------------
186	!! * ROUTINE nemo_init *
187	!!
188	!! ** Purpose : initialization of the nemo model in off-line mode
189	!!----------------------------------------------------------------------
190	INTEGER :: ios, ilocal_comm ! local integers
191	!!
192	NAMELIST/namctl/ sn_cfctl, nn_print, nn_ictls, nn_ictle, &
193	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
194	& ln_timing, ln_diacfl
195	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
196	!!----------------------------------------------------------------------
197	!
198	cxios_context = 'nemo'
199	!
200	! !-------------------------------------------------!
201	! ! set communicator & select the local rank !
202	! ! must be done as soon as possible to get narea !
203	! !-------------------------------------------------!
204	!
205	#if defined key_iomput
206	CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios
207	CALL mpp_start( ilocal_comm )
208	#else
209	CALL mpp_start( )
210	#endif
211	!
212	narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 )
213	lwm = (narea == 1) ! control of output namelists
214	!
215	! !---------------------------------------------------------------!
216	! ! Open output files, reference and configuration namelist files !
217	! !---------------------------------------------------------------!
218	!
219	! open ocean.output as soon as possible to get all output prints (including errors messages)
220	IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
221	! open reference and configuration namelist files
222	CALL load_nml( numnam_ref, 'namelist_ref', -1, lwm )
223	CALL load_nml( numnam_cfg, 'namelist_cfg', -1, lwm )
224	IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
225	! open /dev/null file to be able to supress output write easily
226	IF( Agrif_Root() ) THEN
227	CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
228	#ifdef key_agrif
229	ELSE
230	numnul = Agrif_Parent(numnul)
231	#endif
232	ENDIF
233	!
234	! !--------------------!
235	! ! Open listing units ! -> need sn_cfctl from namctl to define lwp
236	! !--------------------!
237	!
238	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
239	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' )
240	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
241	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' )
242	!
243	! finalize the definition of namctl variables
244	IF( sn_cfctl%l_allon ) THEN
245	! Turn on all options.
246	CALL nemo_set_cfctl( sn_cfctl, .TRUE., .TRUE. )
247	! Ensure all processors are active
248	sn_cfctl%procmin = 0 ; sn_cfctl%procmax = 1000000 ; sn_cfctl%procincr = 1
249	ELSEIF( sn_cfctl%l_config ) THEN
250	! Activate finer control of report outputs
251	! optionally switch off output from selected areas (note this only
252	! applies to output which does not involve global communications)
253	IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax ) .OR. &
254	& ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) ) &
255	& CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
256	ELSE
257	! turn off all options.
258	CALL nemo_set_cfctl( sn_cfctl, .FALSE., .TRUE. )
259	ENDIF
260	!
261	lwp = (narea == 1) .OR. sn_cfctl%l_oceout ! control of all listing output print
262	!
263	IF(lwp) THEN ! open listing units
264	!
265	IF( .NOT. lwm ) & ! alreay opened for narea == 1
266	& CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
267	!
268	WRITE(numout,*)
269	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
270	WRITE(numout,*) ' NEMO team'
271	WRITE(numout,*) ' Off-line TOP Model'
272	WRITE(numout,*) ' NEMO version 4.0 (2019) '
273	WRITE(numout,*)
274	WRITE(numout,*) " ._ ._ ._ ._ ._ "
275	WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
276	WRITE(numout,*)
277	WRITE(numout,*) " o _, _, "
278	WRITE(numout,*) " o .' ( .-' / "
279	WRITE(numout,*) " o _/..._'. .' / "
280	WRITE(numout,*) " ( o .-'` ` '-./ _.' "
281	WRITE(numout,*) " ) ( o) ;= <_ ( "
282	WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) "
283	WRITE(numout,*) " ) ) \) \|`\ \) '. \ ( ( "
284	WRITE(numout,*) " ( ( \_/ '-._\ ) ) "
285	WRITE(numout,*) " ) ) ` ( ( "
286	WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
287	WRITE(numout,*)
288	!
289	WRITE(numout,cform_aaa) ! Flag AAAAAAA
290	!
291	ENDIF
292	!
293	IF(lwm) WRITE( numond, namctl )
294	!
295	! !------------------------------------!
296	! ! Set global domain size parameters !
297	! !------------------------------------!
298	!
299	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
300	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' )
301	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
302	904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' )
303	!
304	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
305	CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
306	ELSE ! user-defined namelist
307	CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
308	ENDIF
309	!
310	IF(lwm) WRITE( numond, namcfg )
311	l_offline = .true. ! passive tracers are run offline
312	!
313	! !-----------------------------------------!
314	! ! mpp parameters and domain decomposition !
315	! !-----------------------------------------!
316	!
317	CALL mpp_init
318
319	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
320	CALL nemo_alloc()
321
322	! Initialise time level indices
323	Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
324
325
326	! !-------------------------------!
327	! ! NEMO general initialization !
328	! !-------------------------------!
329
330	CALL nemo_ctl ! Control prints
331	!
332	! ! General initialization
333	IF( ln_timing ) CALL timing_init
334	IF( ln_timing ) CALL timing_start( 'nemo_init')
335	!
336	CALL phy_cst ! Physical constants
337	CALL eos_init ! Equation of state
338	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
339	CALL dom_init( Nbb, Nnn, Naa, "OPA") ! Domain
340	IF( sn_cfctl%l_prtctl ) &
341	& CALL prt_ctl_init ! Print control
342
343	CALL istate_init( Nnn, Naa ) ! ocean initial state (Dynamics and tracers)
344
345	CALL sbc_init( Nbb, Nnn, Naa ) ! Forcings : surface module
346
347	! ! Tracer physics
348	CALL ldf_tra_init ! Lateral ocean tracer physics
349	CALL ldf_eiv_init ! Eddy induced velocity param
350	CALL tra_ldf_init ! lateral mixing
351	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
352	IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation
353	IF( ln_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
354
355	! ! Passive tracers
356	CALL trc_nam_run ! Needed to get restart parameters for passive tracers
357	CALL trc_rst_cal( nit000, 'READ' ) ! calendar
358	#if defined key_sed_off
359	CALL dta_dyn_sed_init( Nnn ) ! Initialization for the dynamics
360	#else
361	CALL dta_dyn_init( Nbb, Nnn, Naa ) ! Initialization for the dynamics
362	#endif
363
364	CALL trc_init( Nbb, Nnn, Naa ) ! Passive tracers initialization
365	CALL dia_ptr_init ! Poleward TRansports initialization
366
367	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
368	!
369	IF( ln_timing ) CALL timing_stop( 'nemo_init')
370	!
371	END SUBROUTINE nemo_init
372
373
374	SUBROUTINE nemo_ctl
375	!!----------------------------------------------------------------------
376	!! * ROUTINE nemo_ctl *
377	!!
378	!! ** Purpose : control print setting
379	!!
380	!! ** Method : - print namctl and namcfg information and check some consistencies
381	!!----------------------------------------------------------------------
382	!
383	IF(lwp) THEN ! control print
384	WRITE(numout,*)
385	WRITE(numout,*) 'nemo_ctl: Control prints'
386	WRITE(numout,*) '~~~~~~~~'
387	WRITE(numout,*) ' Namelist namctl'
388	WRITE(numout,*) ' sn_cfctl%l_glochk = ', sn_cfctl%l_glochk
389	WRITE(numout,*) ' sn_cfctl%l_allon = ', sn_cfctl%l_allon
390	WRITE(numout,*) ' finer control over o/p sn_cfctl%l_config = ', sn_cfctl%l_config
391	WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
392	WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
393	WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout
394	WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout
395	WRITE(numout,*) ' sn_cfctl%l_prtctl = ', sn_cfctl%l_prtctl
396	WRITE(numout,*) ' sn_cfctl%l_prttrc = ', sn_cfctl%l_prttrc
397	WRITE(numout,*) ' sn_cfctl%l_oasout = ', sn_cfctl%l_oasout
398	WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin
399	WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax
400	WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr
401	WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr
402	WRITE(numout,*) ' level of print nn_print = ', nn_print
403	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
404	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
405	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
406	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
407	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
408	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
409	WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing
410	WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl
411	ENDIF
412	!
413	nprint = nn_print ! convert DOCTOR namelist names into OLD names
414	nictls = nn_ictls
415	nictle = nn_ictle
416	njctls = nn_jctls
417	njctle = nn_jctle
418	isplt = nn_isplt
419	jsplt = nn_jsplt
420
421	IF(lwp) THEN ! control print
422	WRITE(numout,*)
423	WRITE(numout,*) ' Namelist namcfg'
424	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
425	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
426	WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea
427	WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg
428	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
429	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
430	ENDIF
431	IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file
432	!
433	! ! Parameter control
434	!
435	IF( sn_cfctl%l_prtctl .OR. sn_cfctl%l_prttrc ) THEN ! sub-domain area indices for the control prints
436	IF( lk_mpp .AND. jpnij > 1 ) THEN
437	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
438	ELSE
439	IF( isplt == 1 .AND. jsplt == 1 ) THEN
440	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
441	& ' - the print control will be done over the whole domain' )
442	ENDIF
443	ijsplt = isplt * jsplt ! total number of processors ijsplt
444	ENDIF
445	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
446	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
447	!
448	! ! indices used for the SUM control
449	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
450	lsp_area = .FALSE.
451	ELSE ! print control done over a specific area
452	lsp_area = .TRUE.
453	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
454	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
455	nictls = 1
456	ENDIF
457	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
458	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
459	nictle = jpiglo
460	ENDIF
461	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
462	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
463	njctls = 1
464	ENDIF
465	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
466	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
467	njctle = jpjglo
468	ENDIF
469	ENDIF
470	ENDIF
471	!
472	IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', &
473	& 'Compile with key_nosignedzero enabled' )
474	!
475	END SUBROUTINE nemo_ctl
476
477
478	SUBROUTINE nemo_closefile
479	!!----------------------------------------------------------------------
480	!! * ROUTINE nemo_closefile *
481	!!
482	!! ** Purpose : Close the files
483	!!----------------------------------------------------------------------
484	!
485	IF( lk_mpp ) CALL mppsync
486	!
487	CALL iom_close ! close all input/output files managed by iom_*
488	!
489	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
490	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
491	!
492	numout = 6 ! redefine numout in case it is used after this point...
493	!
494	END SUBROUTINE nemo_closefile
495
496
497	SUBROUTINE nemo_alloc
498	!!----------------------------------------------------------------------
499	!! * ROUTINE nemo_alloc *
500	!!
501	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
502	!!
503	!! ** Method :
504	!!----------------------------------------------------------------------
505	USE diawri , ONLY : dia_wri_alloc
506	USE dom_oce, ONLY : dom_oce_alloc
507	USE zdf_oce, ONLY : zdf_oce_alloc
508	USE trc_oce, ONLY : trc_oce_alloc
509	!
510	INTEGER :: ierr
511	!!----------------------------------------------------------------------
512	!
513	ierr = oce_alloc () ! ocean
514	ierr = ierr + dia_wri_alloc()
515	ierr = ierr + dom_oce_alloc() ! ocean domain
516	ierr = ierr + zdf_oce_alloc() ! ocean vertical physics
517	ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays
518	!
519	CALL mpp_sum( 'nemogcm', ierr )
520	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
521	!
522	END SUBROUTINE nemo_alloc
523
524	SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
525	!!----------------------------------------------------------------------
526	!! * ROUTINE nemo_set_cfctl *
527	!!
528	!! ** Purpose : Set elements of the output control structure to setto.
529	!! for_all should be .false. unless all areas are to be
530	!! treated identically.
531	!!
532	!! ** Method : Note this routine can be used to switch on/off some
533	!! types of output for selected areas but any output types
534	!! that involve global communications (e.g. mpp_max, glob_sum)
535	!! should be protected from selective switching by the
536	!! for_all argument
537	!!----------------------------------------------------------------------
538	LOGICAL :: setto, for_all
539	TYPE(sn_ctl) :: sn_cfctl
540	!!----------------------------------------------------------------------
541	IF( for_all ) THEN
542	sn_cfctl%l_runstat = setto
543	sn_cfctl%l_trcstat = setto
544	ENDIF
545	sn_cfctl%l_oceout = setto
546	sn_cfctl%l_layout = setto
547	sn_cfctl%l_prtctl = setto
548	sn_cfctl%l_prttrc = setto
549	sn_cfctl%l_oasout = setto
550	END SUBROUTINE nemo_set_cfctl
551
552	SUBROUTINE istate_init( Kmm, Kaa )
553	!!----------------------------------------------------------------------
554	!! * ROUTINE istate_init *
555	!!
556	!! ** Purpose : Initialization to zero of the dynamics and tracers.
557	!!----------------------------------------------------------------------
558	INTEGER, INTENT(in) :: Kmm, Kaa ! ocean time level indices
559	!
560	! now fields ! after fields !
561	uu (:,:,:,Kmm) = 0._wp ; uu(:,:,:,Kaa) = 0._wp !
562	vv (:,:,:,Kmm) = 0._wp ; vv(:,:,:,Kaa) = 0._wp !
563	ww (:,:,:) = 0._wp ! !
564	hdiv (:,:,:) = 0._wp ! !
565	ts (:,:,:,:,Kmm) = 0._wp ! !
566	!
567	rhd (:,:,:) = 0.e0
568	rhop (:,:,:) = 0.e0
569	rn2 (:,:,:) = 0.e0
570	!
571	END SUBROUTINE istate_init
572
573
574	SUBROUTINE stp_ctl( kt, kindic )
575	!!----------------------------------------------------------------------
576	!! * ROUTINE stp_ctl *
577	!!
578	!! ** Purpose : Control the run
579	!!
580	!! ** Method : - Save the time step in numstp
581	!!
582	!! ** Actions : 'time.step' file containing the last ocean time-step
583	!!----------------------------------------------------------------------
584	INTEGER, INTENT(in ) :: kt ! ocean time-step index
585	INTEGER, INTENT(inout) :: kindic ! indicator of solver convergence
586	!!----------------------------------------------------------------------
587	!
588	IF( kt == nit000 .AND. lwm ) THEN
589	WRITE(numout,*)
590	WRITE(numout,*) 'stp_ctl : time-stepping control'
591	WRITE(numout,*) '~~~~~~~'
592	! open time.step file
593	CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
594	ENDIF
595	!
596	IF(lwm) WRITE ( numstp, '(1x, i8)' ) kt !* save the current time step in numstp
597	IF(lwm) REWIND( numstp ) ! --------------------------
598	!
599	END SUBROUTINE stp_ctl
600	!!======================================================================
601	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: