| 1 | #define SPONGE && define SPONGE_TOP |
|---|
| 2 | |
|---|
| 3 | MODULE agrif_oce_sponge |
|---|
| 4 | !!====================================================================== |
|---|
| 5 | !! *** MODULE agrif_oce_interp *** |
|---|
| 6 | !! AGRIF: sponge package for the ocean dynamics (OPA) |
|---|
| 7 | !!====================================================================== |
|---|
| 8 | !! History : 2.0 ! 2002-06 (XXX) Original cade |
|---|
| 9 | !! - ! 2005-11 (XXX) |
|---|
| 10 | !! 3.2 ! 2009-04 (R. Benshila) |
|---|
| 11 | !! 3.6 ! 2014-09 (R. Benshila) |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | #if defined key_agrif |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! 'key_agrif' AGRIF zoom |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE par_oce |
|---|
| 18 | USE oce |
|---|
| 19 | USE dom_oce |
|---|
| 20 | ! |
|---|
| 21 | USE in_out_manager |
|---|
| 22 | USE agrif_oce |
|---|
| 23 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 24 | USE iom |
|---|
| 25 | USE vremap |
|---|
| 26 | |
|---|
| 27 | IMPLICIT NONE |
|---|
| 28 | PRIVATE |
|---|
| 29 | |
|---|
| 30 | PUBLIC Agrif_Sponge, Agrif_Sponge_Tra, Agrif_Sponge_Dyn |
|---|
| 31 | PUBLIC interptsn_sponge, interpun_sponge, interpvn_sponge |
|---|
| 32 | |
|---|
| 33 | !! * Substitutions |
|---|
| 34 | # include "do_loop_substitute.h90" |
|---|
| 35 | !!---------------------------------------------------------------------- |
|---|
| 36 | !! NEMO/NST 4.0 , NEMO Consortium (2018) |
|---|
| 37 | !! $Id$ |
|---|
| 38 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 39 | !!---------------------------------------------------------------------- |
|---|
| 40 | CONTAINS |
|---|
| 41 | |
|---|
| 42 | SUBROUTINE Agrif_Sponge_Tra |
|---|
| 43 | !!---------------------------------------------------------------------- |
|---|
| 44 | !! *** ROUTINE Agrif_Sponge_Tra *** |
|---|
| 45 | !!---------------------------------------------------------------------- |
|---|
| 46 | REAL(wp) :: zcoef ! local scalar |
|---|
| 47 | |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | ! |
|---|
| 50 | #if defined SPONGE |
|---|
| 51 | !! Assume persistence: |
|---|
| 52 | zcoef = REAL(Agrif_rhot()-1,wp)/REAL(Agrif_rhot()) |
|---|
| 53 | |
|---|
| 54 | CALL Agrif_Sponge |
|---|
| 55 | Agrif_SpecialValue = 0._wp |
|---|
| 56 | Agrif_UseSpecialValue = .TRUE. |
|---|
| 57 | tabspongedone_tsn = .FALSE. |
|---|
| 58 | ! |
|---|
| 59 | CALL Agrif_Bc_Variable( tsn_sponge_id, calledweight=zcoef, procname=interptsn_sponge ) |
|---|
| 60 | ! |
|---|
| 61 | Agrif_UseSpecialValue = .FALSE. |
|---|
| 62 | #endif |
|---|
| 63 | ! |
|---|
| 64 | CALL iom_put( 'agrif_spu', fspu(:,:)) |
|---|
| 65 | CALL iom_put( 'agrif_spv', fspv(:,:)) |
|---|
| 66 | ! |
|---|
| 67 | END SUBROUTINE Agrif_Sponge_Tra |
|---|
| 68 | |
|---|
| 69 | |
|---|
| 70 | SUBROUTINE Agrif_Sponge_dyn |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | !! *** ROUTINE Agrif_Sponge_dyn *** |
|---|
| 73 | !!---------------------------------------------------------------------- |
|---|
| 74 | REAL(wp) :: zcoef ! local scalar |
|---|
| 75 | !!---------------------------------------------------------------------- |
|---|
| 76 | ! |
|---|
| 77 | #if defined SPONGE |
|---|
| 78 | zcoef = REAL(Agrif_rhot()-1,wp)/REAL(Agrif_rhot()) |
|---|
| 79 | |
|---|
| 80 | Agrif_SpecialValue=0. |
|---|
| 81 | Agrif_UseSpecialValue = ln_spc_dyn |
|---|
| 82 | use_sign_north = .TRUE. |
|---|
| 83 | sign_north = -1. |
|---|
| 84 | ! |
|---|
| 85 | tabspongedone_u = .FALSE. |
|---|
| 86 | tabspongedone_v = .FALSE. |
|---|
| 87 | CALL Agrif_Bc_Variable( un_sponge_id, calledweight=zcoef, procname=interpun_sponge ) |
|---|
| 88 | ! |
|---|
| 89 | tabspongedone_u = .FALSE. |
|---|
| 90 | tabspongedone_v = .FALSE. |
|---|
| 91 | CALL Agrif_Bc_Variable( vn_sponge_id, calledweight=zcoef, procname=interpvn_sponge ) |
|---|
| 92 | ! |
|---|
| 93 | Agrif_UseSpecialValue = .FALSE. |
|---|
| 94 | use_sign_north = .FALSE. |
|---|
| 95 | #endif |
|---|
| 96 | ! |
|---|
| 97 | CALL iom_put( 'agrif_spt', fspt(:,:)) |
|---|
| 98 | CALL iom_put( 'agrif_spf', fspf(:,:)) |
|---|
| 99 | ! |
|---|
| 100 | END SUBROUTINE Agrif_Sponge_dyn |
|---|
| 101 | |
|---|
| 102 | |
|---|
| 103 | SUBROUTINE Agrif_Sponge |
|---|
| 104 | !!---------------------------------------------------------------------- |
|---|
| 105 | !! *** ROUTINE Agrif_Sponge *** |
|---|
| 106 | !!---------------------------------------------------------------------- |
|---|
| 107 | INTEGER :: ji, jj, ind1, ind2 |
|---|
| 108 | INTEGER :: ispongearea, jspongearea |
|---|
| 109 | REAL(wp) :: z1_ispongearea, z1_jspongearea |
|---|
| 110 | REAL(wp), DIMENSION(jpi,jpj) :: ztabramp |
|---|
| 111 | REAL(wp), DIMENSION(jpjmax) :: zmskwest, zmskeast |
|---|
| 112 | REAL(wp), DIMENSION(jpimax) :: zmsknorth, zmsksouth |
|---|
| 113 | !!---------------------------------------------------------------------- |
|---|
| 114 | ! |
|---|
| 115 | ! Sponge 1d example with: |
|---|
| 116 | ! iraf = 3 ; nbghost = 3 ; nn_sponge_len = 2 |
|---|
| 117 | ! |
|---|
| 118 | !coarse : U T U T U T U |
|---|
| 119 | !| | | | | |
|---|
| 120 | !fine : t u t u t u t u t u t u t u t u t u t u t |
|---|
| 121 | !sponge val:0 0 0 1 5/6 4/6 3/6 2/6 1/6 0 0 |
|---|
| 122 | ! | ghost | <-- sponge area -- > | |
|---|
| 123 | ! | points | | |
|---|
| 124 | ! |--> dynamical interface |
|---|
| 125 | |
|---|
| 126 | #if defined SPONGE || defined SPONGE_TOP |
|---|
| 127 | IF (( .NOT. spongedoneT ).OR.( .NOT. spongedoneU )) THEN |
|---|
| 128 | ! |
|---|
| 129 | ! Retrieve masks at open boundaries: |
|---|
| 130 | |
|---|
| 131 | ! --- West --- ! |
|---|
| 132 | IF( lk_west) THEN |
|---|
| 133 | ztabramp(:,:) = 0._wp |
|---|
| 134 | ind1 = nn_hls + 1 + nbghostcells ! halo + land + nbghostcells |
|---|
| 135 | DO ji = mi0(ind1), mi1(ind1) |
|---|
| 136 | ztabramp(ji,:) = ssumask(ji,:) |
|---|
| 137 | END DO |
|---|
| 138 | zmskwest( 1:jpj ) = MAXVAL(ztabramp(:,:), dim=1) |
|---|
| 139 | zmskwest(jpj+1:jpjmax) = 0._wp |
|---|
| 140 | ENDIF |
|---|
| 141 | |
|---|
| 142 | ! --- East --- ! |
|---|
| 143 | IF( lk_east ) THEN |
|---|
| 144 | ztabramp(:,:) = 0._wp |
|---|
| 145 | ind1 = jpiglo - ( nn_hls + nbghostcells + 1) ! halo + land + nbghostcells |
|---|
| 146 | DO ji = mi0(ind1), mi1(ind1) |
|---|
| 147 | ztabramp(ji,:) = ssumask(ji,:) |
|---|
| 148 | END DO |
|---|
| 149 | zmskeast( 1:jpj ) = MAXVAL(ztabramp(:,:), dim=1) |
|---|
| 150 | zmskeast(jpj+1:jpjmax) = 0._wp |
|---|
| 151 | ENDIF |
|---|
| 152 | |
|---|
| 153 | ! --- South --- ! |
|---|
| 154 | IF( lk_south ) THEN |
|---|
| 155 | ztabramp(:,:) = 0._wp |
|---|
| 156 | ind1 = nn_hls + 1 + nbghostcells ! halo + land + nbghostcells |
|---|
| 157 | DO jj = mj0(ind1), mj1(ind1) |
|---|
| 158 | ztabramp(:,jj) = ssvmask(:,jj) |
|---|
| 159 | END DO |
|---|
| 160 | zmsksouth( 1:jpi ) = MAXVAL(ztabramp(:,:), dim=2) |
|---|
| 161 | zmsksouth(jpi+1:jpimax) = 0._wp |
|---|
| 162 | ENDIF |
|---|
| 163 | |
|---|
| 164 | ! --- North --- ! |
|---|
| 165 | IF( lk_north) THEN |
|---|
| 166 | ztabramp(:,:) = 0._wp |
|---|
| 167 | ind1 = jpjglo - ( nn_hls + nbghostcells + 1) ! halo + land + nbghostcells |
|---|
| 168 | DO jj = mj0(ind1), mj1(ind1) |
|---|
| 169 | ztabramp(:,jj) = ssvmask(:,jj) |
|---|
| 170 | END DO |
|---|
| 171 | zmsknorth( 1:jpi ) = MAXVAL(ztabramp(:,:), dim=2) |
|---|
| 172 | zmsknorth(jpi+1:jpimax) = 0._wp |
|---|
| 173 | ENDIF |
|---|
| 174 | |
|---|
| 175 | ! JC: SPONGE MASKING TO BE SORTED OUT: |
|---|
| 176 | zmskwest(:) = 1._wp |
|---|
| 177 | zmskeast(:) = 1._wp |
|---|
| 178 | zmsksouth(:) = 1._wp |
|---|
| 179 | zmsknorth(:) = 1._wp |
|---|
| 180 | #if defined key_mpp_mpi |
|---|
| 181 | ! CALL mpp_max( 'AGRIF_sponge', zmskwest(:) , jpjmax ) |
|---|
| 182 | ! CALL mpp_max( 'AGRIF_Sponge', zmskeast(:) , jpjmax ) |
|---|
| 183 | ! CALL mpp_max( 'AGRIF_Sponge', zmsksouth(:), jpimax ) |
|---|
| 184 | ! CALL mpp_max( 'AGRIF_Sponge', zmsknorth(:), jpimax ) |
|---|
| 185 | #endif |
|---|
| 186 | |
|---|
| 187 | ! Define ramp from boundaries towards domain interior at T-points |
|---|
| 188 | ! Store it in ztabramp |
|---|
| 189 | |
|---|
| 190 | ispongearea = nn_sponge_len * Agrif_irhox() |
|---|
| 191 | z1_ispongearea = 1._wp / REAL( ispongearea ) |
|---|
| 192 | jspongearea = nn_sponge_len * Agrif_irhoy() |
|---|
| 193 | z1_jspongearea = 1._wp / REAL( jspongearea ) |
|---|
| 194 | |
|---|
| 195 | ztabramp(:,:) = 0._wp |
|---|
| 196 | |
|---|
| 197 | ! Trick to remove sponge in 2DV domains: |
|---|
| 198 | IF ( nbcellsx <= 3 ) ispongearea = -1 |
|---|
| 199 | IF ( nbcellsy <= 3 ) jspongearea = -1 |
|---|
| 200 | |
|---|
| 201 | ! --- West --- ! |
|---|
| 202 | IF(lk_west) THEN |
|---|
| 203 | ind1 = nn_hls + 1 + nbghostcells ! halo + land + nbghostcells |
|---|
| 204 | ind2 = nn_hls + 1 + nbghostcells + ispongearea |
|---|
| 205 | DO ji = mi0(ind1), mi1(ind2) |
|---|
| 206 | DO jj = 1, jpj |
|---|
| 207 | ztabramp(ji,jj) = REAL( ind2 - mig(ji) ) * z1_ispongearea * zmskwest(jj) |
|---|
| 208 | END DO |
|---|
| 209 | END DO |
|---|
| 210 | ! ghost cells: |
|---|
| 211 | ind1 = 1 |
|---|
| 212 | ind2 = nn_hls + 1 + nbghostcells ! halo + land + nbghostcells |
|---|
| 213 | DO ji = mi0(ind1), mi1(ind2) |
|---|
| 214 | DO jj = 1, jpj |
|---|
| 215 | ztabramp(ji,jj) = zmskwest(jj) |
|---|
| 216 | END DO |
|---|
| 217 | END DO |
|---|
| 218 | ENDIF |
|---|
| 219 | |
|---|
| 220 | ! --- East --- ! |
|---|
| 221 | IF(lk_east) THEN |
|---|
| 222 | ind1 = jpiglo - ( nn_hls + nbghostcells ) - ispongearea |
|---|
| 223 | ind2 = jpiglo - ( nn_hls + nbghostcells ) ! halo + land + nbghostcells - 1 |
|---|
| 224 | DO ji = mi0(ind1), mi1(ind2) |
|---|
| 225 | DO jj = 1, jpj |
|---|
| 226 | ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL( mig(ji) - ind1 ) * z1_ispongearea) * zmskeast(jj) |
|---|
| 227 | END DO |
|---|
| 228 | END DO |
|---|
| 229 | ! ghost cells: |
|---|
| 230 | ind1 = jpiglo - ( nn_hls + nbghostcells ) ! halo + land + nbghostcells - 1 |
|---|
| 231 | ind2 = jpiglo |
|---|
| 232 | DO ji = mi0(ind1), mi1(ind2) |
|---|
| 233 | DO jj = 1, jpj |
|---|
| 234 | ztabramp(ji,jj) = zmskeast(jj) |
|---|
| 235 | END DO |
|---|
| 236 | END DO |
|---|
| 237 | ENDIF |
|---|
| 238 | |
|---|
| 239 | ! --- South --- ! |
|---|
| 240 | IF( lk_south ) THEN |
|---|
| 241 | ind1 = nn_hls + 1 + nbghostcells ! halo + land + nbghostcells |
|---|
| 242 | ind2 = nn_hls + 1 + nbghostcells + jspongearea |
|---|
| 243 | DO jj = mj0(ind1), mj1(ind2) |
|---|
| 244 | DO ji = 1, jpi |
|---|
| 245 | ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL( ind2 - mjg(jj) ) * z1_jspongearea) * zmsksouth(ji) |
|---|
| 246 | END DO |
|---|
| 247 | END DO |
|---|
| 248 | ! ghost cells: |
|---|
| 249 | ind1 = 1 |
|---|
| 250 | ind2 = nn_hls + 1 + nbghostcells ! halo + land + nbghostcells |
|---|
| 251 | DO jj = mj0(ind1), mj1(ind2) |
|---|
| 252 | DO ji = 1, jpi |
|---|
| 253 | ztabramp(ji,jj) = zmsksouth(ji) |
|---|
| 254 | END DO |
|---|
| 255 | END DO |
|---|
| 256 | ENDIF |
|---|
| 257 | |
|---|
| 258 | ! --- North --- ! |
|---|
| 259 | IF( lk_north ) THEN |
|---|
| 260 | ind1 = jpjglo - ( nn_hls + nbghostcells ) - jspongearea |
|---|
| 261 | ind2 = jpjglo - ( nn_hls + nbghostcells ) ! halo + land + nbghostcells - 1 |
|---|
| 262 | DO jj = mj0(ind1), mj1(ind2) |
|---|
| 263 | DO ji = 1, jpi |
|---|
| 264 | ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL( mjg(jj) - ind1 ) * z1_jspongearea) * zmsknorth(ji) |
|---|
| 265 | END DO |
|---|
| 266 | END DO |
|---|
| 267 | ! ghost cells: |
|---|
| 268 | ind1 = jpjglo - ( nn_hls + nbghostcells ) ! halo + land + nbghostcells - 1 |
|---|
| 269 | ind2 = jpjglo |
|---|
| 270 | DO jj = mj0(ind1), mj1(ind2) |
|---|
| 271 | DO ji = 1, jpi |
|---|
| 272 | ztabramp(ji,jj) = zmsknorth(ji) |
|---|
| 273 | END DO |
|---|
| 274 | END DO |
|---|
| 275 | ENDIF |
|---|
| 276 | ! |
|---|
| 277 | ENDIF |
|---|
| 278 | |
|---|
| 279 | ! Tracers |
|---|
| 280 | IF( .NOT. spongedoneT ) THEN |
|---|
| 281 | fspu(:,:) = 0._wp |
|---|
| 282 | fspv(:,:) = 0._wp |
|---|
| 283 | DO_2D_00_00 |
|---|
| 284 | fspu(ji,jj) = 0.5_wp * ( ztabramp(ji,jj) + ztabramp(ji+1,jj ) ) * ssumask(ji,jj) |
|---|
| 285 | fspv(ji,jj) = 0.5_wp * ( ztabramp(ji,jj) + ztabramp(ji ,jj+1) ) * ssvmask(ji,jj) |
|---|
| 286 | END_2D |
|---|
| 287 | ENDIF |
|---|
| 288 | |
|---|
| 289 | ! Dynamics |
|---|
| 290 | IF( .NOT. spongedoneU ) THEN |
|---|
| 291 | fspt(:,:) = 0._wp |
|---|
| 292 | fspf(:,:) = 0._wp |
|---|
| 293 | DO_2D_00_00 |
|---|
| 294 | fspt(ji,jj) = ztabramp(ji,jj) * ssmask(ji,jj) |
|---|
| 295 | fspf(ji,jj) = 0.25_wp * ( ztabramp(ji ,jj ) + ztabramp(ji ,jj+1) & |
|---|
| 296 | & +ztabramp(ji+1,jj+1) + ztabramp(ji+1,jj ) ) & |
|---|
| 297 | & * ssvmask(ji,jj) * ssvmask(ji,jj+1) |
|---|
| 298 | END_2D |
|---|
| 299 | ENDIF |
|---|
| 300 | |
|---|
| 301 | IF( .NOT. spongedoneT .AND. .NOT. spongedoneU ) THEN |
|---|
| 302 | CALL lbc_lnk_multi( 'agrif_Sponge', fspu, 'U', 1._wp, fspv, 'V', 1._wp, fspt, 'T', 1._wp, fspf, 'F', 1._wp ) |
|---|
| 303 | spongedoneT = .TRUE. |
|---|
| 304 | spongedoneU = .TRUE. |
|---|
| 305 | ENDIF |
|---|
| 306 | IF( .NOT. spongedoneT ) THEN |
|---|
| 307 | CALL lbc_lnk_multi( 'agrif_Sponge', fspu, 'U', 1._wp, fspv, 'V', 1._wp ) |
|---|
| 308 | spongedoneT = .TRUE. |
|---|
| 309 | ENDIF |
|---|
| 310 | IF( .NOT. spongedoneT .AND. .NOT. spongedoneU ) THEN |
|---|
| 311 | CALL lbc_lnk_multi( 'agrif_Sponge', fspt, 'T', 1._wp, fspf, 'F', 1._wp ) |
|---|
| 312 | spongedoneU = .TRUE. |
|---|
| 313 | ENDIF |
|---|
| 314 | |
|---|
| 315 | #if defined key_vertical |
|---|
| 316 | ! Remove vertical interpolation where not needed: |
|---|
| 317 | DO_2D_00_00 |
|---|
| 318 | IF ((fspu(ji-1,jj)==0._wp).AND.(fspu(ji,jj)==0._wp).AND. & |
|---|
| 319 | & (fspv(ji,jj-1)==0._wp).AND.(fspv(ji,jj)==0._wp)) mbkt_parent(ji,jj) = 0 |
|---|
| 320 | ! |
|---|
| 321 | IF ((fspt(ji+1,jj)==0._wp).AND.(fspt(ji,jj)==0._wp).AND. & |
|---|
| 322 | & (fspf(ji,jj-1)==0._wp).AND.(fspf(ji,jj)==0._wp)) mbku_parent(ji,jj) = 0 |
|---|
| 323 | ! |
|---|
| 324 | IF ((fspt(ji,jj+1)==0._wp).AND.(fspt(ji,jj)==0._wp).AND. & |
|---|
| 325 | & (fspf(ji-1,jj)==0._wp).AND.(fspf(ji,jj)==0._wp)) mbkv_parent(ji,jj) = 0 |
|---|
| 326 | ! |
|---|
| 327 | IF ( ssmask(ji,jj) == 0._wp) mbkt_parent(ji,jj) = 0 |
|---|
| 328 | IF (ssumask(ji,jj) == 0._wp) mbku_parent(ji,jj) = 0 |
|---|
| 329 | IF (ssvmask(ji,jj) == 0._wp) mbkv_parent(ji,jj) = 0 |
|---|
| 330 | END_2D |
|---|
| 331 | ! |
|---|
| 332 | ztabramp (:,:) = REAL( mbkt_parent (:,:), wp ) |
|---|
| 333 | ztabrampu(:,:) = REAL( mbku_parentu(:,:), wp ) |
|---|
| 334 | ztabrampv(:,:) = REAL( mbkv_parentv(:,:), wp ) |
|---|
| 335 | CALL lbc_lnk_multi( 'Agrif_Sponge', ztabramp, 'T', 1., ztabrampu, 'U', 1., ztabrampv, 'V', 1. ) |
|---|
| 336 | mbkt_parent(:,:) = NINT( ztabramp (:,:) ) |
|---|
| 337 | mbku_parent(:,:) = NINT( ztabrampu(:,:) ) |
|---|
| 338 | mbkv_parent(:,:) = NINT( ztabrampv(:,:) ) |
|---|
| 339 | #endif |
|---|
| 340 | ! |
|---|
| 341 | #endif |
|---|
| 342 | ! |
|---|
| 343 | END SUBROUTINE Agrif_Sponge |
|---|
| 344 | |
|---|
| 345 | |
|---|
| 346 | SUBROUTINE interptsn_sponge( tabres, i1, i2, j1, j2, k1, k2, n1, n2, before ) |
|---|
| 347 | !!---------------------------------------------------------------------- |
|---|
| 348 | !! *** ROUTINE interptsn_sponge *** |
|---|
| 349 | !!---------------------------------------------------------------------- |
|---|
| 350 | INTEGER , INTENT(in ) :: i1, i2, j1, j2, k1, k2, n1, n2 |
|---|
| 351 | REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,n1:n2), INTENT(inout) :: tabres |
|---|
| 352 | LOGICAL , INTENT(in ) :: before |
|---|
| 353 | ! |
|---|
| 354 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 355 | INTEGER :: iku, ikv |
|---|
| 356 | REAL(wp) :: ztsa, zabe1, zabe2, zbtr, zhtot |
|---|
| 357 | REAL(wp), DIMENSION(i1:i2,j1:j2,jpk) :: ztu, ztv |
|---|
| 358 | REAL(wp), DIMENSION(i1:i2,j1:j2,jpk,n1:n2) ::tsbdiff |
|---|
| 359 | ! vertical interpolation: |
|---|
| 360 | REAL(wp), DIMENSION(i1:i2,j1:j2,jpk,n1:n2) ::tabres_child |
|---|
| 361 | REAL(wp), DIMENSION(k1:k2,n1:n2-1) :: tabin |
|---|
| 362 | REAL(wp), DIMENSION(k1:k2) :: h_in |
|---|
| 363 | REAL(wp), DIMENSION(1:jpk) :: h_out |
|---|
| 364 | INTEGER :: N_in, N_out |
|---|
| 365 | !!---------------------------------------------------------------------- |
|---|
| 366 | ! |
|---|
| 367 | IF( before ) THEN |
|---|
| 368 | DO jn = 1, jpts |
|---|
| 369 | DO jk=k1,k2 |
|---|
| 370 | DO jj=j1,j2 |
|---|
| 371 | DO ji=i1,i2 |
|---|
| 372 | tabres(ji,jj,jk,jn) = ts(ji,jj,jk,jn,Kbb_a) |
|---|
| 373 | END DO |
|---|
| 374 | END DO |
|---|
| 375 | END DO |
|---|
| 376 | END DO |
|---|
| 377 | |
|---|
| 378 | # if defined key_vertical |
|---|
| 379 | ! Interpolate thicknesses |
|---|
| 380 | ! Warning: these are masked, hence extrapolated prior interpolation. |
|---|
| 381 | DO jk=k1,k2 |
|---|
| 382 | DO jj=j1,j2 |
|---|
| 383 | DO ji=i1,i2 |
|---|
| 384 | tabres(ji,jj,jk,jpts+1) = tmask(ji,jj,jk) * e3t(ji,jj,jk,Kbb_a) |
|---|
| 385 | END DO |
|---|
| 386 | END DO |
|---|
| 387 | END DO |
|---|
| 388 | |
|---|
| 389 | ! Extrapolate thicknesses in partial bottom cells: |
|---|
| 390 | ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on |
|---|
| 391 | IF (ln_zps) THEN |
|---|
| 392 | DO jj=j1,j2 |
|---|
| 393 | DO ji=i1,i2 |
|---|
| 394 | jk = mbkt(ji,jj) |
|---|
| 395 | tabres(ji,jj,jk,jpts+1) = 0._wp |
|---|
| 396 | END DO |
|---|
| 397 | END DO |
|---|
| 398 | END IF |
|---|
| 399 | |
|---|
| 400 | ! Save ssh at last level: |
|---|
| 401 | IF (.NOT.ln_linssh) THEN |
|---|
| 402 | tabres(i1:i2,j1:j2,k2,jpts+1) = ssh(i1:i2,j1:j2,Kbb_a)*tmask(i1:i2,j1:j2,1) |
|---|
| 403 | ELSE |
|---|
| 404 | tabres(i1:i2,j1:j2,k2,jpts+1) = 0._wp |
|---|
| 405 | END IF |
|---|
| 406 | # endif |
|---|
| 407 | |
|---|
| 408 | ELSE |
|---|
| 409 | ! |
|---|
| 410 | # if defined key_vertical |
|---|
| 411 | |
|---|
| 412 | IF (ln_linssh) tabres(i1:i2,j1:j2,k2,n2) = 0._wp |
|---|
| 413 | |
|---|
| 414 | DO jj=j1,j2 |
|---|
| 415 | DO ji=i1,i2 |
|---|
| 416 | tabres_child(ji,jj,:,:) = 0._wp |
|---|
| 417 | N_in = mbkt_parent(ji,jj) |
|---|
| 418 | zhtot = 0._wp |
|---|
| 419 | DO jk=1,N_in !k2 = jpk of parent grid |
|---|
| 420 | IF (jk==N_in) THEN |
|---|
| 421 | h_in(jk) = ht0_parent(ji,jj) + tabres(ji,jj,k2,n2) - zhtot |
|---|
| 422 | ELSE |
|---|
| 423 | h_in(jk) = tabres(ji,jj,jk,n2) |
|---|
| 424 | ENDIF |
|---|
| 425 | zhtot = zhtot + h_in(jk) |
|---|
| 426 | tabin(jk,:) = tabres(ji,jj,jk,n1:n2-1) |
|---|
| 427 | END DO |
|---|
| 428 | N_out = 0 |
|---|
| 429 | DO jk=1,jpk ! jpk of child grid |
|---|
| 430 | IF (tmask(ji,jj,jk) == 0) EXIT |
|---|
| 431 | N_out = N_out + 1 |
|---|
| 432 | h_out(jk) = e3t(ji,jj,jk,Kbb_a) !Child grid scale factors. Could multiply by e1e2t here instead of division above |
|---|
| 433 | END DO |
|---|
| 434 | |
|---|
| 435 | ! Account for small differences in free-surface |
|---|
| 436 | IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN |
|---|
| 437 | h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) ) |
|---|
| 438 | ELSE |
|---|
| 439 | h_in(1) = h_in(1) - (sum(h_in(1:N_in))-sum(h_out(1:N_out)) ) |
|---|
| 440 | ENDIF |
|---|
| 441 | IF (N_in*N_out > 0) THEN |
|---|
| 442 | CALL reconstructandremap(tabin(1:N_in,1:jpts),h_in(1:N_in),tabres_child(ji,jj,1:N_out,1:jpts),h_out(1:N_out),N_in,N_out,jpts) |
|---|
| 443 | ENDIF |
|---|
| 444 | END DO |
|---|
| 445 | END DO |
|---|
| 446 | # endif |
|---|
| 447 | |
|---|
| 448 | DO jj=j1,j2 |
|---|
| 449 | DO ji=i1,i2 |
|---|
| 450 | DO jk=1,jpkm1 |
|---|
| 451 | # if defined key_vertical |
|---|
| 452 | tsbdiff(ji,jj,jk,1:jpts) = (ts(ji,jj,jk,1:jpts,Kbb_a) - tabres_child(ji,jj,jk,1:jpts)) * tmask(ji,jj,jk) |
|---|
| 453 | # else |
|---|
| 454 | tsbdiff(ji,jj,jk,1:jpts) = (ts(ji,jj,jk,1:jpts,Kbb_a) - tabres(ji,jj,jk,1:jpts))*tmask(ji,jj,jk) |
|---|
| 455 | # endif |
|---|
| 456 | END DO |
|---|
| 457 | END DO |
|---|
| 458 | END DO |
|---|
| 459 | |
|---|
| 460 | DO jn = 1, jpts |
|---|
| 461 | DO jk = 1, jpkm1 |
|---|
| 462 | ztu(i1:i2,j1:j2,jk) = 0._wp |
|---|
| 463 | DO jj = j1,j2 |
|---|
| 464 | DO ji = i1,i2-1 |
|---|
| 465 | zabe1 = rn_sponge_tra * r1_Dt * fspu(ji,jj) * umask(ji,jj,jk) * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm_a) |
|---|
| 466 | ztu(ji,jj,jk) = zabe1 * ( tsbdiff(ji+1,jj ,jk,jn) - tsbdiff(ji,jj,jk,jn) ) |
|---|
| 467 | END DO |
|---|
| 468 | END DO |
|---|
| 469 | ztv(i1:i2,j1:j2,jk) = 0._wp |
|---|
| 470 | DO ji = i1,i2 |
|---|
| 471 | DO jj = j1,j2-1 |
|---|
| 472 | zabe2 = rn_sponge_tra * r1_Dt * fspv(ji,jj) * vmask(ji,jj,jk) * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm_a) |
|---|
| 473 | ztv(ji,jj,jk) = zabe2 * ( tsbdiff(ji ,jj+1,jk,jn) - tsbdiff(ji,jj,jk,jn) ) |
|---|
| 474 | END DO |
|---|
| 475 | END DO |
|---|
| 476 | ! |
|---|
| 477 | IF( ln_zps ) THEN ! set gradient at partial step level |
|---|
| 478 | DO jj = j1,j2 |
|---|
| 479 | DO ji = i1,i2 |
|---|
| 480 | ! last level |
|---|
| 481 | iku = mbku(ji,jj) |
|---|
| 482 | ikv = mbkv(ji,jj) |
|---|
| 483 | IF( iku == jk ) ztu(ji,jj,jk) = 0._wp |
|---|
| 484 | IF( ikv == jk ) ztv(ji,jj,jk) = 0._wp |
|---|
| 485 | END DO |
|---|
| 486 | END DO |
|---|
| 487 | ENDIF |
|---|
| 488 | END DO |
|---|
| 489 | ! |
|---|
| 490 | DO jk = 1, jpkm1 |
|---|
| 491 | DO jj = j1+1,j2-1 |
|---|
| 492 | DO ji = i1+1,i2-1 |
|---|
| 493 | IF (.NOT. tabspongedone_tsn(ji,jj)) THEN |
|---|
| 494 | zbtr = r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm_a) |
|---|
| 495 | ! horizontal diffusive trends |
|---|
| 496 | ztsa = zbtr * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) & |
|---|
| 497 | & - rn_trelax_tra * r1_Dt * fspt(ji,jj) * tsbdiff(ji,jj,jk,jn) |
|---|
| 498 | ! add it to the general tracer trends |
|---|
| 499 | ts(ji,jj,jk,jn,Krhs_a) = ts(ji,jj,jk,jn,Krhs_a) + ztsa |
|---|
| 500 | ENDIF |
|---|
| 501 | END DO |
|---|
| 502 | END DO |
|---|
| 503 | END DO |
|---|
| 504 | ! |
|---|
| 505 | END DO |
|---|
| 506 | ! |
|---|
| 507 | tabspongedone_tsn(i1+1:i2-1,j1+1:j2-1) = .TRUE. |
|---|
| 508 | ! |
|---|
| 509 | ENDIF |
|---|
| 510 | ! |
|---|
| 511 | END SUBROUTINE interptsn_sponge |
|---|
| 512 | |
|---|
| 513 | |
|---|
| 514 | SUBROUTINE interpun_sponge(tabres,i1,i2,j1,j2,k1,k2,m1,m2, before) |
|---|
| 515 | !!--------------------------------------------- |
|---|
| 516 | !! *** ROUTINE interpun_sponge *** |
|---|
| 517 | !!--------------------------------------------- |
|---|
| 518 | INTEGER, INTENT(in) :: i1,i2,j1,j2,k1,k2,m1,m2 |
|---|
| 519 | REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,m1:m2), INTENT(inout) :: tabres |
|---|
| 520 | LOGICAL, INTENT(in) :: before |
|---|
| 521 | |
|---|
| 522 | INTEGER :: ji,jj,jk,jmax |
|---|
| 523 | INTEGER :: ind1 |
|---|
| 524 | ! sponge parameters |
|---|
| 525 | REAL(wp) :: ze2u, ze1v, zua, zva, zbtr, zhtot |
|---|
| 526 | REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: ubdiff |
|---|
| 527 | REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: rotdiff, hdivdiff |
|---|
| 528 | ! vertical interpolation: |
|---|
| 529 | REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: tabres_child |
|---|
| 530 | REAL(wp), DIMENSION(k1:k2) :: tabin, h_in |
|---|
| 531 | REAL(wp), DIMENSION(1:jpk) :: h_out |
|---|
| 532 | INTEGER ::N_in, N_out |
|---|
| 533 | !!--------------------------------------------- |
|---|
| 534 | ! |
|---|
| 535 | IF( before ) THEN |
|---|
| 536 | DO jk=k1,k2 |
|---|
| 537 | DO jj=j1,j2 |
|---|
| 538 | DO ji=i1,i2 |
|---|
| 539 | tabres(ji,jj,jk,m1) = uu(ji,jj,jk,Kbb_a) |
|---|
| 540 | # if defined key_vertical |
|---|
| 541 | tabres(ji,jj,jk,m2) = e3u(ji,jj,jk,Kbb_a)*umask(ji,jj,jk) |
|---|
| 542 | # endif |
|---|
| 543 | END DO |
|---|
| 544 | END DO |
|---|
| 545 | END DO |
|---|
| 546 | |
|---|
| 547 | # if defined key_vertical |
|---|
| 548 | ! Extrapolate thicknesses in partial bottom cells: |
|---|
| 549 | ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on |
|---|
| 550 | IF (ln_zps) THEN |
|---|
| 551 | DO jj=j1,j2 |
|---|
| 552 | DO ji=i1,i2 |
|---|
| 553 | jk = mbku(ji,jj) |
|---|
| 554 | tabres(ji,jj,jk,m2) = 0._wp |
|---|
| 555 | END DO |
|---|
| 556 | END DO |
|---|
| 557 | END IF |
|---|
| 558 | ! Save ssh at last level: |
|---|
| 559 | tabres(i1:i2,j1:j2,k2,m2) = 0._wp |
|---|
| 560 | IF (.NOT.ln_linssh) THEN |
|---|
| 561 | ! This vertical sum below should be replaced by the sea-level at U-points (optimization): |
|---|
| 562 | DO jk=1,jpk |
|---|
| 563 | tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) + e3u(i1:i2,j1:j2,jk,Kbb_a) * umask(i1:i2,j1:j2,jk) |
|---|
| 564 | END DO |
|---|
| 565 | tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) - hu_0(i1:i2,j1:j2) |
|---|
| 566 | END IF |
|---|
| 567 | # endif |
|---|
| 568 | |
|---|
| 569 | ELSE |
|---|
| 570 | |
|---|
| 571 | # if defined key_vertical |
|---|
| 572 | IF (ln_linssh) tabres(i1:i2,j1:j2,k2,m2) = 0._wp |
|---|
| 573 | |
|---|
| 574 | DO jj=j1,j2 |
|---|
| 575 | DO ji=i1,i2 |
|---|
| 576 | tabres_child(ji,jj,:) = 0._wp |
|---|
| 577 | N_in = mbku_parent(ji,jj) |
|---|
| 578 | zhtot = 0._wp |
|---|
| 579 | DO jk=1,N_in |
|---|
| 580 | IF (jk==N_in) THEN |
|---|
| 581 | h_in(jk) = hu0_parent(ji,jj) + tabres(ji,jj,k2,m2) - zhtot |
|---|
| 582 | ELSE |
|---|
| 583 | h_in(jk) = tabres(ji,jj,jk,m2) |
|---|
| 584 | ENDIF |
|---|
| 585 | zhtot = zhtot + h_in(jk) |
|---|
| 586 | tabin(jk) = tabres(ji,jj,jk,m1) |
|---|
| 587 | END DO |
|---|
| 588 | ! |
|---|
| 589 | N_out = 0 |
|---|
| 590 | DO jk=1,jpk |
|---|
| 591 | IF (umask(ji,jj,jk) == 0) EXIT |
|---|
| 592 | N_out = N_out + 1 |
|---|
| 593 | h_out(N_out) = e3u(ji,jj,jk,Kbb_a) |
|---|
| 594 | END DO |
|---|
| 595 | |
|---|
| 596 | ! Account for small differences in free-surface |
|---|
| 597 | IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN |
|---|
| 598 | h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) ) |
|---|
| 599 | ELSE |
|---|
| 600 | h_in(1) = h_in(1) - (sum(h_in(1:N_in))-sum(h_out(1:N_out)) ) |
|---|
| 601 | ENDIF |
|---|
| 602 | |
|---|
| 603 | IF (N_in * N_out > 0) THEN |
|---|
| 604 | CALL reconstructandremap(tabin(1:N_in),h_in(1:N_in),tabres_child(ji,jj,1:N_out),h_out(1:N_out),N_in,N_out,1) |
|---|
| 605 | ENDIF |
|---|
| 606 | END DO |
|---|
| 607 | END DO |
|---|
| 608 | |
|---|
| 609 | ubdiff(i1:i2,j1:j2,:) = (uu(i1:i2,j1:j2,:,Kbb_a) - tabres_child(i1:i2,j1:j2,:))*umask(i1:i2,j1:j2,:) |
|---|
| 610 | #else |
|---|
| 611 | ubdiff(i1:i2,j1:j2,:) = (uu(i1:i2,j1:j2,:,Kbb_a) - tabres(i1:i2,j1:j2,:,1))*umask(i1:i2,j1:j2,:) |
|---|
| 612 | #endif |
|---|
| 613 | ! |
|---|
| 614 | DO jk = 1, jpkm1 ! Horizontal slab |
|---|
| 615 | ! ! =============== |
|---|
| 616 | |
|---|
| 617 | ! ! -------- |
|---|
| 618 | ! Horizontal divergence ! div |
|---|
| 619 | ! ! -------- |
|---|
| 620 | DO jj = j1,j2 |
|---|
| 621 | DO ji = i1+1,i2 ! vector opt. |
|---|
| 622 | zbtr = rn_sponge_dyn * r1_Dt * fspt(ji,jj) / e3t(ji,jj,jk,Kbb_a) |
|---|
| 623 | hdivdiff(ji,jj,jk) = ( e2u(ji ,jj)*e3u(ji ,jj,jk,Kbb_a) * ubdiff(ji ,jj,jk) & |
|---|
| 624 | & -e2u(ji-1,jj)*e3u(ji-1,jj,jk,Kbb_a) * ubdiff(ji-1,jj,jk) ) * zbtr |
|---|
| 625 | END DO |
|---|
| 626 | END DO |
|---|
| 627 | |
|---|
| 628 | DO jj = j1,j2-1 |
|---|
| 629 | DO ji = i1,i2 ! vector opt. |
|---|
| 630 | zbtr = rn_sponge_dyn * r1_Dt * fspf(ji,jj) * e3f(ji,jj,jk) |
|---|
| 631 | rotdiff(ji,jj,jk) = ( -e1u(ji,jj+1) * ubdiff(ji,jj+1,jk) & |
|---|
| 632 | & +e1u(ji,jj ) * ubdiff(ji,jj ,jk) ) * fmask(ji,jj,jk) * zbtr |
|---|
| 633 | END DO |
|---|
| 634 | END DO |
|---|
| 635 | END DO |
|---|
| 636 | ! |
|---|
| 637 | DO jj = j1+1, j2-1 |
|---|
| 638 | DO ji = i1+1, i2-1 ! vector opt. |
|---|
| 639 | |
|---|
| 640 | IF (.NOT. tabspongedone_u(ji,jj)) THEN |
|---|
| 641 | DO jk = 1, jpkm1 ! Horizontal slab |
|---|
| 642 | ze2u = rotdiff (ji,jj,jk) |
|---|
| 643 | ze1v = hdivdiff(ji,jj,jk) |
|---|
| 644 | ! horizontal diffusive trends |
|---|
| 645 | zua = - ( ze2u - rotdiff (ji,jj-1,jk) ) / ( e2u(ji,jj) * e3u(ji,jj,jk,Kmm_a) ) & |
|---|
| 646 | & + ( hdivdiff(ji+1,jj,jk) - ze1v ) * r1_e1u(ji,jj) & |
|---|
| 647 | & - rn_trelax_dyn * r1_Dt * fspu(ji,jj) * ubdiff(ji,jj,jk) |
|---|
| 648 | |
|---|
| 649 | ! add it to the general momentum trends |
|---|
| 650 | uu(ji,jj,jk,Krhs_a) = uu(ji,jj,jk,Krhs_a) + zua |
|---|
| 651 | END DO |
|---|
| 652 | ENDIF |
|---|
| 653 | |
|---|
| 654 | END DO |
|---|
| 655 | END DO |
|---|
| 656 | |
|---|
| 657 | tabspongedone_u(i1+1:i2-1,j1+1:j2-1) = .TRUE. |
|---|
| 658 | |
|---|
| 659 | jmax = j2-1 |
|---|
| 660 | ind1 = jpjglo - ( nn_hls + nbghostcells + 2 ) ! North |
|---|
| 661 | DO jj = mj0(ind1), mj1(ind1) |
|---|
| 662 | jmax = MIN(jmax,jj) |
|---|
| 663 | END DO |
|---|
| 664 | |
|---|
| 665 | DO jj = j1+1, jmax |
|---|
| 666 | DO ji = i1+1, i2 ! vector opt. |
|---|
| 667 | |
|---|
| 668 | IF (.NOT. tabspongedone_v(ji,jj)) THEN |
|---|
| 669 | DO jk = 1, jpkm1 ! Horizontal slab |
|---|
| 670 | ze2u = rotdiff (ji,jj,jk) |
|---|
| 671 | ze1v = hdivdiff(ji,jj,jk) |
|---|
| 672 | |
|---|
| 673 | ! horizontal diffusive trends |
|---|
| 674 | zva = + ( ze2u - rotdiff (ji-1,jj,jk) ) / ( e1v(ji,jj) * e3v(ji,jj,jk,Kmm_a) ) & |
|---|
| 675 | + ( hdivdiff(ji,jj+1,jk) - ze1v ) * r1_e2v(ji,jj) |
|---|
| 676 | |
|---|
| 677 | ! add it to the general momentum trends |
|---|
| 678 | vv(ji,jj,jk,Krhs_a) = vv(ji,jj,jk,Krhs_a) + zva |
|---|
| 679 | END DO |
|---|
| 680 | ENDIF |
|---|
| 681 | ! |
|---|
| 682 | END DO |
|---|
| 683 | END DO |
|---|
| 684 | ! |
|---|
| 685 | tabspongedone_v(i1+1:i2,j1+1:jmax) = .TRUE. |
|---|
| 686 | ! |
|---|
| 687 | ENDIF |
|---|
| 688 | ! |
|---|
| 689 | END SUBROUTINE interpun_sponge |
|---|
| 690 | |
|---|
| 691 | |
|---|
| 692 | SUBROUTINE interpvn_sponge(tabres,i1,i2,j1,j2,k1,k2,m1,m2, before) |
|---|
| 693 | !!--------------------------------------------- |
|---|
| 694 | !! *** ROUTINE interpvn_sponge *** |
|---|
| 695 | !!--------------------------------------------- |
|---|
| 696 | INTEGER, INTENT(in) :: i1,i2,j1,j2,k1,k2,m1,m2 |
|---|
| 697 | REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,m1:m2), INTENT(inout) :: tabres |
|---|
| 698 | LOGICAL, INTENT(in) :: before |
|---|
| 699 | ! |
|---|
| 700 | INTEGER :: ji, jj, jk, imax |
|---|
| 701 | INTEGER :: ind1 |
|---|
| 702 | REAL(wp) :: ze2u, ze1v, zua, zva, zbtr, zhtot |
|---|
| 703 | REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: vbdiff |
|---|
| 704 | REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: rotdiff, hdivdiff |
|---|
| 705 | ! vertical interpolation: |
|---|
| 706 | REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: tabres_child |
|---|
| 707 | REAL(wp), DIMENSION(k1:k2) :: tabin, h_in |
|---|
| 708 | REAL(wp), DIMENSION(1:jpk) :: h_out |
|---|
| 709 | INTEGER :: N_in, N_out |
|---|
| 710 | !!--------------------------------------------- |
|---|
| 711 | |
|---|
| 712 | IF( before ) THEN |
|---|
| 713 | DO jk=k1,k2 |
|---|
| 714 | DO jj=j1,j2 |
|---|
| 715 | DO ji=i1,i2 |
|---|
| 716 | tabres(ji,jj,jk,m1) = vv(ji,jj,jk,Kbb_a) |
|---|
| 717 | # if defined key_vertical |
|---|
| 718 | tabres(ji,jj,jk,m2) = vmask(ji,jj,jk) * e3v(ji,jj,jk,Kbb_a) |
|---|
| 719 | # endif |
|---|
| 720 | END DO |
|---|
| 721 | END DO |
|---|
| 722 | END DO |
|---|
| 723 | |
|---|
| 724 | # if defined key_vertical |
|---|
| 725 | ! Extrapolate thicknesses in partial bottom cells: |
|---|
| 726 | ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on |
|---|
| 727 | IF (ln_zps) THEN |
|---|
| 728 | DO jj=j1,j2 |
|---|
| 729 | DO ji=i1,i2 |
|---|
| 730 | jk = mbkv(ji,jj) |
|---|
| 731 | tabres(ji,jj,jk,m2) = 0._wp |
|---|
| 732 | END DO |
|---|
| 733 | END DO |
|---|
| 734 | END IF |
|---|
| 735 | ! Save ssh at last level: |
|---|
| 736 | tabres(i1:i2,j1:j2,k2,m2) = 0._wp |
|---|
| 737 | IF (.NOT.ln_linssh) THEN |
|---|
| 738 | ! This vertical sum below should be replaced by the sea-level at V-points (optimization): |
|---|
| 739 | DO jk=1,jpk |
|---|
| 740 | tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) + e3v(i1:i2,j1:j2,jk,Kbb_a) * vmask(i1:i2,j1:j2,jk) |
|---|
| 741 | END DO |
|---|
| 742 | tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) - hv_0(i1:i2,j1:j2) |
|---|
| 743 | END IF |
|---|
| 744 | # endif |
|---|
| 745 | |
|---|
| 746 | ELSE |
|---|
| 747 | |
|---|
| 748 | # if defined key_vertical |
|---|
| 749 | IF (ln_linssh) tabres(i1:i2,j1:j2,k2,m2) = 0._wp |
|---|
| 750 | DO jj=j1,j2 |
|---|
| 751 | DO ji=i1,i2 |
|---|
| 752 | tabres_child(ji,jj,:) = 0._wp |
|---|
| 753 | N_in = mbkv_parent(ji,jj) |
|---|
| 754 | zhtot = 0._wp |
|---|
| 755 | DO jk=1,N_in |
|---|
| 756 | IF (jk==N_in) THEN |
|---|
| 757 | h_in(jk) = hv0_parent(ji,jj) + tabres(ji,jj,k2,m2) - zhtot |
|---|
| 758 | ELSE |
|---|
| 759 | h_in(jk) = tabres(ji,jj,jk,m2) |
|---|
| 760 | ENDIF |
|---|
| 761 | zhtot = zhtot + h_in(jk) |
|---|
| 762 | tabin(jk) = tabres(ji,jj,jk,m1) |
|---|
| 763 | END DO |
|---|
| 764 | ! |
|---|
| 765 | N_out = 0 |
|---|
| 766 | DO jk=1,jpk |
|---|
| 767 | IF (vmask(ji,jj,jk) == 0) EXIT |
|---|
| 768 | N_out = N_out + 1 |
|---|
| 769 | h_out(N_out) = e3v(ji,jj,jk,Kbb_a) |
|---|
| 770 | END DO |
|---|
| 771 | |
|---|
| 772 | ! Account for small differences in free-surface |
|---|
| 773 | IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN |
|---|
| 774 | h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) ) |
|---|
| 775 | ELSE |
|---|
| 776 | h_in(1) = h_in(1) - ( sum(h_in(1:N_in))-sum(h_out(1:N_out)) ) |
|---|
| 777 | ENDIF |
|---|
| 778 | |
|---|
| 779 | IF (N_in * N_out > 0) THEN |
|---|
| 780 | CALL reconstructandremap(tabin(1:N_in),h_in(1:N_in),tabres_child(ji,jj,1:N_out),h_out(1:N_out),N_in,N_out,1) |
|---|
| 781 | ENDIF |
|---|
| 782 | END DO |
|---|
| 783 | END DO |
|---|
| 784 | |
|---|
| 785 | vbdiff(i1:i2,j1:j2,:) = (vv(i1:i2,j1:j2,:,Kbb_a) - tabres_child(i1:i2,j1:j2,:))*vmask(i1:i2,j1:j2,:) |
|---|
| 786 | # else |
|---|
| 787 | vbdiff(i1:i2,j1:j2,:) = (vv(i1:i2,j1:j2,:,Kbb_a) - tabres(i1:i2,j1:j2,:,1))*vmask(i1:i2,j1:j2,:) |
|---|
| 788 | # endif |
|---|
| 789 | ! |
|---|
| 790 | DO jk = 1, jpkm1 ! Horizontal slab |
|---|
| 791 | ! ! =============== |
|---|
| 792 | |
|---|
| 793 | ! ! -------- |
|---|
| 794 | ! Horizontal divergence ! div |
|---|
| 795 | ! ! -------- |
|---|
| 796 | DO jj = j1+1,j2 |
|---|
| 797 | DO ji = i1,i2 ! vector opt. |
|---|
| 798 | zbtr = rn_sponge_dyn * r1_Dt * fspt(ji,jj) / e3t(ji,jj,jk,Kbb_a) |
|---|
| 799 | hdivdiff(ji,jj,jk) = ( e1v(ji,jj ) * e3v(ji,jj ,jk,Kbb_a) * vbdiff(ji,jj ,jk) & |
|---|
| 800 | & -e1v(ji,jj-1) * e3v(ji,jj-1,jk,Kbb_a) * vbdiff(ji,jj-1,jk) ) * zbtr |
|---|
| 801 | END DO |
|---|
| 802 | END DO |
|---|
| 803 | DO jj = j1,j2 |
|---|
| 804 | DO ji = i1,i2-1 ! vector opt. |
|---|
| 805 | zbtr = rn_sponge_dyn * r1_Dt * fspf(ji,jj) * e3f(ji,jj,jk) |
|---|
| 806 | rotdiff(ji,jj,jk) = ( e2v(ji+1,jj) * vbdiff(ji+1,jj,jk) & |
|---|
| 807 | & -e2v(ji ,jj) * vbdiff(ji ,jj,jk) ) * fmask(ji,jj,jk) * zbtr |
|---|
| 808 | END DO |
|---|
| 809 | END DO |
|---|
| 810 | END DO |
|---|
| 811 | |
|---|
| 812 | ! ! =============== |
|---|
| 813 | ! |
|---|
| 814 | |
|---|
| 815 | imax = i2 - 1 |
|---|
| 816 | ind1 = jpiglo - ( nn_hls + nbghostcells + 2 ) ! East |
|---|
| 817 | DO ji = mi0(ind1), mi1(ind1) |
|---|
| 818 | imax = MIN(imax,ji) |
|---|
| 819 | END DO |
|---|
| 820 | |
|---|
| 821 | DO jj = j1+1, j2 |
|---|
| 822 | DO ji = i1+1, imax ! vector opt. |
|---|
| 823 | IF( .NOT. tabspongedone_u(ji,jj) ) THEN |
|---|
| 824 | DO jk = 1, jpkm1 |
|---|
| 825 | uu(ji,jj,jk,Krhs_a) = uu(ji,jj,jk,Krhs_a) & |
|---|
| 826 | & - ( rotdiff (ji ,jj,jk) - rotdiff (ji,jj-1,jk)) / ( e2u(ji,jj) * e3u(ji,jj,jk,Kmm_a) ) & |
|---|
| 827 | & + ( hdivdiff(ji+1,jj,jk) - hdivdiff(ji,jj ,jk)) * r1_e1u(ji,jj) |
|---|
| 828 | END DO |
|---|
| 829 | ENDIF |
|---|
| 830 | END DO |
|---|
| 831 | END DO |
|---|
| 832 | ! |
|---|
| 833 | tabspongedone_u(i1+1:imax,j1+1:j2) = .TRUE. |
|---|
| 834 | ! |
|---|
| 835 | DO jj = j1+1, j2-1 |
|---|
| 836 | DO ji = i1+1, i2-1 ! vector opt. |
|---|
| 837 | IF( .NOT. tabspongedone_v(ji,jj) ) THEN |
|---|
| 838 | DO jk = 1, jpkm1 |
|---|
| 839 | vv(ji,jj,jk,Krhs_a) = vv(ji,jj,jk,Krhs_a) & |
|---|
| 840 | & + ( rotdiff (ji,jj ,jk) - rotdiff (ji-1,jj,jk) ) / ( e1v(ji,jj) * e3v(ji,jj,jk,Kmm_a) ) & |
|---|
| 841 | & + ( hdivdiff(ji,jj+1,jk) - hdivdiff(ji ,jj,jk) ) * r1_e2v(ji,jj) & |
|---|
| 842 | & - rn_trelax_dyn * r1_Dt * fspv(ji,jj) * vbdiff(ji,jj,jk) |
|---|
| 843 | END DO |
|---|
| 844 | ENDIF |
|---|
| 845 | END DO |
|---|
| 846 | END DO |
|---|
| 847 | tabspongedone_v(i1+1:i2-1,j1+1:j2-1) = .TRUE. |
|---|
| 848 | ENDIF |
|---|
| 849 | ! |
|---|
| 850 | END SUBROUTINE interpvn_sponge |
|---|
| 851 | |
|---|
| 852 | #else |
|---|
| 853 | !!---------------------------------------------------------------------- |
|---|
| 854 | !! Empty module no AGRIF zoom |
|---|
| 855 | !!---------------------------------------------------------------------- |
|---|
| 856 | CONTAINS |
|---|
| 857 | SUBROUTINE agrif_oce_sponge_empty |
|---|
| 858 | WRITE(*,*) 'agrif_oce_sponge : You should not have seen this print! error?' |
|---|
| 859 | END SUBROUTINE agrif_oce_sponge_empty |
|---|
| 860 | #endif |
|---|
| 861 | |
|---|
| 862 | !!====================================================================== |
|---|
| 863 | END MODULE agrif_oce_sponge |
|---|
