New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/OCE – NEMO

Context Navigation

source: NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/OCE/nemogcm.F90 @ 13220

Last change on this file since 13220 was 13220, checked in by orioltp, 4 years ago
dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation: updating from trunk r13218
Property svn:keywords set to `Id`
File size: 35.6 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! - ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!! 3.6 ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32	!! - ! 2014-12 (G. Madec) remove KPP scheme and cross-land advection (cla)
33	!! 4.0 ! 2016-10 (G. Madec, S. Flavoni) domain configuration / user defined interface
34	!!----------------------------------------------------------------------
35
36	!!----------------------------------------------------------------------
37	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38	!! nemo_init : initialization of the NEMO system
39	!! nemo_ctl : initialisation of the contol print
40	!! nemo_closefile: close remaining open files
41	!! nemo_alloc : dynamical allocation
42	!!----------------------------------------------------------------------
43	USE step_oce ! module used in the ocean time stepping module (step.F90)
44	USE phycst ! physical constant (par_cst routine)
45	USE domain ! domain initialization (dom_init & dom_cfg routines)
46	USE closea ! treatment of closed seas (for ln_closea)
47	USE usrdef_nam ! user defined configuration
48	USE tide_mod, ONLY : tide_init ! tidal components initialization (tide_init routine)
49	USE bdy_oce, ONLY : ln_bdy
50	USE bdyini ! open boundary cond. setting (bdy_init routine)
51	USE istate ! initial state setting (istate_init routine)
52	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
53	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
54	USE trdini ! dyn/tra trends initialization (trd_init routine)
55	USE asminc ! assimilation increments
56	USE asmbkg ! writing out state trajectory
57	USE diaptr ! poleward transports (dia_ptr_init routine)
58	USE diadct ! sections transports (dia_dct_init routine)
59	USE diaobs ! Observation diagnostics (dia_obs_init routine)
60	USE diacfl ! CFL diagnostics (dia_cfl_init routine)
61	USE diamlr ! IOM context management for multiple-linear-regression analysis
62	USE step ! NEMO time-stepping (stp routine)
63	USE isfstp ! ice shelf (isf_stp_init routine)
64	USE icbini ! handle bergs, initialisation
65	USE icbstp ! handle bergs, calving, themodynamics and transport
66	USE cpl_oasis3 ! OASIS3 coupling
67	USE c1d ! 1D configuration
68	USE step_c1d ! Time stepping loop for the 1D configuration
69	USE dyndmp ! Momentum damping
70	USE stopar ! Stochastic param.: ???
71	USE stopts ! Stochastic param.: ???
72	USE diu_layers ! diurnal bulk SST and coolskin
73	USE step_diu ! diurnal bulk SST timestepping (called from here if run offline)
74	USE crsini ! initialise grid coarsening utility
75	USE dia25h ! 25h mean output
76	USE diadetide ! Weights computation for daily detiding of model diagnostics
77	USE sbc_oce , ONLY : lk_oasis
78	USE wet_dry ! Wetting and drying setting (wad_init routine)
79	#if defined key_top
80	USE trcini ! passive tracer initialisation
81	#endif
82	#if defined key_nemocice_decomp
83	USE ice_domain_size, only: nx_global, ny_global
84	#endif
85	!
86	USE in_out_manager ! I/O manager
87	USE lib_mpp ! distributed memory computing
88	USE mppini ! shared/distributed memory setting (mpp_init routine)
89	USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
90	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
91	#if defined key_iomput
92	USE xios ! xIOserver
93	#endif
94	#if defined key_agrif
95	USE agrif_all_update ! Master Agrif update
96	#endif
97
98	IMPLICIT NONE
99	PRIVATE
100
101	PUBLIC nemo_gcm ! called by model.F90
102	PUBLIC nemo_init ! needed by AGRIF
103	PUBLIC nemo_alloc ! needed by TAM
104
105	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
106
107	#if defined key_mpp_mpi
108	! need MPI_Wtime
109	INCLUDE 'mpif.h'
110	#endif
111
112	!!----------------------------------------------------------------------
113	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
114	!! $Id$
115	!! Software governed by the CeCILL license (see ./LICENSE)
116	!!----------------------------------------------------------------------
117	CONTAINS
118
119	SUBROUTINE nemo_gcm
120	!!----------------------------------------------------------------------
121	!! * ROUTINE nemo_gcm *
122	!!
123	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
124	!! curvilinear mesh on the sphere.
125	!!
126	!! ** Method : - model general initialization
127	!! - launch the time-stepping (stp routine)
128	!! - finalize the run by closing files and communications
129	!!
130	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
131	!! Madec, 2008, internal report, IPSL.
132	!!----------------------------------------------------------------------
133	INTEGER :: istp ! time step index
134	REAL(wp):: zstptiming ! elapsed time for 1 time step
135	!!----------------------------------------------------------------------
136	!
137	#if defined key_agrif
138	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
139	#endif
140	! !-----------------------!
141	CALL nemo_init !== Initialisations ==!
142	! !-----------------------!
143	#if defined key_agrif
144	Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices
145	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
146	# if defined key_top
147	CALL Agrif_Declare_Var_top ! " " " " " TOP
148	# endif
149	#endif
150	! check that all process are still there... If some process have an error,
151	! they will never enter in step and other processes will wait until the end of the cpu time!
152	CALL mpp_max( 'nemogcm', nstop )
153
154	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
155
156	! !-----------------------!
157	! !== time stepping ==!
158	! !-----------------------!
159	!
160	! !== set the model time-step ==!
161	!
162	istp = nit000
163	!
164	#if defined key_c1d
165	DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== C1D time-stepping ==!
166	CALL stp_c1d( istp )
167	istp = istp + 1
168	END DO
169	#else
170	!
171	# if defined key_agrif
172	! !== AGRIF time-stepping ==!
173	CALL Agrif_Regrid()
174	!
175	! Recursive update from highest nested level to lowest:
176	Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices
177	CALL Agrif_step_child_adj(Agrif_Update_All)
178	!
179	DO WHILE( istp <= nitend .AND. nstop == 0 )
180	CALL stp
181	istp = istp + 1
182	END DO
183	!
184	# else
185	!
186	IF( .NOT.ln_diurnal_only ) THEN !== Standard time-stepping ==!
187	!
188	DO WHILE( istp <= nitend .AND. nstop == 0 )
189
190	ncom_stp = istp
191	IF( ln_timing ) THEN
192	zstptiming = MPI_Wtime()
193	IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
194	IF ( istp == nitend ) elapsed_time = zstptiming - elapsed_time
195	ENDIF
196
197	CALL stp ( istp )
198	istp = istp + 1
199
200	IF( lwp .AND. ln_timing ) WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
201
202	END DO
203	!
204	ELSE !== diurnal SST time-steeping only ==!
205	!
206	DO WHILE( istp <= nitend .AND. nstop == 0 )
207	CALL stp_diurnal( istp ) ! time step only the diurnal SST
208	istp = istp + 1
209	END DO
210	!
211	ENDIF
212	!
213	# endif
214	!
215	#endif
216	!
217	IF( ln_diaobs ) CALL dia_obs_wri
218	!
219	IF( ln_icebergs ) CALL icb_end( nitend )
220
221	! !------------------------!
222	! !== finalize the run ==!
223	! !------------------------!
224	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
225	!
226	IF( nstop /= 0 .AND. lwp ) THEN ! error print
227	WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found'
228	IF( ngrdstop > 0 ) THEN
229	WRITE(ctmp9,'(i2)') ngrdstop
230	WRITE(ctmp2,*) ' E R R O R detected in Agrif grid '//TRIM(ctmp9)
231	WRITE(ctmp3,) ' Look for "E R R O R" messages in all existing '//TRIM(ctmp9)//'_ocean_output files'
232	CALL ctl_stop( ' ', ctmp1, ' ', ctmp2, ' ', ctmp3 )
233	ELSE
234	WRITE(ctmp2,) ' Look for "E R R O R" messages in all existing ocean_output files'
235	CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 )
236	ENDIF
237	ENDIF
238	!
239	IF( ln_timing ) CALL timing_finalize
240	!
241	CALL nemo_closefile
242	!
243	#if defined key_iomput
244	CALL xios_finalize ! end mpp communications with xios
245	IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS
246	#else
247	IF ( lk_oasis ) THEN ; CALL cpl_finalize ! end coupling and mpp communications with OASIS
248	ELSEIF( lk_mpp ) THEN ; CALL mppstop ! end mpp communications
249	ENDIF
250	#endif
251	!
252	IF(lwm) THEN
253	IF( nstop == 0 ) THEN ; STOP 0
254	ELSE ; STOP 123
255	ENDIF
256	ENDIF
257	!
258	END SUBROUTINE nemo_gcm
259
260
261	SUBROUTINE nemo_init
262	!!----------------------------------------------------------------------
263	!! * ROUTINE nemo_init *
264	!!
265	!! ** Purpose : initialization of the NEMO GCM
266	!!----------------------------------------------------------------------
267	INTEGER :: ios, ilocal_comm ! local integers
268	!!
269	NAMELIST/namctl/ sn_cfctl, nn_print, nn_ictls, nn_ictle, &
270	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
271	& ln_timing, ln_diacfl
272	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
273	!!----------------------------------------------------------------------
274	!
275	cxios_context = 'nemo'
276	!
277	! !-------------------------------------------------!
278	! ! set communicator & select the local rank !
279	! ! must be done as soon as possible to get narea !
280	! !-------------------------------------------------!
281	!
282	#if defined key_iomput
283	IF( Agrif_Root() ) THEN
284	IF( lk_oasis ) THEN
285	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
286	CALL xios_initialize( "not used" , local_comm =ilocal_comm ) ! send nemo communicator to xios
287	ELSE
288	CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios
289	ENDIF
290	ENDIF
291	CALL mpp_start( ilocal_comm )
292	#else
293	IF( lk_oasis ) THEN
294	IF( Agrif_Root() ) THEN
295	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
296	ENDIF
297	CALL mpp_start( ilocal_comm )
298	ELSE
299	CALL mpp_start( )
300	ENDIF
301	#endif
302	!
303	narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 )
304	lwm = (narea == 1) ! control of output namelists
305	!
306	! !---------------------------------------------------------------!
307	! ! Open output files, reference and configuration namelist files !
308	! !---------------------------------------------------------------!
309	!
310	! open ocean.output as soon as possible to get all output prints (including errors messages)
311	IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
312	! open reference and configuration namelist files
313	CALL load_nml( numnam_ref, 'namelist_ref', -1, lwm )
314	CALL load_nml( numnam_cfg, 'namelist_cfg', -1, lwm )
315	IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
316	! open /dev/null file to be able to supress output write easily
317	IF( Agrif_Root() ) THEN
318	CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
319	#ifdef key_agrif
320	ELSE
321	numnul = Agrif_Parent(numnul)
322	#endif
323	ENDIF
324	! !--------------------!
325	! ! Open listing units ! -> need sn_cfctl from namctl to define lwp
326	! !--------------------!
327	!
328	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
329	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' )
330	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
331	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' )
332	!
333	! finalize the definition of namctl variables
334	IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) &
335	& CALL nemo_set_cfctl( sn_cfctl, .FALSE. )
336	!
337	lwp = (narea == 1) .OR. sn_cfctl%l_oceout ! control of all listing output print
338	!
339	IF(lwp) THEN ! open listing units
340	!
341	IF( .NOT. lwm ) & ! alreay opened for narea == 1
342	& CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
343	!
344	WRITE(numout,*)
345	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
346	WRITE(numout,*) ' NEMO team'
347	WRITE(numout,*) ' Ocean General Circulation Model'
348	WRITE(numout,*) ' NEMO version 4.0 (2019) '
349	WRITE(numout,*)
350	WRITE(numout,*) " ._ ._ ._ ._ ._ "
351	WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
352	WRITE(numout,*)
353	WRITE(numout,*) " o _, _, "
354	WRITE(numout,*) " o .' ( .-' / "
355	WRITE(numout,*) " o _/..._'. .' / "
356	WRITE(numout,*) " ( o .-'` ` '-./ _.' "
357	WRITE(numout,*) " ) ( o) ;= <_ ( "
358	WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) "
359	WRITE(numout,*) " ) ) \) \|`\ \) '. \ ( ( "
360	WRITE(numout,*) " ( ( \_/ '-._\ ) ) "
361	WRITE(numout,*) " ) ) jgs ` ( ( "
362	WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
363	WRITE(numout,*)
364
365	! Print the working precision to ocean.output
366	IF (wp == dp) THEN
367	WRITE(numout,*) "Working precision = double-precision"
368	ELSE
369	WRITE(numout,*) "Working precision = single-precision"
370	ENDIF
371	WRITE(numout,*)
372	!
373	WRITE(numout,cform_aaa) ! Flag AAAAAAA
374	!
375	ENDIF
376	!
377	IF(lwm) WRITE( numond, namctl )
378	!
379	! !------------------------------------!
380	! ! Set global domain size parameters !
381	! !------------------------------------!
382	!
383	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
384	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' )
385	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
386	904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' )
387	!
388	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
389	CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
390	ELSE ! user-defined namelist
391	CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
392	ENDIF
393	!
394	IF(lwm) WRITE( numond, namcfg )
395	!
396	! !-----------------------------------------!
397	! ! mpp parameters and domain decomposition !
398	! !-----------------------------------------!
399	CALL mpp_init
400
401	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
402	CALL nemo_alloc()
403
404	! Initialise time level indices
405	Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
406	#if defined key_agrif
407	Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices
408	#endif
409	! !-------------------------------!
410	! ! NEMO general initialization !
411	! !-------------------------------!
412
413	CALL nemo_ctl ! Control prints
414	!
415	! ! General initialization
416	IF( ln_timing ) CALL timing_init ! timing
417	IF( ln_timing ) CALL timing_start( 'nemo_init')
418	!
419	CALL phy_cst ! Physical constants
420	CALL eos_init ! Equation of state
421	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
422	CALL wad_init ! Wetting and drying options
423
424	#if defined key_agrif
425	CALL Agrif_Declare_Var_ini ! " " " " " DOM
426	#endif
427	CALL dom_init( Nbb, Nnn, Naa, "OPA") ! Domain
428
429
430
431	IF( ln_crs ) CALL crs_init( Nnn ) ! coarsened grid: domain initialization
432	IF( sn_cfctl%l_prtctl ) &
433	& CALL prt_ctl_init ! Print control
434
435	CALL diurnal_sst_bulk_init ! diurnal sst
436	IF( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin
437	!
438	IF( ln_diurnal_only ) THEN ! diurnal only: a subset of the initialisation routines
439	CALL istate_init( Nbb, Nnn, Naa ) ! ocean initial state (Dynamics and tracers)
440	CALL sbc_init( Nbb, Nnn, Naa ) ! Forcings : surface module
441	CALL tra_qsr_init ! penetrative solar radiation qsr
442	IF( ln_diaobs ) THEN ! Observation & model comparison
443	CALL dia_obs_init( Nnn ) ! Initialize observational data
444	CALL dia_obs( nit000 - 1, Nnn ) ! Observation operator for restart
445	ENDIF
446	IF( lk_asminc ) CALL asm_inc_init( Nbb, Nnn, Nrhs ) ! Assimilation increments
447	!
448	RETURN ! end of initialization
449	ENDIF
450	!
451
452	CALL istate_init( Nbb, Nnn, Naa ) ! ocean initial state (Dynamics and tracers)
453
454	! ! external forcing
455	CALL tide_init ! tidal harmonics
456	CALL sbc_init( Nbb, Nnn, Naa ) ! surface boundary conditions (including sea-ice)
457	CALL bdy_init ! Open boundaries initialisation
458
459	! ! Ocean physics
460	CALL zdf_phy_init( Nnn ) ! Vertical physics
461
462	! ! Lateral physics
463	CALL ldf_tra_init ! Lateral ocean tracer physics
464	CALL ldf_eiv_init ! eddy induced velocity param.
465	CALL ldf_dyn_init ! Lateral ocean momentum physics
466
467	! ! Active tracers
468	IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation qsr
469	CALL tra_bbc_init ! bottom heat flux
470	CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
471	CALL tra_dmp_init ! internal tracer damping
472	CALL tra_adv_init ! horizontal & vertical advection
473	CALL tra_ldf_init ! lateral mixing
474
475	! ! Dynamics
476	IF( lk_c1d ) CALL dyn_dmp_init ! internal momentum damping
477	CALL dyn_adv_init ! advection (vector or flux form)
478	CALL dyn_vor_init ! vorticity term including Coriolis
479	CALL dyn_ldf_init ! lateral mixing
480	CALL dyn_hpg_init( Nnn ) ! horizontal gradient of Hydrostatic pressure
481	CALL dyn_spg_init ! surface pressure gradient
482
483	#if defined key_top
484	! ! Passive tracers
485	CALL trc_init( Nbb, Nnn, Naa )
486	#endif
487	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
488
489	! ! Icebergs
490	CALL icb_init( rn_Dt, nit000) ! initialise icebergs instance
491
492	! ice shelf
493	CALL isf_init( Nbb, Nnn, Naa )
494
495	! ! Misc. options
496	CALL sto_par_init ! Stochastic parametrization
497	IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations
498
499	! ! Diagnostics
500	CALL flo_init( Nnn ) ! drifting Floats
501	IF( ln_diacfl ) CALL dia_cfl_init ! Initialise CFL diagnostics
502	! CALL dia_ptr_init ! Poleward TRansports initialization
503	CALL dia_dct_init ! Sections tranports
504	CALL dia_hsb_init( Nnn ) ! heat content, salt content and volume budgets
505	CALL trd_init( Nnn ) ! Mixed-layer/Vorticity/Integral constraints trends
506	CALL dia_obs_init( Nnn ) ! Initialize observational data
507	CALL dia_25h_init( Nbb ) ! 25h mean outputs
508	CALL dia_detide_init ! Weights computation for daily detiding of model diagnostics
509	IF( ln_diaobs ) CALL dia_obs( nit000-1, Nnn ) ! Observation operator for restart
510	CALL dia_mlr_init ! Initialisation of IOM context management for multiple-linear-regression analysis
511
512	! ! Assimilation increments
513	IF( lk_asminc ) CALL asm_inc_init( Nbb, Nnn, Nrhs ) ! Initialize assimilation increments
514	!
515	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
516	!
517	IF( ln_timing ) CALL timing_stop( 'nemo_init')
518	!
519	END SUBROUTINE nemo_init
520
521
522	SUBROUTINE nemo_ctl
523	!!----------------------------------------------------------------------
524	!! * ROUTINE nemo_ctl *
525	!!
526	!! ** Purpose : control print setting
527	!!
528	!! ** Method : - print namctl and namcfg information and check some consistencies
529	!!----------------------------------------------------------------------
530	!
531	IF(lwp) THEN ! control print
532	WRITE(numout,*)
533	WRITE(numout,*) 'nemo_ctl: Control prints'
534	WRITE(numout,*) '~~~~~~~~'
535	WRITE(numout,*) ' Namelist namctl'
536	WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
537	WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
538	WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout
539	WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout
540	WRITE(numout,*) ' sn_cfctl%l_prtctl = ', sn_cfctl%l_prtctl
541	WRITE(numout,*) ' sn_cfctl%l_prttrc = ', sn_cfctl%l_prttrc
542	WRITE(numout,*) ' sn_cfctl%l_oasout = ', sn_cfctl%l_oasout
543	WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin
544	WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax
545	WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr
546	WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr
547	WRITE(numout,*) ' level of print nn_print = ', nn_print
548	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
549	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
550	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
551	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
552	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
553	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
554	WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing
555	WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl
556	ENDIF
557	!
558	nprint = nn_print ! convert DOCTOR namelist names into OLD names
559	nictls = nn_ictls
560	nictle = nn_ictle
561	njctls = nn_jctls
562	njctle = nn_jctle
563	isplt = nn_isplt
564	jsplt = nn_jsplt
565
566	IF(lwp) THEN ! control print
567	WRITE(numout,*)
568	WRITE(numout,*) ' Namelist namcfg'
569	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
570	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
571	WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea
572	WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg
573	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
574	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
575	ENDIF
576	IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file
577	!
578	! ! Parameter control
579	!
580	IF( sn_cfctl%l_prtctl .OR. sn_cfctl%l_prttrc ) THEN ! sub-domain area indices for the control prints
581	IF( lk_mpp .AND. jpnij > 1 ) THEN
582	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
583	ELSE
584	IF( isplt == 1 .AND. jsplt == 1 ) THEN
585	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
586	& ' - the print control will be done over the whole domain' )
587	ENDIF
588	ijsplt = isplt * jsplt ! total number of processors ijsplt
589	ENDIF
590	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
591	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
592	!
593	! ! indices used for the SUM control
594	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
595	lsp_area = .FALSE.
596	ELSE ! print control done over a specific area
597	lsp_area = .TRUE.
598	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
599	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
600	nictls = 1
601	ENDIF
602	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
603	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
604	nictle = jpiglo
605	ENDIF
606	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
607	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
608	njctls = 1
609	ENDIF
610	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
611	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
612	njctle = jpjglo
613	ENDIF
614	ENDIF
615	ENDIF
616	!
617	IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', &
618	& 'Compile with key_nosignedzero enabled:', &
619	& '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
620	!
621	#if defined key_agrif
622	IF( ln_timing ) CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
623	#endif
624	!
625	END SUBROUTINE nemo_ctl
626
627
628	SUBROUTINE nemo_closefile
629	!!----------------------------------------------------------------------
630	!! * ROUTINE nemo_closefile *
631	!!
632	!! ** Purpose : Close the files
633	!!----------------------------------------------------------------------
634	!
635	IF( lk_mpp ) CALL mppsync
636	!
637	CALL iom_close ! close all input/output files managed by iom_*
638	!
639	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
640	IF( numrun /= -1 ) CLOSE( numrun ) ! run statistics file
641	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
642	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
643	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
644	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
645	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
646	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
647	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
648	!
649	numout = 6 ! redefine numout in case it is used after this point...
650	!
651	END SUBROUTINE nemo_closefile
652
653
654	SUBROUTINE nemo_alloc
655	!!----------------------------------------------------------------------
656	!! * ROUTINE nemo_alloc *
657	!!
658	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
659	!!
660	!! ** Method :
661	!!----------------------------------------------------------------------
662	USE diawri , ONLY : dia_wri_alloc
663	USE dom_oce , ONLY : dom_oce_alloc
664	USE trc_oce , ONLY : trc_oce_alloc
665	USE bdy_oce , ONLY : bdy_oce_alloc
666	!
667	INTEGER :: ierr
668	!!----------------------------------------------------------------------
669	!
670	ierr = oce_alloc () ! ocean
671	ierr = ierr + dia_wri_alloc()
672	ierr = ierr + dom_oce_alloc() ! ocean domain
673	ierr = ierr + zdf_oce_alloc() ! ocean vertical physics
674	ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays
675	ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization)
676	!
677	CALL mpp_sum( 'nemogcm', ierr )
678	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
679	!
680	END SUBROUTINE nemo_alloc
681
682
683	SUBROUTINE nemo_set_cfctl(sn_cfctl, setto )
684	!!----------------------------------------------------------------------
685	!! * ROUTINE nemo_set_cfctl *
686	!!
687	!! ** Purpose : Set elements of the output control structure to setto.
688	!!
689	!! ** Method : Note this routine can be used to switch on/off some
690	!! types of output for selected areas.
691	!!----------------------------------------------------------------------
692	TYPE(sn_ctl), INTENT(inout) :: sn_cfctl
693	LOGICAL , INTENT(in ) :: setto
694	!!----------------------------------------------------------------------
695	sn_cfctl%l_runstat = setto
696	sn_cfctl%l_trcstat = setto
697	sn_cfctl%l_oceout = setto
698	sn_cfctl%l_layout = setto
699	sn_cfctl%l_prtctl = setto
700	sn_cfctl%l_prttrc = setto
701	sn_cfctl%l_oasout = setto
702	END SUBROUTINE nemo_set_cfctl
703
704	!!======================================================================
705	END MODULE nemogcm
706

Note: See TracBrowser for help on using the repository browser.

Download in other formats: