New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zprod.F90 in NEMO/branches/2020/dev_r12527_Gurvan_ShallowWater/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2020/dev_r12527_Gurvan_ShallowWater/src/TOP/PISCES/P4Z/p5zprod.F90 @ 13151

Last change on this file since 13151 was 13151, checked in by gm, 4 years ago

result from merge with qco r12983
  • Property svn:keywords set to Id
File size: 31.7 KB
Line 
1MODULE p5zprod
2   !!======================================================================
3   !!                         ***  MODULE p5zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11   !!   p5z_prod       :   Compute the growth Rate of the two phytoplanktons groups
12   !!   p5z_prod_init  :   Initialization of the parameters for growth
13   !!   p5z_prod_alloc :   Allocate variables for growth
14   !!----------------------------------------------------------------------
15   USE oce_trc         !  shared variables between ocean and passive tracers
16   USE trc             !  passive tracers common variables
17   USE sms_pisces      !  PISCES Source Minus Sink variables
18   USE p4zlim
19   USE p5zlim          !  Co-limitations of differents nutrients
20   USE prtctl_trc      !  print control for debugging
21   USE iom             !  I/O manager
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p5z_prod         ! called in p5zbio.F90
27   PUBLIC   p5z_prod_init    ! called in trcsms_pisces.F90
28   PUBLIC   p5z_prod_alloc
29
30   !! * Shared module variables
31   REAL(wp), PUBLIC ::  pislopen        !:
32   REAL(wp), PUBLIC ::  pislopep        !:
33   REAL(wp), PUBLIC ::  pisloped        !:
34   REAL(wp), PUBLIC ::  xadap           !:
35   REAL(wp), PUBLIC ::  excretn         !:
36   REAL(wp), PUBLIC ::  excretp         !:
37   REAL(wp), PUBLIC ::  excretd         !:
38   REAL(wp), PUBLIC ::  bresp           !:
39   REAL(wp), PUBLIC ::  thetanpm        !:
40   REAL(wp), PUBLIC ::  thetannm        !:
41   REAL(wp), PUBLIC ::  thetandm        !:
42   REAL(wp), PUBLIC ::  chlcmin         !:
43   REAL(wp), PUBLIC ::  grosip          !:
44
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   zdaylen
46   
47   REAL(wp) :: r1_rday                !: 1 / rday
48   REAL(wp) :: texcretn               !: 1 - excret
49   REAL(wp) :: texcretp               !: 1 - excretp
50   REAL(wp) :: texcretd               !: 1 - excret2       
51
52   !! * Substitutions
53#  include "do_loop_substitute.h90"
54#  include "domzgr_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
57   !! $Id$
58   !! Software governed by the CeCILL license (see ./LICENSE)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE p5z_prod( kt , knt, Kbb, Kmm, Krhs )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p5z_prod  ***
65      !!
66      !! ** Purpose :   Compute the phytoplankton production depending on
67      !!              light, temperature and nutrient availability
68      !!
69      !! ** Method  : - ???
70      !!---------------------------------------------------------------------
71      !
72      INTEGER, INTENT(in) :: kt, knt
73      INTEGER, INTENT(in) :: Kbb, Kmm, Krhs      ! time level indices
74      !
75      INTEGER  ::   ji, jj, jk
76      REAL(wp) ::   zsilfac, znanotot, zpicotot, zdiattot, zconctemp, zconctemp2
77      REAL(wp) ::   zration, zratiop, zratiof, zmax, zmax2, zsilim, ztn, zadap
78      REAL(wp) ::   zpronmax, zpropmax, zprofmax, zrat
79      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zprontot, zproptot, zprodtot
80      REAL(wp) ::   zprnutmax, zdocprod, zprochln, zprochld, zprochlp
81      REAL(wp) ::   zpislopen, zpislopep, zpisloped, thetannm_n, thetandm_n, thetanpm_n
82      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup
83      REAL(wp) ::   zfact, zrfact2
84      CHARACTER (len=25) :: charout
85      REAL(wp), DIMENSION(jpi,jpj    ) :: zmixnano, zmixpico, zmixdiat, zstrn
86      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpislopeadn, zpislopeadp, zpislopeadd
87      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprnut, zprmaxp, zprmaxn, zprmaxd
88      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprbio, zprpic, zprdia, zysopt
89      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprchln, zprchlp, zprchld
90      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprorcan, zprorcap, zprorcad 
91      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprofed, zprofep, zprofen
92      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpronewn, zpronewp, zpronewd
93      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zproregn, zproregp, zproregd
94      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpropo4n, zpropo4p, zpropo4d
95      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprodopn, zprodopp, zprodopd
96      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zrespn, zrespp, zrespd
97      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zcroissn, zcroissp, zcroissd
98      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zmxl_fac, zmxl_chl
99      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpligprod1, zpligprod2
100      !!---------------------------------------------------------------------
101      !
102      IF( ln_timing )   CALL timing_start('p5z_prod')
103      !
104      zprorcan(:,:,:) = 0._wp ; zprorcap(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp
105      zcroissn(:,:,:) = 0._wp ; zcroissp(:,:,:) = 0._wp ; zcroissd(:,:,:) = 0._wp
106      zprofed (:,:,:) = 0._wp ; zprofep (:,:,:) = 0._wp ; zprofen (:,:,:) = 0._wp
107      zpronewn(:,:,:) = 0._wp ; zpronewp(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp
108      zproregn(:,:,:) = 0._wp ; zproregp(:,:,:) = 0._wp ; zproregd(:,:,:) = 0._wp 
109      zpropo4n(:,:,:) = 0._wp ; zpropo4p(:,:,:) = 0._wp ; zpropo4d(:,:,:) = 0._wp
110      zprdia  (:,:,:) = 0._wp ; zprpic  (:,:,:) = 0._wp ; zprbio  (:,:,:) = 0._wp
111      zprodopn(:,:,:) = 0._wp ; zprodopp(:,:,:) = 0._wp ; zprodopd(:,:,:) = 0._wp
112      zysopt  (:,:,:) = 0._wp 
113      zrespn  (:,:,:) = 0._wp ; zrespp  (:,:,:) = 0._wp ; zrespd  (:,:,:) = 0._wp 
114
115      ! Computation of the optimal production
116      zprnut (:,:,:) = 0.65_wp * r1_rday * tgfunc(:,:,:)
117      zprmaxn(:,:,:) = ( 0.65_wp * (1. + zpsino3 * qnpmax ) ) * r1_rday * tgfunc(:,:,:)
118      zprmaxp(:,:,:) = 0.5 / 0.65 * zprmaxn(:,:,:) 
119      zprmaxd(:,:,:) = zprmaxn(:,:,:) 
120
121      ! compute the day length depending on latitude and the day
122      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
123      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
124
125      ! day length in hours
126      zstrn(:,:) = 0.
127      DO_2D_11_11
128         zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
129         zargu = MAX( -1., MIN(  1., zargu ) )
130         zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
131      END_2D
132
133         ! Impact of the day duration on phytoplankton growth
134      DO_3D_11_11( 1, jpkm1 )
135         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
136            zval = MAX( 1., zstrn(ji,jj) )
137            IF( gdepw(ji,jj,jk+1,Kmm) <= hmld(ji,jj) ) THEN
138               zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
139            ENDIF
140            zmxl_chl(ji,jj,jk) = zval / 24.
141            zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval )
142         ENDIF
143      END_3D
144
145      zprbio(:,:,:) = zprmaxn(:,:,:) * zmxl_fac(:,:,:)
146      zprdia(:,:,:) = zprmaxd(:,:,:) * zmxl_fac(:,:,:)
147      zprpic(:,:,:) = zprmaxp(:,:,:) * zmxl_fac(:,:,:)
148
149
150      ! Maximum light intensity
151      zdaylen(:,:) = MAX(1., zstrn(:,:)) / 24.
152      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
153
154      DO_3D_11_11( 1, jpkm1 )
155         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
156            ! Computation of the P-I slope for nanos and diatoms
157            ztn         = MAX( 0., ts(ji,jj,jk,jp_tem,Kmm) - 15. )
158            zadap       = xadap * ztn / ( 2.+ ztn )
159            !
160            zpislopeadn(ji,jj,jk) = pislopen * tr(ji,jj,jk,jpnch,Kbb)    &
161            &                       /( tr(ji,jj,jk,jpphy,Kbb) * 12. + rtrn)
162            zpislopeadp(ji,jj,jk) = pislopep * ( 1. + zadap * EXP( -0.25 * epico(ji,jj,jk) ) )   &
163            &                       * tr(ji,jj,jk,jppch,Kbb) /( tr(ji,jj,jk,jppic,Kbb) * 12. + rtrn)
164            zpislopeadd(ji,jj,jk) = pisloped * tr(ji,jj,jk,jpdch,Kbb)    &
165               &                    /( tr(ji,jj,jk,jpdia,Kbb) * 12. + rtrn)
166            !
167            zpislopen = zpislopeadn(ji,jj,jk) / ( zprbio(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
168            zpislopep = zpislopeadp(ji,jj,jk) / ( zprpic(ji,jj,jk) * rday * xlimpic(ji,jj,jk) + rtrn )
169            zpisloped = zpislopeadd(ji,jj,jk) / ( zprdia(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
170
171            ! Computation of production function for Carbon
172            !  ---------------------------------------------
173            zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
174            zprpic(ji,jj,jk) = zprpic(ji,jj,jk) * ( 1.- EXP( -zpislopep * epico(ji,jj,jk) )  )
175            zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
176
177            ! Computation of production function for Chlorophyll
178            !  -------------------------------------------------
179            zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
180            zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
181            zpislopep = zpislopep * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
182            zprchln(ji,jj,jk) = zprmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enanom(ji,jj,jk) )  )
183            zprchlp(ji,jj,jk) = zprmaxp(ji,jj,jk) * ( 1.- EXP( -zpislopep * epicom(ji,jj,jk) )  )
184            zprchld(ji,jj,jk) = zprmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediatm(ji,jj,jk) )  )
185         ENDIF
186      END_3D
187
188      DO_3D_11_11( 1, jpkm1 )
189
190          IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
191            !    Si/C of diatoms
192            !    ------------------------
193            !    Si/C increases with iron stress and silicate availability
194            !    Si/C is arbitrariliy increased for very high Si concentrations
195            !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
196            zlim  = tr(ji,jj,jk,jpsil,Kbb) / ( tr(ji,jj,jk,jpsil,Kbb) + xksi1 )
197            zsilim = MIN( zprdia(ji,jj,jk) / ( zprmaxd(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
198            zsilfac = 3.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
199            zsiborn = tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb)
200            IF (gphit(ji,jj) < -30 ) THEN
201              zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
202            ELSE
203              zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
204            ENDIF
205            zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
206        ENDIF
207      END_3D
208
209      !  Sea-ice effect on production                                                                               
210      DO_3D_11_11( 1, jpkm1 )
211         zprbio(ji,jj,jk)  = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
212         zprpic(ji,jj,jk)  = zprpic(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
213         zprdia(ji,jj,jk)  = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
214         zprnut(ji,jj,jk)  = zprnut(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
215      END_3D
216
217      ! Computation of the various production terms of nanophytoplankton
218      DO_3D_11_11( 1, jpkm1 )
219         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
220            !  production terms for nanophyto.
221            zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * tr(ji,jj,jk,jpphy,Kbb) * rfact2
222            !
223            zration = tr(ji,jj,jk,jpnph,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn )
224            zratiop = tr(ji,jj,jk,jppph,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn )
225            zratiof = tr(ji,jj,jk,jpnfe,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn )
226            zprnutmax = zprnut(ji,jj,jk) * fvnuptk(ji,jj,jk) / rno3 * tr(ji,jj,jk,jpphy,Kbb) * rfact2
227            ! Uptake of nitrogen
228            zrat = MIN( 1., zration / (xqnnmax(ji,jj,jk) + rtrn) ) 
229            zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
230            zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpnmin(ji,jj,jk) )   &
231            &          / ( xqpnmax(ji,jj,jk) - xqpnmin(ji,jj,jk) + rtrn ), xlimnfe(ji,jj,jk) ) )
232            zpronewn(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xnanono3(ji,jj,jk)
233            zproregn(ji,jj,jk) = zpronmax * xnanonh4(ji,jj,jk)
234            ! Uptake of phosphorus
235            zrat = MIN( 1., zratiop / (xqpnmax(ji,jj,jk) + rtrn) )
236            zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
237            zpropmax = zprnutmax * zmax * xlimnfe(ji,jj,jk)
238            zpropo4n(ji,jj,jk) = zpropmax * xnanopo4(ji,jj,jk)
239            zprodopn(ji,jj,jk) = zpropmax * xnanodop(ji,jj,jk)
240            ! Uptake of iron
241            zrat = MIN( 1., zratiof / qfnmax )
242            zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
243            zprofmax = zprnutmax * qfnmax * zmax
244            zprofen(ji,jj,jk) = zprofmax * xnanofer(ji,jj,jk) * ( 3. - 2.4 * xlimnfe(ji,jj,jk)    &
245            &          / ( xlimnfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xnanono3(ji,jj,jk) / ( rtrn  &
246            &          + xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) ) * (1. - xnanofer(ji,jj,jk) ) )
247         ENDIF
248      END_3D
249
250      ! Computation of the various production terms of picophytoplankton
251      DO_3D_11_11( 1, jpkm1 )
252         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
253            !  production terms for picophyto.
254            zprorcap(ji,jj,jk) = zprpic(ji,jj,jk)  * xlimpic(ji,jj,jk) * tr(ji,jj,jk,jppic,Kbb) * rfact2
255            !
256            zration = tr(ji,jj,jk,jpnpi,Kbb) / ( tr(ji,jj,jk,jppic,Kbb) + rtrn )
257            zratiop = tr(ji,jj,jk,jpppi,Kbb) / ( tr(ji,jj,jk,jppic,Kbb) + rtrn )
258            zratiof = tr(ji,jj,jk,jppfe,Kbb) / ( tr(ji,jj,jk,jppic,Kbb) + rtrn )
259            zprnutmax = zprnut(ji,jj,jk) * fvpuptk(ji,jj,jk) / rno3 * tr(ji,jj,jk,jppic,Kbb) * rfact2
260            ! Uptake of nitrogen
261            zrat = MIN( 1., zration / (xqnpmax(ji,jj,jk) + rtrn) )
262            zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
263            zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqppmin(ji,jj,jk) )   &
264            &          / ( xqppmax(ji,jj,jk) - xqppmin(ji,jj,jk) + rtrn ), xlimpfe(ji,jj,jk) ) )
265            zpronewp(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xpicono3(ji,jj,jk) 
266            zproregp(ji,jj,jk) = zpronmax * xpiconh4(ji,jj,jk)
267            ! Uptake of phosphorus
268            zrat = MIN( 1., zratiop / (xqppmax(ji,jj,jk) + rtrn) )
269            zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
270            zpropmax = zprnutmax * zmax * xlimpfe(ji,jj,jk)
271            zpropo4p(ji,jj,jk) = zpropmax * xpicopo4(ji,jj,jk)
272            zprodopp(ji,jj,jk) = zpropmax * xpicodop(ji,jj,jk)
273            ! Uptake of iron
274            zrat = MIN( 1., zratiof / qfpmax )
275            zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
276            zprofmax = zprnutmax * qfpmax * zmax
277            zprofep(ji,jj,jk) = zprofmax * xpicofer(ji,jj,jk) * ( 3. - 2.4 * xlimpfe(ji,jj,jk)   &
278            &          / ( xlimpfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xpicono3(ji,jj,jk) / ( rtrn   &
279            &          + xpicono3(ji,jj,jk) + xpiconh4(ji,jj,jk) ) * (1. - xpicofer(ji,jj,jk) ) )
280         ENDIF
281      END_3D
282
283      ! Computation of the various production terms of diatoms
284      DO_3D_11_11( 1, jpkm1 )
285         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
286            !  production terms for diatomees
287            zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * tr(ji,jj,jk,jpdia,Kbb) * rfact2
288            ! Computation of the respiration term according to pahlow
289            ! & oschlies (2013)
290            !
291            zration = tr(ji,jj,jk,jpndi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
292            zratiop = tr(ji,jj,jk,jppdi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
293            zratiof = tr(ji,jj,jk,jpdfe,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
294            zprnutmax = zprnut(ji,jj,jk) * fvduptk(ji,jj,jk) / rno3 * tr(ji,jj,jk,jpdia,Kbb) * rfact2
295            ! Uptake of nitrogen
296            zrat = MIN( 1., zration / (xqndmax(ji,jj,jk) + rtrn) )
297            zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05)) 
298            zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpdmin(ji,jj,jk) )   &
299            &          / ( xqpdmax(ji,jj,jk) - xqpdmin(ji,jj,jk) + rtrn ), xlimdfe(ji,jj,jk) ) )
300            zpronewd(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xdiatno3(ji,jj,jk)
301            zproregd(ji,jj,jk) = zpronmax * xdiatnh4(ji,jj,jk)
302            ! Uptake of phosphorus
303            zrat = MIN( 1., zratiop / (xqpdmax(ji,jj,jk) + rtrn) )
304            zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05)) 
305            zpropmax = zprnutmax * zmax * xlimdfe(ji,jj,jk)
306            zpropo4d(ji,jj,jk) = zpropmax * xdiatpo4(ji,jj,jk)
307            zprodopd(ji,jj,jk) = zpropmax * xdiatdop(ji,jj,jk)
308            ! Uptake of iron
309            zrat = MIN( 1., zratiof / qfdmax )
310            zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
311            zprofmax = zprnutmax * qfdmax * zmax
312            zprofed(ji,jj,jk) = zprofmax * xdiatfer(ji,jj,jk) * ( 3. - 2.4 * xlimdfe(ji,jj,jk)     &
313            &          / ( xlimdfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xdiatno3(ji,jj,jk) / ( rtrn   &
314            &          + xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) ) * (1. - xdiatfer(ji,jj,jk) ) )
315         ENDIF
316      END_3D
317
318      DO_3D_11_11( 1, jpkm1 )
319         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
320               !  production terms for nanophyto. ( chlorophyll )
321            znanotot = enanom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
322            zprod = rday * (zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)) * zprchln(ji,jj,jk) * xlimphy(ji,jj,jk)
323            thetannm_n   = MIN ( thetannm, ( thetannm / (1. - 1.14 / 43.4 *ts(ji,jj,jk,jp_tem,Kmm)))   &
324            &               * (1. - 1.14 / 43.4 * 20.))
325            zprochln = thetannm_n * zprod / ( zpislopeadn(ji,jj,jk) * znanotot + rtrn )
326            zprochln = MAX(zprochln, chlcmin * 12. * zprorcan (ji,jj,jk) )
327               !  production terms for picophyto. ( chlorophyll )
328            zpicotot = epicom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
329            zprod = rday * (zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)) * zprchlp(ji,jj,jk) * xlimpic(ji,jj,jk)
330            thetanpm_n   = MIN ( thetanpm, ( thetanpm / (1. - 1.14 / 43.4 *ts(ji,jj,jk,jp_tem,Kmm)))   &
331            &               * (1. - 1.14 / 43.4 * 20.))
332            zprochlp = thetanpm_n * zprod / ( zpislopeadp(ji,jj,jk) * zpicotot + rtrn )
333            zprochlp = MAX(zprochlp, chlcmin * 12. * zprorcap(ji,jj,jk) )
334            !  production terms for diatomees ( chlorophyll )
335            zdiattot = ediatm(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
336            zprod = rday * (zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)) * zprchld(ji,jj,jk) * xlimdia(ji,jj,jk)
337            thetandm_n   = MIN ( thetandm, ( thetandm / (1. - 1.14 / 43.4 *ts(ji,jj,jk,jp_tem,Kmm)))   &
338            &               * (1. - 1.14 / 43.4 * 20.))
339            zprochld = thetandm_n * zprod / ( zpislopeadd(ji,jj,jk) * zdiattot + rtrn )
340            zprochld = MAX(zprochld, chlcmin * 12. * zprorcad(ji,jj,jk) )
341            !   Update the arrays TRA which contain the Chla sources and sinks
342            tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) + zprochln * texcretn
343            tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) + zprochld * texcretd
344            tr(ji,jj,jk,jppch,Krhs) = tr(ji,jj,jk,jppch,Krhs) + zprochlp * texcretp
345         ENDIF
346      END_3D
347
348      !   Update the arrays TRA which contain the biological sources and sinks
349      DO_3D_11_11( 1, jpkm1 )
350        zprontot = zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)
351        zproptot = zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)
352        zprodtot = zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)
353        zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)  &
354        &          + excretp * zprorcap(ji,jj,jk)
355        tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) - zpropo4n(ji,jj,jk) - zpropo4d(ji,jj,jk)  &
356        &                     - zpropo4p(ji,jj,jk)
357        tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)  &
358        &                     - zpronewp(ji,jj,jk)
359        tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) - zproregn(ji,jj,jk) - zproregd(ji,jj,jk)  &
360        &                     - zproregp(ji,jj,jk)
361        tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs) + zprorcan(ji,jj,jk) * texcretn    &
362           &                  - zpsino3 * zpronewn(ji,jj,jk) - zpsinh4 * zproregn(ji,jj,jk)   &
363           &                  - zrespn(ji,jj,jk) 
364        zcroissn(ji,jj,jk) = tr(ji,jj,jk,jpphy,Krhs) / rfact2/ (tr(ji,jj,jk,jpphy,Kbb) + rtrn)
365        tr(ji,jj,jk,jpnph,Krhs) = tr(ji,jj,jk,jpnph,Krhs) + zprontot * texcretn
366        tr(ji,jj,jk,jppph,Krhs) = tr(ji,jj,jk,jppph,Krhs) + zpropo4n(ji,jj,jk) * texcretn   &
367        &                     + zprodopn(ji,jj,jk) * texcretn
368        tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) + zprofen(ji,jj,jk) * texcretn
369        tr(ji,jj,jk,jppic,Krhs) = tr(ji,jj,jk,jppic,Krhs) + zprorcap(ji,jj,jk) * texcretp     &
370           &                  - zpsino3 * zpronewp(ji,jj,jk) - zpsinh4 * zproregp(ji,jj,jk)   &
371           &                  - zrespp(ji,jj,jk) 
372        zcroissp(ji,jj,jk) = tr(ji,jj,jk,jppic,Krhs) / rfact2/ (tr(ji,jj,jk,jppic,Kbb) + rtrn)
373        tr(ji,jj,jk,jpnpi,Krhs) = tr(ji,jj,jk,jpnpi,Krhs) + zproptot * texcretp
374        tr(ji,jj,jk,jpppi,Krhs) = tr(ji,jj,jk,jpppi,Krhs) + zpropo4p(ji,jj,jk) * texcretp   &
375        &                     + zprodopp(ji,jj,jk) * texcretp
376        tr(ji,jj,jk,jppfe,Krhs) = tr(ji,jj,jk,jppfe,Krhs) + zprofep(ji,jj,jk) * texcretp
377        tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs) + zprorcad(ji,jj,jk) * texcretd   &
378           &                  - zpsino3 * zpronewd(ji,jj,jk) - zpsinh4 * zproregd(ji,jj,jk)   &
379           &                  - zrespd(ji,jj,jk) 
380        zcroissd(ji,jj,jk) = tr(ji,jj,jk,jpdia,Krhs) / rfact2 / (tr(ji,jj,jk,jpdia,Kbb) + rtrn)
381        tr(ji,jj,jk,jpndi,Krhs) = tr(ji,jj,jk,jpndi,Krhs) + zprodtot * texcretd
382        tr(ji,jj,jk,jppdi,Krhs) = tr(ji,jj,jk,jppdi,Krhs) + zpropo4d(ji,jj,jk) * texcretd   &
383        &                     + zprodopd(ji,jj,jk) * texcretd
384        tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) + zprofed(ji,jj,jk) * texcretd
385        tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
386        tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)  &
387        &                     + excretp * zprorcap(ji,jj,jk)
388        tr(ji,jj,jk,jpdon,Krhs) = tr(ji,jj,jk,jpdon,Krhs) + excretd * zprodtot + excretn * zprontot   &
389        &                     + excretp * zproptot
390        tr(ji,jj,jk,jpdop,Krhs) = tr(ji,jj,jk,jpdop,Krhs) + excretd * zpropo4d(ji,jj,jk) + excretn * zpropo4n(ji,jj,jk)   &
391        &    - texcretn * zprodopn(ji,jj,jk) - texcretd * zprodopd(ji,jj,jk) + excretp * zpropo4p(ji,jj,jk)     &
392        &    - texcretp * zprodopp(ji,jj,jk)
393        tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) + o2ut * ( zproregn(ji,jj,jk) + zproregd(ji,jj,jk)   &
394           &                + zproregp(ji,jj,jk) ) + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk)           &
395           &                + zpronewd(ji,jj,jk) + zpronewp(ji,jj,jk) )   &
396           &                - o2ut * ( zrespn(ji,jj,jk) + zrespp(ji,jj,jk) + zrespd(ji,jj,jk) )
397        zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
398        tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zfeup
399        tr(ji,jj,jk,jpsil,Krhs) = tr(ji,jj,jk,jpsil,Krhs) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
400        tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk) - zprorcap(ji,jj,jk)  &
401        &                     + zpsino3 * zpronewn(ji,jj,jk) + zpsinh4 * zproregn(ji,jj,jk)   &
402        &                     + zpsino3 * zpronewp(ji,jj,jk) + zpsinh4 * zproregp(ji,jj,jk)   &
403        &                     + zpsino3 * zpronewd(ji,jj,jk) + zpsinh4 * zproregd(ji,jj,jk)  &
404        &                     + zrespn(ji,jj,jk) + zrespd(ji,jj,jk) + zrespp(ji,jj,jk) 
405        tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk)  &
406        &                     + zpronewp(ji,jj,jk) ) - rno3 * ( zproregn(ji,jj,jk) + zproregd(ji,jj,jk)     &
407        &                     + zproregp(ji,jj,jk) ) 
408      END_3D
409     !
410     IF( ln_ligand ) THEN
411         zpligprod1(:,:,:) = 0._wp    ;    zpligprod2(:,:,:) = 0._wp             
412         DO_3D_11_11( 1, jpkm1 )
413           zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk) + excretp * zprorcap(ji,jj,jk)
414           zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
415           tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
416           zpligprod1(ji,jj,jk) = zdocprod * ldocp
417           zpligprod2(ji,jj,jk) = zfeup * plig(ji,jj,jk) * lthet
418         END_3D
419     ENDIF
420
421
422     ! Total primary production per year
423
424    ! Total primary production per year
425    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
426      & tpp = glob_sum( 'p5zprod', ( zprorcan(:,:,:) + zprorcad(:,:,:) + zprorcap(:,:,:) ) * cvol(:,:,:) )
427
428    IF( lk_iomput .AND.  knt == nrdttrc ) THEN
429       zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
430       !
431       CALL iom_put( "PPPHYP"  , zprorcap(:,:,:) * zfact * tmask(:,:,:)   ) ! primary production by picophyto
432       CALL iom_put( "PPPHYN"  , zprorcan(:,:,:) * zfact * tmask(:,:,:) )  ! primary production by nanophyto
433       CALL iom_put( "PPPHYD"  , zprorcad(:,:,:) * zfact * tmask(:,:,:)   ) ! primary production by diatomes
434       CALL iom_put( "PPNEWN"  , zpronewp(:,:,:) * zfact * tmask(:,:,:)    ) ! new primary production by picophyto
435       CALL iom_put( "PPNEWN"  , zpronewn(:,:,:) * zfact * tmask(:,:,:)    ) ! new primary production by nanophyto
436       CALL iom_put( "PPNEWD"  , zpronewd(:,:,:) * zfact * tmask(:,:,:)   ) ! new primary production by diatomes
437       CALL iom_put( "PBSi"    , zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:)  ) ! biogenic silica production
438       CALL iom_put( "PFeP"    , zprofep(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by picophyto
439       CALL iom_put( "PFeN"    , zprofen(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by nanophyto
440       CALL iom_put( "PFeD"    , zprofed(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by  diatomes
441       IF( ln_ligand ) THEN
442         CALL iom_put( "LPRODP"  , zpligprod1(:,:,:) * 1e9 * zfact * tmask(:,:,:) )
443         CALL iom_put( "LDETP"   , zpligprod2(:,:,:) * 1e9 * zfact * tmask(:,:,:) )
444       ENDIF
445       CALL iom_put( "Mumax"   , zprmaxn(:,:,:) * tmask(:,:,:)  ) ! Maximum growth rate
446       CALL iom_put( "MuP"     , zprpic(:,:,:) * xlimpic(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for picophyto
447       CALL iom_put( "MuN"     , zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for nanophyto
448       CALL iom_put( "MuD"     , zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for diatoms
449       CALL iom_put( "LPlight" , zprpic(:,:,:) / (zprmaxp(:,:,:) + rtrn) * tmask(:,:,:)  )  ! light limitation term
450       CALL iom_put( "LNlight" , zprbio(:,:,:) / (zprmaxn(:,:,:) + rtrn) * tmask(:,:,:)  )  ! light limitation term
451       CALL iom_put( "LDlight" , zprdia(:,:,:) / (zprmaxd(:,:,:) + rtrn) * tmask(:,:,:)   )
452       CALL iom_put( "MunetP"  , zcroissp(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for picophyto
453       CALL iom_put( "MunetN"  , zcroissn(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for nanophyto
454       CALL iom_put( "MunetD"  , zcroissd(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for diatoms
455       CALL iom_put( "TPP"     , ( zprorcap(:,:,:) + zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  )  ! total primary production
456       CALL iom_put( "TPNEW"   , ( zpronewp(:,:,:) + zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ) ! total new production
457       CALL iom_put( "TPBFE"   , ( zprofep (:,:,:) + zprofen (:,:,:) + zprofed (:,:,:) ) * zfact * tmask(:,:,:)  )  ! total biogenic iron production
458       CALL iom_put( "tintpp"  , tpp * zfact )  !  global total integrated primary production molC/s
459     ENDIF
460
461      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
462         WRITE(charout, FMT="('prod')")
463         CALL prt_ctl_trc_info(charout)
464         CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
465      ENDIF
466      !
467      IF( ln_timing )   CALL timing_stop('p5z_prod')
468      !
469   END SUBROUTINE p5z_prod
470
471
472   SUBROUTINE p5z_prod_init
473      !!----------------------------------------------------------------------
474      !!                  ***  ROUTINE p5z_prod_init  ***
475      !!
476      !! ** Purpose :   Initialization of phytoplankton production parameters
477      !!
478      !! ** Method  :   Read the nampisprod namelist and check the parameters
479      !!      called at the first timestep (nittrc000)
480      !!
481      !! ** input   :   Namelist nampisprod
482      !!----------------------------------------------------------------------
483      INTEGER :: ios                 ! Local integer output status for namelist read
484      !!
485      NAMELIST/namp5zprod/ pislopen, pislopep, pisloped, excretn, excretp, excretd,     &
486         &                 thetannm, thetanpm, thetandm, chlcmin, grosip, bresp, xadap
487      !!----------------------------------------------------------------------
488
489      READ  ( numnatp_ref, namp5zprod, IOSTAT = ios, ERR = 901)
490901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zprod in reference namelist' )
491
492      READ  ( numnatp_cfg, namp5zprod, IOSTAT = ios, ERR = 902 )
493902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp5zprod in configuration namelist' )
494      IF(lwm) WRITE ( numonp, namp5zprod )
495
496      IF(lwp) THEN                         ! control print
497         WRITE(numout,*) ' '
498         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, namp5zprod'
499         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
500         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
501         WRITE(numout,*) '    P-I slope                                 pislopen     =', pislopen
502         WRITE(numout,*) '    P-I slope  for diatoms                    pisloped     =', pisloped
503         WRITE(numout,*) '    P-I slope  for picophytoplankton          pislopep     =', pislopep
504         WRITE(numout,*) '    Acclimation factor to low light           xadap        =', xadap
505         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excretn      =', excretn
506         WRITE(numout,*) '    excretion ratio of picophytoplankton      excretp      =', excretp
507         WRITE(numout,*) '    excretion ratio of diatoms                excretd      =', excretd
508         WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
509         WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
510         WRITE(numout,*) '    Minimum Chl/N in nanophytoplankton        thetannm     =', thetannm
511         WRITE(numout,*) '    Minimum Chl/N in picophytoplankton        thetanpm     =', thetanpm
512         WRITE(numout,*) '    Minimum Chl/N in diatoms                  thetandm     =', thetandm
513      ENDIF
514      !
515      r1_rday   = 1._wp / rday 
516      texcretn  = 1._wp - excretn
517      texcretp  = 1._wp - excretp
518      texcretd  = 1._wp - excretd
519      tpp       = 0._wp
520      !
521   END SUBROUTINE p5z_prod_init
522
523
524   INTEGER FUNCTION p5z_prod_alloc()
525      !!----------------------------------------------------------------------
526      !!                     ***  ROUTINE p5z_prod_alloc  ***
527      !!----------------------------------------------------------------------
528      ALLOCATE( zdaylen(jpi,jpj), STAT = p5z_prod_alloc )
529      !
530      IF( p5z_prod_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p5z_prod_alloc : failed to allocate arrays.' )
531      !
532   END FUNCTION p5z_prod_alloc
533   !!======================================================================
534END MODULE p5zprod
Note: See TracBrowser for help on using the repository browser.