New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcstp.F90 in NEMO/branches/2020/dev_r12527_Gurvan_ShallowWater/src/TOP – NEMO

source: NEMO/branches/2020/dev_r12527_Gurvan_ShallowWater/src/TOP/trcstp.F90 @ 13151

Last change on this file since 13151 was 13151, checked in by gm, 4 years ago

result from merge with qco r12983

  • Property svn:keywords set to Id
File size: 12.7 KB
Line 
1MODULE trcstp
2   !!======================================================================
3   !!                       ***  MODULE trcstp  ***
4   !! Time-stepping    : time loop of opa for passive tracer
5   !!======================================================================
6   !! History :  1.0  !  2004-03  (C. Ethe)  Original
7   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   trc_stp       : passive tracer system time-stepping
12   !!----------------------------------------------------------------------
13   USE oce_trc        ! ocean dynamics and active tracers variables
14   USE sbc_oce
15   USE trc
16   USE trctrp         ! passive tracers transport
17   USE trcsms         ! passive tracers sources and sinks
18   USE trcwri
19   USE trcrst
20   USE trdtrc_oce
21   USE trdmxl_trc
22   USE sms_pisces,  ONLY : ln_check_mass
23   !
24   USE prtctl_trc     ! Print control for debbuging
25   USE iom            !
26   USE in_out_manager !
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   trc_stp    ! called by step
32
33   LOGICAL  ::   llnew                   ! ???
34   REAL(wp) ::   rdt_sampl               ! ???
35   INTEGER  ::   nb_rec_per_day, ktdcy   ! ???
36   REAL(wp) ::   rsecfst, rseclast       ! ???
37   REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   qsr_arr   ! save qsr during TOP time-step
38   
39#  include "domzgr_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE trc_stp( kt, Kbb, Kmm, Krhs, Kaa )
48      !!-------------------------------------------------------------------
49      !!                     ***  ROUTINE trc_stp  ***
50      !!                     
51      !! ** Purpose :   Time loop of opa for passive tracer
52      !!
53      !! ** Method  :   Compute the passive tracers trends
54      !!                Update the passive tracers
55      !!-------------------------------------------------------------------
56      INTEGER, INTENT( in ) :: kt                  ! ocean time-step index
57      INTEGER, INTENT( in ) :: Kbb, Kmm, Krhs, Kaa ! time level indices
58      !
59      INTEGER ::   jk, jn   ! dummy loop indices
60      REAL(wp)::   ztrai    ! local scalar
61      LOGICAL ::   ll_trcstat ! local logical
62      CHARACTER (len=25) ::   charout   !
63      !!-------------------------------------------------------------------
64      !
65      IF( ln_timing )   CALL timing_start('trc_stp')
66      !
67      IF( l_1st_euler .OR. ln_top_euler ) THEN     ! at nittrc000
68         rDt_trc =  rn_Dt           ! = rn_Dt (use or restarting with Euler time stepping)
69      ELSEIF( kt <= nittrc000 + 1 ) THEN                                     ! at nittrc000 or nittrc000+1
70         rDt_trc = 2. * rn_Dt       ! = 2 rn_Dt (leapfrog)
71      ENDIF
72      !
73      ll_trcstat  = ( sn_cfctl%l_trcstat ) .AND. &
74     &              ( ( MOD( kt, sn_cfctl%ptimincr ) == 0 ) .OR. ( kt == nitend ) )
75
76      IF( kt == nittrc000 )                      CALL trc_stp_ctl   ! control
77      IF( kt == nittrc000 .AND. lk_trdmxl_trc )  CALL trd_mxl_trc_init    ! trends: Mixed-layer
78      !
79      IF( .NOT.ln_linssh ) THEN                                           ! update ocean volume due to ssh temporal evolution
80         DO jk = 1, jpk
81            cvol(:,:,jk) = e1e2t(:,:) * e3t(:,:,jk,Kmm) * tmask(:,:,jk)
82         END DO
83         IF ( ll_trcstat .OR. kt == nitrst .OR. ( ln_check_mass .AND. kt == nitend )   &
84            & .OR. iom_use( "pno3tot" ) .OR. iom_use( "ppo4tot" ) .OR. iom_use( "psiltot" )   &
85            & .OR. iom_use( "palktot" ) .OR. iom_use( "pfertot" ) )                           &
86            &     areatot = glob_sum( 'trcstp', cvol(:,:,:) )
87      ENDIF
88      !
89      IF( l_trcdm2dc )   CALL trc_mean_qsr( kt )
90      !   
91      !
92      IF(sn_cfctl%l_prttrc) THEN
93         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
94         CALL prt_ctl_trc_info(charout)
95      ENDIF
96      !
97      tr(:,:,:,:,Krhs) = 0._wp
98      !
99      CALL trc_rst_opn  ( kt )                            ! Open tracer restart file
100      IF( lrst_trc )  CALL trc_rst_cal  ( kt, 'WRITE' )   ! calendar
101      CALL trc_wri      ( kt,      Kmm            )       ! output of passive tracers with iom I/O manager
102      CALL trc_sms      ( kt, Kbb, Kmm, Krhs      )       ! tracers: sinks and sources
103      CALL trc_trp      ( kt, Kbb, Kmm, Krhs, Kaa )       ! transport of passive tracers
104           !
105           ! Note passive tracers have been time-filtered in trc_trp but the time level
106           ! indices will not be swapped until after tra_atf/dyn_atf/ssh_atf in stp. Subsequent calls here
107           ! anticipate this update which will be: Nrhs= Nbb ; Nbb = Nnn ; Nnn = Naa ; Naa = Nrhs
108           ! and use the filtered levels explicitly.
109           !
110      IF( kt == nittrc000 ) THEN
111         CALL iom_close( numrtr )                         ! close input tracer restart file
112         IF(lwm) CALL FLUSH( numont )                     ! flush namelist output
113      ENDIF
114      IF( lrst_trc )            CALL trc_rst_wri  ( kt, Kmm, Kaa, Kbb  )       ! write tracer restart file
115      IF( lk_trdmxl_trc  )      CALL trd_mxl_trc  ( kt,      Kaa       )       ! trends: Mixed-layer
116      !
117      IF( ln_top_euler ) THEN 
118         ! For Euler timestepping for TOP we need to copy the "after" to the "now" fields
119         ! here then after the (leapfrog) swapping of the time-level indices in OCE/step.F90 we have
120         ! "before" fields = "now" fields.
121         tr(:,:,:,:,Kmm) = tr(:,:,:,:,Kaa)
122      ENDIF
123      !
124      IF (ll_trcstat) THEN
125         ztrai = 0._wp                                                   !  content of all tracers
126         DO jn = 1, jptra
127            ztrai = ztrai + glob_sum( 'trcstp', tr(:,:,:,jn,Kaa) * cvol(:,:,:)   )
128         END DO
129         IF( lwm ) WRITE(numstr,9300) kt,  ztrai / areatot
130      ENDIF
1319300  FORMAT(i10,D23.16)
132      !
133      IF( ln_timing )   CALL timing_stop('trc_stp')
134      !
135   END SUBROUTINE trc_stp
136
137
138   SUBROUTINE trc_stp_ctl
139      !!----------------------------------------------------------------------
140      !!                     ***  ROUTINE trc_stp_ctl  ***
141      !! ** Purpose :        Control  + ocean volume
142      !!----------------------------------------------------------------------
143      !
144      ! Define logical parameter ton control dirunal cycle in TOP
145      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 .AND. ncpl_qsr_freq /= 0 )
146      l_trcdm2dc = l_trcdm2dc .AND. .NOT. l_offline
147      !
148      IF( l_trcdm2dc .AND. lwp )   CALL ctl_warn( 'Coupling with passive tracers and used of diurnal cycle.',   &
149         &                           'Computation of a daily mean shortwave for some biogeochemical models ' )
150      !
151   END SUBROUTINE trc_stp_ctl
152
153
154   SUBROUTINE trc_mean_qsr( kt )
155      !!----------------------------------------------------------------------
156      !!             ***  ROUTINE trc_mean_qsr  ***
157      !!
158      !! ** Purpose :  Compute daily mean qsr for biogeochemical model in case
159      !!               of diurnal cycle
160      !!
161      !! ** Method  : store in TOP the qsr every hour ( or every time-step if the latter
162      !!              is greater than 1 hour ) and then, compute the  mean with
163      !!              a moving average over 24 hours.
164      !!              In coupled mode, the sampling is done at every coupling frequency
165      !!----------------------------------------------------------------------
166      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
167      !
168      INTEGER  ::   jn   ! dummy loop indices
169      REAL(wp) ::   zkt, zrec     ! local scalars
170      CHARACTER(len=1) ::   cl1   ! 1 character
171      CHARACTER(len=2) ::   cl2   ! 2 characters
172      !!----------------------------------------------------------------------
173      !
174      IF( ln_timing )   CALL timing_start('trc_mean_qsr')
175      !
176      IF( kt == nittrc000 ) THEN
177         IF( ln_cpl )  THEN 
178            rdt_sampl = rday / ncpl_qsr_freq
179            nb_rec_per_day = ncpl_qsr_freq
180         ELSE 
181            rdt_sampl = MAX( 3600., rn_Dt )
182            nb_rec_per_day = INT( rday / rdt_sampl )
183         ENDIF
184         !
185         IF(lwp) THEN
186            WRITE(numout,*) 
187            WRITE(numout,*) ' Sampling frequency dt = ', rdt_sampl, 's','   Number of sampling per day  nrec = ', nb_rec_per_day
188            WRITE(numout,*) 
189         ENDIF
190         !
191         ALLOCATE( qsr_arr(jpi,jpj,nb_rec_per_day ) )
192         !
193         !                                            !* Restart: read in restart file
194         IF( ln_rsttr .AND. nn_rsttr /= 0 .AND. iom_varid( numrtr, 'qsr_mean' , ldstop = .FALSE. ) > 0  &
195           &                              .AND. iom_varid( numrtr, 'qsr_arr_1', ldstop = .FALSE. ) > 0  &
196           &                              .AND. iom_varid( numrtr, 'ktdcy'    , ldstop = .FALSE. ) > 0  &
197           &                              .AND. iom_varid( numrtr, 'nrdcy'    , ldstop = .FALSE. ) > 0  ) THEN
198
199            CALL iom_get( numrtr, 'ktdcy', zkt ) 
200            rsecfst = INT( zkt ) * rn_Dt
201            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean read in the restart file at time-step rsecfst =', rsecfst, ' s '
202            CALL iom_get( numrtr, jpdom_autoglo, 'qsr_mean', qsr_mean )   !  A mean of qsr
203            CALL iom_get( numrtr, 'nrdcy', zrec )   !  Number of record per days
204            IF( INT( zrec ) == nb_rec_per_day ) THEN
205               DO jn = 1, nb_rec_per_day 
206                  IF( jn <= 9 )  THEN
207                    WRITE(cl1,'(i1)') jn
208                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )   !  A mean of qsr
209                  ELSE
210                    WRITE(cl2,'(i2.2)') jn
211                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )   !  A mean of qsr
212                  ENDIF
213              END DO
214            ELSE
215               DO jn = 1, nb_rec_per_day
216                  qsr_arr(:,:,jn) = qsr_mean(:,:)
217               ENDDO
218            ENDIF
219         ELSE                                         !* no restart: set from nit000 values
220            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean set to nit000 values'
221            rsecfst  = kt * rn_Dt
222            !
223            qsr_mean(:,:) = qsr(:,:)
224            DO jn = 1, nb_rec_per_day
225               qsr_arr(:,:,jn) = qsr_mean(:,:)
226            END DO
227         ENDIF
228         !
229      ENDIF
230      !
231      rseclast = kt * rn_Dt
232      !
233      llnew   = ( rseclast - rsecfst ) .ge.  rdt_sampl    !   new shortwave to store
234      IF( llnew ) THEN
235          ktdcy = kt
236          IF( lwp .AND. kt < nittrc000 + 100 ) WRITE(numout,*) ' New shortwave to sample for TOP at time kt = ', ktdcy, &
237             &                      ' time = ', rseclast/3600.,'hours '
238          rsecfst = rseclast
239          DO jn = 1, nb_rec_per_day - 1
240             qsr_arr(:,:,jn) = qsr_arr(:,:,jn+1)
241          ENDDO
242          qsr_arr (:,:,nb_rec_per_day) = qsr(:,:)
243          qsr_mean(:,:                ) = SUM( qsr_arr(:,:,:), 3 ) / nb_rec_per_day
244      ENDIF
245      !
246      IF( lrst_trc ) THEN    !* Write the mean of qsr in restart file
247         IF(lwp) WRITE(numout,*)
248         IF(lwp) WRITE(numout,*) 'trc_mean_qsr : write qsr_mean in restart file  kt =', kt
249         IF(lwp) WRITE(numout,*) '~~~~~~~'
250         zkt  = REAL( ktdcy, wp )
251         zrec = REAL( nb_rec_per_day, wp )
252         CALL iom_rstput( kt, nitrst, numrtw, 'ktdcy', zkt  )
253         CALL iom_rstput( kt, nitrst, numrtw, 'nrdcy', zrec )
254          DO jn = 1, nb_rec_per_day 
255             IF( jn <= 9 )  THEN
256               WRITE(cl1,'(i1)') jn
257               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )
258             ELSE
259               WRITE(cl2,'(i2.2)') jn
260               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )
261             ENDIF
262         END DO
263         CALL iom_rstput( kt, nitrst, numrtw, 'qsr_mean', qsr_mean(:,:) )
264      ENDIF
265      !
266      IF( ln_timing )   CALL timing_stop('trc_mean_qsr')
267      !
268   END SUBROUTINE trc_mean_qsr
269
270#else
271   !!----------------------------------------------------------------------
272   !!   Default key                                     NO passive tracers
273   !!----------------------------------------------------------------------
274CONTAINS
275   SUBROUTINE trc_stp( kt )        ! Empty routine
276      WRITE(*,*) 'trc_stp: You should not have seen this print! error?', kt
277   END SUBROUTINE trc_stp
278#endif
279
280   !!======================================================================
281END MODULE trcstp
Note: See TracBrowser for help on using the repository browser.