New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_nf90.F90 in NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/OCE/IOM – NEMO

source: NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/OCE/IOM/iom_nf90.F90 @ 12603

Last change on this file since 12603 was 12603, checked in by orioltp, 4 years ago

Adding several interfaces to work with both single and double precision
  • Property svn:keywords set to Id
File size: 45.4 KB
Line 
1MODULE iom_nf90
2   !!======================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!======================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!            3.6  ! 2015-15  (J. Harle) Added procedure to read REAL attributes
10   !!            4.0  ! 2017-11 (M. Andrejczuk) Extend IOM interface to write any 3D fields
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   iom_open       : open a file read only
15   !!   iom_close      : close a file or all files opened by iom
16   !!   iom_get        : read a field (interfaced to several routines)
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!----------------------------------------------------------------------
20   USE dom_oce         ! ocean space and time domain
21   USE sbc_oce, ONLY: jpka, ght_abl ! abl vertical level number and height
22   USE lbclnk          ! lateal boundary condition / mpp exchanges
23   USE iom_def         ! iom variables definitions
24   USE netcdf          ! NetCDF library
25   USE in_out_manager  ! I/O manager
26   USE lib_mpp         ! MPP library
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC iom_nf90_open  , iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_rstput
32   PUBLIC iom_nf90_chkatt, iom_nf90_getatt, iom_nf90_putatt
33
34   INTERFACE iom_nf90_get
35      MODULE PROCEDURE iom_nf90_g0d_sp                   
36      MODULE PROCEDURE iom_nf90_g0d_dp, iom_nf90_g123d_dp
37   END INTERFACE
38   INTERFACE iom_nf90_rstput
39      MODULE PROCEDURE iom_nf90_rp0123d_dp
40   END INTERFACE
41
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar, kdlev )
50      !!---------------------------------------------------------------------
51      !!                   ***  SUBROUTINE  iom_open  ***
52      !!
53      !! ** Purpose : open an input file with NF90
54      !!---------------------------------------------------------------------
55      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
56      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
57      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
58      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
59      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar     ! domain parameters:
60      INTEGER                , INTENT(in   ), OPTIONAL ::   kdlev       ! size of the ice/abl third dimension
61
62      CHARACTER(LEN=256) ::   clinfo           ! info character
63      CHARACTER(LEN=256) ::   cltmp            ! temporary character
64      INTEGER            ::   iln              ! lengths of character
65      INTEGER            ::   istop            ! temporary storage of nstop
66      INTEGER            ::   if90id           ! nf90 identifier of the opened file
67      INTEGER            ::   idmy             ! dummy variable
68      INTEGER            ::   jl               ! loop variable
69      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
70      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER or NF90_HDF5
71      INTEGER            ::   ihdf5            ! local variable for retrieval of value for NF90_HDF5
72      LOGICAL            ::   llclobber        ! local definition of ln_clobber
73      INTEGER            ::   ilevels          ! vertical levels
74      !---------------------------------------------------------------------
75      !
76      clinfo = '                    iom_nf90_open ~~~  '
77      istop = nstop     ! store the actual value of nstop
78      !
79      !                 !number of vertical levels
80      IF( PRESENT(kdlev) )   THEN   ;   ilevels = kdlev    ! use input value (useful for sea-ice and abl)
81      ELSE                          ;   ilevels = jpk      ! by default jpk
82      ENDIF
83      !
84      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
85      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
86      ENDIF
87      !
88      llclobber = ldwrt .AND. ln_clobber
89      IF( ldok .AND. .NOT. llclobber ) THEN      !==  Open existing file ==!
90         !                                       !=========================!
91         IF( ldwrt ) THEN  ! ... in write mode
92            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
93            IF( snc4set%luse ) THEN
94               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id ), clinfo)
95            ELSE
96               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
97            ENDIF
98            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
99         ELSE              ! ... in read mode
100            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
101            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
102         ENDIF
103      ELSE                                       !== the file doesn't exist ==!   (or we overwrite it)
104         !                                       !============================!
105         iln = INDEX( cdname, '.nc' )
106         IF( ldwrt ) THEN              !* the file should be open in write mode so we create it...
107            IF( jpnij > 1 ) THEN
108               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc'
109               cdname = TRIM(cltmp)
110            ENDIF
111            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
112
113            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
114            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) 
115            ENDIF
116            IF( snc4set%luse ) THEN
117               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' creating file: '//TRIM(cdname)//' in hdf5 (netcdf4) mode'
118               CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5)
119               IF( llclobber ) THEN   ;   imode = IOR(ihdf5, NF90_CLOBBER)
120               ELSE                   ;   imode = IOR(ihdf5, NF90_NOCLOBBER)
121               ENDIF
122               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo)
123            ELSE
124               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
125            ENDIF
126            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL,                   idmy ), clinfo)
127            ! define dimensions
128            CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'x',   kdompar(1,1), idmy ), clinfo)
129            CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'y',   kdompar(2,1), idmy ), clinfo)
130            IF( PRESENT(kdlev) ) THEN
131              IF( kdlev == jpka ) THEN
132                 CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'nav_lev',          kdlev, idmy ), clinfo)
133                 CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'time_counter', NF90_UNLIMITED, idmy ), clinfo)
134              ELSE
135                 CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'nav_lev',            jpk, idmy ), clinfo)
136                 CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'time_counter', NF90_UNLIMITED, idmy ), clinfo)
137                 CALL iom_nf90_check(NF90_DEF_DIM( if90id,  'numcat',          kdlev, idmy ), clinfo)
138              ENDIF
139            ELSE
140               CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'nav_lev',            jpk, idmy ), clinfo)
141               CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'time_counter', NF90_UNLIMITED, idmy ), clinfo)
142            ENDIF
143            ! global attributes
144            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              ), clinfo)
145            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            ), clinfo)
146            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) ), clinfo)
147            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) ), clinfo)
148            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , kdompar(:,1)       ), clinfo)
149            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2)       ), clinfo)
150            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , kdompar(:,3)       ), clinfo)
151            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4)       ), clinfo)
152            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , kdompar(:,5)       ), clinfo)
153            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              ), clinfo)
154         ELSE                          !* the file should be open for read mode so it must exist...
155            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
156         ENDIF
157      ENDIF
158      !
159      ! start to fill file informations
160      ! =============
161      IF( istop == nstop ) THEN   ! no error within this routine
162!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
163         kiomid = 0
164         DO jl = jpmax_files, 1, -1
165            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
166         ENDDO
167         iom_file(kiomid)%name   = TRIM(cdname)
168         iom_file(kiomid)%nfid   = if90id
169         iom_file(kiomid)%nvars  = 0
170         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
171         iom_file(kiomid)%nlev   = ilevels
172         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
173         IF( iom_file(kiomid)%iduld .GE. 0 ) THEN
174            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,    & 
175               &                                       name = iom_file(kiomid)%uldname,   &
176               &                                       len  = iom_file(kiomid)%lenuld ), clinfo )
177         ENDIF
178         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
179      ELSE
180         kiomid = 0               ! return error flag
181      ENDIF
182      !
183   END SUBROUTINE iom_nf90_open
184
185
186   SUBROUTINE iom_nf90_close( kiomid )
187      !!--------------------------------------------------------------------
188      !!                   ***  SUBROUTINE  iom_nf90_close  ***
189      !!
190      !! ** Purpose : close an input file with NF90
191      !!--------------------------------------------------------------------
192      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
193      CHARACTER(LEN=100)  ::   clinfo   ! info character
194      !---------------------------------------------------------------------
195      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
196      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
197   END SUBROUTINE iom_nf90_close
198
199
200   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz, kndims, lduld ) 
201      !!-----------------------------------------------------------------------
202      !!                  ***  FUNCTION  iom_varid  ***
203      !!
204      !! ** Purpose : get the id of a variable in a file with NF90
205      !!-----------------------------------------------------------------------
206      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
207      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
208      INTEGER              , INTENT(in   )           ::   kiv   !
209      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of each dimension
210      INTEGER              , INTENT(  out), OPTIONAL ::   kndims   ! number of dimensions
211      LOGICAL              , INTENT(  out), OPTIONAL ::   lduld    ! true if the last dimension is unlimited (time)
212      !
213      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
214      INTEGER                        ::   if90id           ! nf90 file identifier
215      INTEGER                        ::   ji               ! dummy loop index
216      INTEGER                        ::   ivarid           ! NetCDF  variable Id
217      INTEGER                        ::   i_nvd            ! number of dimension of the variable
218      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
219      LOGICAL                        ::   llok             ! ok  test
220      CHARACTER(LEN=100)             ::   clinfo           ! info character
221      !!-----------------------------------------------------------------------
222      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
223      iom_nf90_varid = 0                    ! default definition
224      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
225      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
226      !
227      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
228      IF( llok ) THEN
229         iom_nf90_varid = kiv
230         iom_file(kiomid)%nvars       = kiv
231         iom_file(kiomid)%nvid(kiv)   = ivarid
232         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
233         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
234         iom_file(kiomid)%ndims(kiv)  = i_nvd
235         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
236         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
237         iom_file(kiomid)%dimsz(:,kiv) = 0      ! reset dimsz in case previously used
238         DO ji = 1, i_nvd                       ! dimensions size
239            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
240            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
241         END DO
242         !---------- Deal with scale_factor and add_offset
243         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
244         IF( llok) THEN
245            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
246         ELSE
247            iom_file(kiomid)%scf(kiv) = 1.
248         END IF
249         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
250         IF( llok ) THEN
251            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
252         ELSE
253            iom_file(kiomid)%ofs(kiv) = 0.
254         END IF
255         ! return the simension size
256         IF( PRESENT(kdimsz) ) THEN
257            IF( i_nvd <= SIZE(kdimsz) ) THEN
258               kdimsz(1:i_nvd) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
259            ELSE
260               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
261               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
262            ENDIF
263         ENDIF
264         IF( PRESENT(kndims) )  kndims = iom_file(kiomid)%ndims(kiv)
265         IF( PRESENT( lduld) )  lduld  = iom_file(kiomid)%luld(kiv)
266      ELSE 
267         iom_nf90_varid = -1   !   variable not found, return error code: -1
268      ENDIF
269      !
270   END FUNCTION iom_nf90_varid
271
272   !!----------------------------------------------------------------------
273   !!                   INTERFACE iom_nf90_get
274   !!----------------------------------------------------------------------
275
276   SUBROUTINE iom_nf90_g0d_sp( kiomid, kvid, pvar, kstart )
277      !!-----------------------------------------------------------------------
278      !!                  ***  ROUTINE  iom_nf90_g0d  ***
279      !!
280      !! ** Purpose : read a scalar with NF90
281      !!-----------------------------------------------------------------------
282      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
283      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
284      REAL(sp),               INTENT(  out)            ::   pvar     ! read field
285      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
286      !
287      CHARACTER(LEN=100)      ::   clinfo   ! info character
288      !---------------------------------------------------------------------
289      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
290      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
291   END SUBROUTINE iom_nf90_g0d_sp
292
293   SUBROUTINE iom_nf90_g0d_dp( kiomid, kvid, pvar, kstart )
294      !!-----------------------------------------------------------------------
295      !!                  ***  ROUTINE  iom_nf90_g0d  ***
296      !!
297      !! ** Purpose : read a scalar with NF90
298      !!-----------------------------------------------------------------------
299      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
300      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
301      REAL(dp),               INTENT(  out)            ::   pvar     ! read field
302      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
303      !
304      CHARACTER(LEN=100)      ::   clinfo   ! info character
305      !---------------------------------------------------------------------
306      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
307      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
308   END SUBROUTINE iom_nf90_g0d_dp
309
310   SUBROUTINE iom_nf90_g123d_dp( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
311         &                    pv_r1d, pv_r2d, pv_r3d )
312      !!-----------------------------------------------------------------------
313      !!                  ***  ROUTINE  iom_nf90_g123d  ***
314      !!
315      !! ** Purpose : read a 1D/2D/3D variable with NF90
316      !!
317      !! ** Method : read ONE record at each CALL
318      !!-----------------------------------------------------------------------
319      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
320      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
321      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
322      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
323      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
324      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
325      REAL(dp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
326      REAL(dp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
327      REAL(dp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
328      !
329      CHARACTER(LEN=100) ::   clinfo               ! info character
330      INTEGER            ::   if90id               ! nf90 identifier of the opened file
331      INTEGER            ::   ivid                 ! nf90 variable id
332      !---------------------------------------------------------------------
333      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
334      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
335      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
336      !
337      IF(     PRESENT(pv_r1d) ) THEN
338         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
339            &                                                                       count = kcount(1:knbdim)), clinfo )
340      ELSEIF( PRESENT(pv_r2d) ) THEN
341         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
342            &                                                                       count = kcount(1:knbdim)), clinfo )
343      ELSEIF( PRESENT(pv_r3d) ) THEN
344         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
345            &                                                                       count = kcount(1:knbdim)), clinfo )
346      ENDIF
347      !
348   END SUBROUTINE iom_nf90_g123d_dp
349
350
351
352   SUBROUTINE iom_nf90_chkatt( kiomid, cdatt, llok, ksize, cdvar )
353      !!-----------------------------------------------------------------------
354      !!                  ***  ROUTINE  iom_nf90_chkatt  ***
355      !!
356      !! ** Purpose : check existence of attribute with NF90
357      !!              (either a global attribute (default) or a variable
358      !!               attribute if optional variable name is supplied (cdvar))
359      !!-----------------------------------------------------------------------
360      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
361      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
362      LOGICAL         , INTENT(  out) ::   llok     ! error code
363      INTEGER         , INTENT(  out), OPTIONAL     &
364                      &               ::   ksize    ! attribute size
365      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
366                      &               ::   cdvar    ! name of the variable
367      !
368      INTEGER                         ::   if90id   ! temporary integer
369      INTEGER                         ::   isize    ! temporary integer
370      INTEGER                         ::   ivarid   ! NetCDF variable Id
371      !---------------------------------------------------------------------
372      !
373      if90id = iom_file(kiomid)%nfid
374      IF( PRESENT(cdvar) ) THEN
375         ! check the variable exists in the file
376         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
377         IF( llok ) &
378            ! check the variable has the attribute required
379            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt, len=isize ) == nf90_noerr
380      ELSE
381         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt, len=isize ) == nf90_noerr
382      ENDIF
383      !
384      IF( PRESENT(ksize) ) ksize = isize
385      !
386      IF( .not. llok) &
387         CALL ctl_warn('iom_nf90_chkatt: no attribute '//cdatt//' found')
388      !
389   END SUBROUTINE iom_nf90_chkatt
390
391
392   !!----------------------------------------------------------------------
393   !!                   INTERFACE iom_nf90_getatt
394   !!----------------------------------------------------------------------
395
396   SUBROUTINE iom_nf90_getatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
397      !!-----------------------------------------------------------------------
398      !!                  ***  ROUTINE  iom_nf90_getatt  ***
399      !!
400      !! ** Purpose : read an attribute with NF90
401      !!              (either a global attribute (default) or a variable
402      !!               attribute if optional variable name is supplied (cdvar))
403      !!-----------------------------------------------------------------------
404      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
405      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
406      INTEGER               , INTENT(  out), OPTIONAL ::   katt0d   ! read scalar integer
407      INTEGER, DIMENSION(:) , INTENT(  out), OPTIONAL ::   katt1d   ! read 1d array integer
408      REAL(wp)              , INTENT(  out), OPTIONAL ::   patt0d   ! read scalar  real
409      REAL(wp), DIMENSION(:), INTENT(  out), OPTIONAL ::   patt1d   ! read 1d array real
410      CHARACTER(len=*)      , INTENT(  out), OPTIONAL ::   cdatt0d  ! read character
411      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
412      !
413      INTEGER                         ::   if90id   ! temporary integer
414      INTEGER                         ::   ivarid   ! NetCDF variable Id
415      LOGICAL                         ::   llok     ! temporary logical
416      CHARACTER(LEN=100)              ::   clinfo   ! info character
417      !---------------------------------------------------------------------
418      !
419      if90id = iom_file(kiomid)%nfid
420      IF( PRESENT(cdvar) ) THEN
421         ! check the variable exists in the file
422         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
423         IF( llok ) THEN
424            ! check the variable has the attribute required
425            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
426         ELSE
427            CALL ctl_warn('iom_nf90_getatt: no variable '//TRIM(cdvar)//' found')
428         ENDIF
429      ELSE
430         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
431         ivarid = NF90_GLOBAL
432      ENDIF
433      !
434      IF( llok) THEN
435         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
436         IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt0d), clinfo)
437         IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt1d), clinfo)
438         IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt0d), clinfo)
439         IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt1d), clinfo)
440         IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values = cdatt0d), clinfo)
441      ELSE
442         CALL ctl_warn('iom_nf90_getatt: no attribute '//TRIM(cdatt)//' found')
443         IF(PRESENT( katt0d))    katt0d    = -999
444         IF(PRESENT( katt1d))    katt1d(:) = -999
445         IF(PRESENT( patt0d))    patt0d    = -999._wp
446         IF(PRESENT( patt1d))    patt1d(:) = -999._wp
447         IF(PRESENT(cdatt0d))   cdatt0d    = '!'
448      ENDIF
449      !
450   END SUBROUTINE iom_nf90_getatt
451
452
453   SUBROUTINE iom_nf90_putatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
454      !!-----------------------------------------------------------------------
455      !!                  ***  ROUTINE  iom_nf90_putatt  ***
456      !!
457      !! ** Purpose : write an attribute with NF90
458      !!              (either a global attribute (default) or a variable
459      !!               attribute if optional variable name is supplied (cdvar))
460      !!-----------------------------------------------------------------------
461      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
462      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
463      INTEGER               , INTENT(in   ), OPTIONAL ::   katt0d   ! read scalar integer
464      INTEGER, DIMENSION(:) , INTENT(in   ), OPTIONAL ::   katt1d   ! read 1d array integer
465      REAL(wp)              , INTENT(in   ), OPTIONAL ::   patt0d   ! read scalar  real
466      REAL(wp), DIMENSION(:), INTENT(in   ), OPTIONAL ::   patt1d   ! read 1d array real
467      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdatt0d  ! read character
468      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
469      !
470      INTEGER                         ::   if90id   ! temporary integer
471      INTEGER                         ::   ivarid   ! NetCDF variable Id
472      INTEGER                         ::   isize    ! Attribute size
473      INTEGER                         ::   itype    ! Attribute type
474      LOGICAL                         ::   llok     ! temporary logical
475      LOGICAL                         ::   llatt     ! temporary logical
476      LOGICAL                         ::   lldata   ! temporary logical
477      CHARACTER(LEN=100)              ::   clinfo   ! info character
478      !---------------------------------------------------------------------
479      !
480      if90id = iom_file(kiomid)%nfid
481      IF( PRESENT(cdvar) ) THEN
482         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! is the variable in the file?
483         IF( .NOT. llok ) THEN
484            CALL ctl_warn('iom_nf90_putatt: no variable '//TRIM(cdvar)//' found'   &
485               &        , '                 no attribute '//cdatt//' written' )
486            RETURN
487         ENDIF
488      ELSE
489         ivarid = NF90_GLOBAL
490      ENDIF
491      llatt = NF90_Inquire_attribute(if90id, ivarid, cdatt, len = isize, xtype = itype ) == nf90_noerr
492      !
493      ! trick: irec used to know if the file is in define mode or not
494      lldata = iom_file(kiomid)%irec /= -1   ! default: go back in define mode if in data mode
495      IF( lldata .AND. llatt ) THEN          ! attribute already there. Do we really need to go back in define mode?
496         ! do we have the appropriate type?
497         IF(PRESENT( katt0d) .OR. PRESENT( katt1d))   llok = itype == NF90_INT
498         IF(PRESENT( patt0d) .OR. PRESENT( patt1d))   llok = itype == NF90_DOUBLE
499         IF(PRESENT(cdatt0d)                      )   llok = itype == NF90_CHAR
500         ! and do we have the appropriate size?
501         IF(PRESENT( katt0d))   llok = llok .AND. isize == 1
502         IF(PRESENT( katt1d))   llok = llok .AND. isize == SIZE(katt1d)
503         IF(PRESENT( patt0d))   llok = llok .AND. isize == 1
504         IF(PRESENT( patt1d))   llok = llok .AND. isize == SIZE(patt1d)
505         IF(PRESENT(cdatt0d))   llok = llok .AND. isize == LEN_TRIM(cdatt0d)
506         !
507         lldata = .NOT. llok
508      ENDIF
509      !
510      clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
511      IF(lldata)   CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ! leave data mode to define mode
512      !
513      IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       katt0d) , clinfo)
514      IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       katt1d) , clinfo)
515      IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       patt0d) , clinfo)
516      IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       patt1d) , clinfo)
517      IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values = trim(cdatt0d)), clinfo)
518      !
519      IF(lldata)   CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ! leave define mode to data mode
520      !
521   END SUBROUTINE iom_nf90_putatt
522
523   SUBROUTINE iom_nf90_rp0123d_dp( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
524         &                                  pv_r0d, pv_r1d, pv_r2d, pv_r3d )
525      !!--------------------------------------------------------------------
526      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
527      !!
528      !! ** Purpose : read the time axis cdvar in the file
529      !!--------------------------------------------------------------------
530      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
531      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
532      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
533      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
534      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
535      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
536      REAL(dp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
537      REAL(dp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
538      REAL(dp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
539      REAL(dp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
540      !
541      INTEGER               :: idims                ! number of dimension
542      INTEGER               :: idvar                ! variable id
543      INTEGER               :: jd                   ! dimension loop counter   
544      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
545      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
546      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
547      CHARACTER(LEN=256)    :: clinfo               ! info character
548      CHARACTER(LEN= 12), DIMENSION(5) :: cltmp     ! temporary character
549      INTEGER               :: if90id               ! nf90 file identifier
550      INTEGER               :: idmy                 ! dummy variable
551      INTEGER               :: itype                ! variable type
552      INTEGER, DIMENSION(4) :: ichunksz             ! NetCDF4 chunk sizes. Will be computed using
553      !                                             ! nn_nchunks_[i,j,k,t] namelist parameters
554      INTEGER               :: ichunkalg, ishuffle, ideflate, ideflate_level
555      !                                             ! NetCDF4 internally fixed parameters
556      LOGICAL               :: lchunk               ! logical switch to activate chunking and compression
557      !                                             ! when appropriate (currently chunking is applied to 4d fields only)
558      INTEGER               :: idlv                 ! local variable
559      INTEGER               :: idim3                ! id of the third dimension
560      !---------------------------------------------------------------------
561      !
562      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
563      if90id = iom_file(kiomid)%nfid
564      !
565      ! define dimension variables if it is not already done
566      ! ==========================
567      IF( iom_file(kiomid)%nvars == 0 ) THEN
568         ! are we in define mode?
569         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
570            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
571         ENDIF
572         ! define the dimension variables if it is not already done
573         ! Warning: we must use the same character length in an array constructor (at least for gcc compiler)
574         cltmp = (/ 'nav_lon     ', 'nav_lat     ', 'nav_lev     ', 'time_counter', 'numcat      ' /)   
575         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(1)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(1) ), clinfo)
576         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(2)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(2) ), clinfo)
577         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(3)), NF90_FLOAT , (/ 3    /), iom_file(kiomid)%nvid(3) ), clinfo)
578         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(4)), NF90_DOUBLE, (/ 4    /), iom_file(kiomid)%nvid(4) ), clinfo)
579         ! update informations structure related the dimension variable we just added...
580         iom_file(kiomid)%nvars       = 4
581         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
582         iom_file(kiomid)%cn_var(1:4) = cltmp(1:4)
583         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /)
584         IF( NF90_INQ_DIMID( if90id, 'numcat', idmy ) == nf90_noerr ) THEN   ! add a 5th variable corresponding to the 5th dimension
585            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(5)), NF90_FLOAT , (/ 5 /), iom_file(kiomid)%nvid(5) ), clinfo)
586            iom_file(kiomid)%nvars     = 5
587            iom_file(kiomid)%luld(5)   = .FALSE.
588            iom_file(kiomid)%cn_var(5) = cltmp(5)
589            iom_file(kiomid)%ndims(5)  = 1
590         ENDIF
591         ! trick: defined to 0 to say that dimension variables are defined but not yet written
592         iom_file(kiomid)%dimsz(1, 1)  = 0   
593         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
594      ENDIF
595      ! define the data if it is not already done
596      ! ===============
597      IF( kvid <= 0 ) THEN
598         !
599         ! NetCDF4 chunking and compression fixed settings
600         ichunkalg = 0
601         ishuffle = 1
602         ideflate = 1
603         ideflate_level = 1
604         !
605         idvar = iom_file(kiomid)%nvars + 1
606         ! are we in define mode?
607         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
608            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
609         ENDIF
610         ! variable definition
611         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
612         ELSEIF( PRESENT(pv_r1d) ) THEN
613            IF(( SIZE(pv_r1d,1) == jpk ).OR.( SIZE(pv_r1d,1) == jpka )) THEN   ;   idim3 = 3
614            ELSE                                                               ;   idim3 = 5
615            ENDIF
616                                              idims = 2   ;   idimid(1:idims) = (/idim3,4/)
617         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
618         ELSEIF( PRESENT(pv_r3d) ) THEN
619            IF(( SIZE(pv_r3d,3) == jpk ).OR.( SIZE(pv_r3d,3) == jpka )) THEN   ;   idim3 = 3
620            ELSE                                                               ;   idim3 = 5
621            ENDIF
622                                              idims = 4   ;   idimid(1:idims) = (/1,2,idim3,4/)
623         ENDIF
624         IF( PRESENT(ktype) ) THEN   ! variable external type
625            SELECT CASE (ktype)
626            CASE (jp_r8)   ;   itype = NF90_DOUBLE
627            CASE (jp_r4)   ;   itype = NF90_FLOAT
628            CASE (jp_i4)   ;   itype = NF90_INT
629            CASE (jp_i2)   ;   itype = NF90_SHORT
630            CASE (jp_i1)   ;   itype = NF90_BYTE
631            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
632            END SELECT
633         ELSE
634            itype = NF90_DOUBLE
635         ENDIF
636         IF( PRESENT(pv_r0d) ) THEN
637            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
638               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
639         ELSE
640            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
641               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
642         ENDIF
643         lchunk = .false.
644         IF( snc4set%luse .AND. idims == 4 )   lchunk = .true.
645         ! update informations structure related the new variable we want to add...
646         iom_file(kiomid)%nvars         = idvar
647         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
648         iom_file(kiomid)%scf(idvar)    = 1.
649         iom_file(kiomid)%ofs(idvar)    = 0.
650         iom_file(kiomid)%ndims(idvar)  = idims
651         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
652         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
653         ENDIF
654         DO jd = 1, idims
655            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
656            IF ( lchunk ) ichunksz(jd) = iom_file(kiomid)%dimsz(jd,idvar)
657         END DO
658         IF ( lchunk ) THEN
659            ! Calculate chunk sizes by partitioning each dimension as requested in namnc4 namelist
660            ! Disallow very small chunk sizes and prevent chunk sizes larger than each individual dimension
661            ichunksz(1) = MIN( ichunksz(1),MAX( (ichunksz(1)-1)/snc4set%ni + 1 ,16 ) ) ! Suggested default nc4set%ni=4
662            ichunksz(2) = MIN( ichunksz(2),MAX( (ichunksz(2)-1)/snc4set%nj + 1 ,16 ) ) ! Suggested default nc4set%nj=2
663            ichunksz(3) = MIN( ichunksz(3),MAX( (ichunksz(3)-1)/snc4set%nk + 1 , 1 ) ) ! Suggested default nc4set%nk=6
664            ichunksz(4) = 1                                                            ! Do not allow chunks to span the
665            !                                                                          ! unlimited dimension
666            CALL iom_nf90_check(SET_NF90_DEF_VAR_CHUNKING(if90id, idvar, ichunkalg, ichunksz), clinfo)
667            CALL iom_nf90_check(SET_NF90_DEF_VAR_DEFLATE(if90id, idvar, ishuffle, ideflate, ideflate_level), clinfo)
668            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' chunked ok. Chunks sizes: ', ichunksz
669         ENDIF
670         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
671      ELSE
672         idvar = kvid
673      ENDIF
674      !
675      ! time step kwrite : write the variable
676      IF( kt == kwrite ) THEN
677         ! are we in write mode?
678         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
679            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
680         ENDIF
681         ! on what kind of domain must the data be written?
682         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
683            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
684            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
685               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
686            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
687               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
688            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
689               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
690            ELSE
691               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
692            ENDIF
693
694            ! write dimension variables if it is not already done
695            ! =============
696            ! trick: is defined to 0 => dimension variable are defined but not yet written
697            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
698               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lon'     , idmy )         , clinfo )
699               CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, glamt(ix1:ix2, iy1:iy2) ), clinfo )
700               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lat'     , idmy )         , clinfo )
701               CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, gphit(ix1:ix2, iy1:iy2) ), clinfo )
702               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lev'     , idmy ), clinfo )
703               IF (iom_file(kiomid)%nlev == jpka) THEN   ;   CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy,  ght_abl), clinfo )
704               ELSE                                      ;   CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, gdept_1d), clinfo )
705               ENDIF
706               IF( NF90_INQ_VARID( if90id, 'numcat', idmy ) == nf90_noerr ) THEN
707                  CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, (/ (idlv, idlv = 1,iom_file(kiomid)%nlev) /)), clinfo )
708               ENDIF
709               ! +++ WRONG VALUE: to be improved but not really useful...
710               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'time_counter', idmy ), clinfo )
711               CALL iom_nf90_check( NF90_PUT_VAR( if90id, idmy, kt                      ), clinfo )   
712               ! update the values of the variables dimensions size
713               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 1, len = iom_file(kiomid)%dimsz(1,1) ), clinfo )
714               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 2, len = iom_file(kiomid)%dimsz(2,1) ), clinfo )
715               iom_file(kiomid)%dimsz(1:2, 2) = iom_file(kiomid)%dimsz(1:2, 1)
716               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 3, len = iom_file(kiomid)%dimsz(1,3) ), clinfo )
717               iom_file(kiomid)%dimsz(1  , 4) = 1   ! unlimited dimension
718               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
719            ENDIF
720         ENDIF
721
722         ! write the data
723         ! =============
724         IF(     PRESENT(pv_r0d) ) THEN
725            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r0d                    ), clinfo )
726         ELSEIF( PRESENT(pv_r1d) ) THEN
727            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r1d(:)                 ), clinfo )
728         ELSEIF( PRESENT(pv_r2d) ) THEN
729            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2,iy1:iy2)   ), clinfo )
730         ELSEIF( PRESENT(pv_r3d) ) THEN
731            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2,iy1:iy2,:) ), clinfo )
732         ENDIF
733         ! add 1 to the size of the temporal dimension (not really useful...)
734         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
735               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
736         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
737      ENDIF
738      !     
739   END SUBROUTINE iom_nf90_rp0123d_dp
740
741
742   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
743      !!--------------------------------------------------------------------
744      !!                   ***  SUBROUTINE iom_nf90_check  ***
745      !!
746      !! ** Purpose :   check nf90 errors
747      !!--------------------------------------------------------------------
748      INTEGER,          INTENT(in) :: kstatus
749      CHARACTER(LEN=*), INTENT(in) :: cdinfo
750      !---------------------------------------------------------------------
751      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
752   END SUBROUTINE iom_nf90_check
753
754   !!======================================================================
755END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.