| 1 | MODULE zdfiwm |
|---|
| 2 | !!======================================================================== |
|---|
| 3 | !! *** MODULE zdfiwm *** |
|---|
| 4 | !! Ocean physics: Internal gravity wave-driven vertical mixing |
|---|
| 5 | !!======================================================================== |
|---|
| 6 | !! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code |
|---|
| 7 | !! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait |
|---|
| 8 | !! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
|---|
| 9 | !! 3.6 ! 2016-03 (C. de Lavergne) New param: internal wave-driven mixing |
|---|
| 10 | !! 4.0 ! 2017-04 (G. Madec) renamed module, remove the old param. and the CPP keys |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! zdf_iwm : global momentum & tracer Kz with wave induced Kz |
|---|
| 15 | !! zdf_iwm_init : global momentum & tracer Kz with wave induced Kz |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers variables |
|---|
| 18 | USE dom_oce ! ocean space and time domain variables |
|---|
| 19 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 20 | USE zdfddm ! ocean vertical physics: double diffusive mixing |
|---|
| 21 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 22 | USE eosbn2 ! ocean equation of state |
|---|
| 23 | USE phycst ! physical constants |
|---|
| 24 | ! |
|---|
| 25 | USE fldread ! field read |
|---|
| 26 | USE prtctl ! Print control |
|---|
| 27 | USE in_out_manager ! I/O manager |
|---|
| 28 | USE iom ! I/O Manager |
|---|
| 29 | USE lib_mpp ! MPP library |
|---|
| 30 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 31 | |
|---|
| 32 | IMPLICIT NONE |
|---|
| 33 | PRIVATE |
|---|
| 34 | |
|---|
| 35 | PUBLIC zdf_iwm ! called in step module |
|---|
| 36 | PUBLIC zdf_iwm_init ! called in nemogcm module |
|---|
| 37 | |
|---|
| 38 | ! !!* Namelist namzdf_iwm : internal wave-driven mixing * |
|---|
| 39 | INTEGER :: nn_zpyc ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2) |
|---|
| 40 | LOGICAL :: ln_mevar ! variable (=T) or constant (=F) mixing efficiency |
|---|
| 41 | LOGICAL :: ln_tsdiff ! account for differential T/S wave-driven mixing (=T) or not (=F) |
|---|
| 42 | |
|---|
| 43 | REAL(wp):: r1_6 = 1._wp / 6._wp |
|---|
| 44 | |
|---|
| 45 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ebot_iwm ! power available from high-mode wave breaking (W/m2) |
|---|
| 46 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: epyc_iwm ! power available from low-mode, pycnocline-intensified wave breaking (W/m2) |
|---|
| 47 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ecri_iwm ! power available from low-mode, critical slope wave breaking (W/m2) |
|---|
| 48 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hbot_iwm ! WKB decay scale for high-mode energy dissipation (m) |
|---|
| 49 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hcri_iwm ! decay scale for low-mode critical slope dissipation (m) |
|---|
| 50 | |
|---|
| 51 | !! * Substitutions |
|---|
| 52 | # include "do_loop_substitute.h90" |
|---|
| 53 | # include "domzgr_substitute.h90" |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 56 | !! $Id$ |
|---|
| 57 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 58 | !!---------------------------------------------------------------------- |
|---|
| 59 | CONTAINS |
|---|
| 60 | |
|---|
| 61 | INTEGER FUNCTION zdf_iwm_alloc() |
|---|
| 62 | !!---------------------------------------------------------------------- |
|---|
| 63 | !! *** FUNCTION zdf_iwm_alloc *** |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | ALLOCATE( ebot_iwm(jpi,jpj), epyc_iwm(jpi,jpj), ecri_iwm(jpi,jpj) , & |
|---|
| 66 | & hbot_iwm(jpi,jpj), hcri_iwm(jpi,jpj) , STAT=zdf_iwm_alloc ) |
|---|
| 67 | ! |
|---|
| 68 | CALL mpp_sum ( 'zdfiwm', zdf_iwm_alloc ) |
|---|
| 69 | IF( zdf_iwm_alloc /= 0 ) CALL ctl_stop( 'STOP', 'zdf_iwm_alloc: failed to allocate arrays' ) |
|---|
| 70 | END FUNCTION zdf_iwm_alloc |
|---|
| 71 | |
|---|
| 72 | |
|---|
| 73 | SUBROUTINE zdf_iwm( kt, Kmm, p_avm, p_avt, p_avs ) |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | !! *** ROUTINE zdf_iwm *** |
|---|
| 76 | !! |
|---|
| 77 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
|---|
| 78 | !! breaking internal waves. |
|---|
| 79 | !! |
|---|
| 80 | !! ** Method : - internal wave-driven vertical mixing is given by: |
|---|
| 81 | !! Kz_wave = min( 100 cm2/s, f( Reb = zemx_iwm /( Nu * N^2 ) ) |
|---|
| 82 | !! where zemx_iwm is the 3D space distribution of the wave-breaking |
|---|
| 83 | !! energy and Nu the molecular kinematic viscosity. |
|---|
| 84 | !! The function f(Reb) is linear (constant mixing efficiency) |
|---|
| 85 | !! if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T. |
|---|
| 86 | !! |
|---|
| 87 | !! - Compute zemx_iwm, the 3D power density that allows to compute |
|---|
| 88 | !! Reb and therefrom the wave-induced vertical diffusivity. |
|---|
| 89 | !! This is divided into three components: |
|---|
| 90 | !! 1. Bottom-intensified low-mode dissipation at critical slopes |
|---|
| 91 | !! zemx_iwm(z) = ( ecri_iwm / rho0 ) * EXP( -(H-z)/hcri_iwm ) |
|---|
| 92 | !! / ( 1. - EXP( - H/hcri_iwm ) ) * hcri_iwm |
|---|
| 93 | !! where hcri_iwm is the characteristic length scale of the bottom |
|---|
| 94 | !! intensification, ecri_iwm a map of available power, and H the ocean depth. |
|---|
| 95 | !! 2. Pycnocline-intensified low-mode dissipation |
|---|
| 96 | !! zemx_iwm(z) = ( epyc_iwm / rho0 ) * ( sqrt(rn2(z))^nn_zpyc ) |
|---|
| 97 | !! / SUM( sqrt(rn2(z))^nn_zpyc * e3w[z) ) |
|---|
| 98 | !! where epyc_iwm is a map of available power, and nn_zpyc |
|---|
| 99 | !! is the chosen stratification-dependence of the internal wave |
|---|
| 100 | !! energy dissipation. |
|---|
| 101 | !! 3. WKB-height dependent high mode dissipation |
|---|
| 102 | !! zemx_iwm(z) = ( ebot_iwm / rho0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_iwm) |
|---|
| 103 | !! / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_iwm) * e3w[z) ) |
|---|
| 104 | !! where hbot_iwm is the characteristic length scale of the WKB bottom |
|---|
| 105 | !! intensification, ebot_iwm is a map of available power, and z_wkb is the |
|---|
| 106 | !! WKB-stretched height above bottom defined as |
|---|
| 107 | !! z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w[z'>=z) ) |
|---|
| 108 | !! / SUM( sqrt(rn2(z')) * e3w[z') ) |
|---|
| 109 | !! |
|---|
| 110 | !! - update the model vertical eddy viscosity and diffusivity: |
|---|
| 111 | !! avt = avt + av_wave |
|---|
| 112 | !! avm = avm + av_wave |
|---|
| 113 | !! |
|---|
| 114 | !! - if namelist parameter ln_tsdiff = T, account for differential mixing: |
|---|
| 115 | !! avs = avt + av_wave * diffusivity_ratio(Reb) |
|---|
| 116 | !! |
|---|
| 117 | !! ** Action : - avt, avs, avm, increased by tide internal wave-driven mixing |
|---|
| 118 | !! |
|---|
| 119 | !! References : de Lavergne et al. 2015, JPO; 2016, in prep. |
|---|
| 120 | !!---------------------------------------------------------------------- |
|---|
| 121 | INTEGER , INTENT(in ) :: kt ! ocean time step |
|---|
| 122 | INTEGER , INTENT(in ) :: Kmm ! time level index |
|---|
| 123 | REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: p_avm ! momentum Kz (w-points) |
|---|
| 124 | REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: p_avt, p_avs ! tracer Kz (w-points) |
|---|
| 125 | ! |
|---|
| 126 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 127 | REAL(wp) :: zztmp, ztmp1, ztmp2 ! scalar workspace |
|---|
| 128 | REAL(wp), DIMENSION(jpi,jpj) :: zfact ! Used for vertical structure |
|---|
| 129 | REAL(wp), DIMENSION(jpi,jpj) :: zhdep ! Ocean depth |
|---|
| 130 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwkb ! WKB-stretched height above bottom |
|---|
| 131 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zweight ! Weight for high mode vertical distribution |
|---|
| 132 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: znu_t ! Molecular kinematic viscosity (T grid) |
|---|
| 133 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: znu_w ! Molecular kinematic viscosity (W grid) |
|---|
| 134 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zReb ! Turbulence intensity parameter |
|---|
| 135 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zemx_iwm ! local energy density available for mixing (W/kg) |
|---|
| 136 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zav_ratio ! S/T diffusivity ratio (only for ln_tsdiff=T) |
|---|
| 137 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zav_wave ! Internal wave-induced diffusivity |
|---|
| 138 | REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: z3d ! 3D workspace used for iom_put |
|---|
| 139 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: z2d ! 2D - - - - |
|---|
| 140 | !!---------------------------------------------------------------------- |
|---|
| 141 | ! |
|---|
| 142 | ! !* Set to zero the 1st and last vertical levels of appropriate variables |
|---|
| 143 | zemx_iwm (:,:,1) = 0._wp ; zemx_iwm (:,:,jpk) = 0._wp |
|---|
| 144 | zav_ratio(:,:,1) = 0._wp ; zav_ratio(:,:,jpk) = 0._wp |
|---|
| 145 | zav_wave (:,:,1) = 0._wp ; zav_wave (:,:,jpk) = 0._wp |
|---|
| 146 | ! |
|---|
| 147 | ! ! ----------------------------- ! |
|---|
| 148 | ! ! Internal wave-driven mixing ! (compute zav_wave) |
|---|
| 149 | ! ! ----------------------------- ! |
|---|
| 150 | ! |
|---|
| 151 | ! !* Critical slope mixing: distribute energy over the time-varying ocean depth, |
|---|
| 152 | ! using an exponential decay from the seafloor. |
|---|
| 153 | DO_2D_11_11 |
|---|
| 154 | zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
|---|
| 155 | zfact(ji,jj) = rho0 * ( 1._wp - EXP( -zhdep(ji,jj) / hcri_iwm(ji,jj) ) ) |
|---|
| 156 | IF( zfact(ji,jj) /= 0._wp ) zfact(ji,jj) = ecri_iwm(ji,jj) / zfact(ji,jj) |
|---|
| 157 | END_2D |
|---|
| 158 | !!gm gde3w ==>>> check for ssh taken into account.... seem OK gde3w_n=gdept(:,:,:,Kmm) - ssh(:,:,Kmm) |
|---|
| 159 | DO_3D_11_11( 2, jpkm1 ) |
|---|
| 160 | IF ( zfact(ji,jj) == 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN ! optimization |
|---|
| 161 | zemx_iwm(ji,jj,jk) = 0._wp |
|---|
| 162 | ELSE |
|---|
| 163 | zemx_iwm(ji,jj,jk) = zfact(ji,jj) * ( EXP( ( gde3w(ji,jj,jk ) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) ) & |
|---|
| 164 | & - EXP( ( gde3w(ji,jj,jk-1) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) ) ) & |
|---|
| 165 | & / ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) ) |
|---|
| 166 | ENDIF |
|---|
| 167 | END_3D |
|---|
| 168 | !!gm delta(gde3w) = e3t(:,:,:,Kmm) !! Please verify the grid-point position w versus t-point |
|---|
| 169 | !!gm it seems to me that only 1/hcri_iwm is used ==> compute it one for all |
|---|
| 170 | |
|---|
| 171 | |
|---|
| 172 | ! !* Pycnocline-intensified mixing: distribute energy over the time-varying |
|---|
| 173 | ! !* ocean depth as proportional to sqrt(rn2)^nn_zpyc |
|---|
| 174 | ! ! (NB: N2 is masked, so no use of wmask here) |
|---|
| 175 | SELECT CASE ( nn_zpyc ) |
|---|
| 176 | ! |
|---|
| 177 | CASE ( 1 ) ! Dissipation scales as N (recommended) |
|---|
| 178 | ! |
|---|
| 179 | zfact(:,:) = 0._wp |
|---|
| 180 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 181 | zfact(:,:) = & |
|---|
| 182 | & zfact(:,:) + & |
|---|
| 183 | & e3w(:,:,jk,Kmm) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 184 | END DO |
|---|
| 185 | ! |
|---|
| 186 | DO_2D_11_11 |
|---|
| 187 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_iwm(ji,jj) / ( rho0 * zfact(ji,jj) ) |
|---|
| 188 | END_2D |
|---|
| 189 | ! |
|---|
| 190 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 191 | zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zfact(:,:) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 192 | END DO |
|---|
| 193 | ! |
|---|
| 194 | CASE ( 2 ) ! Dissipation scales as N^2 |
|---|
| 195 | ! |
|---|
| 196 | zfact(:,:) = 0._wp |
|---|
| 197 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 198 | zfact(:,:) = zfact(:,:) + e3w(:,:,jk,Kmm) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 199 | END DO |
|---|
| 200 | ! |
|---|
| 201 | DO_2D_11_11 |
|---|
| 202 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_iwm(ji,jj) / ( rho0 * zfact(ji,jj) ) |
|---|
| 203 | END_2D |
|---|
| 204 | ! |
|---|
| 205 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 206 | zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zfact(:,:) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 207 | END DO |
|---|
| 208 | ! |
|---|
| 209 | END SELECT |
|---|
| 210 | |
|---|
| 211 | ! !* WKB-height dependent mixing: distribute energy over the time-varying |
|---|
| 212 | ! !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot) |
|---|
| 213 | ! |
|---|
| 214 | zwkb (:,:,:) = 0._wp |
|---|
| 215 | zfact(:,:) = 0._wp |
|---|
| 216 | DO jk = 2, jpkm1 |
|---|
| 217 | zfact(:,:) = zfact(:,:) + e3w(:,:,jk,Kmm) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 218 | zwkb(:,:,jk) = zfact(:,:) |
|---|
| 219 | END DO |
|---|
| 220 | !!gm even better: |
|---|
| 221 | ! DO jk = 2, jpkm1 |
|---|
| 222 | ! zwkb(:,:) = zwkb(:,:) + e3w(:,:,jk,Kmm) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) |
|---|
| 223 | ! END DO |
|---|
| 224 | ! zfact(:,:) = zwkb(:,:,jpkm1) |
|---|
| 225 | !!gm or just use zwkb(k=jpk-1) instead of zfact... |
|---|
| 226 | !!gm |
|---|
| 227 | ! |
|---|
| 228 | DO_3D_11_11( 2, jpkm1 ) |
|---|
| 229 | IF( zfact(ji,jj) /= 0 ) zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) ) & |
|---|
| 230 | & * wmask(ji,jj,jk) / zfact(ji,jj) |
|---|
| 231 | END_3D |
|---|
| 232 | zwkb(:,:,1) = zhdep(:,:) * wmask(:,:,1) |
|---|
| 233 | ! |
|---|
| 234 | DO_3D_11_11( 2, jpkm1 ) |
|---|
| 235 | IF ( rn2(ji,jj,jk) <= 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN ! optimization |
|---|
| 236 | zweight(ji,jj,jk) = 0._wp |
|---|
| 237 | ELSE |
|---|
| 238 | zweight(ji,jj,jk) = rn2(ji,jj,jk) * hbot_iwm(ji,jj) & |
|---|
| 239 | & * ( EXP( -zwkb(ji,jj,jk) / hbot_iwm(ji,jj) ) - EXP( -zwkb(ji,jj,jk-1) / hbot_iwm(ji,jj) ) ) |
|---|
| 240 | ENDIF |
|---|
| 241 | END_3D |
|---|
| 242 | ! |
|---|
| 243 | zfact(:,:) = 0._wp |
|---|
| 244 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 245 | zfact(:,:) = zfact(:,:) + zweight(:,:,jk) |
|---|
| 246 | END DO |
|---|
| 247 | ! |
|---|
| 248 | DO_2D_11_11 |
|---|
| 249 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ebot_iwm(ji,jj) / ( rho0 * zfact(ji,jj) ) |
|---|
| 250 | END_2D |
|---|
| 251 | ! |
|---|
| 252 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 253 | zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zweight(:,:,jk) * zfact(:,:) * wmask(:,:,jk) & |
|---|
| 254 | & / ( gde3w(:,:,jk) - gde3w(:,:,jk-1) ) |
|---|
| 255 | !!gm use of e3t(:,:,:,Kmm) just above? |
|---|
| 256 | END DO |
|---|
| 257 | ! |
|---|
| 258 | !!gm this is to be replaced by just a constant value znu=1.e-6 m2/s |
|---|
| 259 | ! Calculate molecular kinematic viscosity |
|---|
| 260 | znu_t(:,:,:) = 1.e-4_wp * ( 17.91_wp - 0.53810_wp * ts(:,:,:,jp_tem,Kmm) + 0.00694_wp * ts(:,:,:,jp_tem,Kmm) * ts(:,:,:,jp_tem,Kmm) & |
|---|
| 261 | & + 0.02305_wp * ts(:,:,:,jp_sal,Kmm) ) * tmask(:,:,:) * r1_rho0 |
|---|
| 262 | DO jk = 2, jpkm1 |
|---|
| 263 | znu_w(:,:,jk) = 0.5_wp * ( znu_t(:,:,jk-1) + znu_t(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 264 | END DO |
|---|
| 265 | !!gm end |
|---|
| 266 | ! |
|---|
| 267 | ! Calculate turbulence intensity parameter Reb |
|---|
| 268 | DO jk = 2, jpkm1 |
|---|
| 269 | zReb(:,:,jk) = zemx_iwm(:,:,jk) / MAX( 1.e-20_wp, znu_w(:,:,jk) * rn2(:,:,jk) ) |
|---|
| 270 | END DO |
|---|
| 271 | ! |
|---|
| 272 | ! Define internal wave-induced diffusivity |
|---|
| 273 | DO jk = 2, jpkm1 |
|---|
| 274 | zav_wave(:,:,jk) = znu_w(:,:,jk) * zReb(:,:,jk) * r1_6 ! This corresponds to a constant mixing efficiency of 1/6 |
|---|
| 275 | END DO |
|---|
| 276 | ! |
|---|
| 277 | IF( ln_mevar ) THEN ! Variable mixing efficiency case : modify zav_wave in the |
|---|
| 278 | DO_3D_11_11( 2, jpkm1 ) |
|---|
| 279 | IF( zReb(ji,jj,jk) > 480.00_wp ) THEN |
|---|
| 280 | zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
|---|
| 281 | ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN |
|---|
| 282 | zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
|---|
| 283 | ENDIF |
|---|
| 284 | END_3D |
|---|
| 285 | ENDIF |
|---|
| 286 | ! |
|---|
| 287 | DO jk = 2, jpkm1 ! Bound diffusivity by molecular value and 100 cm2/s |
|---|
| 288 | zav_wave(:,:,jk) = MIN( MAX( 1.4e-7_wp, zav_wave(:,:,jk) ), 1.e-2_wp ) * wmask(:,:,jk) |
|---|
| 289 | END DO |
|---|
| 290 | ! |
|---|
| 291 | IF( kt == nit000 ) THEN !* Control print at first time-step: diagnose the energy consumed by zav_wave |
|---|
| 292 | zztmp = 0._wp |
|---|
| 293 | !!gm used of glosum 3D.... |
|---|
| 294 | DO_3D_11_11( 2, jpkm1 ) |
|---|
| 295 | zztmp = zztmp + e3w(ji,jj,jk,Kmm) * e1e2t(ji,jj) & |
|---|
| 296 | & * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 297 | END_3D |
|---|
| 298 | CALL mpp_sum( 'zdfiwm', zztmp ) |
|---|
| 299 | zztmp = rho0 * zztmp ! Global integral of rauo * Kz * N^2 = power contributing to mixing |
|---|
| 300 | ! |
|---|
| 301 | IF(lwp) THEN |
|---|
| 302 | WRITE(numout,*) |
|---|
| 303 | WRITE(numout,*) 'zdf_iwm : Internal wave-driven mixing (iwm)' |
|---|
| 304 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 305 | WRITE(numout,*) |
|---|
| 306 | WRITE(numout,*) ' Total power consumption by av_wave = ', zztmp * 1.e-12_wp, 'TW' |
|---|
| 307 | ENDIF |
|---|
| 308 | ENDIF |
|---|
| 309 | |
|---|
| 310 | ! ! ----------------------- ! |
|---|
| 311 | ! ! Update mixing coefs ! |
|---|
| 312 | ! ! ----------------------- ! |
|---|
| 313 | ! |
|---|
| 314 | IF( ln_tsdiff ) THEN !* Option for differential mixing of salinity and temperature |
|---|
| 315 | ztmp1 = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10( 1.e-20_wp ) - 0.60_wp ) ) |
|---|
| 316 | DO_3D_11_11( 2, jpkm1 ) |
|---|
| 317 | ztmp2 = zReb(ji,jj,jk) * 5._wp * r1_6 |
|---|
| 318 | IF ( ztmp2 > 1.e-20_wp .AND. wmask(ji,jj,jk) == 1._wp ) THEN |
|---|
| 319 | zav_ratio(ji,jj,jk) = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10(ztmp2) - 0.60_wp ) ) |
|---|
| 320 | ELSE |
|---|
| 321 | zav_ratio(ji,jj,jk) = ztmp1 * wmask(ji,jj,jk) |
|---|
| 322 | ENDIF |
|---|
| 323 | END_3D |
|---|
| 324 | CALL iom_put( "av_ratio", zav_ratio ) |
|---|
| 325 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with wave-driven mixing |
|---|
| 326 | p_avs(:,:,jk) = p_avs(:,:,jk) + zav_wave(:,:,jk) * zav_ratio(:,:,jk) |
|---|
| 327 | p_avt(:,:,jk) = p_avt(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 328 | p_avm(:,:,jk) = p_avm(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 329 | END DO |
|---|
| 330 | ! |
|---|
| 331 | ELSE !* update momentum & tracer diffusivity with wave-driven mixing |
|---|
| 332 | DO jk = 2, jpkm1 |
|---|
| 333 | p_avs(:,:,jk) = p_avs(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 334 | p_avt(:,:,jk) = p_avt(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 335 | p_avm(:,:,jk) = p_avm(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 336 | END DO |
|---|
| 337 | ENDIF |
|---|
| 338 | |
|---|
| 339 | ! !* output internal wave-driven mixing coefficient |
|---|
| 340 | CALL iom_put( "av_wave", zav_wave ) |
|---|
| 341 | !* output useful diagnostics: Kz*N^2 , |
|---|
| 342 | !!gm Kz*N2 should take into account the ratio avs/avt if it is used.... (see diaar5) |
|---|
| 343 | ! vertical integral of rho0 * Kz * N^2 , energy density (zemx_iwm) |
|---|
| 344 | IF( iom_use("bflx_iwm") .OR. iom_use("pcmap_iwm") ) THEN |
|---|
| 345 | ALLOCATE( z2d(jpi,jpj) , z3d(jpi,jpj,jpk) ) |
|---|
| 346 | z3d(:,:,:) = MAX( 0._wp, rn2(:,:,:) ) * zav_wave(:,:,:) |
|---|
| 347 | z2d(:,:) = 0._wp |
|---|
| 348 | DO jk = 2, jpkm1 |
|---|
| 349 | z2d(:,:) = z2d(:,:) + e3w(:,:,jk,Kmm) * z3d(:,:,jk) * wmask(:,:,jk) |
|---|
| 350 | END DO |
|---|
| 351 | z2d(:,:) = rho0 * z2d(:,:) |
|---|
| 352 | CALL iom_put( "bflx_iwm", z3d ) |
|---|
| 353 | CALL iom_put( "pcmap_iwm", z2d ) |
|---|
| 354 | DEALLOCATE( z2d , z3d ) |
|---|
| 355 | ENDIF |
|---|
| 356 | CALL iom_put( "emix_iwm", zemx_iwm ) |
|---|
| 357 | |
|---|
| 358 | IF(sn_cfctl%l_prtctl) CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' iwm - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', kdim=jpk) |
|---|
| 359 | ! |
|---|
| 360 | END SUBROUTINE zdf_iwm |
|---|
| 361 | |
|---|
| 362 | |
|---|
| 363 | SUBROUTINE zdf_iwm_init |
|---|
| 364 | !!---------------------------------------------------------------------- |
|---|
| 365 | !! *** ROUTINE zdf_iwm_init *** |
|---|
| 366 | !! |
|---|
| 367 | !! ** Purpose : Initialization of the wave-driven vertical mixing, reading |
|---|
| 368 | !! of input power maps and decay length scales in netcdf files. |
|---|
| 369 | !! |
|---|
| 370 | !! ** Method : - Read the namzdf_iwm namelist and check the parameters |
|---|
| 371 | !! |
|---|
| 372 | !! - Read the input data in NetCDF files : |
|---|
| 373 | !! power available from high-mode wave breaking (mixing_power_bot.nc) |
|---|
| 374 | !! power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc) |
|---|
| 375 | !! power available from critical slope wave-breaking (mixing_power_cri.nc) |
|---|
| 376 | !! WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc) |
|---|
| 377 | !! decay scale for critical slope wave-breaking (decay_scale_cri.nc) |
|---|
| 378 | !! |
|---|
| 379 | !! ** input : - Namlist namzdf_iwm |
|---|
| 380 | !! - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc, |
|---|
| 381 | !! decay_scale_bot.nc decay_scale_cri.nc |
|---|
| 382 | !! |
|---|
| 383 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
|---|
| 384 | !! - Define ebot_iwm, epyc_iwm, ecri_iwm, hbot_iwm, hcri_iwm |
|---|
| 385 | !! |
|---|
| 386 | !! References : de Lavergne et al. JPO, 2015 ; de Lavergne PhD 2016 |
|---|
| 387 | !! de Lavergne et al. in prep., 2017 |
|---|
| 388 | !!---------------------------------------------------------------------- |
|---|
| 389 | INTEGER :: ifpr ! dummy loop indices |
|---|
| 390 | INTEGER :: inum ! local integer |
|---|
| 391 | INTEGER :: ios |
|---|
| 392 | REAL(wp) :: zbot, zpyc, zcri ! local scalars |
|---|
| 393 | ! |
|---|
| 394 | CHARACTER(len=256) :: cn_dir ! Root directory for location of ssr files |
|---|
| 395 | INTEGER, PARAMETER :: jpiwm = 5 ! maximum number of files to read |
|---|
| 396 | INTEGER, PARAMETER :: jp_mpb = 1 |
|---|
| 397 | INTEGER, PARAMETER :: jp_mpp = 2 |
|---|
| 398 | INTEGER, PARAMETER :: jp_mpc = 3 |
|---|
| 399 | INTEGER, PARAMETER :: jp_dsb = 4 |
|---|
| 400 | INTEGER, PARAMETER :: jp_dsc = 5 |
|---|
| 401 | ! |
|---|
| 402 | TYPE(FLD_N), DIMENSION(jpiwm) :: slf_iwm ! array of namelist informations |
|---|
| 403 | TYPE(FLD_N) :: sn_mpb, sn_mpp, sn_mpc ! informations about Mixing Power field to be read |
|---|
| 404 | TYPE(FLD_N) :: sn_dsb, sn_dsc ! informations about Decay Scale field to be read |
|---|
| 405 | TYPE(FLD ), DIMENSION(jpiwm) :: sf_iwm ! structure of input fields (file informations, fields read) |
|---|
| 406 | ! |
|---|
| 407 | NAMELIST/namzdf_iwm/ nn_zpyc, ln_mevar, ln_tsdiff, & |
|---|
| 408 | & cn_dir, sn_mpb, sn_mpp, sn_mpc, sn_dsb, sn_dsc |
|---|
| 409 | !!---------------------------------------------------------------------- |
|---|
| 410 | ! |
|---|
| 411 | READ ( numnam_ref, namzdf_iwm, IOSTAT = ios, ERR = 901) |
|---|
| 412 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_iwm in reference namelist' ) |
|---|
| 413 | ! |
|---|
| 414 | READ ( numnam_cfg, namzdf_iwm, IOSTAT = ios, ERR = 902 ) |
|---|
| 415 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namzdf_iwm in configuration namelist' ) |
|---|
| 416 | IF(lwm) WRITE ( numond, namzdf_iwm ) |
|---|
| 417 | ! |
|---|
| 418 | IF(lwp) THEN ! Control print |
|---|
| 419 | WRITE(numout,*) |
|---|
| 420 | WRITE(numout,*) 'zdf_iwm_init : internal wave-driven mixing' |
|---|
| 421 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 422 | WRITE(numout,*) ' Namelist namzdf_iwm : set wave-driven mixing parameters' |
|---|
| 423 | WRITE(numout,*) ' Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc |
|---|
| 424 | WRITE(numout,*) ' Variable (T) or constant (F) mixing efficiency = ', ln_mevar |
|---|
| 425 | WRITE(numout,*) ' Differential internal wave-driven mixing (T) or not (F) = ', ln_tsdiff |
|---|
| 426 | ENDIF |
|---|
| 427 | |
|---|
| 428 | ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and |
|---|
| 429 | ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should |
|---|
| 430 | ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6). |
|---|
| 431 | avmb(:) = 1.4e-6_wp ! viscous molecular value |
|---|
| 432 | avtb(:) = 1.e-10_wp ! very small diffusive minimum (background avt is specified in zdf_iwm) |
|---|
| 433 | avtb_2d(:,:) = 1.e0_wp ! uniform |
|---|
| 434 | IF(lwp) THEN ! Control print |
|---|
| 435 | WRITE(numout,*) |
|---|
| 436 | WRITE(numout,*) ' Force the background value applied to avm & avt in TKE to be everywhere ', & |
|---|
| 437 | & 'the viscous molecular value & a very small diffusive value, resp.' |
|---|
| 438 | ENDIF |
|---|
| 439 | |
|---|
| 440 | ! ! allocate iwm arrays |
|---|
| 441 | IF( zdf_iwm_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_iwm_init : unable to allocate iwm arrays' ) |
|---|
| 442 | ! |
|---|
| 443 | ! store namelist information in an array |
|---|
| 444 | slf_iwm(jp_mpb) = sn_mpb ; slf_iwm(jp_mpp) = sn_mpp ; slf_iwm(jp_mpc) = sn_mpc |
|---|
| 445 | slf_iwm(jp_dsb) = sn_dsb ; slf_iwm(jp_dsc) = sn_dsc |
|---|
| 446 | ! |
|---|
| 447 | DO ifpr= 1, jpiwm |
|---|
| 448 | ALLOCATE( sf_iwm(ifpr)%fnow(jpi,jpj,1) ) |
|---|
| 449 | IF( slf_iwm(ifpr)%ln_tint )ALLOCATE( sf_iwm(ifpr)%fdta(jpi,jpj,1,2) ) |
|---|
| 450 | END DO |
|---|
| 451 | |
|---|
| 452 | ! fill sf_iwm with sf_iwm and control print |
|---|
| 453 | CALL fld_fill( sf_iwm, slf_iwm , cn_dir, 'zdfiwm_init', 'iwm input file', 'namiwm' ) |
|---|
| 454 | |
|---|
| 455 | ! ! hard-coded default definition (to be defined in namelist ?) |
|---|
| 456 | sf_iwm(jp_mpb)%fnow(:,:,1) = 1.e-6 |
|---|
| 457 | sf_iwm(jp_mpp)%fnow(:,:,1) = 1.e-6 |
|---|
| 458 | sf_iwm(jp_mpc)%fnow(:,:,1) = 1.e-10 |
|---|
| 459 | sf_iwm(jp_dsb)%fnow(:,:,1) = 100. |
|---|
| 460 | sf_iwm(jp_dsc)%fnow(:,:,1) = 100. |
|---|
| 461 | |
|---|
| 462 | ! ! read necessary fields |
|---|
| 463 | CALL fld_read( nit000, 1, sf_iwm ) |
|---|
| 464 | |
|---|
| 465 | ebot_iwm(:,:) = sf_iwm(1)%fnow(:,:,1) * ssmask(:,:) ! energy flux for high-mode wave breaking [W/m2] |
|---|
| 466 | epyc_iwm(:,:) = sf_iwm(2)%fnow(:,:,1) * ssmask(:,:) ! energy flux for pynocline-intensified wave breaking [W/m2] |
|---|
| 467 | ecri_iwm(:,:) = sf_iwm(3)%fnow(:,:,1) * ssmask(:,:) ! energy flux for critical slope wave breaking [W/m2] |
|---|
| 468 | hbot_iwm(:,:) = sf_iwm(4)%fnow(:,:,1) ! spatially variable decay scale for high-mode wave breaking [m] |
|---|
| 469 | hcri_iwm(:,:) = sf_iwm(5)%fnow(:,:,1) ! spatially variable decay scale for critical slope wave breaking [m] |
|---|
| 470 | |
|---|
| 471 | zbot = glob_sum( 'zdfiwm', e1e2t(:,:) * ebot_iwm(:,:) ) |
|---|
| 472 | zpyc = glob_sum( 'zdfiwm', e1e2t(:,:) * epyc_iwm(:,:) ) |
|---|
| 473 | zcri = glob_sum( 'zdfiwm', e1e2t(:,:) * ecri_iwm(:,:) ) |
|---|
| 474 | |
|---|
| 475 | IF(lwp) THEN |
|---|
| 476 | WRITE(numout,*) ' High-mode wave-breaking energy: ', zbot * 1.e-12_wp, 'TW' |
|---|
| 477 | WRITE(numout,*) ' Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW' |
|---|
| 478 | WRITE(numout,*) ' Critical slope wave-breaking energy: ', zcri * 1.e-12_wp, 'TW' |
|---|
| 479 | ENDIF |
|---|
| 480 | ! |
|---|
| 481 | END SUBROUTINE zdf_iwm_init |
|---|
| 482 | |
|---|
| 483 | !!====================================================================== |
|---|
| 484 | END MODULE zdfiwm |
|---|
