New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in NEMO/branches/2020/dev_r12558_HPC-08_epico_Extra_Halo/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r12558_HPC-08_epico_Extra_Halo/src/OCE/TRA/traadv_mus.F90 @ 12601

Last change on this file since 12601 was 12601, checked in by francesca, 4 years ago

Add extra-halo support (jperio 5,6) - ticket #2366

  • Property svn:keywords set to Id
File size: 15.6 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   USE diaar5         ! AR5 diagnostics
26
27   !
28   USE iom            ! XIOS library
29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
33   USE halo_mng
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
39   
40   REAL(wp), POINTER, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
41   !                                                           !  and in closed seas (orca 2 and 1 configurations)
42   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
43   
44   LOGICAL  ::   l_trd   ! flag to compute trends
45   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
46   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
47
48   INTEGER :: jphls = 2
49
50   !! * Substitutions
51#  include "do_loop_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
54   !! $Id$
55   !! Software governed by the CeCILL license (see ./LICENSE)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pU, pV, pW,             &
60      &                    Kbb, Kmm, pt, kjpt, Krhs, ld_msc_ups )
61      !!----------------------------------------------------------------------
62      !!                    ***  ROUTINE tra_adv_mus  ***
63      !!
64      !! ** Purpose :   Compute the now trend due to total advection of tracers
65      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
66      !!              Conservation Laws) and add it to the general tracer trend.
67      !!
68      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
69      !!              ld_msc_ups=T :
70      !!
71      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
72      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
73      !!             - poleward advective heat and salt transport (ln_diaptr=T)
74      !!
75      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
76      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
77      !!----------------------------------------------------------------------
78      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
79      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
80      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
81      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
82      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
83      LOGICAL                                  , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
84      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
85      REAL(wp), POINTER, DIMENSION(:,:,:    )           , INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
86      REAL(wp), POINTER, DIMENSION(:,:,:,:,:)           , INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
87      !
88      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
89      INTEGER  ::   ierr             ! local integer
90      REAL(wp) ::   zu, z0u, zzwx, zw , zalpha   ! local scalars
91      REAL(wp) ::   zv, z0v, zzwy, z0w           !   -      -
92      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zwx, zslpx   ! 3D workspace
93      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zwy, zslpy   ! -      -
94      !!----------------------------------------------------------------------
95      !
96      CALL halo_mng_set(jphls)
97
98      ALLOCATE(zwx(jplbi:jpi,jplbj:jpj,jpk))
99      ALLOCATE(zwy(jplbi:jpi,jplbj:jpj,jpk))
100      ALLOCATE(zslpx(jplbi:jpi,jplbj:jpj,jpk))
101      ALLOCATE(zslpy(jplbi:jpi,jplbj:jpj,jpk))
102
103      CALL halo_mng_resize(r1_e1e2t,'T', 1._wp)
104      CALL halo_mng_resize(r1_e1e2u,'U', 1._wp)
105      CALL halo_mng_resize(r1_e1e2v,'V', 1._wp)
106      CALL halo_mng_resize(tmask,'T', 1._wp)
107      CALL halo_mng_resize(wmask, 'W', 1._wp)
108      CALL halo_mng_resize(umask, 'U', 1._wp)
109      CALL halo_mng_resize(vmask, 'V', 1._wp)
110      CALL halo_mng_resize(pt, 'T', 1._wp, kjpt=kjpt, fjpt=Kbb )
111      CALL halo_mng_resize(pt, 'T', 1._wp, kjpt=kjpt, fjpt=Krhs )
112      CALL halo_mng_resize(e3t,'T', 1._wp, fillval=1._wp, fjpt=Kmm)
113      CALL halo_mng_resize(e3u, 'U', 1._wp, fillval=1._wp, fjpt=Kmm )
114      CALL halo_mng_resize(e3v, 'V', 1._wp, fillval=1._wp, fjpt=Kmm)
115      CALL halo_mng_resize(e3w, 'W', 1._wp, fillval=1._wp, fjpt=Kmm)
116      CALL halo_mng_resize(pU, 'U', -1._wp)
117      CALL halo_mng_resize(pV, 'V', -1._wp)
118      CALL halo_mng_resize(pW, 'W', 1._wp)
119      !     
120      IF( ln_isfcav ) CALL halo_mng_resize(mikt, 'T', 1._wp)
121      IF( ld_msc_ups) CALL halo_mng_resize(rnfmsk, 'T', 1._wp)
122      IF( ld_msc_ups) CALL halo_mng_resize(upsmsk, 'T', 1._wp)
123
124      IF( kt == kit000 )  THEN
125         IF(lwp) WRITE(numout,*)
126         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
127         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
128         IF(lwp) WRITE(numout,*) '~~~~~~~'
129         IF(lwp) WRITE(numout,*)
130         !
131         ! Upstream / MUSCL scheme indicator
132         !
133         ALLOCATE( xind(jplbi:jpi,jplbj:jpj,jpk), STAT=ierr )
134         xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
135         !
136         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
137            ALLOCATE( upsmsk(jplbi:jpi,jplbj:jpj), STAT=ierr )
138            upsmsk(:,:) = 0._wp                             ! not upstream by default
139            !
140            DO jk = 1, jpkm1
141               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
142                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
143                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
144            END DO
145         ENDIF 
146         !
147      ENDIF
148
149      l_trd = .FALSE.
150      l_hst = .FALSE.
151      l_ptr = .FALSE.
152      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
153      IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) )  )   l_ptr = .TRUE. 
154      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
155         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) ) l_hst = .TRUE.
156      !
157      DO jn = 1, kjpt            !==  loop over the tracers  ==!
158         !
159         !                          !* Horizontal advective fluxes
160         !
161         !                                !-- first guess of the slopes
162         zwx(:,:,jpk) = 0._wp                   ! bottom values
163         zwy(:,:,jpk) = 0._wp 
164         DO_3D_20_20( 1, jpkm1 )
165            zwx(ji,jj,jk) = umask(ji,jj,jk) * ( pt(ji+1,jj,jk,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
166            zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( pt(ji,jj+1,jk,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
167         END_3D
168         !
169         !                                !-- Slopes of tracer
170         zslpx(:,:,jpk) = 0._wp                 ! bottom values
171         zslpy(:,:,jpk) = 0._wp
172         DO_3D_31_31( 1, jpkm1 )
173            zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
174               &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
175            zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
176               &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
177         END_3D
178         !
179         DO_3D_31_31( 1, jpkm1 )
180            zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
181               &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
182               &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
183            zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
184               &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
185               &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
186         END_3D
187         !
188         DO_3D_30_30( 1, jpkm1 )
189            ! MUSCL fluxes
190            z0u = SIGN( 0.5, pU(ji,jj,jk) )
191            zalpha = 0.5 - z0u
192            zu  = z0u - 0.5 * pU(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u(ji,jj,jk,Kmm)
193            zzwx = pt(ji+1,jj,jk,jn,Kbb) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
194            zzwy = pt(ji  ,jj,jk,jn,Kbb) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
195            zwx(ji,jj,jk) = pU(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
196            !
197            z0v = SIGN( 0.5, pV(ji,jj,jk) )
198            zalpha = 0.5 - z0v
199            zv  = z0v - 0.5 * pV(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v(ji,jj,jk,Kmm)
200            zzwx = pt(ji,jj+1,jk,jn,Kbb) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
201            zzwy = pt(ji,jj  ,jk,jn,Kbb) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
202            zwy(ji,jj,jk) = pV(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
203         END_3D
204         !
205         DO_3D_30_30( 1, jpkm1 )
206            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
207            &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
208            &                                   * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
209         END_3D
210         !                                ! trend diagnostics
211         IF( l_trd )  THEN
212            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, zwx, pU, pt(:,:,:,jn,Kbb) )
213            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, zwy, pV, pt(:,:,:,jn,Kbb) )
214         END IF
215         !                                 ! "Poleward" heat and salt transports
216         IF( l_ptr )  CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
217         !                                 !  heat transport
218         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
219         !
220         !                          !* Vertical advective fluxes
221         !
222         !                                !-- first guess of the slopes
223         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
224         zwx(:,:,jpk) = 0._wp
225         DO jk = 2, jpkm1                       ! interior values
226            zwx(:,:,jk) = tmask(:,:,jk) * ( pt(:,:,jk-1,jn,Kbb) - pt(:,:,jk,jn,Kbb) )
227         END DO
228         !                                !-- Slopes of tracer
229         zslpx(:,:,1) = 0._wp                   ! surface values
230         DO_3D_21_21( 2, jpkm1 )
231            zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
232               &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
233         END_3D
234         DO_3D_21_21( 2, jpkm1 )
235            zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
236               &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
237               &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
238         END_3D
239         DO_3D_30_30( 1, jpk-2 )
240            z0w = SIGN( 0.5, pW(ji,jj,jk+1) )
241            zalpha = 0.5 + z0w
242            zw  = z0w - 0.5 * pW(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w(ji,jj,jk+1,Kmm)
243            zzwx = pt(ji,jj,jk+1,jn,Kbb) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
244            zzwy = pt(ji,jj,jk  ,jn,Kbb) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
245            zwx(ji,jj,jk+1) = pW(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
246         END_3D
247         IF( ln_linssh ) THEN                   ! top values, linear free surface only
248            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
249               DO_2D_21_21
250                  zwx(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)
251               END_2D
252            ELSE                                      ! no cavities: only at the ocean surface
253               zwx(:,:,1) = pW(:,:,1) * pt(:,:,1,jn,Kbb)
254            ENDIF
255         ENDIF
256         !
257         DO_3D_30_30( 1, jpkm1 )
258            pt(ji,jj,jk,jn,Krhs) =  pt(ji,jj,jk,jn,Krhs) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
259         END_3D
260         !                                ! send trends for diagnostic
261         IF( l_trd )  CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, zwx, pW, pt(:,:,:,jn,Kbb) )
262         !
263      END DO                     ! end of tracer loop
264      !
265      DEALLOCATE(zwx,zwy)
266      DEALLOCATE(zslpx,zslpy)
267
268      CALL halo_mng_set(1)
269
270      CALL halo_mng_resize(r1_e1e2t,'T', 1._wp)
271      CALL halo_mng_resize(r1_e1e2u,'U', 1._wp)
272      CALL halo_mng_resize(r1_e1e2v,'V', 1._wp)
273      CALL halo_mng_resize(pt, 'T', 1._wp, kjpt=kjpt, fjpt=Kbb )
274      CALL halo_mng_resize(pt, 'T', 1._wp, kjpt=kjpt, fjpt=Krhs )
275      CALL halo_mng_resize(tmask,'T', 1._wp)
276      CALL halo_mng_resize(wmask, 'W', 1._wp)
277      CALL halo_mng_resize(umask, 'U', 1._wp)
278      CALL halo_mng_resize(vmask, 'V', 1._wp)
279      CALL halo_mng_resize(e3t,'T', 1._wp, fillval=1._wp, fjpt=Kmm)
280      CALL halo_mng_resize(e3u, 'U', 1._wp, fillval=1._wp, fjpt=Kmm)
281      CALL halo_mng_resize(e3v, 'V', 1._wp, fillval=1._wp, fjpt=Kmm)
282      CALL halo_mng_resize(e3w, 'W', 1._wp, fillval=1._wp, fjpt=Kmm)
283      CALL halo_mng_resize(pU, 'U', 1._wp)
284      CALL halo_mng_resize(pV, 'V', 1._wp)
285      CALL halo_mng_resize(pW, 'W', 1._wp)
286
287      IF( ln_isfcav ) CALL halo_mng_resize(mikt, 'T', 1._wp)
288      IF( ld_msc_ups) CALL halo_mng_resize(rnfmsk, 'T', 1._wp)
289      IF( ld_msc_ups) CALL halo_mng_resize(upsmsk, 'T', 1._wp)
290
291   END SUBROUTINE tra_adv_mus
292
293   !!======================================================================
294END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.