| 1 | #define SPONGE && define SPONGE_TOP |
|---|
| 2 | |
|---|
| 3 | MODULE agrif_oce_sponge |
|---|
| 4 | !!====================================================================== |
|---|
| 5 | !! *** MODULE agrif_oce_interp *** |
|---|
| 6 | !! AGRIF: sponge package for the ocean dynamics (OPA) |
|---|
| 7 | !!====================================================================== |
|---|
| 8 | !! History : 2.0 ! 2002-06 (XXX) Original cade |
|---|
| 9 | !! - ! 2005-11 (XXX) |
|---|
| 10 | !! 3.2 ! 2009-04 (R. Benshila) |
|---|
| 11 | !! 3.6 ! 2014-09 (R. Benshila) |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | #if defined key_agrif |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! 'key_agrif' AGRIF zoom |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE par_oce |
|---|
| 18 | USE oce |
|---|
| 19 | USE dom_oce |
|---|
| 20 | ! |
|---|
| 21 | USE in_out_manager |
|---|
| 22 | USE agrif_oce |
|---|
| 23 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 24 | USE iom |
|---|
| 25 | USE vremap |
|---|
| 26 | |
|---|
| 27 | IMPLICIT NONE |
|---|
| 28 | PRIVATE |
|---|
| 29 | |
|---|
| 30 | PUBLIC Agrif_Sponge, Agrif_Sponge_Tra, Agrif_Sponge_Dyn |
|---|
| 31 | PUBLIC interptsn_sponge, interpun_sponge, interpvn_sponge |
|---|
| 32 | |
|---|
| 33 | !! * Substitutions |
|---|
| 34 | # include "do_loop_substitute.h90" |
|---|
| 35 | !!---------------------------------------------------------------------- |
|---|
| 36 | !! NEMO/NST 4.0 , NEMO Consortium (2018) |
|---|
| 37 | !! $Id$ |
|---|
| 38 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 39 | !!---------------------------------------------------------------------- |
|---|
| 40 | CONTAINS |
|---|
| 41 | |
|---|
| 42 | SUBROUTINE Agrif_Sponge_Tra |
|---|
| 43 | !!---------------------------------------------------------------------- |
|---|
| 44 | !! *** ROUTINE Agrif_Sponge_Tra *** |
|---|
| 45 | !!---------------------------------------------------------------------- |
|---|
| 46 | REAL(wp) :: zcoef ! local scalar |
|---|
| 47 | |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | ! |
|---|
| 50 | #if defined SPONGE |
|---|
| 51 | !! Assume persistence: |
|---|
| 52 | zcoef = REAL(Agrif_rhot()-1,wp)/REAL(Agrif_rhot()) |
|---|
| 53 | |
|---|
| 54 | CALL Agrif_Sponge |
|---|
| 55 | Agrif_SpecialValue = 0._wp |
|---|
| 56 | Agrif_UseSpecialValue = .TRUE. |
|---|
| 57 | tabspongedone_tsn = .FALSE. |
|---|
| 58 | ! |
|---|
| 59 | CALL Agrif_Bc_Variable( tsn_sponge_id, calledweight=zcoef, procname=interptsn_sponge ) |
|---|
| 60 | ! |
|---|
| 61 | Agrif_UseSpecialValue = .FALSE. |
|---|
| 62 | #endif |
|---|
| 63 | ! |
|---|
| 64 | CALL iom_put( 'agrif_spu', fspu(:,:)) |
|---|
| 65 | CALL iom_put( 'agrif_spv', fspv(:,:)) |
|---|
| 66 | ! |
|---|
| 67 | END SUBROUTINE Agrif_Sponge_Tra |
|---|
| 68 | |
|---|
| 69 | |
|---|
| 70 | SUBROUTINE Agrif_Sponge_dyn |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | !! *** ROUTINE Agrif_Sponge_dyn *** |
|---|
| 73 | !!---------------------------------------------------------------------- |
|---|
| 74 | REAL(wp) :: zcoef ! local scalar |
|---|
| 75 | !!---------------------------------------------------------------------- |
|---|
| 76 | ! |
|---|
| 77 | #if defined SPONGE |
|---|
| 78 | zcoef = REAL(Agrif_rhot()-1,wp)/REAL(Agrif_rhot()) |
|---|
| 79 | |
|---|
| 80 | Agrif_SpecialValue=0. |
|---|
| 81 | Agrif_UseSpecialValue = ln_spc_dyn |
|---|
| 82 | ! |
|---|
| 83 | tabspongedone_u = .FALSE. |
|---|
| 84 | tabspongedone_v = .FALSE. |
|---|
| 85 | CALL Agrif_Bc_Variable( un_sponge_id, calledweight=zcoef, procname=interpun_sponge ) |
|---|
| 86 | ! |
|---|
| 87 | tabspongedone_u = .FALSE. |
|---|
| 88 | tabspongedone_v = .FALSE. |
|---|
| 89 | CALL Agrif_Bc_Variable( vn_sponge_id, calledweight=zcoef, procname=interpvn_sponge ) |
|---|
| 90 | ! |
|---|
| 91 | Agrif_UseSpecialValue = .FALSE. |
|---|
| 92 | #endif |
|---|
| 93 | ! |
|---|
| 94 | CALL iom_put( 'agrif_spt', fspt(:,:)) |
|---|
| 95 | CALL iom_put( 'agrif_spf', fspf(:,:)) |
|---|
| 96 | ! |
|---|
| 97 | END SUBROUTINE Agrif_Sponge_dyn |
|---|
| 98 | |
|---|
| 99 | |
|---|
| 100 | SUBROUTINE Agrif_Sponge |
|---|
| 101 | !!---------------------------------------------------------------------- |
|---|
| 102 | !! *** ROUTINE Agrif_Sponge *** |
|---|
| 103 | !!---------------------------------------------------------------------- |
|---|
| 104 | INTEGER :: ji, jj, ind1, ind2 |
|---|
| 105 | INTEGER :: ispongearea, jspongearea |
|---|
| 106 | REAL(wp) :: z1_ispongearea, z1_jspongearea |
|---|
| 107 | REAL(wp), DIMENSION(jpi,jpj) :: ztabramp |
|---|
| 108 | #if defined key_vertical |
|---|
| 109 | REAL(wp), DIMENSION(jpi,jpj) :: ztabrampu |
|---|
| 110 | REAL(wp), DIMENSION(jpi,jpj) :: ztabrampv |
|---|
| 111 | #endif |
|---|
| 112 | REAL(wp), DIMENSION(jpjmax) :: zmskwest, zmskeast |
|---|
| 113 | REAL(wp), DIMENSION(jpimax) :: zmsknorth, zmsksouth |
|---|
| 114 | !!---------------------------------------------------------------------- |
|---|
| 115 | ! |
|---|
| 116 | ! Sponge 1d example with: |
|---|
| 117 | ! iraf = 3 ; nbghost = 3 ; nn_sponge_len = 2 |
|---|
| 118 | ! |
|---|
| 119 | !coarse : U T U T U T U |
|---|
| 120 | !| | | | | |
|---|
| 121 | !fine : t u t u t u t u t u t u t u t u t u t u t |
|---|
| 122 | !sponge val:0 0 0 1 5/6 4/6 3/6 2/6 1/6 0 0 |
|---|
| 123 | ! | ghost | <-- sponge area -- > | |
|---|
| 124 | ! | points | | |
|---|
| 125 | ! |--> dynamical interface |
|---|
| 126 | |
|---|
| 127 | #if defined SPONGE || defined SPONGE_TOP |
|---|
| 128 | IF (( .NOT. spongedoneT ).OR.( .NOT. spongedoneU )) THEN |
|---|
| 129 | ! |
|---|
| 130 | ! Retrieve masks at open boundaries: |
|---|
| 131 | |
|---|
| 132 | ! --- West --- ! |
|---|
| 133 | ztabramp(:,:) = 0._wp |
|---|
| 134 | ind1 = nn_hls + 1 + nbghostcells ! halo + land + nbghostcells |
|---|
| 135 | DO ji = mi0(ind1), mi1(ind1) |
|---|
| 136 | ztabramp(ji,:) = ssumask(ji,:) |
|---|
| 137 | END DO |
|---|
| 138 | ! |
|---|
| 139 | zmskwest(1:jpj) = MAXVAL(ztabramp(:,:), dim=1) |
|---|
| 140 | zmskwest(jpj+1:jpjmax) = 0._wp |
|---|
| 141 | |
|---|
| 142 | ! --- East --- ! |
|---|
| 143 | ztabramp(:,:) = 0._wp |
|---|
| 144 | ind1 = jpiglo - ( nn_hls + nbghostcells + 1) ! halo + land + nbghostcells |
|---|
| 145 | DO ji = mi0(ind1), mi1(ind1) |
|---|
| 146 | ztabramp(ji,:) = ssumask(ji,:) |
|---|
| 147 | END DO |
|---|
| 148 | ! |
|---|
| 149 | zmskeast(1:jpj) = MAXVAL(ztabramp(:,:), dim=1) |
|---|
| 150 | zmskeast(jpj+1:jpjmax) = 0._wp |
|---|
| 151 | |
|---|
| 152 | ! --- South --- ! |
|---|
| 153 | ztabramp(:,:) = 0._wp |
|---|
| 154 | ind1 = nn_hls + 1 + nbghostcells ! halo + land + nbghostcells |
|---|
| 155 | DO jj = mj0(ind1), mj1(ind1) |
|---|
| 156 | ztabramp(:,jj) = ssvmask(:,jj) |
|---|
| 157 | END DO |
|---|
| 158 | ! |
|---|
| 159 | zmsksouth(1:jpi) = MAXVAL(ztabramp(:,:), dim=2) |
|---|
| 160 | zmsksouth(jpi+1:jpimax) = 0._wp |
|---|
| 161 | |
|---|
| 162 | ! --- North --- ! |
|---|
| 163 | ztabramp(:,:) = 0._wp |
|---|
| 164 | ind1 = jpjglo - ( nn_hls + nbghostcells + 1) ! halo + land + nbghostcells |
|---|
| 165 | DO jj = mj0(ind1), mj1(ind1) |
|---|
| 166 | ztabramp(:,jj) = ssvmask(:,jj) |
|---|
| 167 | END DO |
|---|
| 168 | ! |
|---|
| 169 | zmsknorth(1:jpi) = MAXVAL(ztabramp(:,:), dim=2) |
|---|
| 170 | zmsknorth(jpi+1:jpimax) = 0._wp |
|---|
| 171 | |
|---|
| 172 | ! JC: SPONGE MASKING TO BE SORTED OUT: |
|---|
| 173 | zmskwest(:) = 1._wp |
|---|
| 174 | zmskeast(:) = 1._wp |
|---|
| 175 | zmsksouth(:) = 1._wp |
|---|
| 176 | zmsknorth(:) = 1._wp |
|---|
| 177 | #if defined key_mpp_mpi |
|---|
| 178 | ! CALL mpp_max( 'AGRIF_sponge', zmskwest(:) , jpjmax ) |
|---|
| 179 | ! CALL mpp_max( 'AGRIF_Sponge', zmskeast(:) , jpjmax ) |
|---|
| 180 | ! CALL mpp_max( 'AGRIF_Sponge', zmsksouth(:), jpimax ) |
|---|
| 181 | ! CALL mpp_max( 'AGRIF_Sponge', zmsknorth(:), jpimax ) |
|---|
| 182 | #endif |
|---|
| 183 | |
|---|
| 184 | ! Define ramp from boundaries towards domain interior at T-points |
|---|
| 185 | ! Store it in ztabramp |
|---|
| 186 | |
|---|
| 187 | ispongearea = nn_sponge_len * Agrif_irhox() |
|---|
| 188 | z1_ispongearea = 1._wp / REAL( ispongearea ) |
|---|
| 189 | jspongearea = nn_sponge_len * Agrif_irhoy() |
|---|
| 190 | z1_jspongearea = 1._wp / REAL( jspongearea ) |
|---|
| 191 | |
|---|
| 192 | ztabramp(:,:) = 0._wp |
|---|
| 193 | |
|---|
| 194 | ! Trick to remove sponge in 2DV domains: |
|---|
| 195 | IF ( nbcellsx <= 3 ) ispongearea = -1 |
|---|
| 196 | IF ( nbcellsy <= 3 ) jspongearea = -1 |
|---|
| 197 | |
|---|
| 198 | ! --- West --- ! |
|---|
| 199 | ind1 = nn_hls + 1 + nbghostcells ! halo + land + nbghostcells |
|---|
| 200 | ind2 = nn_hls + 1 + nbghostcells + ispongearea |
|---|
| 201 | DO ji = mi0(ind1), mi1(ind2) |
|---|
| 202 | DO jj = 1, jpj |
|---|
| 203 | ztabramp(ji,jj) = REAL( ind2 - mig(ji) ) * z1_ispongearea * zmskwest(jj) |
|---|
| 204 | END DO |
|---|
| 205 | END DO |
|---|
| 206 | |
|---|
| 207 | ! ghost cells: |
|---|
| 208 | ind1 = 1 |
|---|
| 209 | ind2 = nn_hls + 1 + nbghostcells ! halo + land + nbghostcells |
|---|
| 210 | DO ji = mi0(ind1), mi1(ind2) |
|---|
| 211 | DO jj = 1, jpj |
|---|
| 212 | ztabramp(ji,jj) = zmskwest(jj) |
|---|
| 213 | END DO |
|---|
| 214 | END DO |
|---|
| 215 | |
|---|
| 216 | ! --- East --- ! |
|---|
| 217 | ind1 = jpiglo - ( nn_hls + nbghostcells ) - ispongearea |
|---|
| 218 | ind2 = jpiglo - ( nn_hls + nbghostcells ) ! halo + land + nbghostcells - 1 |
|---|
| 219 | DO ji = mi0(ind1), mi1(ind2) |
|---|
| 220 | DO jj = 1, jpj |
|---|
| 221 | ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL( mig(ji) - ind1 ) * z1_ispongearea) * zmskeast(jj) |
|---|
| 222 | ENDDO |
|---|
| 223 | END DO |
|---|
| 224 | |
|---|
| 225 | ! ghost cells: |
|---|
| 226 | ind1 = jpiglo - ( nn_hls + nbghostcells ) ! halo + land + nbghostcells - 1 |
|---|
| 227 | ind2 = jpiglo |
|---|
| 228 | DO ji = mi0(ind1), mi1(ind2) |
|---|
| 229 | DO jj = 1, jpj |
|---|
| 230 | ztabramp(ji,jj) = zmskeast(jj) |
|---|
| 231 | ENDDO |
|---|
| 232 | END DO |
|---|
| 233 | |
|---|
| 234 | ! --- South --- ! |
|---|
| 235 | ind1 = nn_hls + 1 + nbghostcells ! halo + land + nbghostcells |
|---|
| 236 | ind2 = nn_hls + 1 + nbghostcells + jspongearea |
|---|
| 237 | DO jj = mj0(ind1), mj1(ind2) |
|---|
| 238 | DO ji = 1, jpi |
|---|
| 239 | ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL( ind2 - mjg(jj) ) * z1_jspongearea) * zmsksouth(ji) |
|---|
| 240 | END DO |
|---|
| 241 | END DO |
|---|
| 242 | |
|---|
| 243 | ! ghost cells: |
|---|
| 244 | ind1 = 1 |
|---|
| 245 | ind2 = nn_hls + 1 + nbghostcells ! halo + land + nbghostcells |
|---|
| 246 | DO jj = mj0(ind1), mj1(ind2) |
|---|
| 247 | DO ji = 1, jpi |
|---|
| 248 | ztabramp(ji,jj) = zmsksouth(ji) |
|---|
| 249 | END DO |
|---|
| 250 | END DO |
|---|
| 251 | |
|---|
| 252 | ! --- North --- ! |
|---|
| 253 | ind1 = jpjglo - ( nn_hls + nbghostcells ) - jspongearea |
|---|
| 254 | ind2 = jpjglo - ( nn_hls + nbghostcells ) ! halo + land + nbghostcells - 1 |
|---|
| 255 | DO jj = mj0(ind1), mj1(ind2) |
|---|
| 256 | DO ji = 1, jpi |
|---|
| 257 | ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL( mjg(jj) - ind1 ) * z1_jspongearea) * zmsknorth(ji) |
|---|
| 258 | END DO |
|---|
| 259 | END DO |
|---|
| 260 | |
|---|
| 261 | ! ghost cells: |
|---|
| 262 | ind1 = jpjglo - ( nn_hls + nbghostcells ) ! halo + land + nbghostcells - 1 |
|---|
| 263 | ind2 = jpjglo |
|---|
| 264 | DO jj = mj0(ind1), mj1(ind2) |
|---|
| 265 | DO ji = 1, jpi |
|---|
| 266 | ztabramp(ji,jj) = zmsknorth(ji) |
|---|
| 267 | END DO |
|---|
| 268 | END DO |
|---|
| 269 | |
|---|
| 270 | ENDIF |
|---|
| 271 | |
|---|
| 272 | ! Tracers |
|---|
| 273 | IF( .NOT. spongedoneT ) THEN |
|---|
| 274 | fspu(:,:) = 0._wp |
|---|
| 275 | fspv(:,:) = 0._wp |
|---|
| 276 | DO_2D_00_00 |
|---|
| 277 | fspu(ji,jj) = 0.5_wp * ( ztabramp(ji,jj) + ztabramp(ji+1,jj ) ) * ssumask(ji,jj) |
|---|
| 278 | fspv(ji,jj) = 0.5_wp * ( ztabramp(ji,jj) + ztabramp(ji ,jj+1) ) * ssvmask(ji,jj) |
|---|
| 279 | END_2D |
|---|
| 280 | ENDIF |
|---|
| 281 | |
|---|
| 282 | ! Dynamics |
|---|
| 283 | IF( .NOT. spongedoneU ) THEN |
|---|
| 284 | fspt(:,:) = 0._wp |
|---|
| 285 | fspf(:,:) = 0._wp |
|---|
| 286 | DO_2D_00_00 |
|---|
| 287 | fspt(ji,jj) = ztabramp(ji,jj) * ssmask(ji,jj) |
|---|
| 288 | fspf(ji,jj) = 0.25_wp * ( ztabramp(ji ,jj ) + ztabramp(ji ,jj+1) & |
|---|
| 289 | & +ztabramp(ji+1,jj+1) + ztabramp(ji+1,jj ) ) & |
|---|
| 290 | & * ssvmask(ji,jj) * ssvmask(ji,jj+1) |
|---|
| 291 | END_2D |
|---|
| 292 | ENDIF |
|---|
| 293 | |
|---|
| 294 | IF( .NOT. spongedoneT .AND. .NOT. spongedoneU ) THEN |
|---|
| 295 | CALL lbc_lnk_multi( 'agrif_Sponge', fspu, 'U', 1., fspv, 'V', 1., fspt, 'T', 1., fspf, 'F', 1. ) |
|---|
| 296 | spongedoneT = .TRUE. |
|---|
| 297 | spongedoneU = .TRUE. |
|---|
| 298 | ENDIF |
|---|
| 299 | IF( .NOT. spongedoneT ) THEN |
|---|
| 300 | CALL lbc_lnk_multi( 'agrif_Sponge', fspu, 'U', 1., fspv, 'V', 1. ) |
|---|
| 301 | spongedoneT = .TRUE. |
|---|
| 302 | ENDIF |
|---|
| 303 | IF( .NOT. spongedoneT .AND. .NOT. spongedoneU ) THEN |
|---|
| 304 | CALL lbc_lnk_multi( 'agrif_Sponge', fspt, 'T', 1., fspf, 'F', 1. ) |
|---|
| 305 | spongedoneU = .TRUE. |
|---|
| 306 | ENDIF |
|---|
| 307 | |
|---|
| 308 | #if defined key_vertical |
|---|
| 309 | ! Remove vertical interpolation where not needed: |
|---|
| 310 | DO_2D_00_00 |
|---|
| 311 | IF ((fspu(ji-1,jj)==0._wp).AND.(fspu(ji,jj)==0._wp).AND. & |
|---|
| 312 | & (fspv(ji,jj-1)==0._wp).AND.(fspv(ji,jj)==0._wp)) mbkt_parent(ji,jj) = 0 |
|---|
| 313 | ! |
|---|
| 314 | IF ((fspt(ji+1,jj)==0._wp).AND.(fspt(ji,jj)==0._wp).AND. & |
|---|
| 315 | & (fspf(ji,jj-1)==0._wp).AND.(fspf(ji,jj)==0._wp)) mbku_parent(ji,jj) = 0 |
|---|
| 316 | ! |
|---|
| 317 | IF ((fspt(ji,jj+1)==0._wp).AND.(fspt(ji,jj)==0._wp).AND. & |
|---|
| 318 | & (fspf(ji-1,jj)==0._wp).AND.(fspf(ji,jj)==0._wp)) mbkv_parent(ji,jj) = 0 |
|---|
| 319 | ! |
|---|
| 320 | IF ( ssmask(ji,jj) == 0._wp) mbkt_parent(ji,jj) = 0 |
|---|
| 321 | IF (ssumask(ji,jj) == 0._wp) mbku_parent(ji,jj) = 0 |
|---|
| 322 | IF (ssvmask(ji,jj) == 0._wp) mbkv_parent(ji,jj) = 0 |
|---|
| 323 | END_2D |
|---|
| 324 | ! |
|---|
| 325 | ztabramp (:,:) = REAL( mbkt_parent (:,:), wp ) |
|---|
| 326 | ztabrampu(:,:) = REAL( mbku_parentu(:,:), wp ) |
|---|
| 327 | ztabrampv(:,:) = REAL( mbkv_parentv(:,:), wp ) |
|---|
| 328 | CALL lbc_lnk_multi( 'Agrif_Sponge', ztabramp, 'T', 1., ztabrampu, 'U', 1., ztabrampv, 'V', 1. ) |
|---|
| 329 | mbkt_parent(:,:) = NINT( ztabramp (:,:) ) |
|---|
| 330 | mbku_parent(:,:) = NINT( ztabrampu(:,:) ) |
|---|
| 331 | mbkv_parent(:,:) = NINT( ztabrampv(:,:) ) |
|---|
| 332 | #endif |
|---|
| 333 | ! |
|---|
| 334 | #endif |
|---|
| 335 | ! |
|---|
| 336 | END SUBROUTINE Agrif_Sponge |
|---|
| 337 | |
|---|
| 338 | SUBROUTINE interptsn_sponge( tabres, i1, i2, j1, j2, k1, k2, n1, n2, before ) |
|---|
| 339 | !!---------------------------------------------------------------------- |
|---|
| 340 | !! *** ROUTINE interptsn_sponge *** |
|---|
| 341 | !!---------------------------------------------------------------------- |
|---|
| 342 | INTEGER , INTENT(in ) :: i1, i2, j1, j2, k1, k2, n1, n2 |
|---|
| 343 | REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,n1:n2), INTENT(inout) :: tabres |
|---|
| 344 | LOGICAL , INTENT(in ) :: before |
|---|
| 345 | ! |
|---|
| 346 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 347 | INTEGER :: iku, ikv |
|---|
| 348 | REAL(wp) :: ztsa, zabe1, zabe2, zbtr, zhtot, ztrelax |
|---|
| 349 | REAL(wp), DIMENSION(i1:i2,j1:j2,jpk) :: ztu, ztv |
|---|
| 350 | REAL(wp), DIMENSION(i1:i2,j1:j2,jpk,n1:n2) ::tsbdiff |
|---|
| 351 | ! vertical interpolation: |
|---|
| 352 | REAL(wp), DIMENSION(i1:i2,j1:j2,jpk,n1:n2) ::tabres_child |
|---|
| 353 | REAL(wp), DIMENSION(k1:k2,n1:n2-1) :: tabin |
|---|
| 354 | REAL(wp), DIMENSION(k1:k2) :: h_in |
|---|
| 355 | REAL(wp), DIMENSION(1:jpk) :: h_out |
|---|
| 356 | INTEGER :: N_in, N_out |
|---|
| 357 | !!---------------------------------------------------------------------- |
|---|
| 358 | ! |
|---|
| 359 | IF( before ) THEN |
|---|
| 360 | DO jn = 1, jpts |
|---|
| 361 | DO jk=k1,k2 |
|---|
| 362 | DO jj=j1,j2 |
|---|
| 363 | DO ji=i1,i2 |
|---|
| 364 | tabres(ji,jj,jk,jn) = ts(ji,jj,jk,jn,Kbb_a) |
|---|
| 365 | END DO |
|---|
| 366 | END DO |
|---|
| 367 | END DO |
|---|
| 368 | END DO |
|---|
| 369 | |
|---|
| 370 | # if defined key_vertical |
|---|
| 371 | ! Interpolate thicknesses |
|---|
| 372 | ! Warning: these are masked, hence extrapolated prior interpolation. |
|---|
| 373 | DO jk=k1,k2 |
|---|
| 374 | DO jj=j1,j2 |
|---|
| 375 | DO ji=i1,i2 |
|---|
| 376 | tabres(ji,jj,jk,jpts+1) = tmask(ji,jj,jk) * e3t(ji,jj,jk,Kbb_a) |
|---|
| 377 | END DO |
|---|
| 378 | END DO |
|---|
| 379 | END DO |
|---|
| 380 | |
|---|
| 381 | ! Extrapolate thicknesses in partial bottom cells: |
|---|
| 382 | ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on |
|---|
| 383 | IF (ln_zps) THEN |
|---|
| 384 | DO jj=j1,j2 |
|---|
| 385 | DO ji=i1,i2 |
|---|
| 386 | jk = mbkt(ji,jj) |
|---|
| 387 | tabres(ji,jj,jk,jpts+1) = 0._wp |
|---|
| 388 | END DO |
|---|
| 389 | END DO |
|---|
| 390 | END IF |
|---|
| 391 | |
|---|
| 392 | ! Save ssh at last level: |
|---|
| 393 | IF (.NOT.ln_linssh) THEN |
|---|
| 394 | tabres(i1:i2,j1:j2,k2,jpts+1) = ssh(i1:i2,j1:j2,Kbb_a)*tmask(i1:i2,j1:j2,1) |
|---|
| 395 | ELSE |
|---|
| 396 | tabres(i1:i2,j1:j2,k2,jpts+1) = 0._wp |
|---|
| 397 | END IF |
|---|
| 398 | # endif |
|---|
| 399 | |
|---|
| 400 | ELSE |
|---|
| 401 | ! |
|---|
| 402 | # if defined key_vertical |
|---|
| 403 | |
|---|
| 404 | IF (ln_linssh) tabres(i1:i2,j1:j2,k2,n2) = 0._wp |
|---|
| 405 | |
|---|
| 406 | DO jj=j1,j2 |
|---|
| 407 | DO ji=i1,i2 |
|---|
| 408 | tabres_child(ji,jj,:,:) = 0._wp |
|---|
| 409 | N_in = mbkt_parent(ji,jj) |
|---|
| 410 | zhtot = 0._wp |
|---|
| 411 | DO jk=1,N_in !k2 = jpk of parent grid |
|---|
| 412 | IF (jk==N_in) THEN |
|---|
| 413 | h_in(jk) = ht0_parent(ji,jj) + tabres(ji,jj,k2,n2) - zhtot |
|---|
| 414 | ELSE |
|---|
| 415 | h_in(jk) = tabres(ji,jj,jk,n2) |
|---|
| 416 | ENDIF |
|---|
| 417 | zhtot = zhtot + h_in(jk) |
|---|
| 418 | tabin(jk,:) = tabres(ji,jj,jk,n1:n2-1) |
|---|
| 419 | END DO |
|---|
| 420 | N_out = 0 |
|---|
| 421 | DO jk=1,jpk ! jpk of child grid |
|---|
| 422 | IF (tmask(ji,jj,jk) == 0) EXIT |
|---|
| 423 | N_out = N_out + 1 |
|---|
| 424 | h_out(jk) = e3t(ji,jj,jk,Kbb_a) !Child grid scale factors. Could multiply by e1e2t here instead of division above |
|---|
| 425 | ENDDO |
|---|
| 426 | |
|---|
| 427 | ! Account for small differences in free-surface |
|---|
| 428 | IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN |
|---|
| 429 | h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) ) |
|---|
| 430 | ELSE |
|---|
| 431 | h_in(1) = h_in(1) - (sum(h_in(1:N_in))-sum(h_out(1:N_out)) ) |
|---|
| 432 | ENDIF |
|---|
| 433 | IF (N_in*N_out > 0) THEN |
|---|
| 434 | CALL reconstructandremap(tabin(1:N_in,1:jpts),h_in(1:N_in),tabres_child(ji,jj,1:N_out,1:jpts),h_out(1:N_out),N_in,N_out,jpts) |
|---|
| 435 | ENDIF |
|---|
| 436 | ENDDO |
|---|
| 437 | ENDDO |
|---|
| 438 | # endif |
|---|
| 439 | |
|---|
| 440 | DO jj=j1,j2 |
|---|
| 441 | DO ji=i1,i2 |
|---|
| 442 | DO jk=1,jpkm1 |
|---|
| 443 | # if defined key_vertical |
|---|
| 444 | tsbdiff(ji,jj,jk,1:jpts) = (ts(ji,jj,jk,1:jpts,Kbb_a) - tabres_child(ji,jj,jk,1:jpts)) * tmask(ji,jj,jk) |
|---|
| 445 | # else |
|---|
| 446 | tsbdiff(ji,jj,jk,1:jpts) = (ts(ji,jj,jk,1:jpts,Kbb_a) - tabres(ji,jj,jk,1:jpts))*tmask(ji,jj,jk) |
|---|
| 447 | # endif |
|---|
| 448 | ENDDO |
|---|
| 449 | ENDDO |
|---|
| 450 | ENDDO |
|---|
| 451 | |
|---|
| 452 | !* set relaxation time scale |
|---|
| 453 | IF( l_1st_euler .AND. lk_agrif_fstep ) THEN ; ztrelax = rn_trelax_tra / ( rn_Dt ) |
|---|
| 454 | ELSE ; ztrelax = rn_trelax_tra / (2._wp * rn_Dt ) |
|---|
| 455 | ENDIF |
|---|
| 456 | |
|---|
| 457 | DO jn = 1, jpts |
|---|
| 458 | DO jk = 1, jpkm1 |
|---|
| 459 | ztu(i1:i2,j1:j2,jk) = 0._wp |
|---|
| 460 | DO jj = j1,j2 |
|---|
| 461 | DO ji = i1,i2-1 |
|---|
| 462 | zabe1 = rn_sponge_tra * fspu(ji,jj) * umask(ji,jj,jk) * e2_e1u(ji,jj) * e3u(ji,jj,jk,Kmm_a) |
|---|
| 463 | ztu(ji,jj,jk) = zabe1 * ( tsbdiff(ji+1,jj ,jk,jn) - tsbdiff(ji,jj,jk,jn) ) |
|---|
| 464 | END DO |
|---|
| 465 | END DO |
|---|
| 466 | ztv(i1:i2,j1:j2,jk) = 0._wp |
|---|
| 467 | DO ji = i1,i2 |
|---|
| 468 | DO jj = j1,j2-1 |
|---|
| 469 | zabe2 = rn_sponge_tra * fspv(ji,jj) * vmask(ji,jj,jk) * e1_e2v(ji,jj) * e3v(ji,jj,jk,Kmm_a) |
|---|
| 470 | ztv(ji,jj,jk) = zabe2 * ( tsbdiff(ji ,jj+1,jk,jn) - tsbdiff(ji,jj,jk,jn) ) |
|---|
| 471 | END DO |
|---|
| 472 | END DO |
|---|
| 473 | ! |
|---|
| 474 | IF( ln_zps ) THEN ! set gradient at partial step level |
|---|
| 475 | DO jj = j1,j2 |
|---|
| 476 | DO ji = i1,i2 |
|---|
| 477 | ! last level |
|---|
| 478 | iku = mbku(ji,jj) |
|---|
| 479 | ikv = mbkv(ji,jj) |
|---|
| 480 | IF( iku == jk ) ztu(ji,jj,jk) = 0._wp |
|---|
| 481 | IF( ikv == jk ) ztv(ji,jj,jk) = 0._wp |
|---|
| 482 | END DO |
|---|
| 483 | END DO |
|---|
| 484 | ENDIF |
|---|
| 485 | END DO |
|---|
| 486 | ! |
|---|
| 487 | DO jk = 1, jpkm1 |
|---|
| 488 | DO jj = j1+1,j2-1 |
|---|
| 489 | DO ji = i1+1,i2-1 |
|---|
| 490 | IF (.NOT. tabspongedone_tsn(ji,jj)) THEN |
|---|
| 491 | zbtr = r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm_a) |
|---|
| 492 | ! horizontal diffusive trends |
|---|
| 493 | ztsa = zbtr * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) & |
|---|
| 494 | & - ztrelax * fspt(ji,jj) * tsbdiff(ji,jj,jk,jn) |
|---|
| 495 | ! add it to the general tracer trends |
|---|
| 496 | ts(ji,jj,jk,jn,Krhs_a) = ts(ji,jj,jk,jn,Krhs_a) + ztsa |
|---|
| 497 | ENDIF |
|---|
| 498 | END DO |
|---|
| 499 | END DO |
|---|
| 500 | END DO |
|---|
| 501 | ! |
|---|
| 502 | END DO |
|---|
| 503 | ! |
|---|
| 504 | tabspongedone_tsn(i1+1:i2-1,j1+1:j2-1) = .TRUE. |
|---|
| 505 | ! |
|---|
| 506 | ENDIF |
|---|
| 507 | ! |
|---|
| 508 | END SUBROUTINE interptsn_sponge |
|---|
| 509 | |
|---|
| 510 | SUBROUTINE interpun_sponge(tabres,i1,i2,j1,j2,k1,k2,m1,m2, before) |
|---|
| 511 | !!--------------------------------------------- |
|---|
| 512 | !! *** ROUTINE interpun_sponge *** |
|---|
| 513 | !!--------------------------------------------- |
|---|
| 514 | INTEGER, INTENT(in) :: i1,i2,j1,j2,k1,k2,m1,m2 |
|---|
| 515 | REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,m1:m2), INTENT(inout) :: tabres |
|---|
| 516 | LOGICAL, INTENT(in) :: before |
|---|
| 517 | |
|---|
| 518 | INTEGER :: ji,jj,jk,jmax |
|---|
| 519 | INTEGER :: ind1 |
|---|
| 520 | ! sponge parameters |
|---|
| 521 | REAL(wp) :: ze2u, ze1v, zua, zva, zbtr, zhtot, ztrelax |
|---|
| 522 | REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: ubdiff |
|---|
| 523 | REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: rotdiff, hdivdiff |
|---|
| 524 | ! vertical interpolation: |
|---|
| 525 | REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: tabres_child |
|---|
| 526 | REAL(wp), DIMENSION(k1:k2) :: tabin, h_in |
|---|
| 527 | REAL(wp), DIMENSION(1:jpk) :: h_out |
|---|
| 528 | INTEGER ::N_in, N_out |
|---|
| 529 | !!--------------------------------------------- |
|---|
| 530 | ! |
|---|
| 531 | IF( before ) THEN |
|---|
| 532 | DO jk=k1,k2 |
|---|
| 533 | DO jj=j1,j2 |
|---|
| 534 | DO ji=i1,i2 |
|---|
| 535 | tabres(ji,jj,jk,m1) = uu(ji,jj,jk,Kbb_a) |
|---|
| 536 | # if defined key_vertical |
|---|
| 537 | tabres(ji,jj,jk,m2) = e3u(ji,jj,jk,Kbb_a)*umask(ji,jj,jk) |
|---|
| 538 | # endif |
|---|
| 539 | END DO |
|---|
| 540 | END DO |
|---|
| 541 | END DO |
|---|
| 542 | |
|---|
| 543 | # if defined key_vertical |
|---|
| 544 | ! Extrapolate thicknesses in partial bottom cells: |
|---|
| 545 | ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on |
|---|
| 546 | IF (ln_zps) THEN |
|---|
| 547 | DO jj=j1,j2 |
|---|
| 548 | DO ji=i1,i2 |
|---|
| 549 | jk = mbku(ji,jj) |
|---|
| 550 | tabres(ji,jj,jk,m2) = 0._wp |
|---|
| 551 | END DO |
|---|
| 552 | END DO |
|---|
| 553 | END IF |
|---|
| 554 | ! Save ssh at last level: |
|---|
| 555 | tabres(i1:i2,j1:j2,k2,m2) = 0._wp |
|---|
| 556 | IF (.NOT.ln_linssh) THEN |
|---|
| 557 | ! This vertical sum below should be replaced by the sea-level at U-points (optimization): |
|---|
| 558 | DO jk=1,jpk |
|---|
| 559 | tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) + e3u(i1:i2,j1:j2,jk,Kbb_a) * umask(i1:i2,j1:j2,jk) |
|---|
| 560 | END DO |
|---|
| 561 | tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) - hu_0(i1:i2,j1:j2) |
|---|
| 562 | END IF |
|---|
| 563 | # endif |
|---|
| 564 | |
|---|
| 565 | ELSE |
|---|
| 566 | |
|---|
| 567 | # if defined key_vertical |
|---|
| 568 | IF (ln_linssh) tabres(i1:i2,j1:j2,k2,m2) = 0._wp |
|---|
| 569 | |
|---|
| 570 | DO jj=j1,j2 |
|---|
| 571 | DO ji=i1,i2 |
|---|
| 572 | tabres_child(ji,jj,:) = 0._wp |
|---|
| 573 | N_in = mbku_parent(ji,jj) |
|---|
| 574 | zhtot = 0._wp |
|---|
| 575 | DO jk=1,N_in |
|---|
| 576 | IF (jk==N_in) THEN |
|---|
| 577 | h_in(jk) = hu0_parent(ji,jj) + tabres(ji,jj,k2,m2) - zhtot |
|---|
| 578 | ELSE |
|---|
| 579 | h_in(jk) = tabres(ji,jj,jk,m2) |
|---|
| 580 | ENDIF |
|---|
| 581 | zhtot = zhtot + h_in(jk) |
|---|
| 582 | tabin(jk) = tabres(ji,jj,jk,m1) |
|---|
| 583 | ENDDO |
|---|
| 584 | ! |
|---|
| 585 | N_out = 0 |
|---|
| 586 | DO jk=1,jpk |
|---|
| 587 | IF (umask(ji,jj,jk) == 0) EXIT |
|---|
| 588 | N_out = N_out + 1 |
|---|
| 589 | h_out(N_out) = e3u(ji,jj,jk,Kbb_a) |
|---|
| 590 | ENDDO |
|---|
| 591 | |
|---|
| 592 | ! Account for small differences in free-surface |
|---|
| 593 | IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN |
|---|
| 594 | h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) ) |
|---|
| 595 | ELSE |
|---|
| 596 | h_in(1) = h_in(1) - (sum(h_in(1:N_in))-sum(h_out(1:N_out)) ) |
|---|
| 597 | ENDIF |
|---|
| 598 | |
|---|
| 599 | IF (N_in * N_out > 0) THEN |
|---|
| 600 | CALL reconstructandremap(tabin(1:N_in),h_in(1:N_in),tabres_child(ji,jj,1:N_out),h_out(1:N_out),N_in,N_out,1) |
|---|
| 601 | ENDIF |
|---|
| 602 | ENDDO |
|---|
| 603 | ENDDO |
|---|
| 604 | |
|---|
| 605 | ubdiff(i1:i2,j1:j2,:) = (uu(i1:i2,j1:j2,:,Kbb_a) - tabres_child(i1:i2,j1:j2,:))*umask(i1:i2,j1:j2,:) |
|---|
| 606 | #else |
|---|
| 607 | ubdiff(i1:i2,j1:j2,:) = (uu(i1:i2,j1:j2,:,Kbb_a) - tabres(i1:i2,j1:j2,:,1))*umask(i1:i2,j1:j2,:) |
|---|
| 608 | #endif |
|---|
| 609 | !* set relaxation time scale |
|---|
| 610 | IF( l_1st_euler .AND. lk_agrif_fstep ) THEN ; ztrelax = rn_trelax_dyn / ( rn_Dt ) |
|---|
| 611 | ELSE ; ztrelax = rn_trelax_dyn / (2._wp * rn_Dt ) |
|---|
| 612 | ENDIF |
|---|
| 613 | ! |
|---|
| 614 | DO jk = 1, jpkm1 ! Horizontal slab |
|---|
| 615 | ! ! =============== |
|---|
| 616 | |
|---|
| 617 | ! ! -------- |
|---|
| 618 | ! Horizontal divergence ! div |
|---|
| 619 | ! ! -------- |
|---|
| 620 | DO jj = j1,j2 |
|---|
| 621 | DO ji = i1+1,i2 ! vector opt. |
|---|
| 622 | zbtr = r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kbb_a) * rn_sponge_dyn * fspt(ji,jj) |
|---|
| 623 | hdivdiff(ji,jj,jk) = ( e2u(ji ,jj)*e3u(ji ,jj,jk,Kbb_a) * ubdiff(ji ,jj,jk) & |
|---|
| 624 | & -e2u(ji-1,jj)*e3u(ji-1,jj,jk,Kbb_a) * ubdiff(ji-1,jj,jk) ) * zbtr |
|---|
| 625 | END DO |
|---|
| 626 | END DO |
|---|
| 627 | |
|---|
| 628 | DO jj = j1,j2-1 |
|---|
| 629 | DO ji = i1,i2 ! vector opt. |
|---|
| 630 | zbtr = r1_e1e2f(ji,jj) * e3f(ji,jj,jk) * rn_sponge_dyn * fspf(ji,jj) |
|---|
| 631 | rotdiff(ji,jj,jk) = ( -e1u(ji,jj+1) * ubdiff(ji,jj+1,jk) & |
|---|
| 632 | & +e1u(ji,jj ) * ubdiff(ji,jj ,jk) ) * fmask(ji,jj,jk) * zbtr |
|---|
| 633 | END DO |
|---|
| 634 | END DO |
|---|
| 635 | END DO |
|---|
| 636 | ! |
|---|
| 637 | DO jj = j1+1, j2-1 |
|---|
| 638 | DO ji = i1+1, i2-1 ! vector opt. |
|---|
| 639 | |
|---|
| 640 | IF (.NOT. tabspongedone_u(ji,jj)) THEN |
|---|
| 641 | DO jk = 1, jpkm1 ! Horizontal slab |
|---|
| 642 | ze2u = rotdiff (ji,jj,jk) |
|---|
| 643 | ze1v = hdivdiff(ji,jj,jk) |
|---|
| 644 | ! horizontal diffusive trends |
|---|
| 645 | zua = - ( ze2u - rotdiff (ji,jj-1,jk) ) / ( e2u(ji,jj) * e3u(ji,jj,jk,Kmm_a) ) & |
|---|
| 646 | & + ( hdivdiff(ji+1,jj,jk) - ze1v ) * r1_e1u(ji,jj) & |
|---|
| 647 | & - ztrelax * fspu(ji,jj) * ubdiff(ji,jj,jk) |
|---|
| 648 | |
|---|
| 649 | ! add it to the general momentum trends |
|---|
| 650 | uu(ji,jj,jk,Krhs_a) = uu(ji,jj,jk,Krhs_a) + zua |
|---|
| 651 | END DO |
|---|
| 652 | ENDIF |
|---|
| 653 | |
|---|
| 654 | END DO |
|---|
| 655 | END DO |
|---|
| 656 | |
|---|
| 657 | tabspongedone_u(i1+1:i2-1,j1+1:j2-1) = .TRUE. |
|---|
| 658 | |
|---|
| 659 | jmax = j2-1 |
|---|
| 660 | ind1 = jpjglo - ( nn_hls + nbghostcells + 2 ) ! North |
|---|
| 661 | DO jj = mj0(ind1), mj1(ind1) |
|---|
| 662 | jmax = MIN(jmax,jj) |
|---|
| 663 | END DO |
|---|
| 664 | |
|---|
| 665 | DO jj = j1+1, jmax |
|---|
| 666 | DO ji = i1+1, i2 ! vector opt. |
|---|
| 667 | |
|---|
| 668 | IF (.NOT. tabspongedone_v(ji,jj)) THEN |
|---|
| 669 | DO jk = 1, jpkm1 ! Horizontal slab |
|---|
| 670 | ze2u = rotdiff (ji,jj,jk) |
|---|
| 671 | ze1v = hdivdiff(ji,jj,jk) |
|---|
| 672 | |
|---|
| 673 | ! horizontal diffusive trends |
|---|
| 674 | zva = + ( ze2u - rotdiff (ji-1,jj,jk) ) / ( e1v(ji,jj) * e3v(ji,jj,jk,Kmm_a) ) & |
|---|
| 675 | + ( hdivdiff(ji,jj+1,jk) - ze1v ) * r1_e2v(ji,jj) |
|---|
| 676 | |
|---|
| 677 | ! add it to the general momentum trends |
|---|
| 678 | vv(ji,jj,jk,Krhs_a) = vv(ji,jj,jk,Krhs_a) + zva |
|---|
| 679 | END DO |
|---|
| 680 | ENDIF |
|---|
| 681 | ! |
|---|
| 682 | END DO |
|---|
| 683 | END DO |
|---|
| 684 | ! |
|---|
| 685 | tabspongedone_v(i1+1:i2,j1+1:jmax) = .TRUE. |
|---|
| 686 | ! |
|---|
| 687 | ENDIF |
|---|
| 688 | ! |
|---|
| 689 | END SUBROUTINE interpun_sponge |
|---|
| 690 | |
|---|
| 691 | SUBROUTINE interpvn_sponge(tabres,i1,i2,j1,j2,k1,k2,m1,m2, before,nb,ndir) |
|---|
| 692 | !!--------------------------------------------- |
|---|
| 693 | !! *** ROUTINE interpvn_sponge *** |
|---|
| 694 | !!--------------------------------------------- |
|---|
| 695 | INTEGER, INTENT(in) :: i1,i2,j1,j2,k1,k2,m1,m2 |
|---|
| 696 | REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,m1:m2), INTENT(inout) :: tabres |
|---|
| 697 | LOGICAL, INTENT(in) :: before |
|---|
| 698 | INTEGER, INTENT(in) :: nb , ndir |
|---|
| 699 | ! |
|---|
| 700 | INTEGER :: ji, jj, jk, imax |
|---|
| 701 | INTEGER :: ind1 |
|---|
| 702 | ! sponge parameters |
|---|
| 703 | REAL(wp) :: ze2u, ze1v, zua, zva, zbtr, zhtot, ztrelax |
|---|
| 704 | REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: vbdiff |
|---|
| 705 | REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: rotdiff, hdivdiff |
|---|
| 706 | ! vertical interpolation: |
|---|
| 707 | REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: tabres_child |
|---|
| 708 | REAL(wp), DIMENSION(k1:k2) :: tabin, h_in |
|---|
| 709 | REAL(wp), DIMENSION(1:jpk) :: h_out |
|---|
| 710 | INTEGER :: N_in, N_out |
|---|
| 711 | !!--------------------------------------------- |
|---|
| 712 | |
|---|
| 713 | IF( before ) THEN |
|---|
| 714 | DO jk=k1,k2 |
|---|
| 715 | DO jj=j1,j2 |
|---|
| 716 | DO ji=i1,i2 |
|---|
| 717 | tabres(ji,jj,jk,m1) = vv(ji,jj,jk,Kbb_a) |
|---|
| 718 | # if defined key_vertical |
|---|
| 719 | tabres(ji,jj,jk,m2) = vmask(ji,jj,jk) * e3v(ji,jj,jk,Kbb_a) |
|---|
| 720 | # endif |
|---|
| 721 | END DO |
|---|
| 722 | END DO |
|---|
| 723 | END DO |
|---|
| 724 | |
|---|
| 725 | # if defined key_vertical |
|---|
| 726 | ! Extrapolate thicknesses in partial bottom cells: |
|---|
| 727 | ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on |
|---|
| 728 | IF (ln_zps) THEN |
|---|
| 729 | DO jj=j1,j2 |
|---|
| 730 | DO ji=i1,i2 |
|---|
| 731 | jk = mbkv(ji,jj) |
|---|
| 732 | tabres(ji,jj,jk,m2) = 0._wp |
|---|
| 733 | END DO |
|---|
| 734 | END DO |
|---|
| 735 | END IF |
|---|
| 736 | ! Save ssh at last level: |
|---|
| 737 | tabres(i1:i2,j1:j2,k2,m2) = 0._wp |
|---|
| 738 | IF (.NOT.ln_linssh) THEN |
|---|
| 739 | ! This vertical sum below should be replaced by the sea-level at V-points (optimization): |
|---|
| 740 | DO jk=1,jpk |
|---|
| 741 | tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) + e3v(i1:i2,j1:j2,jk,Kbb_a) * vmask(i1:i2,j1:j2,jk) |
|---|
| 742 | END DO |
|---|
| 743 | tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) - hv_0(i1:i2,j1:j2) |
|---|
| 744 | END IF |
|---|
| 745 | # endif |
|---|
| 746 | |
|---|
| 747 | ELSE |
|---|
| 748 | |
|---|
| 749 | # if defined key_vertical |
|---|
| 750 | IF (ln_linssh) tabres(i1:i2,j1:j2,k2,m2) = 0._wp |
|---|
| 751 | DO jj=j1,j2 |
|---|
| 752 | DO ji=i1,i2 |
|---|
| 753 | tabres_child(ji,jj,:) = 0._wp |
|---|
| 754 | N_in = mbkv_parent(ji,jj) |
|---|
| 755 | zhtot = 0._wp |
|---|
| 756 | DO jk=1,N_in |
|---|
| 757 | IF (jk==N_in) THEN |
|---|
| 758 | h_in(jk) = hv0_parent(ji,jj) + tabres(ji,jj,k2,m2) - zhtot |
|---|
| 759 | ELSE |
|---|
| 760 | h_in(jk) = tabres(ji,jj,jk,m2) |
|---|
| 761 | ENDIF |
|---|
| 762 | zhtot = zhtot + h_in(jk) |
|---|
| 763 | tabin(jk) = tabres(ji,jj,jk,m1) |
|---|
| 764 | ENDDO |
|---|
| 765 | ! |
|---|
| 766 | N_out = 0 |
|---|
| 767 | DO jk=1,jpk |
|---|
| 768 | IF (vmask(ji,jj,jk) == 0) EXIT |
|---|
| 769 | N_out = N_out + 1 |
|---|
| 770 | h_out(N_out) = e3v(ji,jj,jk,Kbb_a) |
|---|
| 771 | ENDDO |
|---|
| 772 | |
|---|
| 773 | ! Account for small differences in free-surface |
|---|
| 774 | IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN |
|---|
| 775 | h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) ) |
|---|
| 776 | ELSE |
|---|
| 777 | h_in(1) = h_in(1) - ( sum(h_in(1:N_in))-sum(h_out(1:N_out)) ) |
|---|
| 778 | ENDIF |
|---|
| 779 | |
|---|
| 780 | IF (N_in * N_out > 0) THEN |
|---|
| 781 | CALL reconstructandremap(tabin(1:N_in),h_in(1:N_in),tabres_child(ji,jj,1:N_out),h_out(1:N_out),N_in,N_out,1) |
|---|
| 782 | ENDIF |
|---|
| 783 | ENDDO |
|---|
| 784 | ENDDO |
|---|
| 785 | |
|---|
| 786 | vbdiff(i1:i2,j1:j2,:) = (vv(i1:i2,j1:j2,:,Kbb_a) - tabres_child(i1:i2,j1:j2,:))*vmask(i1:i2,j1:j2,:) |
|---|
| 787 | # else |
|---|
| 788 | vbdiff(i1:i2,j1:j2,:) = (vv(i1:i2,j1:j2,:,Kbb_a) - tabres(i1:i2,j1:j2,:,1))*vmask(i1:i2,j1:j2,:) |
|---|
| 789 | # endif |
|---|
| 790 | !* set relaxation time scale |
|---|
| 791 | IF( l_1st_euler .AND. lk_agrif_fstep ) THEN ; ztrelax = rn_trelax_dyn / ( rn_Dt ) |
|---|
| 792 | ELSE ; ztrelax = rn_trelax_dyn / (2._wp * rn_Dt ) |
|---|
| 793 | ENDIF |
|---|
| 794 | ! |
|---|
| 795 | DO jk = 1, jpkm1 ! Horizontal slab |
|---|
| 796 | ! ! =============== |
|---|
| 797 | |
|---|
| 798 | ! ! -------- |
|---|
| 799 | ! Horizontal divergence ! div |
|---|
| 800 | ! ! -------- |
|---|
| 801 | DO jj = j1+1,j2 |
|---|
| 802 | DO ji = i1,i2 ! vector opt. |
|---|
| 803 | zbtr = r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kbb_a) * rn_sponge_dyn * fspt(ji,jj) |
|---|
| 804 | hdivdiff(ji,jj,jk) = ( e1v(ji,jj ) * e3v(ji,jj ,jk,Kbb_a) * vbdiff(ji,jj ,jk) & |
|---|
| 805 | & -e1v(ji,jj-1) * e3v(ji,jj-1,jk,Kbb_a) * vbdiff(ji,jj-1,jk) ) * zbtr |
|---|
| 806 | END DO |
|---|
| 807 | END DO |
|---|
| 808 | DO jj = j1,j2 |
|---|
| 809 | DO ji = i1,i2-1 ! vector opt. |
|---|
| 810 | zbtr = r1_e1e2f(ji,jj) * e3f(ji,jj,jk) * rn_sponge_dyn * fspf(ji,jj) |
|---|
| 811 | rotdiff(ji,jj,jk) = ( e2v(ji+1,jj) * vbdiff(ji+1,jj,jk) & |
|---|
| 812 | & -e2v(ji ,jj) * vbdiff(ji ,jj,jk) ) * fmask(ji,jj,jk) * zbtr |
|---|
| 813 | END DO |
|---|
| 814 | END DO |
|---|
| 815 | END DO |
|---|
| 816 | |
|---|
| 817 | ! ! =============== |
|---|
| 818 | ! |
|---|
| 819 | |
|---|
| 820 | imax = i2 - 1 |
|---|
| 821 | ind1 = jpiglo - ( nn_hls + nbghostcells + 2 ) ! East |
|---|
| 822 | DO ji = mi0(ind1), mi1(ind1) |
|---|
| 823 | imax = MIN(imax,ji) |
|---|
| 824 | END DO |
|---|
| 825 | |
|---|
| 826 | DO jj = j1+1, j2 |
|---|
| 827 | DO ji = i1+1, imax ! vector opt. |
|---|
| 828 | IF( .NOT. tabspongedone_u(ji,jj) ) THEN |
|---|
| 829 | DO jk = 1, jpkm1 |
|---|
| 830 | uu(ji,jj,jk,Krhs_a) = uu(ji,jj,jk,Krhs_a) & |
|---|
| 831 | & - ( rotdiff (ji ,jj,jk) - rotdiff (ji,jj-1,jk)) / ( e2u(ji,jj) * e3u(ji,jj,jk,Kmm_a) ) & |
|---|
| 832 | & + ( hdivdiff(ji+1,jj,jk) - hdivdiff(ji,jj ,jk)) * r1_e1u(ji,jj) |
|---|
| 833 | END DO |
|---|
| 834 | ENDIF |
|---|
| 835 | END DO |
|---|
| 836 | END DO |
|---|
| 837 | ! |
|---|
| 838 | tabspongedone_u(i1+1:imax,j1+1:j2) = .TRUE. |
|---|
| 839 | ! |
|---|
| 840 | DO jj = j1+1, j2-1 |
|---|
| 841 | DO ji = i1+1, i2-1 ! vector opt. |
|---|
| 842 | IF( .NOT. tabspongedone_v(ji,jj) ) THEN |
|---|
| 843 | DO jk = 1, jpkm1 |
|---|
| 844 | vv(ji,jj,jk,Krhs_a) = vv(ji,jj,jk,Krhs_a) & |
|---|
| 845 | & + ( rotdiff (ji,jj ,jk) - rotdiff (ji-1,jj,jk) ) / ( e1v(ji,jj) * e3v(ji,jj,jk,Kmm_a) ) & |
|---|
| 846 | & + ( hdivdiff(ji,jj+1,jk) - hdivdiff(ji ,jj,jk) ) * r1_e2v(ji,jj) & |
|---|
| 847 | & - ztrelax * fspv(ji,jj) * vbdiff(ji,jj,jk) |
|---|
| 848 | END DO |
|---|
| 849 | ENDIF |
|---|
| 850 | END DO |
|---|
| 851 | END DO |
|---|
| 852 | tabspongedone_v(i1+1:i2-1,j1+1:j2-1) = .TRUE. |
|---|
| 853 | ENDIF |
|---|
| 854 | ! |
|---|
| 855 | END SUBROUTINE interpvn_sponge |
|---|
| 856 | |
|---|
| 857 | #else |
|---|
| 858 | !!---------------------------------------------------------------------- |
|---|
| 859 | !! Empty module no AGRIF zoom |
|---|
| 860 | !!---------------------------------------------------------------------- |
|---|
| 861 | CONTAINS |
|---|
| 862 | SUBROUTINE agrif_oce_sponge_empty |
|---|
| 863 | WRITE(*,*) 'agrif_oce_sponge : You should not have seen this print! error?' |
|---|
| 864 | END SUBROUTINE agrif_oce_sponge_empty |
|---|
| 865 | #endif |
|---|
| 866 | |
|---|
| 867 | !!====================================================================== |
|---|
| 868 | END MODULE agrif_oce_sponge |
|---|
