New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traatf_qco.F90 in NEMO/branches/2020/dev_r12527_Gurvan_ShallowWater/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r12527_Gurvan_ShallowWater/src/OCE/TRA/traatf_qco.F90 @ 13328

Last change on this file since 13328 was 13328, checked in by gm, 4 years ago

fixes from last merge qco r12983

  • Property svn:keywords set to Id
File size: 19.3 KB
RevLine 
[13151]1MODULE traatfqco
2   !!======================================================================
3   !!                       ***  MODULE  traatfqco  ***
4   !! Ocean active tracers:  Asselin time filtering for temperature and salinity
5   !!======================================================================
6   !! History :  OPA  !  1991-11  (G. Madec)  Original code
7   !!            7.0  !  1993-03  (M. Guyon)  symetrical conditions
8   !!            8.0  !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
9   !!             -   !  1996-04  (A. Weaver)  Euler forward step
10   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
11   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
12   !!             -   !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
13   !!             -   !  2005-04  (C. Deltel) Add Asselin trend in the ML budget
14   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
15   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
16   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
17   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  semi-implicit hpg with asselin filter + modified LF-RA
18   !!             -   !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
19   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rename tranxt.F90 -> traatfLF.F90. Now only does time filtering.
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   tra_atf       : time filtering on tracers
24   !!   tra_atf_fix   : time filtering on tracers : fixed    volume case
25   !!   tra_atf_vvl   : time filtering on tracers : variable volume case
26   !!----------------------------------------------------------------------
27   USE oce             ! ocean dynamics and tracers variables
28   USE dom_oce         ! ocean space and time domain variables
29   USE sbc_oce         ! surface boundary condition: ocean
30   USE sbcrnf          ! river runoffs
31   USE isf_oce         ! ice shelf melting
32   USE zdf_oce         ! ocean vertical mixing
33   USE domvvl          ! variable volume
34   USE trd_oce         ! trends: ocean variables
35   USE trdtra          ! trends manager: tracers
36   USE traqsr          ! penetrative solar radiation (needed for nksr)
37   USE phycst          ! physical constant
38   USE ldftra          ! lateral physics : tracers
39   USE ldfslp          ! lateral physics : slopes
40   USE bdy_oce  , ONLY : ln_bdy
41   USE bdytra          ! open boundary condition (bdy_tra routine)
42   !
43   USE in_out_manager  ! I/O manager
44   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
45   USE prtctl          ! Print control
46   USE timing          ! Timing
47#if defined key_agrif
48   USE agrif_oce_interp
49#endif
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   tra_atf_qco       ! routine called by step.F90
55   PUBLIC   tra_atf_fix_lf    ! to be used in trcnxt !!st WARNING discrepancy here interpol is used by PISCES
56   PUBLIC   tra_atf_qco_lf    ! to be used in trcnxt !!st WARNING discrepancy here interpol is used by PISCES
57
58   !! * Substitutions
59#  include "do_loop_substitute.h90"
60#  include "domzgr_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
[13328]63   !! $Id$
[13151]64   !! Software governed by the CeCILL license (see ./LICENSE)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE tra_atf_qco( kt, Kbb, Kmm, Kaa, pts )
69      !!----------------------------------------------------------------------
70      !!                   ***  ROUTINE traatfLF  ***
71      !!
72      !! ** Purpose :   Apply the boundary condition on the after temperature
73      !!             and salinity fields and add the Asselin time filter on now fields.
74      !!
75      !! ** Method  :   At this stage of the computation, ta and sa are the
76      !!             after temperature and salinity as the time stepping has
77      !!             been performed in trazdf_imp or trazdf_exp module.
78      !!
79      !!              - Apply lateral boundary conditions on (ta,sa)
80      !!             at the local domain   boundaries through lbc_lnk call,
81      !!             at the one-way open boundaries (ln_bdy=T),
82      !!             at the AGRIF zoom   boundaries (lk_agrif=T)
83      !!
84      !!              - Update lateral boundary conditions on AGRIF children
85      !!             domains (lk_agrif=T)
86      !!
87      !! ** Action  : - ts(Kmm) time filtered
88      !!----------------------------------------------------------------------
89      INTEGER                                  , INTENT(in   ) :: kt             ! ocean time-step index
90      INTEGER                                  , INTENT(in   ) :: Kbb, Kmm, Kaa  ! time level indices
91      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts            ! active tracers
92      !!
93      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
94      REAL(wp) ::   zfact            ! local scalars
95      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdt, ztrds
96      !!----------------------------------------------------------------------
97      !
98      IF( ln_timing )   CALL timing_start( 'tra_atf_qco')
99      !
100      IF( kt == nit000 ) THEN
101         IF(lwp) WRITE(numout,*)
102         IF(lwp) WRITE(numout,*) 'tra_atf_qco : apply Asselin time filter to "now" fields'
103         IF(lwp) WRITE(numout,*) '~~~~~~~'
104      ENDIF
105!!st  Update after tracer on domain lateral boundaries as been removed outside
106
107      ! trends computation initialisation
108      IF( l_trdtra )   THEN
109         ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) )
110         ztrdt(:,:,jpk) = 0._wp
111         ztrds(:,:,jpk) = 0._wp
112         IF( ln_traldf_iso ) THEN              ! diagnose the "pure" Kz diffusive trend
113            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_zdfp, ztrdt )
114            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_zdfp, ztrds )
115         ENDIF
116         ! total trend for the non-time-filtered variables.
117         zfact = 1.0 / rn_Dt
118         ! G Nurser 23 Mar 2017. Recalculate trend as Delta(e3t*T)/e3tn; e3tn cancel from pts(Kmm) terms
119         DO jk = 1, jpkm1
120            ztrdt(:,:,jk) = ( pts(:,:,jk,jp_tem,Kaa) * (1._wp + r3t(:,:,Kaa) * tmask(:,:,jk))/(1._wp + r3t(:,:,Kmm) * tmask(:,:,jk))  &
121               &            - pts(:,:,jk,jp_tem,Kmm) ) * zfact
122            ztrds(:,:,jk) = ( pts(:,:,jk,jp_sal,Kaa) * (1._wp + r3t(:,:,Kaa) * tmask(:,:,jk))/(1._wp + r3t(:,:,Kmm) * tmask(:,:,jk))  &
123               &            - pts(:,:,jk,jp_sal,Kmm) ) * zfact
124         END DO
125         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_tot, ztrdt )
126         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_tot, ztrds )
127         IF( ln_linssh ) THEN       ! linear sea surface height only
128            ! Store now fields before applying the Asselin filter
129            ! in order to calculate Asselin filter trend later.
130            ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kmm)
131            ztrds(:,:,:) = pts(:,:,:,jp_sal,Kmm)
132         ENDIF
133      ENDIF
134
135      IF( l_1st_euler ) THEN       ! Euler time-stepping
136         !
137         IF (l_trdtra .AND. .NOT. ln_linssh ) THEN   ! Zero Asselin filter contribution must be explicitly written out since for vvl
138            !                                        ! Asselin filter is output by tra_atf_vvl that is not called on this time step
139            ztrdt(:,:,:) = 0._wp
140            ztrds(:,:,:) = 0._wp
141            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_atf, ztrdt )
142            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_atf, ztrds )
143         END IF
144         !
145      ELSE                                            ! Leap-Frog + Asselin filter time stepping
146         !
147         IF ( ln_linssh ) THEN   ;   CALL tra_atf_fix_lf( kt, Kbb, Kmm, Kaa, nit000,        'TRA', pts, jpts )  ! linear free surface
148         ELSE                    ;   CALL tra_atf_qco_lf( kt, Kbb, Kmm, Kaa, nit000, rn_Dt, 'TRA', pts, sbc_tsc, sbc_tsc_b, jpts )  ! non-linear free surface
149         ENDIF
150         !
151         CALL lbc_lnk_multi( 'traatfqco', pts(:,:,:,jp_tem,Kbb) , 'T', 1., pts(:,:,:,jp_sal,Kbb) , 'T', 1., &
152                  &                    pts(:,:,:,jp_tem,Kmm) , 'T', 1., pts(:,:,:,jp_sal,Kmm) , 'T', 1., &
153                  &                    pts(:,:,:,jp_tem,Kaa), 'T', 1., pts(:,:,:,jp_sal,Kaa), 'T', 1.  )
154         !
155      ENDIF
156      !
157      IF( l_trdtra .AND. ln_linssh ) THEN      ! trend of the Asselin filter (tb filtered - tb)/dt
158         DO jk = 1, jpkm1
159            ztrdt(:,:,jk) = ( pts(:,:,jk,jp_tem,Kmm) - ztrdt(:,:,jk) ) * r1_Dt
160            ztrds(:,:,jk) = ( pts(:,:,jk,jp_sal,Kmm) - ztrds(:,:,jk) ) * r1_Dt
161         END DO
162         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_atf, ztrdt )
163         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_atf, ztrds )
164      END IF
165      IF( l_trdtra )   DEALLOCATE( ztrdt , ztrds )
166      !
167      !                        ! control print
168      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kmm), clinfo1=' nxt  - Tn: ', mask1=tmask,   &
169         &                                  tab3d_2=pts(:,:,:,jp_sal,Kmm), clinfo2=       ' Sn: ', mask2=tmask )
170      !
171      IF( ln_timing )   CALL timing_stop('tra_atf_qco')
172      !
173   END SUBROUTINE tra_atf_qco
174
175
176   SUBROUTINE tra_atf_fix_lf( kt, Kbb, Kmm, Kaa, kit000, cdtype, pt, kjpt )
177      !!----------------------------------------------------------------------
178      !!                   ***  ROUTINE tra_atf_fix  ***
179      !!
180      !! ** Purpose :   fixed volume: apply the Asselin time filter to the "now" field
181      !!
182      !! ** Method  : - Apply a Asselin time filter on now fields.
183      !!
184      !! ** Action  : - pt(Kmm) ready for the next time step
185      !!----------------------------------------------------------------------
186      INTEGER                                  , INTENT(in   ) ::  kt            ! ocean time-step index
187      INTEGER                                  , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
188      INTEGER                                  , INTENT(in   ) ::  kit000        ! first time step index
189      CHARACTER(len=3)                         , INTENT(in   ) ::  cdtype        ! =TRA or TRC (tracer indicator)
190      INTEGER                                  , INTENT(in   ) ::  kjpt          ! number of tracers
191      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::  pt            ! tracer fields
192      !
193      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
194      REAL(wp) ::   ztn, ztd         ! local scalars
195      !!----------------------------------------------------------------------
196      !
197      IF( kt == kit000 )  THEN
198         IF(lwp) WRITE(numout,*)
199         IF(lwp) WRITE(numout,*) 'tra_atf_fix_lf : time filtering', cdtype
200         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
201      ENDIF
202      !
203      DO jn = 1, kjpt
204         !
205         DO_3D_00_00( 1, jpkm1 )
206            ztn = pt(ji,jj,jk,jn,Kmm)
207            ztd = pt(ji,jj,jk,jn,Kaa) - 2._wp * ztn + pt(ji,jj,jk,jn,Kbb)  ! time laplacian on tracers
208            !
209            pt(ji,jj,jk,jn,Kmm) = ztn + rn_atfp * ztd                      ! pt <-- filtered pt
210         END_3D
211         !
212      END DO
213      !
214   END SUBROUTINE tra_atf_fix_lf
215
216
217   SUBROUTINE tra_atf_qco_lf( kt, Kbb, Kmm, Kaa, kit000, p2dt, cdtype, pt, psbc_tc, psbc_tc_b, kjpt )
218      !!----------------------------------------------------------------------
219      !!                   ***  ROUTINE tra_atf_vvl  ***
220      !!
221      !! ** Purpose :   Time varying volume: apply the Asselin time filter
222      !!
223      !! ** Method  : - Apply a thickness weighted Asselin time filter on now fields.
224      !!             pt(Kmm)  = ( e3t_m*pt(Kmm) + rn_atfp*[ e3t_b*pt(Kbb) - 2 e3t_m*pt(Kmm) + e3t_a*pt(Kaa) ] )
225      !!                       /( e3t_m         + rn_atfp*[ e3t_b         - 2 e3t_m         + e3t_a    ] )
226      !!
227      !! ** Action  : - pt(Kmm) ready for the next time step
228      !!----------------------------------------------------------------------
229      INTEGER                                  , INTENT(in   ) ::  kt        ! ocean time-step index
230      INTEGER                                  , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
231      INTEGER                                  , INTENT(in   ) ::  kit000    ! first time step index
232      REAL(wp)                                 , INTENT(in   ) ::  p2dt      ! time-step
233      CHARACTER(len=3)                         , INTENT(in   ) ::  cdtype    ! =TRA or TRC (tracer indicator)
234      INTEGER                                  , INTENT(in   ) ::  kjpt      ! number of tracers
235      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::  pt        ! tracer fields
236      REAL(wp), DIMENSION(jpi,jpj    ,kjpt)    , INTENT(in   ) ::  psbc_tc   ! surface tracer content
237      REAL(wp), DIMENSION(jpi,jpj    ,kjpt)    , INTENT(in   ) ::  psbc_tc_b ! before surface tracer content
238      !
239      LOGICAL  ::   ll_traqsr, ll_rnf, ll_isf   ! local logical
240      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices
241      REAL(wp) ::   zfact, zfact1, ztc_a , ztc_n , ztc_b , ztc_f , ztc_d    ! local scalar
242      REAL(wp) ::   zfact2, ze3t_b, ze3t_n, ze3t_a, ze3t_f                  !   -      -
243      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ztrd_atf
244      !!----------------------------------------------------------------------
245      !
246      IF( kt == kit000 )  THEN
247         IF(lwp) WRITE(numout,*)
248         IF(lwp) WRITE(numout,*) 'tra_atf_qco : time filtering', cdtype
249         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
250      ENDIF
251      !
252      IF( cdtype == 'TRA' )  THEN
253         ll_traqsr  = ln_traqsr        ! active  tracers case  and  solar penetration
254         ll_rnf     = ln_rnf           ! active  tracers case  and  river runoffs
255         ll_isf     = ln_isf           ! active  tracers case  and  ice shelf melting
256      ELSE                          ! passive tracers case
257         ll_traqsr  = .FALSE.          ! NO solar penetration
258         ll_rnf     = .FALSE.          ! NO river runoffs ????          !!gm BUG ?
259         ll_isf     = .FALSE.          ! NO ice shelf melting/freezing  !!gm BUG ??
260      ENDIF
261      !
262      IF( ( l_trdtra .AND. cdtype == 'TRA' ) .OR. ( l_trdtrc .AND. cdtype == 'TRC' ) )   THEN
263         ALLOCATE( ztrd_atf(jpi,jpj,jpk,kjpt) )
264         ztrd_atf(:,:,:,:) = 0.0_wp
265      ENDIF
266      zfact = 1._wp / p2dt
267      zfact1 = rn_atfp * p2dt
268      zfact2 = zfact1 * r1_rho0
269      DO jn = 1, kjpt
270         DO_3D_00_00( 1, jpkm1 )
271            ze3t_b = e3t(ji,jj,jk,Kbb)
272            ze3t_n = e3t(ji,jj,jk,Kmm)
273            ze3t_a = e3t(ji,jj,jk,Kaa)
274            !                                         ! tracer content at Before, now and after
275            ztc_b  = pt(ji,jj,jk,jn,Kbb) * ze3t_b
276            ztc_n  = pt(ji,jj,jk,jn,Kmm) * ze3t_n
277            ztc_a  = pt(ji,jj,jk,jn,Kaa) * ze3t_a
278            !
279            ztc_d  = ztc_a  - 2. * ztc_n  + ztc_b
280            !
281            ztc_f  = ztc_n  + rn_atfp * ztc_d
282            !
283            ! Asselin correction on scale factors is done via ssh in r3t_f
284            ze3t_f = e3t_0(ji,jj,jk) * ( 1._wp + r3t_f(ji,jj) * tmask(ji,jj,jk) )
285
286            !
287            IF( jk == mikt(ji,jj) ) THEN           ! first level
288               ztc_f  = ztc_f  - zfact1 * ( psbc_tc(ji,jj,jn) - psbc_tc_b(ji,jj,jn) )
289            ENDIF
290            !
291            ! solar penetration (temperature only)
292            IF( ll_traqsr .AND. jn == jp_tem .AND. jk <= nksr )                            &
293               &     ztc_f  = ztc_f  - zfact1 * ( qsr_hc(ji,jj,jk) - qsr_hc_b(ji,jj,jk) )
294               !
295            !
296            IF( ll_rnf .AND. jk <= nk_rnf(ji,jj) )                                          &
297               &     ztc_f  = ztc_f  - zfact1 * ( rnf_tsc(ji,jj,jn) - rnf_tsc_b(ji,jj,jn) ) &
298               &                              * e3t(ji,jj,jk,Kmm) / h_rnf(ji,jj)
299
300            !
301            ! ice shelf
302            IF( ll_isf ) THEN
303               !
304               ! melt in the cavity
305               IF ( ln_isfcav_mlt ) THEN
306                  ! level fully include in the Losch_2008 ice shelf boundary layer
307                  IF ( jk >= misfkt_cav(ji,jj) .AND. jk < misfkb_cav(ji,jj) ) THEN
308                     ztc_f  = ztc_f  - zfact1 * ( risf_cav_tsc(ji,jj,jn) - risf_cav_tsc_b(ji,jj,jn) ) &
309                        &                     * e3t(ji,jj,jk,Kmm) / rhisf_tbl_cav(ji,jj)
310                  END IF
311                  ! level partially include in Losch_2008 ice shelf boundary layer
312                  IF ( jk == misfkb_cav(ji,jj) ) THEN
313                     ztc_f  = ztc_f  - zfact1 * ( risf_cav_tsc(ji,jj,jn) - risf_cav_tsc_b(ji,jj,jn) )  &
314                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_cav(ji,jj)               &
315                            &                 * rfrac_tbl_cav(ji,jj)
316                  END IF
317               END IF
318               !
319               ! parametrised melt (cavity closed)
320               IF ( ln_isfpar_mlt ) THEN
321                  ! level fully include in the Losch_2008 ice shelf boundary layer
322                  IF ( jk >= misfkt_par(ji,jj) .AND. jk < misfkb_par(ji,jj) ) THEN
323                     ztc_f  = ztc_f  - zfact1 * ( risf_par_tsc(ji,jj,jn) - risf_par_tsc_b(ji,jj,jn) )  &
324                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_par(ji,jj)
325                  END IF
326                  ! level partially include in Losch_2008 ice shelf boundary layer
327                  IF ( jk == misfkb_par(ji,jj) ) THEN
328                     ztc_f  = ztc_f  - zfact1 * ( risf_par_tsc(ji,jj,jn) - risf_par_tsc_b(ji,jj,jn) )  &
329                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_par(ji,jj)               &
330                            &                 * rfrac_tbl_par(ji,jj)
331                  END IF
332               END IF
333               !
334               ! ice sheet coupling correction
335               IF ( ln_isfcpl ) THEN
336                  !
337                  ! at kt = nit000,  risfcpl_vol_n = 0 and risfcpl_vol_b = risfcpl_vol so contribution nul
338                  IF ( ln_rstart .AND. kt == nit000+1 ) THEN
339                     ztc_f  = ztc_f  + zfact1 * risfcpl_tsc(ji,jj,jk,jn) * r1_e1e2t(ji,jj)
340                     ! Shouldn't volume increment be spread according thanks to zscale  ?
341                  END IF
342                  !
343               END IF
344               !
345            END IF
346            !
347            ze3t_f = 1.e0 / ze3t_f
348            pt(ji,jj,jk,jn,Kmm) = ztc_f * ze3t_f    ! time filtered "now" field
349            !
350            IF( ( l_trdtra .and. cdtype == 'TRA' ) .OR. ( l_trdtrc .and. cdtype == 'TRC' ) ) THEN
351               ztrd_atf(ji,jj,jk,jn) = (ztc_f - ztc_n) * zfact/ze3t_n
352            ENDIF
353            !
354         END_3D
355         !
356      END DO
357      !
358      IF( ( l_trdtra .AND. cdtype == 'TRA' ) .OR. ( l_trdtrc .AND. cdtype == 'TRC' ) )   THEN
359         IF( l_trdtra .AND. cdtype == 'TRA' ) THEN
360            CALL trd_tra( kt, Kmm, Kaa, cdtype, jp_tem, jptra_atf, ztrd_atf(:,:,:,jp_tem) )
361            CALL trd_tra( kt, Kmm, Kaa, cdtype, jp_sal, jptra_atf, ztrd_atf(:,:,:,jp_sal) )
362         ENDIF
363         IF( l_trdtrc .AND. cdtype == 'TRC' ) THEN
364            DO jn = 1, kjpt
365               CALL trd_tra( kt, Kmm, Kaa, cdtype, jn, jptra_atf, ztrd_atf(:,:,:,jn) )
366            END DO
367         ENDIF
368         DEALLOCATE( ztrd_atf )
369      ENDIF
370      !
371   END SUBROUTINE tra_atf_qco_lf
372
373   !!======================================================================
374END MODULE traatfqco
Note: See TracBrowser for help on using the repository browser.