New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trazdf.F90 in NEMO/branches/2020/dev_r12472_ASINTER-05_Masson_CurrentFeedback/tests/CANAL/MY_SRC – NEMO

source: NEMO/branches/2020/dev_r12472_ASINTER-05_Masson_CurrentFeedback/tests/CANAL/MY_SRC/trazdf.F90 @ 12495

Last change on this file since 12495 was 12495, checked in by smasson, 4 years ago

dev_r12472_ASINTER-05: update to trunk@12493, see #2156

  • Property svn:keywords set to Id
File size: 13.9 KB
Line 
1MODULE trazdf
2   !!==============================================================================
3   !!                 ***  MODULE  trazdf  ***
4   !! Ocean active tracers:  vertical component of the tracer mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!            4.0  !  2017-06  (G. Madec)  remove explict time-stepping option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_zdf       : Update the tracer trend with the vertical diffusion
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE domvvl         ! variable volume
17   USE phycst         ! physical constant
18   USE zdf_oce        ! ocean vertical physics variables
19   USE sbc_oce        ! surface boundary condition: ocean
20   USE ldftra         ! lateral diffusion: eddy diffusivity
21   USE ldfslp         ! lateral diffusion: iso-neutral slope
22   USE trd_oce        ! trends: ocean variables
23   USE trdtra         ! trends: tracer trend manager
24   !
25   USE in_out_manager ! I/O manager
26   USE prtctl         ! Print control
27   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
28   USE lib_mpp        ! MPP library
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_zdf       ! called by step.F90
35   PUBLIC   tra_zdf_imp   ! called by trczdf.F90
36
37   !!----------------------------------------------------------------------
38   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
39   !! $Id$
40   !! Software governed by the CeCILL license (see ./LICENSE)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE tra_zdf( kt, Kbb, Kmm, Krhs, pts, Kaa )
45      !!----------------------------------------------------------------------
46      !!                  ***  ROUTINE tra_zdf  ***
47      !!
48      !! ** Purpose :   compute the vertical ocean tracer physics.
49      !!---------------------------------------------------------------------
50      INTEGER                                  , INTENT(in)    :: kt                  ! ocean time-step index
51      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs, Kaa ! time level indices
52      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts                 ! active tracers and RHS of tracer equation
53      !
54      INTEGER  ::   jk   ! Dummy loop indices
55      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdt, ztrds   ! 3D workspace
56      !!---------------------------------------------------------------------
57      !
58      IF( ln_timing )   CALL timing_start('tra_zdf')
59      !
60      IF( kt == nit000 )  THEN
61         IF(lwp)WRITE(numout,*)
62         IF(lwp)WRITE(numout,*) 'tra_zdf : implicit vertical mixing on T & S'
63         IF(lwp)WRITE(numout,*) '~~~~~~~ '
64      ENDIF
65      !
66      IF( l_trdtra )   THEN                  !* Save ta and sa trends
67         ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) )
68         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kaa)
69         ztrds(:,:,:) = pts(:,:,:,jp_sal,Kaa)
70      ENDIF
71      !
72      !                                      !* compute lateral mixing trend and add it to the general trend
73      CALL tra_zdf_imp( kt, nit000, 'TRA', rDt, Kbb, Kmm, Krhs, pts, Kaa, jpts ) 
74
75!!gm WHY here !   and I don't like that !
76      ! DRAKKAR SSS control {
77      ! JMM avoid negative salinities near river outlet ! Ugly fix
78      ! JMM : restore negative salinities to small salinities:
79!!$   WHERE( pts(:,:,:,jp_sal,Kaa) < 0._wp )   pts(:,:,:,jp_sal,Kaa) = 0.1_wp
80!!gm
81
82      IF( l_trdtra )   THEN                      ! save the vertical diffusive trends for further diagnostics
83         DO jk = 1, jpkm1
84            ztrdt(:,:,jk) = ( ( pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa) - pts(:,:,jk,jp_tem,Kbb)*e3t(:,:,jk,Kbb) ) &
85               &          / (e3t(:,:,jk,Kmm)*rDt) ) - ztrdt(:,:,jk)
86            ztrds(:,:,jk) = ( ( pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa) - pts(:,:,jk,jp_sal,Kbb)*e3t(:,:,jk,Kbb) ) &
87              &           / (e3t(:,:,jk,Kmm)*rDt) ) - ztrds(:,:,jk)
88         END DO
89!!gm this should be moved in trdtra.F90 and done on all trends
90         CALL lbc_lnk_multi( 'trazdf', ztrdt, 'T', 1. , ztrds, 'T', 1. )
91!!gm
92         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_zdf, ztrdt )
93         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_zdf, ztrds )
94         DEALLOCATE( ztrdt , ztrds )
95      ENDIF
96      !                                          ! print mean trends (used for debugging)
97      IF(ln_ctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kaa), clinfo1=' zdf  - Ta: ', mask1=tmask,               &
98         &                       tab3d_2=pts(:,:,:,jp_sal,Kaa), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
99      !
100      IF( ln_timing )   CALL timing_stop('tra_zdf')
101      !
102   END SUBROUTINE tra_zdf
103
104 
105   SUBROUTINE tra_zdf_imp( kt, kit000, cdtype, p2dt, Kbb, Kmm, Krhs, pt, Kaa, kjpt ) 
106      !!----------------------------------------------------------------------
107      !!                  ***  ROUTINE tra_zdf_imp  ***
108      !!
109      !! ** Purpose :   Compute the after tracer through a implicit computation
110      !!     of the vertical tracer diffusion (including the vertical component
111      !!     of lateral mixing (only for 2nd order operator, for fourth order
112      !!     it is already computed and add to the general trend in traldf)
113      !!
114      !! ** Method  :  The vertical diffusion of a tracer ,t , is given by:
115      !!          difft = dz( avt dz(t) ) = 1/e3t dk+1( avt/e3w dk(t) )
116      !!      It is computed using a backward time scheme (t=after field)
117      !!      which provide directly the after tracer field.
118      !!      If ln_zdfddm=T, use avs for salinity or for passive tracers
119      !!      Surface and bottom boundary conditions: no diffusive flux on
120      !!      both tracers (bottom, applied through the masked field avt).
121      !!      If iso-neutral mixing, add to avt the contribution due to lateral mixing.
122      !!
123      !! ** Action  : - pt(:,:,:,:,Kaa)  becomes the after tracer
124      !!---------------------------------------------------------------------
125      INTEGER                                  , INTENT(in   ) ::   kt       ! ocean time-step index
126      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs, Kaa  ! ocean time level indices
127      INTEGER                                  , INTENT(in   ) ::   kit000   ! first time step index
128      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
129      INTEGER                                  , INTENT(in   ) ::   kjpt     ! number of tracers
130      REAL(wp)                                 , INTENT(in   ) ::   p2dt     ! tracer time-step
131      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt       ! tracers and RHS of tracer equation
132      !
133      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
134      REAL(wp) ::  zrhs, zzwi, zzws ! local scalars
135      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zwi, zwt, zwd, zws
136      !!---------------------------------------------------------------------
137      !
138      !                                               ! ============= !
139      DO jn = 1, kjpt                                 !  tracer loop  !
140         !                                            ! ============= !
141         !  Matrix construction
142         ! --------------------
143         ! Build matrix if temperature or salinity (only in double diffusion case) or first passive tracer
144         !
145         IF(  ( cdtype == 'TRA' .AND. ( jn == jp_tem .OR. ( jn == jp_sal .AND. ln_zdfddm ) ) ) .OR.   &
146            & ( cdtype == 'TRC' .AND. jn == 1 )  )  THEN
147            !
148            ! vertical mixing coef.: avt for temperature, avs for salinity and passive tracers
149            IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN   ;   zwt(:,:,2:jpk) = avt(:,:,2:jpk)
150            ELSE                                            ;   zwt(:,:,2:jpk) = avs(:,:,2:jpk)
151            ENDIF
152            zwt(:,:,1) = 0._wp
153            !
154            IF( l_ldfslp ) THEN            ! isoneutral diffusion: add the contribution
155               IF( ln_traldf_msc  ) THEN     ! MSC iso-neutral operator
156                  DO jk = 2, jpkm1
157                     DO jj = 2, jpjm1
158                        DO ji = fs_2, fs_jpim1   ! vector opt.
159                           zwt(ji,jj,jk) = zwt(ji,jj,jk) + akz(ji,jj,jk) 
160                        END DO
161                     END DO
162                  END DO
163               ELSE                          ! standard or triad iso-neutral operator
164                  DO jk = 2, jpkm1
165                     DO jj = 2, jpjm1
166                        DO ji = fs_2, fs_jpim1   ! vector opt.
167                           zwt(ji,jj,jk) = zwt(ji,jj,jk) + ah_wslp2(ji,jj,jk)
168                        END DO
169                     END DO
170                  END DO
171               ENDIF
172            ENDIF
173            !
174            ! Diagonal, lower (i), upper (s)  (including the bottom boundary condition since avt is masked)
175            IF( ln_zad_Aimp ) THEN         ! Adaptive implicit vertical advection
176               DO jk = 1, jpkm1
177                  DO jj = 2, jpjm1
178                     DO ji = fs_2, fs_jpim1   ! vector opt. (ensure same order of calculation as below if wi=0.)
179                        zzwi = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk  ,Kmm)
180                        zzws = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
181                        zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zzwi - zzws   &
182                           &                 + p2dt * ( MAX( wi(ji,jj,jk  ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )
183                        zwi(ji,jj,jk) = zzwi + p2dt *   MIN( wi(ji,jj,jk  ) , 0._wp )
184                        zws(ji,jj,jk) = zzws - p2dt *   MAX( wi(ji,jj,jk+1) , 0._wp )
185                    END DO
186                  END DO
187               END DO
188            ELSE
189               DO jk = 1, jpkm1
190                  DO jj = 2, jpjm1
191                     DO ji = fs_2, fs_jpim1   ! vector opt.
192                        zwi(ji,jj,jk) = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk,Kmm)
193                        zws(ji,jj,jk) = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
194                        zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zwi(ji,jj,jk) - zws(ji,jj,jk)
195                    END DO
196                  END DO
197               END DO
198            ENDIF
199            !
200            !! Matrix inversion from the first level
201            !!----------------------------------------------------------------------
202            !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
203            !
204            !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
205            !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
206            !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
207            !        (        ...               )( ...  ) ( ...  )
208            !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
209            !
210            !   m is decomposed in the product of an upper and lower triangular matrix.
211            !   The 3 diagonal terms are in 3d arrays: zwd, zws, zwi.
212            !   Suffices i,s and d indicate "inferior" (below diagonal), diagonal
213            !   and "superior" (above diagonal) components of the tridiagonal system.
214            !   The solution will be in the 4d array pta.
215            !   The 3d array zwt is used as a work space array.
216            !   En route to the solution pt(:,:,:,:,Kaa) is used a to evaluate the rhs and then
217            !   used as a work space array: its value is modified.
218            !
219            DO jj = 2, jpjm1        !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1   (increasing k)
220               DO ji = fs_2, fs_jpim1            ! done one for all passive tracers (so included in the IF instruction)
221                  zwt(ji,jj,1) = zwd(ji,jj,1)
222               END DO
223            END DO
224            DO jk = 2, jpkm1
225               DO jj = 2, jpjm1
226                  DO ji = fs_2, fs_jpim1
227                     zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwt(ji,jj,jk-1)
228                  END DO
229               END DO
230            END DO
231            !
232         ENDIF 
233         !         
234         DO jj = 2, jpjm1           !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
235            DO ji = fs_2, fs_jpim1
236               pt(ji,jj,1,jn,Kaa) = e3t(ji,jj,1,Kbb) * pt(ji,jj,1,jn,Kbb) + p2dt * e3t(ji,jj,1,Kmm) * pt(ji,jj,1,jn,Krhs)
237            END DO
238         END DO
239         DO jk = 2, jpkm1
240            DO jj = 2, jpjm1
241               DO ji = fs_2, fs_jpim1
242                  zrhs = e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * e3t(ji,jj,jk,Kmm) * pt(ji,jj,jk,jn,Krhs)   ! zrhs=right hand side
243                  pt(ji,jj,jk,jn,Kaa) = zrhs - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) * pt(ji,jj,jk-1,jn,Kaa)
244               END DO
245            END DO
246         END DO
247         !
248         DO jj = 2, jpjm1           !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk   (result is the after tracer)
249            DO ji = fs_2, fs_jpim1
250               pt(ji,jj,jpkm1,jn,Kaa) = pt(ji,jj,jpkm1,jn,Kaa) / zwt(ji,jj,jpkm1) * tmask(ji,jj,jpkm1)
251            END DO
252         END DO
253         DO jk = jpk-2, 1, -1
254            DO jj = 2, jpjm1
255               DO ji = fs_2, fs_jpim1
256                  pt(ji,jj,jk,jn,Kaa) = ( pt(ji,jj,jk,jn,Kaa) - zws(ji,jj,jk) * pt(ji,jj,jk+1,jn,Kaa) )   &
257                     &             / zwt(ji,jj,jk) * tmask(ji,jj,jk)
258               END DO
259            END DO
260         END DO
261         !                                            ! ================= !
262      END DO                                          !  end tracer loop  !
263      !                                               ! ================= !
264   END SUBROUTINE tra_zdf_imp
265
266   !!==============================================================================
267END MODULE trazdf
Note: See TracBrowser for help on using the repository browser.