New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zfechem.F90 in NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/TOP/PISCES/P4Z/p4zfechem.F90 @ 13257

Last change on this file since 13257 was 13257, checked in by orioltp, 4 years ago

Updated with trunk at r13245 and small change allocating variables in icb_oce.F90.

  • Property svn:keywords set to Id
File size: 13.5 KB
Line 
1MODULE p4zfechem
2   !!======================================================================
3   !!                         ***  MODULE p4zfechem  ***
4   !! TOP :   PISCES Compute iron chemistry and scavenging
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, A. Tagliabue, C. Ethe) Original code
7   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
8   !!----------------------------------------------------------------------
9   !!   p4z_fechem       : Compute remineralization/scavenging of iron
10   !!   p4z_fechem_init  : Initialisation of parameters for remineralisation
11   !!   p4z_fechem_alloc : Allocate remineralisation variables
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zche          ! chemical model
17   USE p4zbc           ! Boundary conditions from sediments
18   USE prtctl_trc      ! print control for debugging
19   USE iom             ! I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_fechem        ! called in p4zbio.F90
25   PUBLIC   p4z_fechem_init   ! called in trcsms_pisces.F90
26
27   LOGICAL          ::   ln_ligvar    !: boolean for variable ligand concentration following Tagliabue and voelker
28   REAL(wp), PUBLIC ::   xlam1        !: scavenging rate of Iron
29   REAL(wp), PUBLIC ::   xlamdust     !: scavenging rate of Iron by dust
30   REAL(wp), PUBLIC ::   ligand       !: ligand concentration in the ocean
31   REAL(wp), PUBLIC ::   kfep         !: rate constant for nanoparticle formation
32
33   !! * Substitutions
34#  include "do_loop_substitute.h90"
35#  include "domzgr_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
38   !! $Id$
39   !! Software governed by the CeCILL license (see ./LICENSE)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE p4z_fechem( kt, knt, Kbb, Kmm, Krhs )
44      !!---------------------------------------------------------------------
45      !!                     ***  ROUTINE p4z_fechem  ***
46      !!
47      !! ** Purpose :   Compute remineralization/scavenging of iron
48      !!
49      !! ** Method  :   A simple chemistry model of iron from Aumont and Bopp (2006)
50      !!                based on one ligand and one inorganic form
51      !!---------------------------------------------------------------------
52      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step
53      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs  ! time level indices
54      !
55      INTEGER  ::   ji, jj, jk, jic, jn
56      REAL(wp) ::   zdep, zlam1a, zlam1b, zlamfac
57      REAL(wp) ::   zkeq, zfeequi, zfesatur, zfecoll, fe3sol
58      REAL(wp) ::   zdenom1, zscave, zaggdfea, zaggdfeb, zcoag
59      REAL(wp) ::   ztrc, zdust
60      REAL(wp) ::   zdenom2
61      REAL(wp) ::   zzFeL1, zzFeL2, zzFe2, zzFeP, zzFe3, zzstrn2
62      REAL(wp) ::   zrum, zcodel, zargu, zlight
63      REAL(wp) ::   zkox, zkph1, zkph2, zph, zionic, ztligand
64      REAL(wp) ::   za, zb, zc, zkappa1, zkappa2, za0, za1, za2
65      REAL(wp) ::   zxs, zfunc, zp, zq, zd, zr, zphi, zfff, zp3, zq2
66      REAL(wp) ::   ztfe, zoxy, zhplus, zxlam
67      REAL(wp) ::   zaggliga, zaggligb
68      REAL(wp) ::   dissol, zligco
69      REAL(wp) :: zrfact2
70      CHARACTER (len=25) :: charout
71      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zTL1, zFe3, ztotlig, precip, zFeL1
72      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zcoll3d, zscav3d, zlcoll3d
73      !!---------------------------------------------------------------------
74      !
75      IF( ln_timing )   CALL timing_start('p4z_fechem')
76      !
77      ! Total ligand concentration : Ligands can be chosen to be constant or variable
78      ! Parameterization from Tagliabue and Voelker (2011)
79      ! -------------------------------------------------
80      IF( ln_ligvar ) THEN
81         ztotlig(:,:,:) =  0.09 * tr(:,:,:,jpdoc,Kbb) * 1E6 + ligand * 1E9
82         ztotlig(:,:,:) =  MIN( ztotlig(:,:,:), 10. )
83      ELSE
84        IF( ln_ligand ) THEN  ;   ztotlig(:,:,:) = tr(:,:,:,jplgw,Kbb) * 1E9
85        ELSE                  ;   ztotlig(:,:,:) = ligand * 1E9
86        ENDIF
87      ENDIF
88
89      ! ------------------------------------------------------------
90      !  from Aumont and Bopp (2006)
91      ! This model is based on one ligand and Fe'
92      ! Chemistry is supposed to be fast enough to be at equilibrium
93      ! ------------------------------------------------------------
94      DO_3D_11_11( 1, jpkm1 )
95         zTL1(ji,jj,jk)  = ztotlig(ji,jj,jk)
96         zkeq            = fekeq(ji,jj,jk)
97         zfesatur        = zTL1(ji,jj,jk) * 1E-9
98         ztfe            = tr(ji,jj,jk,jpfer,Kbb) 
99         ! Fe' is the root of a 2nd order polynom
100         zFe3 (ji,jj,jk) = ( -( 1. + zfesatur * zkeq - zkeq * ztfe )               &
101            &              + SQRT( ( 1. + zfesatur * zkeq - zkeq * ztfe )**2       &
102            &              + 4. * ztfe * zkeq) ) / ( 2. * zkeq )
103         zFe3 (ji,jj,jk) = zFe3(ji,jj,jk) * 1E9
104         zFeL1(ji,jj,jk) = MAX( 0., tr(ji,jj,jk,jpfer,Kbb) * 1E9 - zFe3(ji,jj,jk) )
105      END_3D
106         !
107
108      zdust = 0.         ! if no dust available
109      DO_3D_11_11( 1, jpkm1 )
110         ! Scavenging rate of iron. This scavenging rate depends on the load of particles of sea water.
111         ! This parameterization assumes a simple second order kinetics (k[Particles][Fe]).
112         ! Scavenging onto dust is also included as evidenced from the DUNE experiments.
113         ! --------------------------------------------------------------------------------------
114         zhplus  = max( rtrn, hi(ji,jj,jk) )
115         fe3sol  = fesol(ji,jj,jk,1) * ( zhplus**3 + fesol(ji,jj,jk,2) * zhplus**2  &
116         &         + fesol(ji,jj,jk,3) * zhplus + fesol(ji,jj,jk,4)     &
117         &         + fesol(ji,jj,jk,5) / zhplus )
118         !
119         zfeequi = zFe3(ji,jj,jk) * 1E-9
120         zhplus  = max( rtrn, hi(ji,jj,jk) )
121         fe3sol  = fesol(ji,jj,jk,1) * ( zhplus**3 + fesol(ji,jj,jk,2) * zhplus**2  &
122            &         + fesol(ji,jj,jk,3) * zhplus + fesol(ji,jj,jk,4)     &
123            &         + fesol(ji,jj,jk,5) / zhplus )
124         zfecoll = 0.5 * zFeL1(ji,jj,jk) * 1E-9
125         ! precipitation of Fe3+, creation of nanoparticles
126         precip(ji,jj,jk) = MAX( 0., ( zFe3(ji,jj,jk) * 1E-9 - fe3sol ) ) * kfep * xstep
127         !
128         ztrc   = ( tr(ji,jj,jk,jppoc,Kbb) + tr(ji,jj,jk,jpgoc,Kbb) + tr(ji,jj,jk,jpcal,Kbb) + tr(ji,jj,jk,jpgsi,Kbb) ) * 1.e6 
129         IF( ll_dust )  zdust  = dust(ji,jj) / ( wdust / rday ) * tmask(ji,jj,jk) &
130         &  * EXP( -gdept(ji,jj,jk,Kmm) / 540. )
131         IF (ln_ligand) THEN
132            zxlam  = xlam1 * MAX( 1.E-3, EXP(-2 * etot(ji,jj,jk) / 10. ) * (1. - EXP(-2 * tr(ji,jj,jk,jpoxy,Kbb) / 100.E-6 ) ))
133         ELSE
134            zxlam  = xlam1 * 1.0
135         ENDIF
136         zlam1b = 3.e-5 + xlamdust * zdust + zxlam * ztrc
137         zscave = zfeequi * zlam1b * xstep
138
139         ! Compute the different ratios for scavenging of iron
140         ! to later allocate scavenged iron to the different organic pools
141         ! ---------------------------------------------------------
142         zdenom1 = zxlam * tr(ji,jj,jk,jppoc,Kbb) / zlam1b
143         zdenom2 = zxlam * tr(ji,jj,jk,jpgoc,Kbb) / zlam1b
144
145         !  Increased scavenging for very high iron concentrations found near the coasts
146         !  due to increased lithogenic particles and let say it is unknown processes (precipitation, ...)
147         !  -----------------------------------------------------------
148         zlamfac = MAX( 0.e0, ( gphit(ji,jj) + 55.) / 30. )
149         zlamfac = MIN( 1.  , zlamfac )
150         zdep    = MIN( 1., 1000. / gdept(ji,jj,jk,Kmm) )
151         zcoag   = 1E-4 * ( 1. - zlamfac ) * zdep * xstep * tr(ji,jj,jk,jpfer,Kbb)
152
153         !  Compute the coagulation of colloidal iron. This parameterization
154         !  could be thought as an equivalent of colloidal pumping.
155         !  It requires certainly some more work as it is very poorly constrained.
156         !  ----------------------------------------------------------------
157         zlam1a   = ( 0.369  * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) + 102.4  * tr(ji,jj,jk,jppoc,Kbb) ) * xdiss(ji,jj,jk)    &
158             &      + ( 114.   * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) )
159         zaggdfea = zlam1a * xstep * zfecoll
160         !
161         zlam1b   = 3.53E3 * tr(ji,jj,jk,jpgoc,Kbb) * xdiss(ji,jj,jk)
162         zaggdfeb = zlam1b * xstep * zfecoll
163         !
164         tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zscave - zaggdfea - zaggdfeb &
165         &                     - zcoag - precip(ji,jj,jk)
166         tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + zscave * zdenom1 + zaggdfea
167         tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + zscave * zdenom2 + zaggdfeb
168         zscav3d(ji,jj,jk)   = zscave
169         zcoll3d(ji,jj,jk)   = zaggdfea + zaggdfeb
170         !
171      END_3D
172      !
173      !  Define the bioavailable fraction of iron
174      !  ----------------------------------------
175      biron(:,:,:) = tr(:,:,:,jpfer,Kbb) 
176      !
177      IF( ln_ligand ) THEN
178         !
179         DO_3D_11_11( 1, jpkm1 )
180            zlam1a   = ( 0.369  * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) + 102.4  * tr(ji,jj,jk,jppoc,Kbb) ) * xdiss(ji,jj,jk)    &
181                &    + ( 114.   * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) )
182            !
183            zlam1b   = 3.53E3 *   tr(ji,jj,jk,jpgoc,Kbb) * xdiss(ji,jj,jk)
184            zligco   = 0.5 * tr(ji,jj,jk,jplgw,Kmm)
185            zaggliga = zlam1a * xstep * zligco
186            zaggligb = zlam1b * xstep * zligco
187            tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) - zaggliga - zaggligb
188            zlcoll3d(ji,jj,jk)  = zaggliga + zaggligb
189         END_3D
190         !
191         plig(:,:,:) =  MAX( 0., ( ( zFeL1(:,:,:) * 1E-9 ) / ( tr(:,:,:,jpfer,Kbb) +rtrn ) ) )
192         !
193      ENDIF
194      !  Output of some diagnostics variables
195      !     ---------------------------------
196      IF( lk_iomput ) THEN
197         IF( knt == nrdttrc ) THEN
198            zrfact2 = 1.e3 * rfact2r  ! conversion from mol/L/timestep into mol/m3/s
199            IF( iom_use("Fe3")  )  THEN
200               zFe3(:,:,jpk) = 0.  ;  CALL iom_put("Fe3" , zFe3(:,:,:) * tmask(:,:,:) )   ! Fe3+
201            ENDIF
202            IF( iom_use("FeL1") )  THEN
203              zFeL1(:,:,jpk) = 0.  ;  CALL iom_put("FeL1", zFeL1(:,:,:) * tmask(:,:,:) )   ! FeL1
204            ENDIF
205            IF( iom_use("TL1")  )  THEN
206              zTL1(:,:,jpk) = 0.   ;  CALL iom_put("TL1" , zTL1(:,:,:) * tmask(:,:,:) )   ! TL1
207            ENDIF
208            IF( iom_use("Totlig") )  CALL iom_put("Totlig" , ztotlig(:,:,:)       * tmask(:,:,:) )   ! TL
209            IF( iom_use("Biron")  )  CALL iom_put("Biron"  , biron  (:,:,:)  * 1e9 * tmask(:,:,:) )   ! biron
210            IF( iom_use("FESCAV") )  THEN
211               zscav3d (:,:,jpk) = 0.  ;  CALL iom_put("FESCAV" , zscav3d(:,:,:)  * 1e9 * tmask(:,:,:) * zrfact2 )
212            ENDIF
213            IF( iom_use("FECOLL") ) THEN
214               zcoll3d (:,:,jpk) = 0.  ;   CALL iom_put("FECOLL" , zcoll3d(:,:,:)  * 1e9 * tmask(:,:,:) * zrfact2 )
215            ENDIF
216            IF( iom_use("LGWCOLL")) THEN
217               zlcoll3d(:,:,jpk) = 0.  ;  CALL iom_put("LGWCOLL", zlcoll3d(:,:,:) * 1e9 * tmask(:,:,:) * zrfact2 )
218            ENDIF
219          ENDIF
220      ENDIF
221
222      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
223         WRITE(charout, FMT="('fechem')")
224         CALL prt_ctl_trc_info(charout)
225         CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
226      ENDIF
227      !
228      IF( ln_timing )   CALL timing_stop('p4z_fechem')
229      !
230   END SUBROUTINE p4z_fechem
231
232
233   SUBROUTINE p4z_fechem_init
234      !!----------------------------------------------------------------------
235      !!                  ***  ROUTINE p4z_fechem_init  ***
236      !!
237      !! ** Purpose :   Initialization of iron chemistry parameters
238      !!
239      !! ** Method  :   Read the nampisfer namelist and check the parameters
240      !!      called at the first timestep
241      !!
242      !! ** input   :   Namelist nampisfer
243      !!
244      !!----------------------------------------------------------------------
245      INTEGER ::   ios   ! Local integer
246      !!
247      NAMELIST/nampisfer/ ln_ligvar, xlam1, xlamdust, ligand, kfep 
248      !!----------------------------------------------------------------------
249      !
250      IF(lwp) THEN
251         WRITE(numout,*)
252         WRITE(numout,*) 'p4z_rem_init : Initialization of iron chemistry parameters'
253         WRITE(numout,*) '~~~~~~~~~~~~'
254      ENDIF
255      !
256      READ  ( numnatp_ref, nampisfer, IOSTAT = ios, ERR = 901)
257901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisfer in reference namelist' )
258      READ  ( numnatp_cfg, nampisfer, IOSTAT = ios, ERR = 902 )
259902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisfer in configuration namelist' )
260      IF(lwm) WRITE( numonp, nampisfer )
261
262      IF(lwp) THEN                     ! control print
263         WRITE(numout,*) '   Namelist : nampisfer'
264         WRITE(numout,*) '      variable concentration of ligand          ln_ligvar    =', ln_ligvar
265         WRITE(numout,*) '      scavenging rate of Iron                   xlam1        =', xlam1
266         WRITE(numout,*) '      scavenging rate of Iron by dust           xlamdust     =', xlamdust
267         WRITE(numout,*) '      ligand concentration in the ocean         ligand       =', ligand
268         WRITE(numout,*) '      rate constant for nanoparticle formation  kfep         =', kfep
269      ENDIF
270      !
271   END SUBROUTINE p4z_fechem_init
272   
273   !!======================================================================
274END MODULE p4zfechem
Note: See TracBrowser for help on using the repository browser.