New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2020/dev_r12558_HPC-08_epico_Extra_Halo/src/OFF – NEMO

source: NEMO/branches/2020/dev_r12558_HPC-08_epico_Extra_Halo/src/OFF/nemogcm.F90 @ 12939

Last change on this file since 12939 was 12939, checked in by smasson, 4 years ago

Extra_Halo: update with trunk@12933, see #2366

  • Property svn:keywords set to Id
File size: 28.2 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            3.4  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!            4.0  ! 2016-10  (C. Ethe, G. Madec, S. Flavoni)  domain configuration / user defined interface
9   !!            4.1  ! 2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   nemo_gcm      : off-line: solve ocean tracer only
14   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
15   !!   nemo_init     : initialization of the NEMO system
16   !!   nemo_ctl      : initialisation of the contol print
17   !!   nemo_closefile: close remaining open files
18   !!   nemo_alloc    : dynamical allocation
19   !!   istate_init   : simple initialization to zero of ocean fields
20   !!   stp_ctl       : reduced step control (no dynamics in off-line)
21   !!----------------------------------------------------------------------
22   USE dom_oce        ! ocean space domain variables
23   USE oce            ! dynamics and tracers variables
24   USE trc_oce        ! Shared ocean/passive tracers variables
25   USE c1d            ! 1D configuration
26   USE domain         ! domain initialization from coordinate & bathymetry (dom_init routine)
27   USE closea         ! treatment of closed seas (for ln_closea)
28   USE usrdef_nam     ! user defined configuration
29   USE eosbn2         ! equation of state            (eos bn2 routine)
30   USE bdy_oce,  ONLY : ln_bdy
31   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
32   !              ! ocean physics
33   USE ldftra         ! lateral diffusivity setting    (ldf_tra_init routine)
34   USE ldfslp         ! slopes of neutral surfaces     (ldf_slp_init routine)
35   USE traqsr         ! solar radiation penetration    (tra_qsr_init routine)
36   USE trabbl         ! bottom boundary layer          (tra_bbl_init routine)
37   USE traldf         ! lateral physics                (tra_ldf_init routine)
38   USE sbcmod         ! surface boundary condition     (sbc_init     routine)
39   USE phycst         ! physical constant                   (par_cst routine)
40   USE dtadyn         ! Lecture and Interpolation of the dynamical fields
41   USE trcini         ! Initilization of the passive tracers
42   USE daymod         ! calendar                            (day     routine)
43   USE trcstp         ! passive tracer time-stepping        (trc_stp routine)
44   USE dtadyn         ! Lecture and interpolation of the dynamical fields
45   !              ! Passive tracers needs
46   USE trc            ! passive tracer : variables
47   USE trcnam         ! passive tracer : namelist
48   USE trcrst         ! passive tracer restart
49   USE diaptr         ! Need to initialise this as some variables are used in if statements later
50   USE sbc_oce , ONLY : ln_rnf
51   USE sbcrnf         ! surface boundary condition : runoffs
52   !              ! I/O & MPP
53   USE iom            ! I/O library
54   USE in_out_manager ! I/O manager
55   USE mppini         ! shared/distributed memory setting (mpp_init routine)
56   USE lib_mpp        ! distributed memory computing
57#if defined key_iomput
58   USE xios           ! xIOserver
59#endif
60   USE prtctl         ! Print control                    (prt_ctl_init routine)
61   USE timing         ! Timing
62   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
63   USE lbcnfd  , ONLY : isendto, nsndto   ! Setup of north fold exchanges
64   USE step, ONLY : Nbb, Nnn, Naa, Nrhs   ! time level indices
65   USE halo_mng
66
67   IMPLICIT NONE
68   PRIVATE
69   
70   PUBLIC   nemo_gcm   ! called by nemo.F90
71
72   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
73
74   !!----------------------------------------------------------------------
75   !! NEMO/OFF 4.0 , NEMO Consortium (2018)
76   !! $Id$
77   !! Software governed by the CeCILL license (see ./LICENSE)
78   !!----------------------------------------------------------------------
79CONTAINS
80
81   SUBROUTINE nemo_gcm
82      !!----------------------------------------------------------------------
83      !!                     ***  ROUTINE nemo_gcm  ***
84      !!
85      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
86      !!              curvilinear mesh on the sphere.
87      !!
88      !! ** Method  : - model general initialization
89      !!              - launch the time-stepping (dta_dyn and trc_stp)
90      !!              - finalize the run by closing files and communications
91      !!
92      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
93      !!              Madec, 2008, internal report, IPSL.
94      !!----------------------------------------------------------------------
95      INTEGER :: istp       ! time step index
96      !!----------------------------------------------------------------------
97
98      CALL nemo_init  ! Initializations
99
100      ! check that all process are still there... If some process have an error,
101      ! they will never enter in step and other processes will wait until the end of the cpu time!
102      CALL mpp_max( 'nemogcm', nstop )
103
104      !                            !-----------------------!
105      !                            !==   time stepping   ==!
106      !                            !-----------------------!
107      istp = nit000
108      !
109      IF( ln_rnf )   CALL sbc_rnf(istp)   ! runoffs initialization
110      !
111      CALL iom_init( cxios_context )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
112      !
113      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  OFF time-stepping  ==!
114         !
115         IF( istp /= nit000 )   CALL day        ( istp )         ! Calendar (day was already called at nit000 in day_init)
116                                CALL iom_setkt  ( istp - nit000 + 1, cxios_context )   ! say to iom that we are at time step kstp
117#if defined key_sed_off
118                                CALL dta_dyn_sed( istp,      Nnn      )       ! Interpolation of the dynamical fields
119#else
120                                CALL dta_dyn    ( istp, Nbb, Nnn, Naa )       ! Interpolation of the dynamical fields
121#endif
122                                CALL trc_stp    ( istp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping
123#if ! defined key_sed_off
124         IF( .NOT.ln_linssh )   CALL dta_dyn_atf( istp, Nbb, Nnn, Naa )       ! time filter of sea  surface height and vertical scale factors
125#endif
126         ! Swap time levels
127         Nrhs = Nbb
128         Nbb = Nnn
129         Nnn = Naa
130         Naa = Nrhs
131         !
132#if ! defined key_sed_off
133         IF( .NOT.ln_linssh )   CALL dta_dyn_sf_interp( istp, Nnn )  ! calculate now grid parameters
134#endif
135                                CALL stp_ctl    ( istp )             ! Time loop: control and print
136         istp = istp + 1
137      END DO
138      !
139#if defined key_iomput
140      CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
141#endif
142
143      !                            !------------------------!
144      !                            !==  finalize the run  ==!
145      !                            !------------------------!
146      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
147
148      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
149         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
150         CALL ctl_stop( ctmp1 )
151      ENDIF
152      !
153      IF( ln_timing )   CALL timing_finalize
154      !
155      CALL nemo_closefile
156      !
157#if defined key_iomput
158                     CALL xios_finalize   ! end mpp communications with xios
159#else
160      IF( lk_mpp )   CALL mppstop         ! end mpp communications
161#endif
162      !
163      IF(lwm) THEN
164         IF( nstop == 0 ) THEN   ;   STOP 0
165         ELSE                    ;   STOP 123
166         ENDIF
167      ENDIF
168      !
169   END SUBROUTINE nemo_gcm
170
171
172   SUBROUTINE nemo_init
173      !!----------------------------------------------------------------------
174      !!                     ***  ROUTINE nemo_init  ***
175      !!
176      !! ** Purpose :   initialization of the nemo model in off-line mode
177      !!----------------------------------------------------------------------
178      INTEGER ::   ios, ilocal_comm   ! local integers
179      !!
180      NAMELIST/namctl/ sn_cfctl, nn_print, nn_ictls, nn_ictle,              &
181         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
182         &             ln_timing, ln_diacfl
183      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
184      !!----------------------------------------------------------------------
185      !
186      cxios_context = 'nemo'
187      nn_hls = 1
188      !
189      !                             !-------------------------------------------------!
190      !                             !     set communicator & select the local rank    !
191      !                             !  must be done as soon as possible to get narea  !
192      !                             !-------------------------------------------------!
193      !
194#if defined key_iomput
195      CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
196      CALL mpp_start( ilocal_comm )
197#else
198      CALL mpp_start( )
199#endif
200      !
201      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
202      lwm = (narea == 1)                ! control of output namelists
203      !
204      !                             !---------------------------------------------------------------!
205      !                             ! Open output files, reference and configuration namelist files !
206      !                             !---------------------------------------------------------------!
207      !
208      ! open ocean.output as soon as possible to get all output prints (including errors messages)
209      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
210      ! open reference and configuration namelist files
211                  CALL load_nml( numnam_ref,        'namelist_ref',                                           -1, lwm )
212                  CALL load_nml( numnam_cfg,        'namelist_cfg',                                           -1, lwm )
213      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
214      ! open /dev/null file to be able to supress output write easily
215      IF( Agrif_Root() ) THEN
216                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
217#ifdef key_agrif
218      ELSE
219                  numnul = Agrif_Parent(numnul)   
220#endif
221      ENDIF
222      !
223      !                             !--------------------!
224      !                             ! Open listing units !  -> need sn_cfctl from namctl to define lwp
225      !                             !--------------------!
226      !
227      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
228901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
229      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
230902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
231      !
232      ! finalize the definition of namctl variables
233      IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 )   &
234         &   CALL nemo_set_cfctl( sn_cfctl, .FALSE. )
235      !
236      lwp = (narea == 1) .OR. sn_cfctl%l_oceout    ! control of all listing output print
237      !
238      IF(lwp) THEN                            ! open listing units
239         !
240         IF( .NOT. lwm )   &           ! alreay opened for narea == 1
241            &     CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
242         !
243         WRITE(numout,*)
244         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
245         WRITE(numout,*) '                       NEMO team'
246         WRITE(numout,*) '                   Off-line TOP Model'
247         WRITE(numout,*) '                NEMO version 4.0  (2019) '
248         WRITE(numout,*)
249         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
250         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
251         WRITE(numout,*)
252         WRITE(numout,*) "           o         _,           _,             "
253         WRITE(numout,*) "            o      .' (        .-' /             "
254         WRITE(numout,*) "           o     _/..._'.    .'   /              "
255         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
256         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
257         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
258         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
259         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
260         WRITE(numout,*) "       )  )                        `     (   (   "
261         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
262         WRITE(numout,*)
263         !
264         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
265         !
266      ENDIF
267      !
268      IF(lwm) WRITE( numond, namctl )
269      !
270      !                             !------------------------------------!
271      !                             !  Set global domain size parameters !
272      !                             !------------------------------------!
273      !     
274      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
275903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
276      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
277904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
278      !
279      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
280         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
281      ELSE                                ! user-defined namelist
282         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
283      ENDIF
284      !
285      IF(lwm)   WRITE( numond, namcfg )
286      l_offline = .true.                  ! passive tracers are run offline
287      !
288      !                             !-----------------------------------------!
289      !                             ! mpp parameters and domain decomposition !
290      !                             !-----------------------------------------!
291      !
292      CALL mpp_init
293
294      CALL halo_mng_init()
295      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
296      CALL nemo_alloc()
297
298      ! Initialise time level indices
299      Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
300
301      !                             !-------------------------------!
302      !                             !  NEMO general initialization  !
303      !                             !-------------------------------!
304
305      CALL nemo_ctl                          ! Control prints
306      !
307      !                                      ! General initialization
308      IF( ln_timing    )   CALL timing_init
309      IF( ln_timing    )   CALL timing_start( 'nemo_init')
310      !
311                           CALL     phy_cst         ! Physical constants
312                           CALL     eos_init        ! Equation of state
313      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
314                           CALL     dom_init( Nbb, Nnn, Naa, "OPA") ! Domain
315      IF( sn_cfctl%l_prtctl )   &
316         &                 CALL prt_ctl_init        ! Print control
317
318                           CALL  istate_init( Nnn, Naa )    ! ocean initial state (Dynamics and tracers)
319
320                           CALL     sbc_init( Nbb, Nnn, Naa )    ! Forcings : surface module
321                           CALL     bdy_init    ! Open boundaries initialisation   
322
323      !                                      ! Tracer physics
324                           CALL ldf_tra_init    ! Lateral ocean tracer physics
325                           CALL ldf_eiv_init    ! Eddy induced velocity param
326                           CALL tra_ldf_init    ! lateral mixing
327      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
328      IF( ln_traqsr    )   CALL tra_qsr_init    ! penetrative solar radiation
329      IF( ln_trabbl    )   CALL tra_bbl_init    ! advective (and/or diffusive) bottom boundary layer scheme
330
331      !                                      ! Passive tracers
332                           CALL trc_nam_run    ! Needed to get restart parameters for passive tracers
333                           CALL trc_rst_cal( nit000, 'READ' )   ! calendar
334#if defined key_sed_off
335                           CALL dta_dyn_sed_init(  Nnn      )        ! Initialization for the dynamics
336#else
337                           CALL dta_dyn_init( Nbb, Nnn, Naa )        ! Initialization for the dynamics
338#endif
339
340                           CALL     trc_init( Nbb, Nnn, Naa )        ! Passive tracers initialization
341                           CALL dia_ptr_init   ! Poleward TRansports initialization
342                           
343      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
344      !
345      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
346      !
347   END SUBROUTINE nemo_init
348
349
350   SUBROUTINE nemo_ctl
351      !!----------------------------------------------------------------------
352      !!                     ***  ROUTINE nemo_ctl  ***
353      !!
354      !! ** Purpose :   control print setting
355      !!
356      !! ** Method  : - print namctl and namcfg information and check some consistencies
357      !!----------------------------------------------------------------------
358      !
359      IF(lwp) THEN                  ! control print
360         WRITE(numout,*)
361         WRITE(numout,*) 'nemo_ctl: Control prints'
362         WRITE(numout,*) '~~~~~~~~'
363         WRITE(numout,*) '   Namelist namctl'
364         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
365         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
366         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
367         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
368         WRITE(numout,*) '                              sn_cfctl%l_prtctl  = ', sn_cfctl%l_prtctl
369         WRITE(numout,*) '                              sn_cfctl%l_prttrc  = ', sn_cfctl%l_prttrc
370         WRITE(numout,*) '                              sn_cfctl%l_oasout  = ', sn_cfctl%l_oasout
371         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
372         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
373         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
374         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
375         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
376         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
377         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
378         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
379         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
380         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
381         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
382         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
383         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
384      ENDIF
385      !
386      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
387      nictls    = nn_ictls
388      nictle    = nn_ictle
389      njctls    = nn_jctls
390      njctle    = nn_jctle
391      isplt     = nn_isplt
392      jsplt     = nn_jsplt
393
394      IF(lwp) THEN                  ! control print
395         WRITE(numout,*)
396         WRITE(numout,*) '   Namelist namcfg'
397         WRITE(numout,*) '      read domain configuration file              ln_read_cfg      = ', ln_read_cfg
398         WRITE(numout,*) '         filename to be read                         cn_domcfg     = ', TRIM(cn_domcfg)
399         WRITE(numout,*) '         keep closed seas in the domain (if exist)   ln_closea     = ', ln_closea
400         WRITE(numout,*) '      create a configuration definition file      ln_write_cfg     = ', ln_write_cfg
401         WRITE(numout,*) '         filename to be written                      cn_domcfg_out = ', TRIM(cn_domcfg_out)
402         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr     = ', ln_use_jattr
403      ENDIF
404      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
405      !
406      !                             ! Parameter control
407      !
408      IF( sn_cfctl%l_prtctl .OR. sn_cfctl%l_prttrc ) THEN              ! sub-domain area indices for the control prints
409         IF( lk_mpp .AND. jpnij > 1 ) THEN
410            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
411         ELSE
412            IF( isplt == 1 .AND. jsplt == 1  ) THEN
413               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
414                  &           ' - the print control will be done over the whole domain' )
415            ENDIF
416            ijsplt = isplt * jsplt            ! total number of processors ijsplt
417         ENDIF
418         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
419         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
420         !
421         !                              ! indices used for the SUM control
422         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
423            lsp_area = .FALSE.
424         ELSE                                             ! print control done over a specific  area
425            lsp_area = .TRUE.
426            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
427               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
428               nictls = 1
429            ENDIF
430            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
431               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
432               nictle = jpiglo
433            ENDIF
434            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
435               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
436               njctls = 1
437            ENDIF
438            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
439               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
440               njctle = jpjglo
441            ENDIF
442         ENDIF
443      ENDIF
444      !
445      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
446         &                                                'Compile with key_nosignedzero enabled' )
447      !
448   END SUBROUTINE nemo_ctl
449
450
451   SUBROUTINE nemo_closefile
452      !!----------------------------------------------------------------------
453      !!                     ***  ROUTINE nemo_closefile  ***
454      !!
455      !! ** Purpose :   Close the files
456      !!----------------------------------------------------------------------
457      !
458      IF( lk_mpp )   CALL mppsync
459      !
460      CALL iom_close                                 ! close all input/output files managed by iom_*
461      !
462      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
463      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
464      !
465      numout = 6                                     ! redefine numout in case it is used after this point...
466      !
467   END SUBROUTINE nemo_closefile
468
469
470   SUBROUTINE nemo_alloc
471      !!----------------------------------------------------------------------
472      !!                     ***  ROUTINE nemo_alloc  ***
473      !!
474      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
475      !!
476      !! ** Method  :
477      !!----------------------------------------------------------------------
478      USE diawri ,   ONLY : dia_wri_alloc
479      USE dom_oce,   ONLY : dom_oce_alloc
480      USE zdf_oce,   ONLY : zdf_oce_alloc
481      USE trc_oce,   ONLY : trc_oce_alloc
482      USE bdy_oce,   ONLY : bdy_oce_alloc
483      !
484      INTEGER :: ierr
485      !!----------------------------------------------------------------------
486      !
487      ierr =        oce_alloc    ()          ! ocean
488      ierr = ierr + dia_wri_alloc()
489      ierr = ierr + dom_oce_alloc()          ! ocean domain
490      ierr = ierr + zdf_oce_alloc()          ! ocean vertical physics
491      ierr = ierr + trc_oce_alloc()          ! shared TRC / TRA arrays
492      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)     
493      !
494      CALL mpp_sum( 'nemogcm', ierr )
495      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
496      !
497   END SUBROUTINE nemo_alloc
498
499   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto )
500      !!----------------------------------------------------------------------
501      !!                     ***  ROUTINE nemo_set_cfctl  ***
502      !!
503      !! ** Purpose :   Set elements of the output control structure to setto.
504     !!
505      !! ** Method  :   Note this routine can be used to switch on/off some
506      !!                types of output for selected areas.
507      !!----------------------------------------------------------------------
508      TYPE(sn_ctl), INTENT(inout) :: sn_cfctl
509      LOGICAL     , INTENT(in   ) :: setto
510      !!----------------------------------------------------------------------
511      sn_cfctl%l_runstat = setto
512      sn_cfctl%l_trcstat = setto
513      sn_cfctl%l_oceout  = setto
514      sn_cfctl%l_layout  = setto
515      sn_cfctl%l_prtctl  = setto
516      sn_cfctl%l_prttrc  = setto
517      sn_cfctl%l_oasout  = setto
518   END SUBROUTINE nemo_set_cfctl
519
520   SUBROUTINE istate_init( Kmm, Kaa )
521      !!----------------------------------------------------------------------
522      !!                   ***  ROUTINE istate_init  ***
523      !!
524      !! ** Purpose :   Initialization to zero of the dynamics and tracers.
525      !!----------------------------------------------------------------------
526      INTEGER, INTENT(in) ::   Kmm, Kaa  ! ocean time level indices
527      !
528      !     now fields         !     after fields      !
529      uu   (:,:,:,Kmm)   = 0._wp   ;   uu(:,:,:,Kaa) = 0._wp   !
530      vv   (:,:,:,Kmm)   = 0._wp   ;   vv(:,:,:,Kaa) = 0._wp   !
531      ww   (:,:,:)   = 0._wp   !                       !
532      hdiv (:,:,:)   = 0._wp   !                       !
533      ts  (:,:,:,:,Kmm) = 0._wp   !                       !
534      !
535      rhd  (:,:,:) = 0.e0
536      rhop (:,:,:) = 0.e0
537      rn2  (:,:,:) = 0.e0
538      !
539   END SUBROUTINE istate_init
540
541
542   SUBROUTINE stp_ctl( kt )
543      !!----------------------------------------------------------------------
544      !!                    ***  ROUTINE stp_ctl  ***
545      !!
546      !! ** Purpose :   Control the run
547      !!
548      !! ** Method  : - Save the time step in numstp
549      !!
550      !! ** Actions :   'time.step' file containing the last ocean time-step
551      !!----------------------------------------------------------------------
552      INTEGER, INTENT(in   ) ::   kt      ! ocean time-step index
553      !!----------------------------------------------------------------------
554      !
555      IF( kt == nit000 .AND. lwm ) THEN
556         WRITE(numout,*)
557         WRITE(numout,*) 'stp_ctl : time-stepping control'
558         WRITE(numout,*) '~~~~~~~'
559         ! open time.step file
560         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
561      ENDIF
562      !
563      IF(lwm) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
564      IF(lwm) REWIND( numstp )                       ! --------------------------
565      !
566   END SUBROUTINE stp_ctl
567   !!======================================================================
568END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.