New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtadyn.F90 in NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/OFF – NEMO

source: NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/OFF/dtadyn.F90 @ 13257

Last change on this file since 13257 was 13257, checked in by orioltp, 4 years ago

Updated with trunk at r13245 and small change allocating variables in icb_oce.F90.

  • Property svn:keywords set to Id
File size: 42.1 KB
Line 
1MODULE dtadyn
2   !!======================================================================
3   !!                       ***  MODULE  dtadyn  ***
4   !! Off-line : interpolation of the physical fields
5   !!======================================================================
6   !! History :   OPA  ! 1992-01 (M. Imbard) Original code
7   !!             8.0  ! 1998-04 (L.Bopp MA Foujols) slopes for isopyc.
8   !!              -   ! 1998-05 (L. Bopp) read output of coupled run
9   !!             8.2  ! 2001-01 (M. Levy et M. Benjelloul) add netcdf FORMAT
10   !!   NEMO      1.0  ! 2005-03 (O. Aumont and A. El Moussaoui) F90
11   !!              -   ! 2005-12 (C. Ethe) Adapted for DEGINT
12   !!             3.0  ! 2007-06 (C. Ethe) use of iom module
13   !!             3.3  ! 2010-11 (C. Ethe) Full reorganization of the off-line: phasing with the on-line
14   !!             3.4  ! 2011-05 (C. Ethe) Use of fldread
15   !!             4.1  ! 2019-08 (A. Coward, D. Storkey) split dta_dyn_sf_swp -> dta_dyn_sf_atf and dta_dyn_sf_interp
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   dta_dyn_init : initialization, namelist read, and SAVEs control
20   !!   dta_dyn      : Interpolation of the fields
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and tracers variables
23   USE c1d             ! 1D configuration: lk_c1d
24   USE dom_oce         ! ocean domain: variables
25#if ! defined key_qco
26   USE domvvl          ! variable volume
27#else
28   USE domqco
29#endif
30   USE zdf_oce         ! ocean vertical physics: variables
31   USE sbc_oce         ! surface module: variables
32   USE trc_oce         ! share ocean/biogeo variables
33   USE phycst          ! physical constants
34   USE trabbl          ! active tracer: bottom boundary layer
35   USE ldfslp          ! lateral diffusion: iso-neutral slopes
36   USE sbcrnf          ! river runoffs
37   USE ldftra          ! ocean tracer   lateral physics
38   USE zdfmxl          ! vertical physics: mixed layer depth
39   USE eosbn2          ! equation of state - Brunt Vaisala frequency
40   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
41   USE zpshde          ! z-coord. with partial steps: horizontal derivatives
42   USE in_out_manager  ! I/O manager
43   USE iom             ! I/O library
44   USE lib_mpp         ! distributed memory computing library
45   USE prtctl          ! print control
46   USE fldread         ! read input fields
47   USE timing          ! Timing
48   USE trc, ONLY : ln_rsttr, numrtr, numrtw, lrst_trc
49
50   IMPLICIT NONE
51   PRIVATE
52
53   PUBLIC   dta_dyn_init       ! called by nemo_init
54   PUBLIC   dta_dyn            ! called by nemo_gcm
55   PUBLIC   dta_dyn_sed_init   ! called by nemo_init
56   PUBLIC   dta_dyn_sed        ! called by nemo_gcm
57   PUBLIC   dta_dyn_atf        ! called by nemo_gcm
58#if ! defined key_qco
59   PUBLIC   dta_dyn_sf_interp  ! called by nemo_gcm
60#endif
61
62   CHARACTER(len=100) ::   cn_dir          !: Root directory for location of ssr files
63   LOGICAL            ::   ln_dynrnf       !: read runoff data in file (T) or set to zero (F)
64   LOGICAL            ::   ln_dynrnf_depth       !: read runoff data in file (T) or set to zero (F)
65   REAL(wp)           ::   fwbcorr
66
67
68   INTEGER  , PARAMETER ::   jpfld = 20     ! maximum number of fields to read
69   INTEGER  , SAVE      ::   jf_tem         ! index of temperature
70   INTEGER  , SAVE      ::   jf_sal         ! index of salinity
71   INTEGER  , SAVE      ::   jf_uwd         ! index of u-transport
72   INTEGER  , SAVE      ::   jf_vwd         ! index of v-transport
73   INTEGER  , SAVE      ::   jf_wwd         ! index of v-transport
74   INTEGER  , SAVE      ::   jf_avt         ! index of Kz
75   INTEGER  , SAVE      ::   jf_mld         ! index of mixed layer deptht
76   INTEGER  , SAVE      ::   jf_emp         ! index of water flux
77   INTEGER  , SAVE      ::   jf_empb        ! index of water flux
78   INTEGER  , SAVE      ::   jf_qsr         ! index of solar radiation
79   INTEGER  , SAVE      ::   jf_wnd         ! index of wind speed
80   INTEGER  , SAVE      ::   jf_ice         ! index of sea ice cover
81   INTEGER  , SAVE      ::   jf_rnf         ! index of river runoff
82   INTEGER  , SAVE      ::   jf_fmf         ! index of downward salt flux
83   INTEGER  , SAVE      ::   jf_ubl         ! index of u-bbl coef
84   INTEGER  , SAVE      ::   jf_vbl         ! index of v-bbl coef
85   INTEGER  , SAVE      ::   jf_div         ! index of e3t
86
87
88   TYPE(FLD), ALLOCATABLE, SAVE, DIMENSION(:) :: sf_dyn  ! structure of input fields (file informations, fields read)
89   !                                               !
90   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: uslpdta    ! zonal isopycnal slopes
91   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: vslpdta    ! meridional isopycnal slopes
92   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: wslpidta   ! zonal diapycnal slopes
93   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: wslpjdta   ! meridional diapycnal slopes
94
95   INTEGER, SAVE  :: nprevrec, nsecdyn
96
97   !! * Substitutions
98#  include "do_loop_substitute.h90"
99   !!----------------------------------------------------------------------
100   !! NEMO/OFF 4.0 , NEMO Consortium (2018)
101   !! $Id$
102   !! Software governed by the CeCILL license (see ./LICENSE)
103   !!----------------------------------------------------------------------
104CONTAINS
105
106   SUBROUTINE dta_dyn( kt, Kbb, Kmm, Kaa )
107      !!----------------------------------------------------------------------
108      !!                  ***  ROUTINE dta_dyn  ***
109      !!
110      !! ** Purpose :  Prepares dynamics and physics fields from a NEMO run
111      !!               for an off-line simulation of passive tracers
112      !!
113      !! ** Method : calculates the position of data
114      !!             - computes slopes if needed
115      !!             - interpolates data if needed
116      !!----------------------------------------------------------------------
117      INTEGER, INTENT(in) ::   kt             ! ocean time-step index
118      INTEGER, INTENT(in) ::   Kbb, Kmm, Kaa  ! ocean time level indices
119      !
120      INTEGER             ::   ji, jj, jk
121      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   zemp
122      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zhdivtr
123      !!----------------------------------------------------------------------
124      !
125      IF( ln_timing )   CALL timing_start( 'dta_dyn')
126      !
127      nsecdyn = nsec_year + nsec1jan000   ! number of seconds between Jan. 1st 00h of nit000 year and the middle of time step
128      !
129      IF( kt == nit000 ) THEN    ;    nprevrec = 0
130      ELSE                       ;    nprevrec = sf_dyn(jf_tem)%nrec_a(2)
131      ENDIF
132      CALL fld_read( kt, 1, sf_dyn )      !=  read data at kt time step   ==!
133      !
134      IF( l_ldfslp .AND. .NOT.lk_c1d )   CALL  dta_dyn_slp( kt, Kbb, Kmm )    ! Computation of slopes
135      !
136      ts(:,:,:,jp_tem,Kmm) = sf_dyn(jf_tem)%fnow(:,:,:)  * tmask(:,:,:)    ! temperature
137      ts(:,:,:,jp_sal,Kmm) = sf_dyn(jf_sal)%fnow(:,:,:)  * tmask(:,:,:)    ! salinity
138      wndm(:,:)         = sf_dyn(jf_wnd)%fnow(:,:,1)  * tmask(:,:,1)    ! wind speed - needed for gas exchange
139      fmmflx(:,:)       = sf_dyn(jf_fmf)%fnow(:,:,1)  * tmask(:,:,1)    ! downward salt flux (v3.5+)
140      fr_i(:,:)         = sf_dyn(jf_ice)%fnow(:,:,1)  * tmask(:,:,1)    ! Sea-ice fraction
141      qsr (:,:)         = sf_dyn(jf_qsr)%fnow(:,:,1)  * tmask(:,:,1)    ! solar radiation
142      emp (:,:)         = sf_dyn(jf_emp)%fnow(:,:,1)  * tmask(:,:,1)    ! E-P
143      IF( ln_dynrnf ) THEN
144         rnf (:,:)      = sf_dyn(jf_rnf)%fnow(:,:,1) * tmask(:,:,1)    ! E-P
145         IF( ln_dynrnf_depth .AND. .NOT. ln_linssh )    CALL  dta_dyn_hrnf(Kmm)
146      ENDIF
147      !
148      uu(:,:,:,Kmm)        = sf_dyn(jf_uwd)%fnow(:,:,:) * umask(:,:,:)    ! effective u-transport
149      vv(:,:,:,Kmm)        = sf_dyn(jf_vwd)%fnow(:,:,:) * vmask(:,:,:)    ! effective v-transport
150      ww(:,:,:)        = sf_dyn(jf_wwd)%fnow(:,:,:) * tmask(:,:,:)    ! effective v-transport
151      !
152      IF( .NOT.ln_linssh ) THEN
153         ALLOCATE( zemp(jpi,jpj) , zhdivtr(jpi,jpj,jpk) )
154         zhdivtr(:,:,:) = sf_dyn(jf_div)%fnow(:,:,:)  * tmask(:,:,:)    ! effective u-transport
155         emp_b  (:,:)   = sf_dyn(jf_empb)%fnow(:,:,1) * tmask(:,:,1)    ! E-P
156         zemp   (:,:)   = ( 0.5_wp * ( emp(:,:) + emp_b(:,:) ) + rnf(:,:) + fwbcorr ) * tmask(:,:,1)
157#if defined key_qco
158         CALL dta_dyn_ssh( kt, zhdivtr, ssh(:,:,Kbb), zemp, ssh(:,:,Kaa) )
159         CALL dom_qco_r3c( ssh(:,:,Kaa), r3t(:,:,Kaa), r3u(:,:,Kaa), r3v(:,:,Kaa) )
160#else
161         CALL dta_dyn_ssh( kt, zhdivtr, ssh(:,:,Kbb), zemp, ssh(:,:,Kaa), e3t(:,:,:,Kaa) )  !=  ssh, vertical scale factor
162#endif
163         DEALLOCATE( zemp , zhdivtr )
164         !                                           Write in the tracer restart file
165         !                                          *********************************
166         IF( lrst_trc ) THEN
167            IF(lwp) WRITE(numout,*)
168            IF(lwp) WRITE(numout,*) 'dta_dyn_ssh : ssh field written in tracer restart file at it= ', kt,' date= ', ndastp
169            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
170            CALL iom_rstput( kt, nitrst, numrtw, 'sshn', ssh(:,:,Kaa) )
171            CALL iom_rstput( kt, nitrst, numrtw, 'sshb', ssh(:,:,Kmm) )
172         ENDIF
173      ENDIF
174      !
175      CALL eos    ( ts(:,:,:,:,Kmm), rhd, rhop, gdept_0(:,:,:) ) ! In any case, we need rhop
176      CALL eos_rab( ts(:,:,:,:,Kmm), rab_n, Kmm )       ! now    local thermal/haline expension ratio at T-points
177      CALL bn2    ( ts(:,:,:,:,Kmm), rab_n, rn2, Kmm )  ! before Brunt-Vaisala frequency need for zdfmxl
178
179      rn2b(:,:,:) = rn2(:,:,:)         ! needed for zdfmxl
180      CALL zdf_mxl( kt, Kmm )          ! In any case, we need mxl
181      !
182      hmld(:,:)       = sf_dyn(jf_mld)%fnow(:,:,1) * tmask(:,:,1)    ! mixed layer depht
183      avt(:,:,:)      = sf_dyn(jf_avt)%fnow(:,:,:) * tmask(:,:,:)    ! vertical diffusive coefficient
184      avs(:,:,:)      = avt(:,:,:)
185      !
186      IF( ln_trabbl .AND. .NOT.lk_c1d ) THEN       ! diffusive Bottom boundary layer param
187         ahu_bbl(:,:) = sf_dyn(jf_ubl)%fnow(:,:,1) * umask(:,:,1)    ! bbl diffusive coef
188         ahv_bbl(:,:) = sf_dyn(jf_vbl)%fnow(:,:,1) * vmask(:,:,1)
189      ENDIF
190      !
191      !
192      CALL eos( ts(:,:,:,:,Kmm), rhd, rhop, gdept_0(:,:,:) ) ! In any case, we need rhop
193      !
194      IF(sn_cfctl%l_prtctl) THEN                 ! print control
195         CALL prt_ctl(tab3d_1=ts(:,:,:,jp_tem,Kmm), clinfo1=' tn      - : ', mask1=tmask,  kdim=jpk   )
196         CALL prt_ctl(tab3d_1=ts(:,:,:,jp_sal,Kmm), clinfo1=' sn      - : ', mask1=tmask,  kdim=jpk   )
197         CALL prt_ctl(tab3d_1=uu(:,:,:,Kmm)               , clinfo1=' uu(:,:,:,Kmm)      - : ', mask1=umask,  kdim=jpk   )
198         CALL prt_ctl(tab3d_1=vv(:,:,:,Kmm)               , clinfo1=' vv(:,:,:,Kmm)      - : ', mask1=vmask,  kdim=jpk   )
199         CALL prt_ctl(tab3d_1=ww               , clinfo1=' ww      - : ', mask1=tmask,  kdim=jpk   )
200         CALL prt_ctl(tab3d_1=avt              , clinfo1=' kz      - : ', mask1=tmask,  kdim=jpk   )
201         CALL prt_ctl(tab3d_1=uslp             , clinfo1=' slp  - u : ', tab3d_2=vslp, clinfo2=' v : ', kdim=jpk)
202         CALL prt_ctl(tab3d_1=wslpi            , clinfo1=' slp  - wi: ', tab3d_2=wslpj, clinfo2=' wj: ', kdim=jpk)
203      ENDIF
204      !
205      IF( ln_timing )   CALL timing_stop( 'dta_dyn')
206      !
207   END SUBROUTINE dta_dyn
208
209
210   SUBROUTINE dta_dyn_init( Kbb, Kmm, Kaa )
211      !!----------------------------------------------------------------------
212      !!                  ***  ROUTINE dta_dyn_init  ***
213      !!
214      !! ** Purpose :   Initialisation of the dynamical data     
215      !! ** Method  : - read the data namdta_dyn namelist
216      !!----------------------------------------------------------------------
217      INTEGER, INTENT(in) ::   Kbb, Kmm, Kaa  ! ocean time level indices
218      !
219      INTEGER  :: ierr, ierr0, ierr1, ierr2, ierr3   ! return error code
220      INTEGER  :: ifpr                               ! dummy loop indice
221      INTEGER  :: jfld                               ! dummy loop arguments
222      INTEGER  :: inum, idv, idimv                   ! local integer
223      INTEGER  :: ios                                ! Local integer output status for namelist read
224      INTEGER  :: ji, jj, jk
225      REAL(wp) :: zcoef
226      INTEGER  :: nkrnf_max
227      REAL(wp) :: hrnf_max
228      !!
229      CHARACTER(len=100)            ::  cn_dir        !   Root directory for location of core files
230      TYPE(FLD_N), DIMENSION(jpfld) ::  slf_d         ! array of namelist informations on the fields to read
231      TYPE(FLD_N) :: sn_uwd, sn_vwd, sn_wwd, sn_empb, sn_emp  ! informations about the fields to be read
232      TYPE(FLD_N) :: sn_tem , sn_sal , sn_avt   !   "                 "
233      TYPE(FLD_N) :: sn_mld, sn_qsr, sn_wnd , sn_ice , sn_fmf   !   "               "
234      TYPE(FLD_N) :: sn_ubl, sn_vbl, sn_rnf    !   "              "
235      TYPE(FLD_N) :: sn_div  ! informations about the fields to be read
236      !!
237      NAMELIST/namdta_dyn/cn_dir, ln_dynrnf, ln_dynrnf_depth,  fwbcorr, &
238         &                sn_uwd, sn_vwd, sn_wwd, sn_emp,               &
239         &                sn_avt, sn_tem, sn_sal, sn_mld , sn_qsr ,     &
240         &                sn_wnd, sn_ice, sn_fmf,                       &
241         &                sn_ubl, sn_vbl, sn_rnf,                       &
242         &                sn_empb, sn_div 
243      !!----------------------------------------------------------------------
244      !
245      READ  ( numnam_ref, namdta_dyn, IOSTAT = ios, ERR = 901)
246901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdta_dyn in reference namelist' )
247      READ  ( numnam_cfg, namdta_dyn, IOSTAT = ios, ERR = 902 )
248902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdta_dyn in configuration namelist' )
249      IF(lwm) WRITE ( numond, namdta_dyn )
250      !                                         ! store namelist information in an array
251      !                                         ! Control print
252      IF(lwp) THEN
253         WRITE(numout,*)
254         WRITE(numout,*) 'dta_dyn : offline dynamics '
255         WRITE(numout,*) '~~~~~~~ '
256         WRITE(numout,*) '   Namelist namdta_dyn'
257         WRITE(numout,*) '      runoffs option enabled (T) or not (F)            ln_dynrnf        = ', ln_dynrnf
258         WRITE(numout,*) '      runoffs is spread in vertical                    ln_dynrnf_depth  = ', ln_dynrnf_depth
259         WRITE(numout,*) '      annual global mean of empmr for ssh correction   fwbcorr          = ', fwbcorr
260         WRITE(numout,*)
261      ENDIF
262      !
263      jf_uwd  = 1     ;   jf_vwd  = 2    ;   jf_wwd = 3    ;   jf_emp = 4    ;   jf_avt = 5
264      jf_tem  = 6     ;   jf_sal  = 7    ;   jf_mld = 8    ;   jf_qsr = 9
265      jf_wnd  = 10    ;   jf_ice  = 11   ;   jf_fmf = 12   ;   jfld   = jf_fmf
266      !
267      slf_d(jf_uwd)  = sn_uwd    ;   slf_d(jf_vwd)  = sn_vwd   ;   slf_d(jf_wwd) = sn_wwd
268      slf_d(jf_emp)  = sn_emp    ;   slf_d(jf_avt)  = sn_avt
269      slf_d(jf_tem)  = sn_tem    ;   slf_d(jf_sal)  = sn_sal   ;   slf_d(jf_mld) = sn_mld
270      slf_d(jf_qsr)  = sn_qsr    ;   slf_d(jf_wnd)  = sn_wnd   ;   slf_d(jf_ice) = sn_ice
271      slf_d(jf_fmf)  = sn_fmf
272      !
273      IF( .NOT.ln_linssh ) THEN
274               jf_div  = jfld + 1   ;         jf_empb  = jfld + 2    ;   jfld = jf_empb
275         slf_d(jf_div) = sn_div     ;   slf_d(jf_empb) = sn_empb
276      ENDIF
277      !
278      IF( ln_trabbl ) THEN
279               jf_ubl  = jfld + 1   ;         jf_vbl  = jfld + 2     ;   jfld = jf_vbl
280         slf_d(jf_ubl) = sn_ubl     ;   slf_d(jf_vbl) = sn_vbl
281      ENDIF
282      !
283      IF( ln_dynrnf ) THEN
284               jf_rnf  = jfld + 1   ;     jfld  = jf_rnf
285         slf_d(jf_rnf) = sn_rnf   
286      ELSE
287         rnf(:,:) = 0._wp
288      ENDIF
289
290      ALLOCATE( sf_dyn(jfld), STAT=ierr )         ! set sf structure
291      IF( ierr > 0 )  THEN
292         CALL ctl_stop( 'dta_dyn: unable to allocate sf structure' )   ;   RETURN
293      ENDIF
294      !                                         ! fill sf with slf_i and control print
295      CALL fld_fill( sf_dyn, slf_d, cn_dir, 'dta_dyn_init', 'Data in file', 'namdta_dyn' )
296      !
297      ! Open file for each variable to get his number of dimension
298      DO ifpr = 1, jfld
299         CALL fld_def( sf_dyn(ifpr) )
300         CALL iom_open( sf_dyn(ifpr)%clname, sf_dyn(ifpr)%num )
301         idv   = iom_varid( sf_dyn(ifpr)%num , slf_d(ifpr)%clvar )        ! id of the variable sdjf%clvar
302         idimv = iom_file ( sf_dyn(ifpr)%num )%ndims(idv)                 ! number of dimension for variable sdjf%clvar
303         CALL iom_close( sf_dyn(ifpr)%num )                               ! close file if already open
304         ierr1=0
305         IF( idimv == 3 ) THEN    ! 2D variable
306                                      ALLOCATE( sf_dyn(ifpr)%fnow(jpi,jpj,1)    , STAT=ierr0 )
307            IF( slf_d(ifpr)%ln_tint ) ALLOCATE( sf_dyn(ifpr)%fdta(jpi,jpj,1,2)  , STAT=ierr1 )
308         ELSE                     ! 3D variable
309                                      ALLOCATE( sf_dyn(ifpr)%fnow(jpi,jpj,jpk)  , STAT=ierr0 )
310            IF( slf_d(ifpr)%ln_tint ) ALLOCATE( sf_dyn(ifpr)%fdta(jpi,jpj,jpk,2), STAT=ierr1 )
311         ENDIF
312         IF( ierr0 + ierr1 > 0 ) THEN
313            CALL ctl_stop( 'dta_dyn_init : unable to allocate sf_dyn array structure' )   ;   RETURN
314         ENDIF
315      END DO
316      !
317      IF( l_ldfslp .AND. .NOT.lk_c1d ) THEN                  ! slopes
318         IF( sf_dyn(jf_tem)%ln_tint ) THEN      ! time interpolation
319            ALLOCATE( uslpdta (jpi,jpj,jpk,2), vslpdta (jpi,jpj,jpk,2),    &
320            &         wslpidta(jpi,jpj,jpk,2), wslpjdta(jpi,jpj,jpk,2), STAT=ierr2 )
321            !
322            IF( ierr2 > 0 )  THEN
323               CALL ctl_stop( 'dta_dyn_init : unable to allocate slope arrays' )   ;   RETURN
324            ENDIF
325         ENDIF
326      ENDIF
327      !
328      IF( .NOT.ln_linssh ) THEN
329        IF( .NOT. sf_dyn(jf_uwd)%ln_clim .AND. ln_rsttr .AND.    &                     ! Restart: read in restart file
330           iom_varid( numrtr, 'sshn', ldstop = .FALSE. ) > 0 ) THEN
331           IF(lwp) WRITE(numout,*) ' ssh(:,:,Kmm) forcing fields read in the restart file for initialisation'
332           CALL iom_get( numrtr, jpdom_autoglo, 'sshn', ssh(:,:,Kmm)   )
333           CALL iom_get( numrtr, jpdom_autoglo, 'sshb', ssh(:,:,Kbb)   )
334        ELSE
335           IF(lwp) WRITE(numout,*) ' ssh(:,:,Kmm) forcing fields read in the restart file for initialisation'
336           CALL iom_open( 'restart', inum )
337           CALL iom_get( inum, jpdom_autoglo, 'sshn', ssh(:,:,Kmm)   )
338           CALL iom_get( inum, jpdom_autoglo, 'sshb', ssh(:,:,Kbb)   )
339           CALL iom_close( inum )                                        ! close file
340        ENDIF
341        !
342#if defined key_qco
343        CALL dom_qco_r3c( ssh(:,:,Kbb), r3t(:,:,Kbb), r3u(:,:,Kbb), r3v(:,:,Kbb) )
344        CALL dom_qco_r3c( ssh(:,:,Kmm), r3t(:,:,Kmm), r3u(:,:,Kmm), r3v(:,:,Kmm) )
345#else
346        DO jk = 1, jpkm1
347           e3t(:,:,jk,Kmm) = e3t_0(:,:,jk) * ( 1._wp + ssh(:,:,Kmm) * r1_ht_0(:,:) * tmask(:,:,jk) )
348        ENDDO
349        e3t(:,:,jpk,Kaa) = e3t_0(:,:,jpk)
350
351        ! Horizontal scale factor interpolations
352        ! --------------------------------------
353        CALL dom_vvl_interpol( e3t(:,:,:,Kmm), e3u(:,:,:,Kmm), 'U' )
354        CALL dom_vvl_interpol( e3t(:,:,:,Kmm), e3v(:,:,:,Kmm), 'V' )
355
356        ! Vertical scale factor interpolations
357        ! ------------------------------------
358        CALL dom_vvl_interpol( e3t(:,:,:,Kmm), e3w(:,:,:,Kmm), 'W' )
359!!gm this should be computed from ssh(Kbb) 
360        e3t(:,:,:,Kbb)  = e3t(:,:,:,Kmm)
361        e3u(:,:,:,Kbb)  = e3u(:,:,:,Kmm)
362        e3v(:,:,:,Kbb)  = e3v(:,:,:,Kmm)
363
364        ! t- and w- points depth
365        ! ----------------------
366        gdept(:,:,1,Kmm) = 0.5_wp * e3w(:,:,1,Kmm)
367        gdepw(:,:,1,Kmm) = 0.0_wp
368
369        DO_3D_11_11( 2, jpk )
370          !    zcoef = (tmask(ji,jj,jk) - wmask(ji,jj,jk))   ! 0 everywhere
371          !    tmask = wmask, ie everywhere expect at jk = mikt
372                                                             ! 1 for jk =
373                                                             ! mikt
374           zcoef = (tmask(ji,jj,jk) - wmask(ji,jj,jk))
375           gdepw(ji,jj,jk,Kmm) = gdepw(ji,jj,jk-1,Kmm) + e3t(ji,jj,jk-1,Kmm)
376           gdept(ji,jj,jk,Kmm) =      zcoef  * ( gdepw(ji,jj,jk  ,Kmm) + 0.5 * e3w(ji,jj,jk,Kmm))  &
377               &                + (1-zcoef) * ( gdept(ji,jj,jk-1,Kmm) + e3w(ji,jj,jk,Kmm))
378        END_3D
379
380        gdept(:,:,:,Kbb) = gdept(:,:,:,Kmm)
381        gdepw(:,:,:,Kbb) = gdepw(:,:,:,Kmm)
382        !
383      ENDIF
384#endif
385      !
386      IF( ln_dynrnf .AND. ln_dynrnf_depth ) THEN       ! read depht over which runoffs are distributed
387         IF(lwp) WRITE(numout,*) 
388         IF(lwp) WRITE(numout,*) ' read in the file depht over which runoffs are distributed'
389         CALL iom_open ( "runoffs", inum )                           ! open file
390         CALL iom_get  ( inum, jpdom_data, 'rodepth', h_rnf )   ! read the river mouth array
391         CALL iom_close( inum )                                        ! close file
392         !
393         nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
394         DO_2D_11_11
395            IF( h_rnf(ji,jj) > 0._wp ) THEN
396               jk = 2
397               DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
398               END DO
399               nk_rnf(ji,jj) = jk
400            ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
401            ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
402            ELSE
403               CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
404               WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
405            ENDIF
406         END_2D
407!!st pourquoi on n'utilise pas le gde3w ici plutôt que de faire une boucle ?
408         DO_2D_11_11
409            h_rnf(ji,jj) = 0._wp
410            DO jk = 1, nk_rnf(ji,jj)
411               h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
412            END DO
413         END_2D
414      ELSE                                       ! runoffs applied at the surface
415         nk_rnf(:,:) = 1
416         h_rnf (:,:) = e3t(:,:,1,Kmm)
417      ENDIF
418      nkrnf_max = MAXVAL( nk_rnf(:,:) )
419      hrnf_max = MAXVAL( h_rnf(:,:) )
420      IF( lk_mpp )  THEN
421         CALL mpp_max( 'dtadyn', nkrnf_max )                 ! max over the  global domain
422         CALL mpp_max( 'dtadyn', hrnf_max )                 ! max over the  global domain
423      ENDIF
424      IF(lwp) WRITE(numout,*) ' '
425      IF(lwp) WRITE(numout,*) ' max depht of runoff : ', hrnf_max,'    max level  : ', nkrnf_max
426      IF(lwp) WRITE(numout,*) ' '
427      !
428      CALL dta_dyn( nit000, Kbb, Kmm, Kaa )
429      !
430   END SUBROUTINE dta_dyn_init
431
432   
433   SUBROUTINE dta_dyn_sed( kt, Kmm )
434      !!----------------------------------------------------------------------
435      !!                  ***  ROUTINE dta_dyn  ***
436      !!
437      !! ** Purpose :  Prepares dynamics and physics fields from a NEMO run
438      !!               for an off-line simulation of passive tracers
439      !!
440      !! ** Method : calculates the position of data
441      !!             - computes slopes if needed
442      !!             - interpolates data if needed
443      !!----------------------------------------------------------------------
444      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
445      INTEGER, INTENT(in) ::   Kmm  ! ocean time level index
446      !
447      !!----------------------------------------------------------------------
448      !
449      IF( ln_timing )   CALL timing_start( 'dta_dyn_sed')
450      !
451      nsecdyn = nsec_year + nsec1jan000   ! number of seconds between Jan. 1st 00h of nit000 year and the middle of time step
452      !
453      IF( kt == nit000 ) THEN    ;    nprevrec = 0
454      ELSE                       ;    nprevrec = sf_dyn(jf_tem)%nrec_a(2)
455      ENDIF
456      CALL fld_read( kt, 1, sf_dyn )      !=  read data at kt time step   ==!
457      !
458      ts(:,:,:,jp_tem,Kmm) = sf_dyn(jf_tem)%fnow(:,:,:)  * tmask(:,:,:)    ! temperature
459      ts(:,:,:,jp_sal,Kmm) = sf_dyn(jf_sal)%fnow(:,:,:)  * tmask(:,:,:)    ! salinity
460      !
461      CALL eos    ( ts(:,:,:,:,Kmm), rhd, rhop, gdept_0(:,:,:) ) ! In any case, we need rhop
462
463      IF(sn_cfctl%l_prtctl) THEN                     ! print control
464         CALL prt_ctl(tab3d_1=ts(:,:,:,jp_tem,Kmm), clinfo1=' tn      - : ', mask1=tmask,  kdim=jpk   )
465         CALL prt_ctl(tab3d_1=ts(:,:,:,jp_sal,Kmm), clinfo1=' sn      - : ', mask1=tmask,  kdim=jpk   )
466      ENDIF
467      !
468      IF( ln_timing )   CALL timing_stop( 'dta_dyn_sed')
469      !
470   END SUBROUTINE dta_dyn_sed
471
472
473   SUBROUTINE dta_dyn_sed_init( Kmm )
474      !!----------------------------------------------------------------------
475      !!                  ***  ROUTINE dta_dyn_init  ***
476      !!
477      !! ** Purpose :   Initialisation of the dynamical data
478      !! ** Method  : - read the data namdta_dyn namelist
479      !!----------------------------------------------------------------------
480      INTEGER, INTENT( in ) :: Kmm                   ! ocean time level index
481      !
482      INTEGER  :: ierr, ierr0, ierr1, ierr2, ierr3   ! return error code
483      INTEGER  :: ifpr                               ! dummy loop indice
484      INTEGER  :: jfld                               ! dummy loop arguments
485      INTEGER  :: inum, idv, idimv                   ! local integer
486      INTEGER  :: ios                                ! Local integer output status for namelist read
487      !!
488      CHARACTER(len=100)            ::  cn_dir        !   Root directory for location of core files
489      TYPE(FLD_N), DIMENSION(2) ::  slf_d         ! array of namelist informations on the fields to read
490      TYPE(FLD_N) :: sn_tem , sn_sal   !   "                 "
491      !!
492      NAMELIST/namdta_dyn/cn_dir, ln_dynrnf, ln_dynrnf_depth,  fwbcorr, &
493         &                sn_tem, sn_sal
494      !!----------------------------------------------------------------------
495      !
496      READ  ( numnam_ref, namdta_dyn, IOSTAT = ios, ERR = 901)
497901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdta_dyn in reference namelist' )
498      READ  ( numnam_cfg, namdta_dyn, IOSTAT = ios, ERR = 902 )
499902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdta_dyn in configuration namelist' )
500      IF(lwm) WRITE ( numond, namdta_dyn )
501      !                                         ! store namelist information in an array
502      !                                         ! Control print
503      IF(lwp) THEN
504         WRITE(numout,*)
505         WRITE(numout,*) 'dta_dyn : offline dynamics '
506         WRITE(numout,*) '~~~~~~~ '
507         WRITE(numout,*) '   Namelist namdta_dyn'
508         WRITE(numout,*) '      runoffs option enabled (T) or not (F)            ln_dynrnf        = ', ln_dynrnf
509         WRITE(numout,*) '      runoffs is spread in vertical                    ln_dynrnf_depth  = ', ln_dynrnf_depth
510         WRITE(numout,*) '      annual global mean of empmr for ssh correction   fwbcorr          = ', fwbcorr
511         WRITE(numout,*)
512      ENDIF
513      !
514      jf_tem  = 1     ;   jf_sal  = 2    ;   jfld   = jf_sal
515      !
516      slf_d(jf_tem)  = sn_tem    ;   slf_d(jf_sal)  = sn_sal
517      !
518      ALLOCATE( sf_dyn(jfld), STAT=ierr )         ! set sf structure
519      IF( ierr > 0 )  THEN
520         CALL ctl_stop( 'dta_dyn: unable to allocate sf structure' )   ;   RETURN
521      ENDIF
522      !                                         ! fill sf with slf_i and control print
523      CALL fld_fill( sf_dyn, slf_d, cn_dir, 'dta_dyn_init', 'Data in file', 'namdta_dyn' )
524      !
525      ! Open file for each variable to get his number of dimension
526      DO ifpr = 1, jfld
527         CALL fld_def( sf_dyn(ifpr) )
528         CALL iom_open( sf_dyn(ifpr)%clname, sf_dyn(ifpr)%num )
529         idv   = iom_varid( sf_dyn(ifpr)%num , slf_d(ifpr)%clvar )        ! id of the variable sdjf%clvar
530         idimv = iom_file ( sf_dyn(ifpr)%num )%ndims(idv)                 ! number of dimension for variable sdjf%clvar
531         CALL iom_close( sf_dyn(ifpr)%num )                               ! close file if already open
532         ierr1=0
533         IF( idimv == 3 ) THEN    ! 2D variable
534                                      ALLOCATE( sf_dyn(ifpr)%fnow(jpi,jpj,1)    , STAT=ierr0 )
535            IF( slf_d(ifpr)%ln_tint ) ALLOCATE( sf_dyn(ifpr)%fdta(jpi,jpj,1,2)  , STAT=ierr1 )
536         ELSE                     ! 3D variable
537                                      ALLOCATE( sf_dyn(ifpr)%fnow(jpi,jpj,jpk)  , STAT=ierr0 )
538            IF( slf_d(ifpr)%ln_tint ) ALLOCATE( sf_dyn(ifpr)%fdta(jpi,jpj,jpk,2), STAT=ierr1 )
539         ENDIF
540         IF( ierr0 + ierr1 > 0 ) THEN
541            CALL ctl_stop( 'dta_dyn_init : unable to allocate sf_dyn array structure' )   ;   RETURN
542         ENDIF
543      END DO
544      !
545      CALL dta_dyn_sed( nit000, Kmm )
546      !
547   END SUBROUTINE dta_dyn_sed_init
548
549   
550   SUBROUTINE dta_dyn_atf( kt, Kbb, Kmm, Kaa )
551     !!---------------------------------------------------------------------
552      !!                    ***  ROUTINE dta_dyn_swp  ***
553      !!
554      !! ** Purpose :   Asselin time filter of now SSH
555      !!---------------------------------------------------------------------
556      INTEGER, INTENT(in) :: kt             ! time step
557      INTEGER, INTENT(in) :: Kbb, Kmm, Kaa  ! ocean time level indices
558      !
559      !!---------------------------------------------------------------------
560
561      IF( kt == nit000 ) THEN
562         IF(lwp) WRITE(numout,*)
563         IF(lwp) WRITE(numout,*) 'dta_dyn_atf : Asselin time filter of sea surface height'
564         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
565      ENDIF
566
567      ssh(:,:,Kmm) = ssh(:,:,Kmm) + rn_atfp * ( ssh(:,:,Kbb) - 2 * ssh(:,:,Kmm) + ssh(:,:,Kaa)) 
568
569      !! Do we also need to time filter e3t??
570      !
571   END SUBROUTINE dta_dyn_atf
572   
573   
574#if ! defined key_qco   
575   SUBROUTINE dta_dyn_sf_interp( kt, Kmm )
576      !!---------------------------------------------------------------------
577      !!                    ***  ROUTINE dta_dyn_sf_interp  ***
578      !!
579      !! ** Purpose :   Calculate scale factors at U/V/W points and depths
580      !!                given the after e3t field
581      !!---------------------------------------------------------------------
582      INTEGER, INTENT(in) :: kt   ! time step
583      INTEGER, INTENT(in) :: Kmm  ! ocean time level indices
584      !
585      INTEGER             :: ji, jj, jk
586      REAL(wp)            :: zcoef
587      !!---------------------------------------------------------------------
588
589      ! Horizontal scale factor interpolations
590      ! --------------------------------------
591      CALL dom_vvl_interpol( e3t(:,:,:,Kmm), e3u(:,:,:,Kmm), 'U' )
592      CALL dom_vvl_interpol( e3t(:,:,:,Kmm), e3v(:,:,:,Kmm), 'V' )
593
594      ! Vertical scale factor interpolations
595      ! ------------------------------------
596      CALL dom_vvl_interpol( e3t(:,:,:,Kmm), e3w (:,:,:,Kmm), 'W' )
597
598      ! t- and w- points depth
599      ! ----------------------
600      gdept(:,:,1,Kmm) = 0.5_wp * e3w(:,:,1,Kmm)
601      gdepw(:,:,1,Kmm) = 0.0_wp
602      !
603      DO_3D_11_11( 2, jpk )
604         zcoef = (tmask(ji,jj,jk) - wmask(ji,jj,jk))
605         gdepw(ji,jj,jk,Kmm) = gdepw(ji,jj,jk-1,Kmm) + e3t(ji,jj,jk-1,Kmm)
606         gdept(ji,jj,jk,Kmm) =      zcoef  * ( gdepw(ji,jj,jk  ,Kmm) + 0.5 * e3w(ji,jj,jk,Kmm))  &
607            &                + (1-zcoef) * ( gdept(ji,jj,jk-1,Kmm) + e3w(ji,jj,jk,Kmm))
608      END_3D
609      !
610   END SUBROUTINE dta_dyn_sf_interp
611#endif
612
613
614   SUBROUTINE dta_dyn_ssh( kt, phdivtr, psshb,  pemp, pssha, pe3ta )
615      !!----------------------------------------------------------------------
616      !!                ***  ROUTINE dta_dyn_wzv  ***
617      !!                   
618      !! ** Purpose :   compute the after ssh (ssh(:,:,Kaa)) and the now vertical velocity
619      !!
620      !! ** Method  : Using the incompressibility hypothesis,
621      !!        - the ssh increment is computed by integrating the horizontal divergence
622      !!          and multiply by the time step.
623      !!
624      !!        - compute the after scale factor : repartition of ssh INCREMENT proportionnaly
625      !!                                           to the level thickness ( z-star case )
626      !!
627      !!        - the vertical velocity is computed by integrating the horizontal divergence 
628      !!          from the bottom to the surface minus the scale factor evolution.
629      !!          The boundary conditions are w=0 at the bottom (no flux)
630      !!
631      !! ** action  :   ssh(:,:,Kaa) / e3t(:,:,k,Kaa) / ww
632      !!
633      !! Reference  : Leclair, M., and G. Madec, 2009, Ocean Modelling.
634      !!----------------------------------------------------------------------
635      INTEGER,                                   INTENT(in )    :: kt        !  time-step
636      REAL(wp), DIMENSION(jpi,jpj,jpk)          , INTENT(in )   :: phdivtr   ! horizontal divergence transport
637      REAL(wp), DIMENSION(jpi,jpj)    , OPTIONAL, INTENT(in )   :: psshb     ! now ssh
638      REAL(wp), DIMENSION(jpi,jpj)    , OPTIONAL, INTENT(in )   :: pemp      ! evaporation minus precipitation
639      REAL(wp), DIMENSION(jpi,jpj)    , OPTIONAL, INTENT(inout) :: pssha     ! after ssh
640      REAL(wp), DIMENSION(jpi,jpj,jpk), OPTIONAL, INTENT(out)   :: pe3ta     ! after vertical scale factor
641      !
642      INTEGER                       :: jk
643      REAL(wp), DIMENSION(jpi,jpj)  :: zhdiv 
644      REAL(wp)  :: z2dt 
645      !!----------------------------------------------------------------------
646      !
647      z2dt = 2._wp * rn_Dt
648      !
649      zhdiv(:,:) = 0._wp
650      DO jk = 1, jpkm1
651         zhdiv(:,:) = zhdiv(:,:) +  phdivtr(:,:,jk) * tmask(:,:,jk)
652      END DO
653      !                                                ! Sea surface  elevation time-stepping
654      pssha(:,:) = ( psshb(:,:) - z2dt * ( r1_rho0 * pemp(:,:)  + zhdiv(:,:) ) ) * ssmask(:,:)
655      !
656      IF( PRESENT( pe3ta ) ) THEN                      ! After acale factors at t-points ( z_star coordinate )
657      DO jk = 1, jpkm1
658            pe3ta(:,:,jk) = e3t_0(:,:,jk) * ( 1._wp + pssha(:,:) * r1_ht_0(:,:) * tmask(:,:,jk) )
659      END DO
660      ENDIF
661      !
662   END SUBROUTINE dta_dyn_ssh
663
664
665   SUBROUTINE dta_dyn_hrnf( Kmm )
666      !!----------------------------------------------------------------------
667      !!                  ***  ROUTINE sbc_rnf  ***
668      !!
669      !! ** Purpose :   update the horizontal divergence with the runoff inflow
670      !!
671      !! ** Method  :
672      !!                CAUTION : rnf is positive (inflow) decreasing the
673      !!                          divergence and expressed in m/s
674      !!
675      !! ** Action  :   phdivn   decreased by the runoff inflow
676      !!----------------------------------------------------------------------
677      !!
678      INTEGER, INTENT(in) :: Kmm  ! ocean time level index
679      !
680      INTEGER  ::   ji, jj, jk    ! dummy loop indices
681      !!----------------------------------------------------------------------
682      !
683!!st code dupliqué même remarque que plus haut pourquoi ne pas utiliser gdepw ?
684      DO_2D_11_11
685         h_rnf(ji,jj) = 0._wp
686         DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
687             h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)   ! to the bottom of the relevant grid box
688         END DO
689      END_2D
690      !
691   END SUBROUTINE dta_dyn_hrnf
692
693
694
695   SUBROUTINE dta_dyn_slp( kt, Kbb, Kmm )
696      !!---------------------------------------------------------------------
697      !!                    ***  ROUTINE dta_dyn_slp  ***
698      !!
699      !! ** Purpose : Computation of slope
700      !!
701      !!---------------------------------------------------------------------
702      INTEGER,  INTENT(in) :: kt       ! time step
703      INTEGER,  INTENT(in) :: Kbb, Kmm ! ocean time level indices
704      !
705      INTEGER  ::   ji, jj     ! dummy loop indices
706      REAL(wp) ::   ztinta     ! ratio applied to after  records when doing time interpolation
707      REAL(wp) ::   ztintb     ! ratio applied to before records when doing time interpolation
708      INTEGER  ::   iswap 
709      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zuslp, zvslp, zwslpi, zwslpj
710      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts) ::   zts
711      !!---------------------------------------------------------------------
712      !
713      IF( sf_dyn(jf_tem)%ln_tint ) THEN    ! Computes slopes (here avt is used as workspace)                       
714         IF( kt == nit000 ) THEN
715            IF(lwp) WRITE(numout,*) ' Compute new slopes at kt = ', kt
716            zts(:,:,:,jp_tem) = sf_dyn(jf_tem)%fdta(:,:,:,1) * tmask(:,:,:)   ! temperature
717            zts(:,:,:,jp_sal) = sf_dyn(jf_sal)%fdta(:,:,:,1) * tmask(:,:,:)   ! salinity
718            avt(:,:,:)        = sf_dyn(jf_avt)%fdta(:,:,:,1) * tmask(:,:,:)   ! vertical diffusive coef.
719            CALL compute_slopes( kt, zts, zuslp, zvslp, zwslpi, zwslpj, Kbb, Kmm )
720            uslpdta (:,:,:,1) = zuslp (:,:,:) 
721            vslpdta (:,:,:,1) = zvslp (:,:,:) 
722            wslpidta(:,:,:,1) = zwslpi(:,:,:) 
723            wslpjdta(:,:,:,1) = zwslpj(:,:,:) 
724            !
725            zts(:,:,:,jp_tem) = sf_dyn(jf_tem)%fdta(:,:,:,2) * tmask(:,:,:)   ! temperature
726            zts(:,:,:,jp_sal) = sf_dyn(jf_sal)%fdta(:,:,:,2) * tmask(:,:,:)   ! salinity
727            avt(:,:,:)        = sf_dyn(jf_avt)%fdta(:,:,:,2) * tmask(:,:,:)   ! vertical diffusive coef.
728            CALL compute_slopes( kt, zts, zuslp, zvslp, zwslpi, zwslpj, Kbb, Kmm )
729            uslpdta (:,:,:,2) = zuslp (:,:,:) 
730            vslpdta (:,:,:,2) = zvslp (:,:,:) 
731            wslpidta(:,:,:,2) = zwslpi(:,:,:) 
732            wslpjdta(:,:,:,2) = zwslpj(:,:,:) 
733         ELSE
734           !
735           iswap = 0
736           IF( sf_dyn(jf_tem)%nrec_a(2) - nprevrec /= 0 )  iswap = 1
737           IF( nsecdyn > sf_dyn(jf_tem)%nrec_b(2) .AND. iswap == 1 )  THEN    ! read/update the after data
738              IF(lwp) WRITE(numout,*) ' Compute new slopes at kt = ', kt
739              uslpdta (:,:,:,1) =  uslpdta (:,:,:,2)         ! swap the data
740              vslpdta (:,:,:,1) =  vslpdta (:,:,:,2) 
741              wslpidta(:,:,:,1) =  wslpidta(:,:,:,2) 
742              wslpjdta(:,:,:,1) =  wslpjdta(:,:,:,2) 
743              !
744              zts(:,:,:,jp_tem) = sf_dyn(jf_tem)%fdta(:,:,:,2) * tmask(:,:,:)   ! temperature
745              zts(:,:,:,jp_sal) = sf_dyn(jf_sal)%fdta(:,:,:,2) * tmask(:,:,:)   ! salinity
746              avt(:,:,:)        = sf_dyn(jf_avt)%fdta(:,:,:,2) * tmask(:,:,:)   ! vertical diffusive coef.
747              CALL compute_slopes( kt, zts, zuslp, zvslp, zwslpi, zwslpj, Kbb, Kmm )
748              !
749              uslpdta (:,:,:,2) = zuslp (:,:,:) 
750              vslpdta (:,:,:,2) = zvslp (:,:,:) 
751              wslpidta(:,:,:,2) = zwslpi(:,:,:) 
752              wslpjdta(:,:,:,2) = zwslpj(:,:,:) 
753            ENDIF
754         ENDIF
755      ENDIF
756      !
757      IF( sf_dyn(jf_tem)%ln_tint )  THEN
758         ztinta =  REAL( nsecdyn - sf_dyn(jf_tem)%nrec_b(2), wp )  &
759            &    / REAL( sf_dyn(jf_tem)%nrec_a(2) - sf_dyn(jf_tem)%nrec_b(2), wp )
760         ztintb =  1. - ztinta
761         IF( l_ldfslp .AND. .NOT.lk_c1d ) THEN    ! Computes slopes (here avt is used as workspace)
762            uslp (:,:,:) = ztintb * uslpdta (:,:,:,1)  + ztinta * uslpdta (:,:,:,2) 
763            vslp (:,:,:) = ztintb * vslpdta (:,:,:,1)  + ztinta * vslpdta (:,:,:,2) 
764            wslpi(:,:,:) = ztintb * wslpidta(:,:,:,1)  + ztinta * wslpidta(:,:,:,2) 
765            wslpj(:,:,:) = ztintb * wslpjdta(:,:,:,1)  + ztinta * wslpjdta(:,:,:,2) 
766         ENDIF
767      ELSE
768         zts(:,:,:,jp_tem) = sf_dyn(jf_tem)%fnow(:,:,:) * tmask(:,:,:)   ! temperature
769         zts(:,:,:,jp_sal) = sf_dyn(jf_sal)%fnow(:,:,:) * tmask(:,:,:)   ! salinity
770         avt(:,:,:)        = sf_dyn(jf_avt)%fnow(:,:,:) * tmask(:,:,:)   ! vertical diffusive coef.
771         CALL compute_slopes( kt, zts, zuslp, zvslp, zwslpi, zwslpj, Kbb, Kmm )
772         !
773         IF( l_ldfslp .AND. .NOT.lk_c1d ) THEN    ! Computes slopes (here avt is used as workspace)
774            uslp (:,:,:) = zuslp (:,:,:)
775            vslp (:,:,:) = zvslp (:,:,:)
776            wslpi(:,:,:) = zwslpi(:,:,:)
777            wslpj(:,:,:) = zwslpj(:,:,:)
778         ENDIF
779      ENDIF
780      !
781   END SUBROUTINE dta_dyn_slp
782
783
784   SUBROUTINE compute_slopes( kt, pts, puslp, pvslp, pwslpi, pwslpj, Kbb, Kmm )
785      !!---------------------------------------------------------------------
786      !!                    ***  ROUTINE dta_dyn_slp  ***
787      !!
788      !! ** Purpose :   Computation of slope
789      !!---------------------------------------------------------------------
790      INTEGER ,                              INTENT(in ) :: kt       ! time step
791      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in ) :: pts      ! temperature/salinity
792      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(out) :: puslp    ! zonal isopycnal slopes
793      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(out) :: pvslp    ! meridional isopycnal slopes
794      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(out) :: pwslpi   ! zonal diapycnal slopes
795      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(out) :: pwslpj   ! meridional diapycnal slopes
796      INTEGER ,                              INTENT(in ) :: Kbb, Kmm ! ocean time level indices
797      !!---------------------------------------------------------------------
798      !
799      IF( l_ldfslp .AND. .NOT.lk_c1d ) THEN    ! Computes slopes (here avt is used as workspace)
800         CALL eos    ( pts, rhd, rhop, gdept_0(:,:,:) )
801         CALL eos_rab( pts, rab_n, Kmm )       ! now local thermal/haline expension ratio at T-points
802         CALL bn2    ( pts, rab_n, rn2, Kmm  ) ! now    Brunt-Vaisala
803
804      ! Partial steps: before Horizontal DErivative
805      IF( ln_zps  .AND. .NOT. ln_isfcav)                            &
806         &            CALL zps_hde    ( kt, Kmm, jpts, pts, gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
807         &                                        rhd, gru , grv    )  ! of t, s, rd at the last ocean level
808      IF( ln_zps .AND.        ln_isfcav)                            &
809         &            CALL zps_hde_isf( kt, Kmm, jpts, pts, gtsu, gtsv, gtui, gtvi, &  ! Partial steps for top cell (ISF)
810         &                                        rhd, gru , grv , grui, grvi )  ! of t, s, rd at the first ocean level
811
812         rn2b(:,:,:) = rn2(:,:,:)                ! needed for zdfmxl
813         CALL zdf_mxl( kt, Kmm )                 ! mixed layer depth
814         CALL ldf_slp( kt, rhd, rn2, Kbb, Kmm )  ! slopes
815         puslp (:,:,:) = uslp (:,:,:)
816         pvslp (:,:,:) = vslp (:,:,:)
817         pwslpi(:,:,:) = wslpi(:,:,:)
818         pwslpj(:,:,:) = wslpj(:,:,:)
819     ELSE
820         puslp (:,:,:) = 0.            ! to avoid warning when compiling
821         pvslp (:,:,:) = 0.
822         pwslpi(:,:,:) = 0.
823         pwslpj(:,:,:) = 0.
824     ENDIF
825      !
826   END SUBROUTINE compute_slopes
827
828   !!======================================================================
829END MODULE dtadyn
Note: See TracBrowser for help on using the repository browser.