New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/SAS – NEMO

source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/SAS/nemogcm.F90 @ 12724

Last change on this file since 12724 was 12724, checked in by techene, 4 years ago

branch KERNEL-06 : merge with trunk@12698 #2385 - in duplcated files : changes to comply to the new trunk variables and some loop bug fixes
  • Property svn:keywords set to Id
File size: 28.4 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! StandAlone Surface module : surface fluxes + sea-ice + iceberg floats
5   !!======================================================================
6   !! History :  3.6  ! 2011-11  (S. Alderson, G. Madec) original code
7   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
8   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
9   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
14   !!   nemo_init     : initialization of the NEMO system
15   !!   nemo_ctl      : initialisation of the contol print
16   !!   nemo_closefile: close remaining open files
17   !!   nemo_alloc    : dynamical allocation
18   !!----------------------------------------------------------------------
19   USE step_oce       ! module used in the ocean time stepping module
20   USE sbc_oce        ! surface boundary condition: ocean
21   USE phycst         ! physical constant                  (par_cst routine)
22   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
23   USE closea         ! treatment of closed seas (for ln_closea)
24   USE usrdef_nam     ! user defined configuration
25   USE daymod         ! calendar
26   USE restart        ! open  restart file
27   USE step           ! NEMO time-stepping                 (stp     routine)
28   USE cpl_oasis3     !
29   USE sbcssm         !
30   USE icbini         ! handle bergs, initialisation
31   USE icbstp         ! handle bergs, calving, themodynamics and transport
32   USE bdyini         ! open boundary cond. setting       (bdy_init routine). mandatory for sea-ice
33   USE bdydta         ! open boundary cond. setting   (bdy_dta_init routine). mandatory for sea-ice
34   USE diu_layers     ! diurnal bulk SST and coolskin
35   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
36   !
37   USE in_out_manager ! I/O manager
38   USE lib_mpp        ! distributed memory computing
39   USE mppini         ! shared/distributed memory setting (mpp_init routine)
40   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
41   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
42#if defined key_iomput
43   USE xios           ! xIOserver
44#endif
45#if defined key_agrif && defined key_si3
46   USE agrif_ice_update ! ice update
47#endif
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   nemo_gcm    ! called by model.F90
53   PUBLIC   nemo_init   ! needed by AGRIF
54
55   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
56
57#if defined key_mpp_mpi
58   INCLUDE 'mpif.h'
59#endif
60
61   !!----------------------------------------------------------------------
62   !! NEMO/SAS 4.0 , NEMO Consortium (2018)
63   !! $Id$
64   !! Software governed by the CeCILL license (see ./LICENSE)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE nemo_gcm
69      !!----------------------------------------------------------------------
70      !!                     ***  ROUTINE nemo_gcm  ***
71      !!
72      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
73      !!              curvilinear mesh on the sphere.
74      !!
75      !! ** Method  : - model general initialization
76      !!              - launch the time-stepping (stp routine)
77      !!              - finalize the run by closing files and communications
78      !!
79      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
80      !!              Madec, 2008, internal report, IPSL.
81      !!----------------------------------------------------------------------
82      INTEGER ::   istp   ! time step index
83      !!----------------------------------------------------------------------
84      !
85#if defined key_agrif
86      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
87#endif
88      !                            !-----------------------!
89      CALL nemo_init               !==  Initialisations  ==!
90      !                            !-----------------------!
91#if defined key_agrif
92      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
93      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
94      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
95# if defined key_top
96      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
97# endif
98# if defined key_si3
99      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
100# endif
101#endif
102      ! check that all process are still there... If some process have an error,
103      ! they will never enter in step and other processes will wait until the end of the cpu time!
104      CALL mpp_max( 'nemogcm', nstop )
105
106      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
107
108      !                            !-----------------------!
109      !                            !==   time stepping   ==!
110      !                            !-----------------------!
111      istp = nit000
112      !
113#if defined key_agrif
114      !                                               !==  AGRIF time-stepping  ==!
115      CALL Agrif_Regrid()
116      !
117#if defined key_si3
118      ! Recursive update from highest nested level to lowest:
119      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
120      CALL Agrif_step_child_adj(Agrif_update_ice)
121#endif
122      !
123      DO WHILE( istp <= nitend .AND. nstop == 0 )
124         CALL stp
125         istp = istp + 1
126      END DO
127      !
128      IF( .NOT. Agrif_Root() ) THEN
129         CALL Agrif_ParentGrid_To_ChildGrid()
130         IF( ln_timing )   CALL timing_finalize
131         CALL Agrif_ChildGrid_To_ParentGrid()
132      ENDIF
133      !
134#else
135      !
136      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
137         !
138         DO WHILE( istp <= nitend .AND. nstop == 0 )
139#if defined key_mpp_mpi
140            ncom_stp = istp
141            IF ( istp == ( nit000 + 1 ) ) elapsed_time = MPI_Wtime()
142            IF ( istp ==         nitend ) elapsed_time = MPI_Wtime() - elapsed_time
143#endif
144            CALL stp        ( istp ) 
145            istp = istp + 1
146         END DO
147         !
148      ELSE                                            !==  diurnal SST time-steeping only  ==!
149         !
150         DO WHILE( istp <= nitend .AND. nstop == 0 )
151            CALL stp_diurnal( istp )   ! time step only the diurnal SST
152            istp = istp + 1
153         END DO
154         !
155      ENDIF
156      !
157#endif
158      !
159      IF( ln_icebergs )   CALL icb_end( nitend )
160
161      !                            !------------------------!
162      !                            !==  finalize the run  ==!
163      !                            !------------------------!
164      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
165      !
166      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
167         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
168         CALL ctl_stop( ctmp1 )
169      ENDIF
170      !
171      IF( ln_timing )   CALL timing_finalize
172      !
173      CALL nemo_closefile
174      !
175#if defined key_iomput
176                                    CALL xios_finalize  ! end mpp communications with xios
177      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
178#else
179      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
180      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop        ! end mpp communications
181      ENDIF
182#endif
183      !
184      IF(lwm) THEN
185         IF( nstop == 0 ) THEN   ;   STOP 0
186         ELSE                    ;   STOP 123
187         ENDIF
188      ENDIF
189      !
190   END SUBROUTINE nemo_gcm
191
192
193   SUBROUTINE nemo_init
194      !!----------------------------------------------------------------------
195      !!                     ***  ROUTINE nemo_init  ***
196      !!
197      !! ** Purpose :   initialization of the NEMO GCM
198      !!----------------------------------------------------------------------
199      INTEGER ::   ios, ilocal_comm   ! local integers
200      !!
201      NAMELIST/namctl/ sn_cfctl, nn_print, nn_ictls, nn_ictle,              &
202         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
203         &             ln_timing, ln_diacfl
204      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
205      !!----------------------------------------------------------------------
206      !
207      IF( lk_oasis ) THEN   ;   cxios_context = 'sas'
208      ELSE                  ;   cxios_context = 'nemo'
209      ENDIF
210      !
211      !                             !-------------------------------------------------!
212      !                             !     set communicator & select the local rank    !
213      !                             !  must be done as soon as possible to get narea  !
214      !                             !-------------------------------------------------!
215      !
216#if defined key_iomput
217      IF( Agrif_Root() ) THEN
218         IF( lk_oasis ) THEN
219            CALL cpl_init( "sas", ilocal_comm )                                  ! nemo local communicator given by oasis
220            CALL xios_initialize( "not used",local_comm=ilocal_comm )            ! send nemo communicator to xios
221         ELSE
222            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
223         ENDIF
224      ENDIF
225      CALL mpp_start( ilocal_comm )
226#else
227      IF( lk_oasis ) THEN
228         IF( Agrif_Root() ) THEN
229            CALL cpl_init( "sas", ilocal_comm )             ! nemo local communicator given by oasis
230         ENDIF
231         CALL mpp_start( ilocal_comm )
232      ELSE
233         CALL mpp_start( )
234      ENDIF
235#endif
236      !
237      narea = mpprank + 1                                   ! mpprank: the rank of proc (0 --> mppsize -1 )
238      lwm = (narea == 1)                ! control of output namelists
239      !
240      !                             !---------------------------------------------------------------!
241      !                             ! Open output files, reference and configuration namelist files !
242      !                             !---------------------------------------------------------------!
243      !
244      ! open ocean.output as soon as possible to get all output prints (including errors messages)
245      IF( lk_oasis ) THEN
246         IF( lwm )   CALL ctl_opn(     numout,               'sas.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
247         ! open reference and configuration namelist files
248                     CALL load_nml( numnam_ref,        'namelist_sas_ref',                                           -1, lwm )
249                     CALL load_nml( numnam_cfg,        'namelist_sas_cfg',                                           -1, lwm )
250         IF( lwm )   CALL ctl_opn(      numond, 'output.namelist_sas.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
251      ELSE
252         IF( lwm )   CALL ctl_opn(      numout,            'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
253         ! open reference and configuration namelist files
254                     CALL load_nml( numnam_ref,            'namelist_ref',                                           -1, lwm )
255                     CALL load_nml( numnam_cfg,            'namelist_cfg',                                           -1, lwm )
256         IF( lwm )   CALL ctl_opn(      numond,     'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
257      ENDIF
258      ! open /dev/null file to be able to supress output write easily
259      IF( Agrif_Root() ) THEN
260                     CALL ctl_opn(     numnul,               '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
261#ifdef key_agrif
262      ELSE
263                  numnul = Agrif_Parent(numnul)   
264#endif
265      ENDIF
266      !
267      !                             !--------------------!
268      !                             ! Open listing units !  -> need sn_cfctl from namctl to define lwp
269      !                             !--------------------!
270      !
271      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
272901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
273      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
274902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
275      !
276      ! finalize the definition of namctl variables
277      IF( sn_cfctl%l_allon ) THEN
278         ! Turn on all options.
279         CALL nemo_set_cfctl( sn_cfctl, .TRUE., .TRUE. )
280         ! Ensure all processors are active
281         sn_cfctl%procmin = 0 ; sn_cfctl%procmax = 1000000 ; sn_cfctl%procincr = 1
282      ELSEIF( sn_cfctl%l_config ) THEN
283         ! Activate finer control of report outputs
284         ! optionally switch off output from selected areas (note this only
285         ! applies to output which does not involve global communications)
286         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
287           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
288           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
289      ELSE
290         ! turn off all options.
291         CALL nemo_set_cfctl( sn_cfctl, .FALSE., .TRUE. )
292      ENDIF
293      !
294      lwp = (narea == 1) .OR. sn_cfctl%l_oceout    ! control of all listing output print
295      !
296      IF(lwp) THEN                      ! open listing units
297         !
298         IF( .NOT. lwm ) THEN           ! alreay opened for narea == 1
299            IF(lk_oasis) THEN   ;   CALL ctl_opn( numout,   'sas.output','REPLACE','FORMATTED','SEQUENTIAL',-1,-1, .FALSE., narea )
300            ELSE                ;   CALL ctl_opn( numout, 'ocean.output','REPLACE','FORMATTED','SEQUENTIAL',-1,-1, .FALSE., narea )
301            ENDIF
302         ENDIF
303         !
304         WRITE(numout,*)
305         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
306         WRITE(numout,*) '                       NEMO team'
307         WRITE(numout,*) '            Ocean General Circulation Model'
308         WRITE(numout,*) '                NEMO version 4.0  (2019) '
309         WRITE(numout,*) '             StandAlone Surface version (SAS) '
310         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
311         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
312         WRITE(numout,*)
313         WRITE(numout,*) "           o         _,           _,             "
314         WRITE(numout,*) "            o      .' (        .-' /             "
315         WRITE(numout,*) "           o     _/..._'.    .'   /              "
316         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
317         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
318         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
319         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
320         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
321         WRITE(numout,*) "       )  ) jgs                    `     (   (   "
322         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
323         WRITE(numout,*)
324         WRITE(numout,*)
325         !
326         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
327         !
328      ENDIF
329      !
330      IF(lwm) WRITE( numond, namctl )
331      !
332      !                             !------------------------------------!
333      !                             !  Set global domain size parameters !
334      !                             !------------------------------------!
335      !
336      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
337903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
338      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
339904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
340      !
341      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
342         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
343      ELSE                              ! user-defined namelist
344         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
345      ENDIF
346      !
347      IF(lwm)   WRITE( numond, namcfg )
348      !
349      !                             !-----------------------------------------!
350      !                             ! mpp parameters and domain decomposition !
351      !                             !-----------------------------------------!
352      CALL mpp_init
353
354      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
355      CALL nemo_alloc()
356
357      ! Initialise time level indices
358      Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
359
360      !                             !-------------------------------!
361      !                             !  NEMO general initialization  !
362      !                             !-------------------------------!
363
364      CALL nemo_ctl                          ! Control prints
365      !
366      !                                      ! General initialization
367      IF( ln_timing    )   CALL timing_init     ! timing
368      IF( ln_timing    )   CALL timing_start( 'nemo_init')
369
370                           CALL phy_cst         ! Physical constants
371                           CALL eos_init        ! Equation of seawater
372                           CALL dom_init( Nbb, Nnn, Naa, 'SAS') ! Domain
373      IF( sn_cfctl%l_prtctl )   &
374         &                 CALL prt_ctl_init        ! Print control
375     
376                           CALL day_init        ! model calendar (using both namelist and restart infos)
377      IF( ln_rstart )      CALL rst_read_open
378
379      !                                      ! external forcing
380                           CALL sbc_init( Nbb, Nnn, Naa )  ! Forcings : surface module
381
382      ! ==> clem: open boundaries init. is mandatory for sea-ice because ice BDY is not decoupled from 
383      !           the environment of ocean BDY. Therefore bdy is called in both OPA and SAS modules.
384      !           This is not clean and should be changed in the future.
385                           CALL bdy_init
386      ! ==>
387                           CALL icb_init( rn_Dt, nit000)   ! initialise icebergs instance
388      !
389      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
390      !
391      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
392      !
393   END SUBROUTINE nemo_init
394
395
396   SUBROUTINE nemo_ctl
397      !!----------------------------------------------------------------------
398      !!                     ***  ROUTINE nemo_ctl  ***
399      !!
400      !! ** Purpose :   control print setting
401      !!
402      !! ** Method  : - print namctl and namcfg information and check some consistencies
403      !!----------------------------------------------------------------------
404      !
405      IF(lwp) THEN                  ! control print
406         WRITE(numout,*)
407         WRITE(numout,*) 'nemo_ctl: Control prints'
408         WRITE(numout,*) '~~~~~~~~'
409         WRITE(numout,*) '   Namelist namctl'
410         WRITE(numout,*) '                              sn_cfctl%l_glochk  = ', sn_cfctl%l_glochk
411         WRITE(numout,*) '                              sn_cfctl%l_allon   = ', sn_cfctl%l_allon
412         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
413         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
414         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
415         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
416         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
417         WRITE(numout,*) '                              sn_cfctl%l_prtctl  = ', sn_cfctl%l_prtctl
418         WRITE(numout,*) '                              sn_cfctl%l_prttrc  = ', sn_cfctl%l_prttrc
419         WRITE(numout,*) '                              sn_cfctl%l_oasout  = ', sn_cfctl%l_oasout
420         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
421         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
422         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
423         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
424         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
425         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
426         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
427         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
428         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
429         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
430         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
431         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
432         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
433      ENDIF
434      !
435      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
436      nictls    = nn_ictls
437      nictle    = nn_ictle
438      njctls    = nn_jctls
439      njctle    = nn_jctle
440      isplt     = nn_isplt
441      jsplt     = nn_jsplt
442
443      IF(lwp) THEN                  ! control print
444         WRITE(numout,*)
445         WRITE(numout,*) '   Namelist namcfg'
446         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
447         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
448         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
449         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
450         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
451         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
452      ENDIF
453      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
454      !
455      !                             ! Parameter control
456      !
457      IF( sn_cfctl%l_prtctl .OR. sn_cfctl%l_prttrc ) THEN              ! sub-domain area indices for the control prints
458         IF( lk_mpp .AND. jpnij > 1 ) THEN
459            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
460         ELSE
461            IF( isplt == 1 .AND. jsplt == 1  ) THEN
462               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
463                  &           ' - the print control will be done over the whole domain' )
464            ENDIF
465            ijsplt = isplt * jsplt            ! total number of processors ijsplt
466         ENDIF
467         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
468         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
469         !
470         !                              ! indices used for the SUM control
471         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
472            lsp_area = .FALSE.
473         ELSE                                             ! print control done over a specific  area
474            lsp_area = .TRUE.
475            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
476               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
477               nictls = 1
478            ENDIF
479            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
480               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
481               nictle = jpiglo
482            ENDIF
483            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
484               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
485               njctls = 1
486            ENDIF
487            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
488               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
489               njctle = jpjglo
490            ENDIF
491         ENDIF
492      ENDIF
493      !
494      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
495         &                                                'Compile with key_nosignedzero enabled:',   &
496         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
497      !
498#if defined key_agrif
499      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
500#endif
501      !
502   END SUBROUTINE nemo_ctl
503
504
505   SUBROUTINE nemo_closefile
506      !!----------------------------------------------------------------------
507      !!                     ***  ROUTINE nemo_closefile  ***
508      !!
509      !! ** Purpose :   Close the files
510      !!----------------------------------------------------------------------
511      !
512      IF( lk_mpp )   CALL mppsync
513      !
514      CALL iom_close                                 ! close all input/output files managed by iom_*
515      !
516      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file     
517      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
518      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
519      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
520      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
521      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
522      !
523      numout = 6                                     ! redefine numout in case it is used after this point...
524      !
525   END SUBROUTINE nemo_closefile
526
527
528   SUBROUTINE nemo_alloc
529      !!----------------------------------------------------------------------
530      !!                     ***  ROUTINE nemo_alloc  ***
531      !!
532      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
533      !!
534      !! ** Method  :
535      !!----------------------------------------------------------------------
536      USE diawri    , ONLY : dia_wri_alloc
537      USE dom_oce   , ONLY : dom_oce_alloc
538      USE bdy_oce   , ONLY : ln_bdy, bdy_oce_alloc
539      USE oce       ! mandatory for sea-ice because needed for bdy arrays
540      !
541      INTEGER :: ierr
542      !!----------------------------------------------------------------------
543      !
544      ierr =        dia_wri_alloc()
545      ierr = ierr + dom_oce_alloc()          ! ocean domain
546      ierr = ierr + oce_alloc    ()          ! (tsn...) needed for agrif and/or SI3 and bdy
547      ierr = ierr + bdy_oce_alloc()          ! bdy masks (incl. initialization)
548      !
549      CALL mpp_sum( 'nemogcm', ierr )
550      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
551      !
552   END SUBROUTINE nemo_alloc
553
554   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
555      !!----------------------------------------------------------------------
556      !!                     ***  ROUTINE nemo_set_cfctl  ***
557      !!
558      !! ** Purpose :   Set elements of the output control structure to setto.
559      !!                for_all should be .false. unless all areas are to be
560      !!                treated identically.
561      !!
562      !! ** Method  :   Note this routine can be used to switch on/off some
563      !!                types of output for selected areas but any output types
564      !!                that involve global communications (e.g. mpp_max, glob_sum)
565      !!                should be protected from selective switching by the
566      !!                for_all argument
567      !!----------------------------------------------------------------------
568      LOGICAL :: setto, for_all
569      TYPE(sn_ctl) :: sn_cfctl
570      !!----------------------------------------------------------------------
571      IF( for_all ) THEN
572         sn_cfctl%l_runstat = setto
573         sn_cfctl%l_trcstat = setto
574      ENDIF
575      sn_cfctl%l_oceout  = setto
576      sn_cfctl%l_layout  = setto
577      sn_cfctl%l_prtctl  = setto
578      sn_cfctl%l_prttrc  = setto
579      sn_cfctl%l_oasout  = setto
580   END SUBROUTINE nemo_set_cfctl
581
582   !!======================================================================
583END MODULE nemogcm
584
Note: See TracBrowser for help on using the repository browser.