New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zche.F90 in NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/TOP/PISCES/P4Z/p4zche.F90 @ 12779

Last change on this file since 12779 was 12779, checked in by techene, 4 years ago

modify TOP to be able to run with key_qco i.e. remove e3. gdep. and use a substitute instead (# include "domzgr_substitute.h90")
  • Property svn:keywords set to Id
File size: 36.2 KB
Line 
1MODULE p4zche
2   !!======================================================================
3   !!                         ***  MODULE p4zche  ***
4   !! TOP :   PISCES Sea water chemistry computed following OCMIP protocol
5   !!======================================================================
6   !! History :   OPA  !  1988     (E. Maier-Reimer)  Original code
7   !!              -   !  1998     (O. Aumont)  addition
8   !!              -   !  1999     (C. Le Quere)  modification
9   !!   NEMO      1.0  !  2004     (O. Aumont)  modification
10   !!              -   !  2006     (R. Gangsto)  modification
11   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
12   !!                  !  2011-02  (J. Simeon, J.Orr ) update O2 solubility constants
13   !!             3.6  !  2016-03  (O. Aumont) Change chemistry to MOCSY standards
14   !!----------------------------------------------------------------------
15   !!   p4z_che      :  Sea water chemistry computed following OCMIP protocol
16   !!----------------------------------------------------------------------
17   USE oce_trc       !  shared variables between ocean and passive tracers
18   USE trc           !  passive tracers common variables
19   USE sms_pisces    !  PISCES Source Minus Sink variables
20   USE lib_mpp       !  MPP library
21   USE eosbn2, ONLY : neos
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_che          !
27   PUBLIC   p4z_che_alloc    !
28   PUBLIC   ahini_for_at     !
29   PUBLIC   solve_at_general !
30
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)   :: sio3eq   ! chemistry of Si
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)   :: fekeq    ! chemistry of Fe
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)   :: chemc    ! Solubilities of O2 and CO2
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)   :: chemo2    ! Solubilities of O2 and CO2
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: fesol    ! solubility of Fe
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   salinprac  ! Practical salinity
37   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   tempis   ! In situ temperature
38
39   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   akb3       !: ???
40   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   akw3       !: ???
41   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   akf3       !: ???
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   aks3       !: ???
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ak1p3      !: ???
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ak2p3      !: ???
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ak3p3      !: ???
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   aksi3      !: ???
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   borat      !: ???
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   fluorid    !: ???
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sulfat     !: ???
50
51   !!* Variable for chemistry of the CO2 cycle
52
53   REAL(wp), PUBLIC ::   atcox  = 0.20946         ! units atm
54
55   REAL(wp) ::   o2atm  = 1. / ( 1000. * 0.20946 ) 
56
57   REAL(wp) ::   rgas   = 83.14472      ! universal gas constants
58   REAL(wp) ::   oxyco  = 1. / 22.4144  ! converts from liters of an ideal gas to moles
59   !                                    ! coeff. for seawater pressure correction : millero 95
60   !                                    ! AGRIF doesn't like the DATA instruction
61   REAL(wp) :: devk10  = -25.5
62   REAL(wp) :: devk11  = -15.82
63   REAL(wp) :: devk12  = -29.48
64   REAL(wp) :: devk13  = -20.02
65   REAL(wp) :: devk14  = -18.03
66   REAL(wp) :: devk15  = -9.78
67   REAL(wp) :: devk16  = -48.76
68   REAL(wp) :: devk17  = -14.51
69   REAL(wp) :: devk18  = -23.12
70   REAL(wp) :: devk19  = -26.57
71   REAL(wp) :: devk110  = -29.48
72   !
73   REAL(wp) :: devk20  = 0.1271
74   REAL(wp) :: devk21  = -0.0219
75   REAL(wp) :: devk22  = 0.1622
76   REAL(wp) :: devk23  = 0.1119
77   REAL(wp) :: devk24  = 0.0466
78   REAL(wp) :: devk25  = -0.0090
79   REAL(wp) :: devk26  = 0.5304
80   REAL(wp) :: devk27  = 0.1211
81   REAL(wp) :: devk28  = 0.1758
82   REAL(wp) :: devk29  = 0.2020
83   REAL(wp) :: devk210  = 0.1622
84   !
85   REAL(wp) :: devk30  = 0.
86   REAL(wp) :: devk31  = 0.
87   REAL(wp) :: devk32  = 2.608E-3
88   REAL(wp) :: devk33  = -1.409e-3
89   REAL(wp) :: devk34  = 0.316e-3
90   REAL(wp) :: devk35  = -0.942e-3
91   REAL(wp) :: devk36  = 0.
92   REAL(wp) :: devk37  = -0.321e-3
93   REAL(wp) :: devk38  = -2.647e-3
94   REAL(wp) :: devk39  = -3.042e-3
95   REAL(wp) :: devk310  = -2.6080e-3
96   !
97   REAL(wp) :: devk40  = -3.08E-3
98   REAL(wp) :: devk41  = 1.13E-3
99   REAL(wp) :: devk42  = -2.84E-3
100   REAL(wp) :: devk43  = -5.13E-3
101   REAL(wp) :: devk44  = -4.53e-3
102   REAL(wp) :: devk45  = -3.91e-3
103   REAL(wp) :: devk46  = -11.76e-3
104   REAL(wp) :: devk47  = -2.67e-3
105   REAL(wp) :: devk48  = -5.15e-3
106   REAL(wp) :: devk49  = -4.08e-3
107   REAL(wp) :: devk410  = -2.84e-3
108   !
109   REAL(wp) :: devk50  = 0.0877E-3
110   REAL(wp) :: devk51  = -0.1475E-3     
111   REAL(wp) :: devk52  = 0.
112   REAL(wp) :: devk53  = 0.0794E-3     
113   REAL(wp) :: devk54  = 0.09e-3
114   REAL(wp) :: devk55  = 0.054e-3
115   REAL(wp) :: devk56  = 0.3692E-3
116   REAL(wp) :: devk57  = 0.0427e-3
117   REAL(wp) :: devk58  = 0.09e-3
118   REAL(wp) :: devk59  = 0.0714e-3
119   REAL(wp) :: devk510  = 0.0
120   !
121   ! General parameters
122   REAL(wp), PARAMETER :: pp_rdel_ah_target = 1.E-4_wp
123   REAL(wp), PARAMETER :: pp_ln10 = 2.302585092994045684018_wp
124
125   ! Maximum number of iterations for each method
126   INTEGER, PARAMETER :: jp_maxniter_atgen    = 20
127
128   ! Bookkeeping variables for each method
129   ! - SOLVE_AT_GENERAL
130   INTEGER :: niter_atgen    = jp_maxniter_atgen
131
132   !! * Substitutions
133#  include "do_loop_substitute.h90"
134#  include "domzgr_substitute.h90"
135   !!----------------------------------------------------------------------
136   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
137   !! $Id$
138   !! Software governed by the CeCILL license (see ./LICENSE)
139   !!----------------------------------------------------------------------
140CONTAINS
141
142   SUBROUTINE p4z_che( Kbb, Kmm )
143      !!---------------------------------------------------------------------
144      !!                     ***  ROUTINE p4z_che  ***
145      !!
146      !! ** Purpose :   Sea water chemistry computed following OCMIP protocol
147      !!
148      !! ** Method  : - ...
149      !!---------------------------------------------------------------------
150      INTEGER, INTENT(in) ::   Kbb, Kmm  ! time level indices
151      INTEGER  ::   ji, jj, jk
152      REAL(wp) ::   ztkel, ztkel1, zt , zsal  , zsal2 , zbuf1 , zbuf2
153      REAL(wp) ::   ztgg , ztgg2, ztgg3 , ztgg4 , ztgg5
154      REAL(wp) ::   zpres, ztc  , zcl   , zcpexp, zoxy  , zcpexp2
155      REAL(wp) ::   zsqrt, ztr  , zlogt , zcek1, zc1, zplat
156      REAL(wp) ::   zis  , zis2 , zsal15, zisqrt, za1, za2
157      REAL(wp) ::   zckb , zck1 , zck2  , zckw  , zak1 , zak2  , zakb , zaksp0, zakw
158      REAL(wp) ::   zck1p, zck2p, zck3p, zcksi, zak1p, zak2p, zak3p, zaksi
159      REAL(wp) ::   zst  , zft  , zcks  , zckf  , zaksp1
160      REAL(wp) ::   total2free, free2SWS, total2SWS, SWS2total
161      !!---------------------------------------------------------------------
162      !
163      IF( ln_timing )   CALL timing_start('p4z_che')
164      !
165      ! Computation of chemical constants require practical salinity
166      ! Thus, when TEOS08 is used, absolute salinity is converted to
167      ! practical salinity
168      ! -------------------------------------------------------------
169      IF (neos == -1) THEN
170         salinprac(:,:,:) = ts(:,:,:,jp_sal,Kmm) * 35.0 / 35.16504
171      ELSE
172         salinprac(:,:,:) = ts(:,:,:,jp_sal,Kmm)
173      ENDIF
174
175      !
176      ! Computations of chemical constants require in situ temperature
177      ! Here a quite simple formulation is used to convert
178      ! potential temperature to in situ temperature. The errors is less than
179      ! 0.04°C relative to an exact computation
180      ! ---------------------------------------------------------------------
181      DO_3D_11_11( 1, jpk )
182         zpres = gdept(ji,jj,jk,Kmm) / 1000.
183         za1 = 0.04 * ( 1.0 + 0.185 * ts(ji,jj,jk,jp_tem,Kmm) + 0.035 * (salinprac(ji,jj,jk) - 35.0) )
184         za2 = 0.0075 * ( 1.0 - ts(ji,jj,jk,jp_tem,Kmm) / 30.0 )
185         tempis(ji,jj,jk) = ts(ji,jj,jk,jp_tem,Kmm) - za1 * zpres + za2 * zpres**2
186      END_3D
187      !
188      ! CHEMICAL CONSTANTS - SURFACE LAYER
189      ! ----------------------------------
190!CDIR NOVERRCHK
191      DO jj = 1, jpj
192!CDIR NOVERRCHK
193         DO ji = 1, jpi
194            !                             ! SET ABSOLUTE TEMPERATURE
195            ztkel = tempis(ji,jj,1) + 273.15
196            zt    = ztkel * 0.01
197            zsal  = salinprac(ji,jj,1) + ( 1.- tmask(ji,jj,1) ) * 35.
198            !                             ! LN(K0) OF SOLUBILITY OF CO2 (EQ. 12, WEISS, 1980)
199            !                             !     AND FOR THE ATMOSPHERE FOR NON IDEAL GAS
200            zcek1 = 9345.17/ztkel - 60.2409 + 23.3585 * LOG(zt) + zsal*(0.023517 - 0.00023656*ztkel    &
201            &       + 0.0047036e-4*ztkel**2)
202            chemc(ji,jj,1) = EXP( zcek1 ) * 1E-6 * rhop(ji,jj,1) / 1000. ! mol/(L atm)
203            chemc(ji,jj,2) = -1636.75 + 12.0408*ztkel - 0.0327957*ztkel**2 + 0.0000316528*ztkel**3
204            chemc(ji,jj,3) = 57.7 - 0.118*ztkel
205            !
206         END DO
207      END DO
208
209      ! OXYGEN SOLUBILITY - DEEP OCEAN
210      ! -------------------------------
211!CDIR NOVERRCHK
212      DO jk = 1, jpk
213!CDIR NOVERRCHK
214         DO jj = 1, jpj
215!CDIR NOVERRCHK
216            DO ji = 1, jpi
217              ztkel = tempis(ji,jj,jk) + 273.15
218              zsal  = salinprac(ji,jj,jk) + ( 1.- tmask(ji,jj,jk) ) * 35.
219              zsal2 = zsal * zsal
220              ztgg  = LOG( ( 298.15 - tempis(ji,jj,jk) ) / ztkel )  ! Set the GORDON & GARCIA scaled temperature
221              ztgg2 = ztgg  * ztgg
222              ztgg3 = ztgg2 * ztgg
223              ztgg4 = ztgg3 * ztgg
224              ztgg5 = ztgg4 * ztgg
225
226              zoxy  = 2.00856 + 3.22400 * ztgg + 3.99063 * ztgg2 + 4.80299 * ztgg3    &
227              &       + 9.78188e-1 * ztgg4 + 1.71069 * ztgg5 + zsal * ( -6.24097e-3   &
228              &       - 6.93498e-3 * ztgg - 6.90358e-3 * ztgg2 - 4.29155e-3 * ztgg3 )   &
229              &       - 3.11680e-7 * zsal2
230              chemo2(ji,jj,jk) = ( EXP( zoxy ) * o2atm ) * oxyco * atcox     ! mol/(L atm)
231            END DO
232          END DO
233        END DO
234
235      ! CHEMICAL CONSTANTS - DEEP OCEAN
236      ! -------------------------------
237!CDIR NOVERRCHK
238      DO jk = 1, jpk
239!CDIR NOVERRCHK
240         DO jj = 1, jpj
241!CDIR NOVERRCHK
242            DO ji = 1, jpi
243
244               ! SET PRESSION ACCORDING TO SAUNDER (1980)
245               zplat   = SIN ( ABS(gphit(ji,jj)*3.141592654/180.) )
246               zc1 = 5.92E-3 + zplat**2 * 5.25E-3
247               zpres = ((1-zc1)-SQRT(((1-zc1)**2)-(8.84E-6*gdept(ji,jj,jk,Kmm)))) / 4.42E-6
248               zpres = zpres / 10.0
249
250               ! SET ABSOLUTE TEMPERATURE
251               ztkel   = tempis(ji,jj,jk) + 273.15
252               zsal    = salinprac(ji,jj,jk) + ( 1.-tmask(ji,jj,jk) ) * 35.
253               zsqrt  = SQRT( zsal )
254               zsal15  = zsqrt * zsal
255               zlogt  = LOG( ztkel )
256               ztr    = 1. / ztkel
257               zis    = 19.924 * zsal / ( 1000.- 1.005 * zsal )
258               zis2   = zis * zis
259               zisqrt = SQRT( zis )
260               ztc     = tempis(ji,jj,jk) + ( 1.- tmask(ji,jj,jk) ) * 20.
261
262               ! CHLORINITY (WOOSTER ET AL., 1969)
263               zcl     = zsal / 1.80655
264
265               ! TOTAL SULFATE CONCENTR. [MOLES/kg soln]
266               zst     = 0.14 * zcl /96.062
267
268               ! TOTAL FLUORIDE CONCENTR. [MOLES/kg soln]
269               zft     = 0.000067 * zcl /18.9984
270
271               ! DISSOCIATION CONSTANT FOR SULFATES on free H scale (Dickson 1990)
272               zcks    = EXP(-4276.1 * ztr + 141.328 - 23.093 * zlogt         &
273               &         + (-13856. * ztr + 324.57 - 47.986 * zlogt) * zisqrt &
274               &         + (35474. * ztr - 771.54 + 114.723 * zlogt) * zis    &
275               &         - 2698. * ztr * zis**1.5 + 1776.* ztr * zis2         &
276               &         + LOG(1.0 - 0.001005 * zsal))
277
278               ! DISSOCIATION CONSTANT FOR FLUORIDES on free H scale (Dickson and Riley 79)
279               zckf    = EXP( 1590.2*ztr - 12.641 + 1.525*zisqrt   &
280               &         + LOG(1.0d0 - 0.001005d0*zsal)            &
281               &         + LOG(1.0d0 + zst/zcks))
282
283               ! DISSOCIATION CONSTANT FOR CARBONATE AND BORATE
284               zckb=  (-8966.90 - 2890.53*zsqrt - 77.942*zsal        &
285               &      + 1.728*zsal15 - 0.0996*zsal*zsal)*ztr         &
286               &      + (148.0248 + 137.1942*zsqrt + 1.62142*zsal)   &
287               &      + (-24.4344 - 25.085*zsqrt - 0.2474*zsal)      & 
288               &      * zlogt + 0.053105*zsqrt*ztkel
289
290               ! DISSOCIATION COEFFICIENT FOR CARBONATE ACCORDING TO
291               ! MEHRBACH (1973) REFIT BY MILLERO (1995), seawater scale
292               zck1    = -1.0*(3633.86*ztr - 61.2172 + 9.6777*zlogt  &
293                  - 0.011555*zsal + 0.0001152*zsal*zsal)
294               zck2    = -1.0*(471.78*ztr + 25.9290 - 3.16967*zlogt      &
295                  - 0.01781*zsal + 0.0001122*zsal*zsal)
296
297               ! PKW (H2O) (MILLERO, 1995) from composite data
298               zckw    = -13847.26 * ztr + 148.9652 - 23.6521 * zlogt + ( 118.67 * ztr    &
299                         - 5.977 + 1.0495 * zlogt ) * zsqrt - 0.01615 * zsal
300
301               ! CONSTANTS FOR PHOSPHATE (MILLERO, 1995)
302              zck1p    = -4576.752*ztr + 115.540 - 18.453*zlogt   &
303              &          + (-106.736*ztr + 0.69171) * zsqrt       &
304              &          + (-0.65643*ztr - 0.01844) * zsal
305
306              zck2p    = -8814.715*ztr + 172.1033 - 27.927*zlogt  &
307              &          + (-160.340*ztr + 1.3566)*zsqrt          &
308              &          + (0.37335*ztr - 0.05778)*zsal
309
310              zck3p    = -3070.75*ztr - 18.126                    &
311              &          + (17.27039*ztr + 2.81197) * zsqrt       &
312              &          + (-44.99486*ztr - 0.09984) * zsal 
313
314              ! CONSTANT FOR SILICATE, MILLERO (1995)
315              zcksi    = -8904.2*ztr  + 117.400 - 19.334*zlogt   &
316              &          + (-458.79*ztr + 3.5913) * zisqrt       &
317              &          + (188.74*ztr - 1.5998) * zis           &
318              &          + (-12.1652*ztr + 0.07871) * zis2       &
319              &          + LOG(1.0 - 0.001005*zsal)
320
321               ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE IN SEAWATER
322               !       (S=27-43, T=2-25 DEG C) at pres =0 (atmos. pressure) (MUCCI 1983)
323               zaksp0  = -171.9065 -0.077993*ztkel + 2839.319*ztr + 71.595*LOG10( ztkel )   &
324                  &      + (-0.77712 + 0.00284263*ztkel + 178.34*ztr) * zsqrt  &
325                  &      - 0.07711*zsal + 0.0041249*zsal15
326
327               ! CONVERT FROM DIFFERENT PH SCALES
328               total2free  = 1.0/(1.0 + zst/zcks)
329               free2SWS    = 1. + zst/zcks + zft/(zckf*total2free)
330               total2SWS   = total2free * free2SWS
331               SWS2total   = 1.0 / total2SWS
332
333               ! K1, K2 OF CARBONIC ACID, KB OF BORIC ACID, KW (H2O) (LIT.?)
334               zak1    = 10**(zck1) * total2SWS
335               zak2    = 10**(zck2) * total2SWS
336               zakb    = EXP( zckb ) * total2SWS
337               zakw    = EXP( zckw )
338               zaksp1  = 10**(zaksp0)
339               zak1p   = exp( zck1p )
340               zak2p   = exp( zck2p )
341               zak3p   = exp( zck3p )
342               zaksi   = exp( zcksi )
343               zckf    = zckf * total2SWS
344
345               ! FORMULA FOR CPEXP AFTER EDMOND & GIESKES (1970)
346               !        (REFERENCE TO CULBERSON & PYTKOQICZ (1968) AS MADE
347               !        IN BROECKER ET AL. (1982) IS INCORRECT; HERE RGAS IS
348               !        TAKEN TENFOLD TO CORRECT FOR THE NOTATION OF pres  IN
349               !        DBAR INSTEAD OF BAR AND THE EXPRESSION FOR CPEXP IS
350               !        MULTIPLIED BY LN(10.) TO ALLOW USE OF EXP-FUNCTION
351               !        WITH BASIS E IN THE FORMULA FOR AKSPP (CF. EDMOND
352               !        & GIESKES (1970), P. 1285-1286 (THE SMALL
353               !        FORMULA ON P. 1286 IS RIGHT AND CONSISTENT WITH THE
354               !        SIGN IN PARTIAL MOLAR VOLUME CHANGE AS SHOWN ON P. 1285))
355               zcpexp  = zpres / (rgas*ztkel)
356               zcpexp2 = zpres * zcpexp
357
358               ! KB OF BORIC ACID, K1,K2 OF CARBONIC ACID PRESSURE
359               !        CORRECTION AFTER CULBERSON AND PYTKOWICZ (1968)
360               !        (CF. BROECKER ET AL., 1982)
361
362               zbuf1  = -     ( devk10 + devk20 * ztc + devk30 * ztc * ztc )
363               zbuf2  = 0.5 * ( devk40 + devk50 * ztc )
364               ak13(ji,jj,jk) = zak1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
365
366               zbuf1  =     - ( devk11 + devk21 * ztc + devk31 * ztc * ztc )
367               zbuf2  = 0.5 * ( devk41 + devk51 * ztc )
368               ak23(ji,jj,jk) = zak2 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
369
370               zbuf1  =     - ( devk12 + devk22 * ztc + devk32 * ztc * ztc )
371               zbuf2  = 0.5 * ( devk42 + devk52 * ztc )
372               akb3(ji,jj,jk) = zakb * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
373
374               zbuf1  =     - ( devk13 + devk23 * ztc + devk33 * ztc * ztc )
375               zbuf2  = 0.5 * ( devk43 + devk53 * ztc )
376               akw3(ji,jj,jk) = zakw * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
377
378               zbuf1  =     - ( devk14 + devk24 * ztc + devk34 * ztc * ztc )
379               zbuf2  = 0.5 * ( devk44 + devk54 * ztc )
380               aks3(ji,jj,jk) = zcks * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
381
382               zbuf1  =     - ( devk15 + devk25 * ztc + devk35 * ztc * ztc )
383               zbuf2  = 0.5 * ( devk45 + devk55 * ztc )
384               akf3(ji,jj,jk) = zckf * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
385
386               zbuf1  =     - ( devk17 + devk27 * ztc + devk37 * ztc * ztc )
387               zbuf2  = 0.5 * ( devk47 + devk57 * ztc )
388               ak1p3(ji,jj,jk) = zak1p * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
389
390               zbuf1  =     - ( devk18 + devk28 * ztc + devk38 * ztc * ztc )
391               zbuf2  = 0.5 * ( devk48 + devk58 * ztc )
392               ak2p3(ji,jj,jk) = zak2p * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
393
394               zbuf1  =     - ( devk19 + devk29 * ztc + devk39 * ztc * ztc )
395               zbuf2  = 0.5 * ( devk49 + devk59 * ztc )
396               ak3p3(ji,jj,jk) = zak3p * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
397
398               zbuf1  =     - ( devk110 + devk210 * ztc + devk310 * ztc * ztc )
399               zbuf2  = 0.5 * ( devk410 + devk510 * ztc )
400               aksi3(ji,jj,jk) = zaksi * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
401
402               ! CONVERT FROM DIFFERENT PH SCALES
403               total2free  = 1.0/(1.0 + zst/aks3(ji,jj,jk))
404               free2SWS    = 1. + zst/aks3(ji,jj,jk) + zft/akf3(ji,jj,jk)
405               total2SWS   = total2free * free2SWS
406               SWS2total   = 1.0 / total2SWS
407
408               ! Convert to total scale
409               ak13(ji,jj,jk)  = ak13(ji,jj,jk)  * SWS2total
410               ak23(ji,jj,jk)  = ak23(ji,jj,jk)  * SWS2total
411               akb3(ji,jj,jk)  = akb3(ji,jj,jk)  * SWS2total
412               akw3(ji,jj,jk)  = akw3(ji,jj,jk)  * SWS2total
413               ak1p3(ji,jj,jk) = ak1p3(ji,jj,jk) * SWS2total
414               ak2p3(ji,jj,jk) = ak2p3(ji,jj,jk) * SWS2total
415               ak3p3(ji,jj,jk) = ak3p3(ji,jj,jk) * SWS2total
416               aksi3(ji,jj,jk) = aksi3(ji,jj,jk) * SWS2total
417               akf3(ji,jj,jk)  = akf3(ji,jj,jk)  / total2free
418
419               ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE
420               !        AS FUNCTION OF PRESSURE FOLLOWING MILLERO
421               !        (P. 1285) AND BERNER (1976)
422               zbuf1  =     - ( devk16 + devk26 * ztc + devk36 * ztc * ztc )
423               zbuf2  = 0.5 * ( devk46 + devk56 * ztc )
424               aksp(ji,jj,jk) = zaksp1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
425
426               ! TOTAL F, S, and BORATE CONCENTR. [MOLES/L]
427               borat(ji,jj,jk) = 0.0002414 * zcl / 10.811
428               sulfat(ji,jj,jk) = zst
429               fluorid(ji,jj,jk) = zft 
430
431               ! Iron and SIO3 saturation concentration from ...
432               sio3eq(ji,jj,jk) = EXP(  LOG( 10.) * ( 6.44 - 968. / ztkel )  ) * 1.e-6
433               fekeq (ji,jj,jk) = 10**( 17.27 - 1565.7 / ztkel )
434
435               ! Liu and Millero (1999) only valid 5 - 50 degC
436               ztkel1 = MAX( 5. , tempis(ji,jj,jk) ) + 273.16
437               fesol(ji,jj,jk,1) = 10**(-13.486 - 0.1856* zis**0.5 + 0.3073*zis + 5254.0/ztkel1)
438               fesol(ji,jj,jk,2) = 10**(2.517 - 0.8885*zis**0.5 + 0.2139 * zis - 1320.0/ztkel1 )
439               fesol(ji,jj,jk,3) = 10**(0.4511 - 0.3305*zis**0.5 - 1996.0/ztkel1 )
440               fesol(ji,jj,jk,4) = 10**(-0.2965 - 0.7881*zis**0.5 - 4086.0/ztkel1 )
441               fesol(ji,jj,jk,5) = 10**(4.4466 - 0.8505*zis**0.5 - 7980.0/ztkel1 )
442            END DO
443         END DO
444      END DO
445      !
446      IF( ln_timing )  CALL timing_stop('p4z_che')
447      !
448   END SUBROUTINE p4z_che
449
450   SUBROUTINE ahini_for_at(p_hini, Kbb )
451      !!---------------------------------------------------------------------
452      !!                     ***  ROUTINE ahini_for_at  ***
453      !!
454      !! Subroutine returns the root for the 2nd order approximation of the
455      !! DIC -- B_T -- A_CB equation for [H+] (reformulated as a cubic
456      !! polynomial) around the local minimum, if it exists.
457      !! Returns * 1E-03_wp if p_alkcb <= 0
458      !!         * 1E-10_wp if p_alkcb >= 2*p_dictot + p_bortot
459      !!         * 1E-07_wp if 0 < p_alkcb < 2*p_dictot + p_bortot
460      !!                    and the 2nd order approximation does not have
461      !!                    a solution
462      !!---------------------------------------------------------------------
463      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT)  ::  p_hini
464      INTEGER,                          INTENT(in)   ::  Kbb      ! time level indices
465      INTEGER  ::   ji, jj, jk
466      REAL(wp)  ::  zca1, zba1
467      REAL(wp)  ::  zd, zsqrtd, zhmin
468      REAL(wp)  ::  za2, za1, za0
469      REAL(wp)  ::  p_dictot, p_bortot, p_alkcb 
470      !!---------------------------------------------------------------------
471
472      IF( ln_timing )  CALL timing_start('ahini_for_at')
473      !
474      DO_3D_11_11( 1, jpk )
475      p_alkcb  = tr(ji,jj,jk,jptal,Kbb) * 1000. / (rhop(ji,jj,jk) + rtrn)
476      p_dictot = tr(ji,jj,jk,jpdic,Kbb) * 1000. / (rhop(ji,jj,jk) + rtrn)
477      p_bortot = borat(ji,jj,jk)
478      IF (p_alkcb <= 0.) THEN
479          p_hini(ji,jj,jk) = 1.e-3
480      ELSEIF (p_alkcb >= (2.*p_dictot + p_bortot)) THEN
481          p_hini(ji,jj,jk) = 1.e-10_wp
482      ELSE
483          zca1 = p_dictot/( p_alkcb + rtrn )
484          zba1 = p_bortot/ (p_alkcb + rtrn )
485     ! Coefficients of the cubic polynomial
486          za2 = aKb3(ji,jj,jk)*(1. - zba1) + ak13(ji,jj,jk)*(1.-zca1)
487          za1 = ak13(ji,jj,jk)*akb3(ji,jj,jk)*(1. - zba1 - zca1)    &
488          &     + ak13(ji,jj,jk)*ak23(ji,jj,jk)*(1. - (zca1+zca1))
489          za0 = ak13(ji,jj,jk)*ak23(ji,jj,jk)*akb3(ji,jj,jk)*(1. - zba1 - (zca1+zca1))
490                                  ! Taylor expansion around the minimum
491          zd = za2*za2 - 3.*za1   ! Discriminant of the quadratic equation
492                                  ! for the minimum close to the root
493
494          IF(zd > 0.) THEN        ! If the discriminant is positive
495            zsqrtd = SQRT(zd)
496            IF(za2 < 0) THEN
497              zhmin = (-za2 + zsqrtd)/3.
498            ELSE
499              zhmin = -za1/(za2 + zsqrtd)
500            ENDIF
501            p_hini(ji,jj,jk) = zhmin + SQRT(-(za0 + zhmin*(za1 + zhmin*(za2 + zhmin)))/zsqrtd)
502          ELSE
503            p_hini(ji,jj,jk) = 1.e-7
504          ENDIF
505       !
506       ENDIF
507      END_3D
508      !
509      IF( ln_timing )  CALL timing_stop('ahini_for_at')
510      !
511   END SUBROUTINE ahini_for_at
512
513   !===============================================================================
514
515   SUBROUTINE anw_infsup( p_alknw_inf, p_alknw_sup, Kbb )
516
517   ! Subroutine returns the lower and upper bounds of "non-water-selfionization"
518   ! contributions to total alkalinity (the infimum and the supremum), i.e
519   ! inf(TA - [OH-] + [H+]) and sup(TA - [OH-] + [H+])
520
521   ! Argument variables
522   REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT) :: p_alknw_inf
523   REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT) :: p_alknw_sup
524   INTEGER,                          INTENT(in)  ::  Kbb      ! time level indices
525
526   p_alknw_inf(:,:,:) =  -tr(:,:,:,jppo4,Kbb) * 1000. / (rhop(:,:,:) + rtrn) - sulfat(:,:,:)  &
527   &              - fluorid(:,:,:)
528   p_alknw_sup(:,:,:) =   (2. * tr(:,:,:,jpdic,Kbb) + 2. * tr(:,:,:,jppo4,Kbb) + tr(:,:,:,jpsil,Kbb) )    &
529   &               * 1000. / (rhop(:,:,:) + rtrn) + borat(:,:,:) 
530
531   END SUBROUTINE anw_infsup
532
533
534   SUBROUTINE solve_at_general( p_hini, zhi, Kbb )
535
536   ! Universal pH solver that converges from any given initial value,
537   ! determines upper an lower bounds for the solution if required
538
539   ! Argument variables
540   !--------------------
541   REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(IN)   :: p_hini
542   REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT)  :: zhi
543   INTEGER,                          INTENT(in)   :: Kbb  ! time level indices
544
545   ! Local variables
546   !-----------------
547   INTEGER   ::  ji, jj, jk, jn
548   REAL(wp)  ::  zh_ini, zh, zh_prev, zh_lnfactor
549   REAL(wp)  ::  zdelta, zh_delta
550   REAL(wp)  ::  zeqn, zdeqndh, zalka
551   REAL(wp)  ::  aphscale
552   REAL(wp)  ::  znumer_dic, zdnumer_dic, zdenom_dic, zalk_dic, zdalk_dic
553   REAL(wp)  ::  znumer_bor, zdnumer_bor, zdenom_bor, zalk_bor, zdalk_bor
554   REAL(wp)  ::  znumer_po4, zdnumer_po4, zdenom_po4, zalk_po4, zdalk_po4
555   REAL(wp)  ::  znumer_sil, zdnumer_sil, zdenom_sil, zalk_sil, zdalk_sil
556   REAL(wp)  ::  znumer_so4, zdnumer_so4, zdenom_so4, zalk_so4, zdalk_so4
557   REAL(wp)  ::  znumer_flu, zdnumer_flu, zdenom_flu, zalk_flu, zdalk_flu
558   REAL(wp)  ::  zalk_wat, zdalk_wat
559   REAL(wp)  ::  zfact, p_alktot, zdic, zbot, zpt, zst, zft, zsit
560   LOGICAL   ::  l_exitnow
561   REAL(wp), PARAMETER :: pz_exp_threshold = 1.0
562   REAL(wp), DIMENSION(jpi,jpj,jpk) :: zalknw_inf, zalknw_sup, rmask, zh_min, zh_max, zeqn_absmin
563
564   IF( ln_timing )  CALL timing_start('solve_at_general')
565
566   CALL anw_infsup( zalknw_inf, zalknw_sup, Kbb )
567
568   rmask(:,:,:) = tmask(:,:,:)
569   zhi(:,:,:)   = 0.
570
571   ! TOTAL H+ scale: conversion factor for Htot = aphscale * Hfree
572   DO_3D_11_11( 1, jpk )
573      IF (rmask(ji,jj,jk) == 1.) THEN
574         p_alktot = tr(ji,jj,jk,jptal,Kbb) * 1000. / (rhop(ji,jj,jk) + rtrn)
575         aphscale = 1. + sulfat(ji,jj,jk)/aks3(ji,jj,jk)
576         zh_ini = p_hini(ji,jj,jk)
577
578         zdelta = (p_alktot-zalknw_inf(ji,jj,jk))**2 + 4.*akw3(ji,jj,jk)/aphscale
579
580         IF(p_alktot >= zalknw_inf(ji,jj,jk)) THEN
581           zh_min(ji,jj,jk) = 2.*akw3(ji,jj,jk) /( p_alktot-zalknw_inf(ji,jj,jk) + SQRT(zdelta) )
582         ELSE
583           zh_min(ji,jj,jk) = aphscale*(-(p_alktot-zalknw_inf(ji,jj,jk)) + SQRT(zdelta) ) / 2.
584         ENDIF
585
586         zdelta = (p_alktot-zalknw_sup(ji,jj,jk))**2 + 4.*akw3(ji,jj,jk)/aphscale
587
588         IF(p_alktot <= zalknw_sup(ji,jj,jk)) THEN
589           zh_max(ji,jj,jk) = aphscale*(-(p_alktot-zalknw_sup(ji,jj,jk)) + SQRT(zdelta) ) / 2.
590         ELSE
591           zh_max(ji,jj,jk) = 2.*akw3(ji,jj,jk) /( p_alktot-zalknw_sup(ji,jj,jk) + SQRT(zdelta) )
592         ENDIF
593
594         zhi(ji,jj,jk) = MAX(MIN(zh_max(ji,jj,jk), zh_ini), zh_min(ji,jj,jk))
595      ENDIF
596   END_3D
597
598   zeqn_absmin(:,:,:) = HUGE(1._wp)
599
600   DO jn = 1, jp_maxniter_atgen 
601   DO_3D_11_11( 1, jpk )
602      IF (rmask(ji,jj,jk) == 1.) THEN
603         zfact = rhop(ji,jj,jk) / 1000. + rtrn
604         p_alktot = tr(ji,jj,jk,jptal,Kbb) / zfact
605         zdic  = tr(ji,jj,jk,jpdic,Kbb) / zfact
606         zbot  = borat(ji,jj,jk)
607         zpt = tr(ji,jj,jk,jppo4,Kbb) / zfact * po4r
608         zsit = tr(ji,jj,jk,jpsil,Kbb) / zfact
609         zst = sulfat (ji,jj,jk)
610         zft = fluorid(ji,jj,jk)
611         aphscale = 1. + sulfat(ji,jj,jk)/aks3(ji,jj,jk)
612         zh = zhi(ji,jj,jk)
613         zh_prev = zh
614
615         ! H2CO3 - HCO3 - CO3 : n=2, m=0
616         znumer_dic = 2.*ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh*ak13(ji,jj,jk)
617         zdenom_dic = ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh*(ak13(ji,jj,jk) + zh)
618         zalk_dic   = zdic * (znumer_dic/zdenom_dic)
619         zdnumer_dic = ak13(ji,jj,jk)*ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh     &
620                       *(4.*ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh*ak13(ji,jj,jk))
621         zdalk_dic   = -zdic*(zdnumer_dic/zdenom_dic**2)
622
623
624         ! B(OH)3 - B(OH)4 : n=1, m=0
625         znumer_bor = akb3(ji,jj,jk)
626         zdenom_bor = akb3(ji,jj,jk) + zh
627         zalk_bor   = zbot * (znumer_bor/zdenom_bor)
628         zdnumer_bor = akb3(ji,jj,jk)
629         zdalk_bor   = -zbot*(zdnumer_bor/zdenom_bor**2)
630
631
632         ! H3PO4 - H2PO4 - HPO4 - PO4 : n=3, m=1
633         znumer_po4 = 3.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)  &
634         &            + zh*(2.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk) + zh* ak1p3(ji,jj,jk))
635         zdenom_po4 = ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)     &
636         &            + zh*( ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk) + zh*(ak1p3(ji,jj,jk) + zh))
637         zalk_po4   = zpt * (znumer_po4/zdenom_po4 - 1.) ! Zero level of H3PO4 = 1
638         zdnumer_po4 = ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)  &
639         &             + zh*(4.*ak1p3(ji,jj,jk)*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)         &
640         &             + zh*(9.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)                         &
641         &             + ak1p3(ji,jj,jk)*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)                                &
642         &             + zh*(4.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk) + zh * ak1p3(ji,jj,jk) ) ) )
643         zdalk_po4   = -zpt * (zdnumer_po4/zdenom_po4**2)
644
645         ! H4SiO4 - H3SiO4 : n=1, m=0
646         znumer_sil = aksi3(ji,jj,jk)
647         zdenom_sil = aksi3(ji,jj,jk) + zh
648         zalk_sil   = zsit * (znumer_sil/zdenom_sil)
649         zdnumer_sil = aksi3(ji,jj,jk)
650         zdalk_sil   = -zsit * (zdnumer_sil/zdenom_sil**2)
651
652         ! HSO4 - SO4 : n=1, m=1
653         aphscale = 1.0 + zst/aks3(ji,jj,jk)
654         znumer_so4 = aks3(ji,jj,jk) * aphscale
655         zdenom_so4 = aks3(ji,jj,jk) * aphscale + zh
656         zalk_so4   = zst * (znumer_so4/zdenom_so4 - 1.)
657         zdnumer_so4 = aks3(ji,jj,jk)
658         zdalk_so4   = -zst * (zdnumer_so4/zdenom_so4**2)
659
660         ! HF - F : n=1, m=1
661         znumer_flu =  akf3(ji,jj,jk)
662         zdenom_flu =  akf3(ji,jj,jk) + zh
663         zalk_flu   =  zft * (znumer_flu/zdenom_flu - 1.)
664         zdnumer_flu = akf3(ji,jj,jk)
665         zdalk_flu   = -zft * (zdnumer_flu/zdenom_flu**2)
666
667         ! H2O - OH
668         aphscale = 1.0 + zst/aks3(ji,jj,jk)
669         zalk_wat   = akw3(ji,jj,jk)/zh - zh/aphscale
670         zdalk_wat  = -akw3(ji,jj,jk)/zh**2 - 1./aphscale
671
672         ! CALCULATE [ALK]([CO3--], [HCO3-])
673         zeqn = zalk_dic + zalk_bor + zalk_po4 + zalk_sil   &
674         &      + zalk_so4 + zalk_flu                       &
675         &      + zalk_wat - p_alktot
676
677         zalka = p_alktot - (zalk_bor + zalk_po4 + zalk_sil   &
678         &       + zalk_so4 + zalk_flu + zalk_wat)
679
680         zdeqndh = zdalk_dic + zdalk_bor + zdalk_po4 + zdalk_sil &
681         &         + zdalk_so4 + zdalk_flu + zdalk_wat
682
683         ! Adapt bracketing interval
684         IF(zeqn > 0._wp) THEN
685           zh_min(ji,jj,jk) = zh_prev
686         ELSEIF(zeqn < 0._wp) THEN
687           zh_max(ji,jj,jk) = zh_prev
688         ENDIF
689
690         IF(ABS(zeqn) >= 0.5_wp*zeqn_absmin(ji,jj,jk)) THEN
691         ! if the function evaluation at the current point is
692         ! not decreasing faster than with a bisection step (at least linearly)
693         ! in absolute value take one bisection step on [ph_min, ph_max]
694         ! ph_new = (ph_min + ph_max)/2d0
695         !
696         ! In terms of [H]_new:
697         ! [H]_new = 10**(-ph_new)
698         !         = 10**(-(ph_min + ph_max)/2d0)
699         !         = SQRT(10**(-(ph_min + phmax)))
700         !         = SQRT(zh_max * zh_min)
701            zh = SQRT(zh_max(ji,jj,jk) * zh_min(ji,jj,jk))
702            zh_lnfactor = (zh - zh_prev)/zh_prev ! Required to test convergence below
703         ELSE
704         ! dzeqn/dpH = dzeqn/d[H] * d[H]/dpH
705         !           = -zdeqndh * LOG(10) * [H]
706         ! \Delta pH = -zeqn/(zdeqndh*d[H]/dpH) = zeqn/(zdeqndh*[H]*LOG(10))
707         !
708         ! pH_new = pH_old + \deltapH
709         !
710         ! [H]_new = 10**(-pH_new)
711         !         = 10**(-pH_old - \Delta pH)
712         !         = [H]_old * 10**(-zeqn/(zdeqndh*[H]_old*LOG(10)))
713         !         = [H]_old * EXP(-LOG(10)*zeqn/(zdeqndh*[H]_old*LOG(10)))
714         !         = [H]_old * EXP(-zeqn/(zdeqndh*[H]_old))
715
716            zh_lnfactor = -zeqn/(zdeqndh*zh_prev)
717
718            IF(ABS(zh_lnfactor) > pz_exp_threshold) THEN
719               zh          = zh_prev*EXP(zh_lnfactor)
720            ELSE
721               zh_delta    = zh_lnfactor*zh_prev
722               zh          = zh_prev + zh_delta
723            ENDIF
724
725            IF( zh < zh_min(ji,jj,jk) ) THEN
726               ! if [H]_new < [H]_min
727               ! i.e., if ph_new > ph_max then
728               ! take one bisection step on [ph_prev, ph_max]
729               ! ph_new = (ph_prev + ph_max)/2d0
730               ! In terms of [H]_new:
731               ! [H]_new = 10**(-ph_new)
732               !         = 10**(-(ph_prev + ph_max)/2d0)
733               !         = SQRT(10**(-(ph_prev + phmax)))
734               !         = SQRT([H]_old*10**(-ph_max))
735               !         = SQRT([H]_old * zh_min)
736               zh                = SQRT(zh_prev * zh_min(ji,jj,jk))
737               zh_lnfactor       = (zh - zh_prev)/zh_prev ! Required to test convergence below
738            ENDIF
739
740            IF( zh > zh_max(ji,jj,jk) ) THEN
741               ! if [H]_new > [H]_max
742               ! i.e., if ph_new < ph_min, then
743               ! take one bisection step on [ph_min, ph_prev]
744               ! ph_new = (ph_prev + ph_min)/2d0
745               ! In terms of [H]_new:
746               ! [H]_new = 10**(-ph_new)
747               !         = 10**(-(ph_prev + ph_min)/2d0)
748               !         = SQRT(10**(-(ph_prev + ph_min)))
749               !         = SQRT([H]_old*10**(-ph_min))
750               !         = SQRT([H]_old * zhmax)
751               zh                = SQRT(zh_prev * zh_max(ji,jj,jk))
752               zh_lnfactor       = (zh - zh_prev)/zh_prev ! Required to test convergence below
753            ENDIF
754         ENDIF
755
756         zeqn_absmin(ji,jj,jk) = MIN( ABS(zeqn), zeqn_absmin(ji,jj,jk))
757
758         ! Stop iterations once |\delta{[H]}/[H]| < rdel
759         ! <=> |(zh - zh_prev)/zh_prev| = |EXP(-zeqn/(zdeqndh*zh_prev)) -1| < rdel
760         ! |EXP(-zeqn/(zdeqndh*zh_prev)) -1| ~ |zeqn/(zdeqndh*zh_prev)|
761
762         ! Alternatively:
763         ! |\Delta pH| = |zeqn/(zdeqndh*zh_prev*LOG(10))|
764         !             ~ 1/LOG(10) * |\Delta [H]|/[H]
765         !             < 1/LOG(10) * rdel
766
767         ! Hence |zeqn/(zdeqndh*zh)| < rdel
768
769         ! rdel <-- pp_rdel_ah_target
770         l_exitnow = (ABS(zh_lnfactor) < pp_rdel_ah_target)
771
772         IF(l_exitnow) THEN
773            rmask(ji,jj,jk) = 0.
774         ENDIF
775
776         zhi(ji,jj,jk) =  zh
777
778         IF(jn >= jp_maxniter_atgen) THEN
779            zhi(ji,jj,jk) = -1._wp
780         ENDIF
781
782      ENDIF
783   END_3D
784   END DO
785   !
786
787      IF( ln_timing )   CALL timing_stop('solve_at_general')
788      !
789   END SUBROUTINE solve_at_general
790
791
792   INTEGER FUNCTION p4z_che_alloc()
793      !!----------------------------------------------------------------------
794      !!                     ***  ROUTINE p4z_che_alloc  ***
795      !!----------------------------------------------------------------------
796      INTEGER ::   ierr(3)        ! Local variables
797      !!----------------------------------------------------------------------
798
799      ierr(:) = 0
800
801      ALLOCATE( sio3eq(jpi,jpj,jpk), fekeq(jpi,jpj,jpk), chemc(jpi,jpj,3), chemo2(jpi,jpj,jpk), STAT=ierr(1) )
802
803      ALLOCATE( akb3(jpi,jpj,jpk)     , tempis(jpi, jpj, jpk),       &
804         &      akw3(jpi,jpj,jpk)     , borat (jpi,jpj,jpk)  ,       &
805         &      aks3(jpi,jpj,jpk)     , akf3(jpi,jpj,jpk)    ,       &
806         &      ak1p3(jpi,jpj,jpk)    , ak2p3(jpi,jpj,jpk)   ,       &
807         &      ak3p3(jpi,jpj,jpk)    , aksi3(jpi,jpj,jpk)   ,       &
808         &      fluorid(jpi,jpj,jpk)  , sulfat(jpi,jpj,jpk)  ,       &
809         &      salinprac(jpi,jpj,jpk),                 STAT=ierr(2) )
810
811      ALLOCATE( fesol(jpi,jpj,jpk,5), STAT=ierr(3) )
812
813      !* Variable for chemistry of the CO2 cycle
814      p4z_che_alloc = MAXVAL( ierr )
815      !
816      IF( p4z_che_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_che_alloc : failed to allocate arrays.' )
817      !
818   END FUNCTION p4z_che_alloc
819
820   !!======================================================================
821END MODULE p4zche
Note: See TracBrowser for help on using the repository browser.