New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in NEMO/branches/2020/dev_r12558_HPC-08_epico_Extra_Halo/src/OFF – NEMO

Context Navigation

source: NEMO/branches/2020/dev_r12558_HPC-08_epico_Extra_Halo/src/OFF/nemogcm.F90 @ 13015

Last change on this file since 13015 was 13015, checked in by smasson, 4 years ago
Extra_Halo: merge with trunk@13012, see #2366
Property svn:keywords set to `Id`
File size: 28.3 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Off-line Ocean : passive tracer evolution, dynamics read in files
5	!!======================================================================
6	!! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line
7	!! 3.4 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8	!! 4.0 ! 2016-10 (C. Ethe, G. Madec, S. Flavoni) domain configuration / user defined interface
9	!! 4.1 ! 2019-08 (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
10	!!----------------------------------------------------------------------
11
12	!!----------------------------------------------------------------------
13	!! nemo_gcm : off-line: solve ocean tracer only
14	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
15	!! nemo_init : initialization of the NEMO system
16	!! nemo_ctl : initialisation of the contol print
17	!! nemo_closefile: close remaining open files
18	!! nemo_alloc : dynamical allocation
19	!! istate_init : simple initialization to zero of ocean fields
20	!! stp_ctl : reduced step control (no dynamics in off-line)
21	!!----------------------------------------------------------------------
22	USE dom_oce ! ocean space domain variables
23	USE oce ! dynamics and tracers variables
24	USE trc_oce ! Shared ocean/passive tracers variables
25	USE c1d ! 1D configuration
26	USE domain ! domain initialization from coordinate & bathymetry (dom_init routine)
27	USE closea ! treatment of closed seas (for ln_closea)
28	USE usrdef_nam ! user defined configuration
29	USE eosbn2 ! equation of state (eos bn2 routine)
30	USE bdy_oce, ONLY : ln_bdy
31	USE bdyini ! open boundary cond. setting (bdy_init routine)
32	! ! ocean physics
33	USE ldftra ! lateral diffusivity setting (ldf_tra_init routine)
34	USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine)
35	USE traqsr ! solar radiation penetration (tra_qsr_init routine)
36	USE trabbl ! bottom boundary layer (tra_bbl_init routine)
37	USE traldf ! lateral physics (tra_ldf_init routine)
38	USE sbcmod ! surface boundary condition (sbc_init routine)
39	USE phycst ! physical constant (par_cst routine)
40	USE dtadyn ! Lecture and Interpolation of the dynamical fields
41	USE trcini ! Initilization of the passive tracers
42	USE daymod ! calendar (day routine)
43	USE trcstp ! passive tracer time-stepping (trc_stp routine)
44	USE dtadyn ! Lecture and interpolation of the dynamical fields
45	! ! Passive tracers needs
46	USE trc ! passive tracer : variables
47	USE trcnam ! passive tracer : namelist
48	USE trcrst ! passive tracer restart
49	USE diaptr ! Need to initialise this as some variables are used in if statements later
50	USE sbc_oce , ONLY : ln_rnf
51	USE sbcrnf ! surface boundary condition : runoffs
52	! ! I/O & MPP
53	USE iom ! I/O library
54	USE in_out_manager ! I/O manager
55	USE mppini ! shared/distributed memory setting (mpp_init routine)
56	USE lib_mpp ! distributed memory computing
57	#if defined key_iomput
58	USE xios ! xIOserver
59	#endif
60	USE prtctl ! Print control (prt_ctl_init routine)
61	USE timing ! Timing
62	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
63	USE lbcnfd , ONLY : isendto, nsndto ! Setup of north fold exchanges
64	USE step, ONLY : Nbb, Nnn, Naa, Nrhs ! time level indices
65	USE halo_mng
66
67	IMPLICIT NONE
68	PRIVATE
69
70	PUBLIC nemo_gcm ! called by nemo.F90
71
72	CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
73
74	!!----------------------------------------------------------------------
75	!! NEMO/OFF 4.0 , NEMO Consortium (2018)
76	!! $Id$
77	!! Software governed by the CeCILL license (see ./LICENSE)
78	!!----------------------------------------------------------------------
79	CONTAINS
80
81	SUBROUTINE nemo_gcm
82	!!----------------------------------------------------------------------
83	!! * ROUTINE nemo_gcm *
84	!!
85	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
86	!! curvilinear mesh on the sphere.
87	!!
88	!! ** Method : - model general initialization
89	!! - launch the time-stepping (dta_dyn and trc_stp)
90	!! - finalize the run by closing files and communications
91	!!
92	!! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL.
93	!! Madec, 2008, internal report, IPSL.
94	!!----------------------------------------------------------------------
95	INTEGER :: istp ! time step index
96	!!----------------------------------------------------------------------
97
98	CALL nemo_init ! Initializations
99
100	! check that all process are still there... If some process have an error,
101	! they will never enter in step and other processes will wait until the end of the cpu time!
102	CALL mpp_max( 'nemogcm', nstop )
103
104	! !-----------------------!
105	! !== time stepping ==!
106	! !-----------------------!
107	istp = nit000
108	!
109	IF( ln_rnf ) CALL sbc_rnf(istp) ! runoffs initialization
110	!
111	CALL iom_init( cxios_context ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
112	!
113	DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== OFF time-stepping ==!
114	!
115	IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init)
116	CALL iom_setkt ( istp - nit000 + 1, cxios_context ) ! say to iom that we are at time step kstp
117	#if defined key_sed_off
118	CALL dta_dyn_sed( istp, Nnn ) ! Interpolation of the dynamical fields
119	#else
120	CALL dta_dyn ( istp, Nbb, Nnn, Naa ) ! Interpolation of the dynamical fields
121	#endif
122	CALL trc_stp ( istp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping
123	#if ! defined key_sed_off
124	IF( .NOT.ln_linssh ) CALL dta_dyn_atf( istp, Nbb, Nnn, Naa ) ! time filter of sea surface height and vertical scale factors
125	#endif
126	! Swap time levels
127	Nrhs = Nbb
128	Nbb = Nnn
129	Nnn = Naa
130	Naa = Nrhs
131	!
132	#if ! defined key_sed_off
133	IF( .NOT.ln_linssh ) CALL dta_dyn_sf_interp( istp, Nnn ) ! calculate now grid parameters
134	#endif
135	CALL stp_ctl ( istp ) ! Time loop: control and print
136	istp = istp + 1
137	END DO
138	!
139	#if defined key_iomput
140	CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
141	#endif
142
143	! !------------------------!
144	! !== finalize the run ==!
145	! !------------------------!
146	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
147
148	IF( nstop /= 0 .AND. lwp ) THEN ! error print
149	WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found'
150	WRITE(ctmp2,) ' Look for "E R R O R" messages in all existing ocean_output files'
151	CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 )
152	ENDIF
153	!
154	IF( ln_timing ) CALL timing_finalize
155	!
156	CALL nemo_closefile
157	!
158	#if defined key_iomput
159	CALL xios_finalize ! end mpp communications with xios
160	#else
161	IF( lk_mpp ) CALL mppstop ! end mpp communications
162	#endif
163	!
164	IF(lwm) THEN
165	IF( nstop == 0 ) THEN ; STOP 0
166	ELSE ; STOP 123
167	ENDIF
168	ENDIF
169	!
170	END SUBROUTINE nemo_gcm
171
172
173	SUBROUTINE nemo_init
174	!!----------------------------------------------------------------------
175	!! * ROUTINE nemo_init *
176	!!
177	!! ** Purpose : initialization of the nemo model in off-line mode
178	!!----------------------------------------------------------------------
179	INTEGER :: ios, ilocal_comm ! local integers
180	!!
181	NAMELIST/namctl/ sn_cfctl, nn_print, nn_ictls, nn_ictle, &
182	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
183	& ln_timing, ln_diacfl
184	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
185	!!----------------------------------------------------------------------
186	!
187	cxios_context = 'nemo'
188	nn_hls = 1
189	!
190	! !-------------------------------------------------!
191	! ! set communicator & select the local rank !
192	! ! must be done as soon as possible to get narea !
193	! !-------------------------------------------------!
194	!
195	#if defined key_iomput
196	CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios
197	CALL mpp_start( ilocal_comm )
198	#else
199	CALL mpp_start( )
200	#endif
201	!
202	narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 )
203	lwm = (narea == 1) ! control of output namelists
204	!
205	! !---------------------------------------------------------------!
206	! ! Open output files, reference and configuration namelist files !
207	! !---------------------------------------------------------------!
208	!
209	! open ocean.output as soon as possible to get all output prints (including errors messages)
210	IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
211	! open reference and configuration namelist files
212	CALL load_nml( numnam_ref, 'namelist_ref', -1, lwm )
213	CALL load_nml( numnam_cfg, 'namelist_cfg', -1, lwm )
214	IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
215	! open /dev/null file to be able to supress output write easily
216	IF( Agrif_Root() ) THEN
217	CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
218	#ifdef key_agrif
219	ELSE
220	numnul = Agrif_Parent(numnul)
221	#endif
222	ENDIF
223	!
224	! !--------------------!
225	! ! Open listing units ! -> need sn_cfctl from namctl to define lwp
226	! !--------------------!
227	!
228	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
229	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' )
230	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
231	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' )
232	!
233	! finalize the definition of namctl variables
234	IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) &
235	& CALL nemo_set_cfctl( sn_cfctl, .FALSE. )
236	!
237	lwp = (narea == 1) .OR. sn_cfctl%l_oceout ! control of all listing output print
238	!
239	IF(lwp) THEN ! open listing units
240	!
241	IF( .NOT. lwm ) & ! alreay opened for narea == 1
242	& CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
243	!
244	WRITE(numout,*)
245	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
246	WRITE(numout,*) ' NEMO team'
247	WRITE(numout,*) ' Off-line TOP Model'
248	WRITE(numout,*) ' NEMO version 4.0 (2019) '
249	WRITE(numout,*)
250	WRITE(numout,*) " ._ ._ ._ ._ ._ "
251	WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
252	WRITE(numout,*)
253	WRITE(numout,*) " o _, _, "
254	WRITE(numout,*) " o .' ( .-' / "
255	WRITE(numout,*) " o _/..._'. .' / "
256	WRITE(numout,*) " ( o .-'` ` '-./ _.' "
257	WRITE(numout,*) " ) ( o) ;= <_ ( "
258	WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) "
259	WRITE(numout,*) " ) ) \) \|`\ \) '. \ ( ( "
260	WRITE(numout,*) " ( ( \_/ '-._\ ) ) "
261	WRITE(numout,*) " ) ) ` ( ( "
262	WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
263	WRITE(numout,*)
264	!
265	WRITE(numout,cform_aaa) ! Flag AAAAAAA
266	!
267	ENDIF
268	!
269	IF(lwm) WRITE( numond, namctl )
270	!
271	! !------------------------------------!
272	! ! Set global domain size parameters !
273	! !------------------------------------!
274	!
275	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
276	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' )
277	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
278	904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' )
279	!
280	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
281	CALL domain_cfg ( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio )
282	ELSE ! user-defined namelist
283	CALL usr_def_nam( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio )
284	ENDIF
285	!
286	IF(lwm) WRITE( numond, namcfg )
287	l_offline = .true. ! passive tracers are run offline
288	!
289	! !-----------------------------------------!
290	! ! mpp parameters and domain decomposition !
291	! !-----------------------------------------!
292	!
293	CALL mpp_init
294
295	CALL halo_mng_init()
296	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
297	CALL nemo_alloc()
298
299	! Initialise time level indices
300	Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
301
302	! !-------------------------------!
303	! ! NEMO general initialization !
304	! !-------------------------------!
305
306	CALL nemo_ctl ! Control prints
307	!
308	! ! General initialization
309	IF( ln_timing ) CALL timing_init
310	IF( ln_timing ) CALL timing_start( 'nemo_init')
311	!
312	CALL phy_cst ! Physical constants
313	CALL eos_init ! Equation of state
314	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
315	CALL dom_init( Nbb, Nnn, Naa, "OPA") ! Domain
316	IF( sn_cfctl%l_prtctl ) &
317	& CALL prt_ctl_init ! Print control
318
319	CALL istate_init( Nnn, Naa ) ! ocean initial state (Dynamics and tracers)
320
321	CALL sbc_init( Nbb, Nnn, Naa ) ! Forcings : surface module
322	CALL bdy_init ! Open boundaries initialisation
323
324	! ! Tracer physics
325	CALL ldf_tra_init ! Lateral ocean tracer physics
326	CALL ldf_eiv_init ! Eddy induced velocity param
327	CALL tra_ldf_init ! lateral mixing
328	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
329	IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation
330	IF( ln_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
331
332	! ! Passive tracers
333	CALL trc_nam_run ! Needed to get restart parameters for passive tracers
334	CALL trc_rst_cal( nit000, 'READ' ) ! calendar
335	#if defined key_sed_off
336	CALL dta_dyn_sed_init( Nnn ) ! Initialization for the dynamics
337	#else
338	CALL dta_dyn_init( Nbb, Nnn, Naa ) ! Initialization for the dynamics
339	#endif
340
341	CALL trc_init( Nbb, Nnn, Naa ) ! Passive tracers initialization
342	CALL dia_ptr_init ! Poleward TRansports initialization
343
344	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
345	!
346	IF( ln_timing ) CALL timing_stop( 'nemo_init')
347	!
348	END SUBROUTINE nemo_init
349
350
351	SUBROUTINE nemo_ctl
352	!!----------------------------------------------------------------------
353	!! * ROUTINE nemo_ctl *
354	!!
355	!! ** Purpose : control print setting
356	!!
357	!! ** Method : - print namctl and namcfg information and check some consistencies
358	!!----------------------------------------------------------------------
359	!
360	IF(lwp) THEN ! control print
361	WRITE(numout,*)
362	WRITE(numout,*) 'nemo_ctl: Control prints'
363	WRITE(numout,*) '~~~~~~~~'
364	WRITE(numout,*) ' Namelist namctl'
365	WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
366	WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
367	WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout
368	WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout
369	WRITE(numout,*) ' sn_cfctl%l_prtctl = ', sn_cfctl%l_prtctl
370	WRITE(numout,*) ' sn_cfctl%l_prttrc = ', sn_cfctl%l_prttrc
371	WRITE(numout,*) ' sn_cfctl%l_oasout = ', sn_cfctl%l_oasout
372	WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin
373	WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax
374	WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr
375	WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr
376	WRITE(numout,*) ' level of print nn_print = ', nn_print
377	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
378	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
379	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
380	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
381	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
382	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
383	WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing
384	WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl
385	ENDIF
386	!
387	nprint = nn_print ! convert DOCTOR namelist names into OLD names
388	nictls = nn_ictls
389	nictle = nn_ictle
390	njctls = nn_jctls
391	njctle = nn_jctle
392	isplt = nn_isplt
393	jsplt = nn_jsplt
394
395	IF(lwp) THEN ! control print
396	WRITE(numout,*)
397	WRITE(numout,*) ' Namelist namcfg'
398	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
399	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
400	WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea
401	WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg
402	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
403	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
404	ENDIF
405	IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file
406	!
407	! ! Parameter control
408	!
409	IF( sn_cfctl%l_prtctl .OR. sn_cfctl%l_prttrc ) THEN ! sub-domain area indices for the control prints
410	IF( lk_mpp .AND. jpnij > 1 ) THEN
411	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
412	ELSE
413	IF( isplt == 1 .AND. jsplt == 1 ) THEN
414	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
415	& ' - the print control will be done over the whole domain' )
416	ENDIF
417	ijsplt = isplt * jsplt ! total number of processors ijsplt
418	ENDIF
419	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
420	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
421	!
422	! ! indices used for the SUM control
423	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
424	lsp_area = .FALSE.
425	ELSE ! print control done over a specific area
426	lsp_area = .TRUE.
427	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
428	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
429	nictls = 1
430	ENDIF
431	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
432	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
433	nictle = jpiglo
434	ENDIF
435	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
436	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
437	njctls = 1
438	ENDIF
439	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
440	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
441	njctle = jpjglo
442	ENDIF
443	ENDIF
444	ENDIF
445	!
446	IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', &
447	& 'Compile with key_nosignedzero enabled' )
448	!
449	END SUBROUTINE nemo_ctl
450
451
452	SUBROUTINE nemo_closefile
453	!!----------------------------------------------------------------------
454	!! * ROUTINE nemo_closefile *
455	!!
456	!! ** Purpose : Close the files
457	!!----------------------------------------------------------------------
458	!
459	IF( lk_mpp ) CALL mppsync
460	!
461	CALL iom_close ! close all input/output files managed by iom_*
462	!
463	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
464	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
465	!
466	numout = 6 ! redefine numout in case it is used after this point...
467	!
468	END SUBROUTINE nemo_closefile
469
470
471	SUBROUTINE nemo_alloc
472	!!----------------------------------------------------------------------
473	!! * ROUTINE nemo_alloc *
474	!!
475	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
476	!!
477	!! ** Method :
478	!!----------------------------------------------------------------------
479	USE diawri , ONLY : dia_wri_alloc
480	USE dom_oce, ONLY : dom_oce_alloc
481	USE zdf_oce, ONLY : zdf_oce_alloc
482	USE trc_oce, ONLY : trc_oce_alloc
483	USE bdy_oce, ONLY : bdy_oce_alloc
484	!
485	INTEGER :: ierr
486	!!----------------------------------------------------------------------
487	!
488	ierr = oce_alloc () ! ocean
489	ierr = ierr + dia_wri_alloc()
490	ierr = ierr + dom_oce_alloc() ! ocean domain
491	ierr = ierr + zdf_oce_alloc() ! ocean vertical physics
492	ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays
493	ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization)
494	!
495	CALL mpp_sum( 'nemogcm', ierr )
496	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
497	!
498	END SUBROUTINE nemo_alloc
499
500	SUBROUTINE nemo_set_cfctl(sn_cfctl, setto )
501	!!----------------------------------------------------------------------
502	!! * ROUTINE nemo_set_cfctl *
503	!!
504	!! ** Purpose : Set elements of the output control structure to setto.
505	!!
506	!! ** Method : Note this routine can be used to switch on/off some
507	!! types of output for selected areas.
508	!!----------------------------------------------------------------------
509	TYPE(sn_ctl), INTENT(inout) :: sn_cfctl
510	LOGICAL , INTENT(in ) :: setto
511	!!----------------------------------------------------------------------
512	sn_cfctl%l_runstat = setto
513	sn_cfctl%l_trcstat = setto
514	sn_cfctl%l_oceout = setto
515	sn_cfctl%l_layout = setto
516	sn_cfctl%l_prtctl = setto
517	sn_cfctl%l_prttrc = setto
518	sn_cfctl%l_oasout = setto
519	END SUBROUTINE nemo_set_cfctl
520
521	SUBROUTINE istate_init( Kmm, Kaa )
522	!!----------------------------------------------------------------------
523	!! * ROUTINE istate_init *
524	!!
525	!! ** Purpose : Initialization to zero of the dynamics and tracers.
526	!!----------------------------------------------------------------------
527	INTEGER, INTENT(in) :: Kmm, Kaa ! ocean time level indices
528	!
529	! now fields ! after fields !
530	uu (:,:,:,Kmm) = 0._wp ; uu(:,:,:,Kaa) = 0._wp !
531	vv (:,:,:,Kmm) = 0._wp ; vv(:,:,:,Kaa) = 0._wp !
532	ww (:,:,:) = 0._wp ! !
533	hdiv (:,:,:) = 0._wp ! !
534	ts (:,:,:,:,Kmm) = 0._wp ! !
535	!
536	rhd (:,:,:) = 0.e0
537	rhop (:,:,:) = 0.e0
538	rn2 (:,:,:) = 0.e0
539	!
540	END SUBROUTINE istate_init
541
542
543	SUBROUTINE stp_ctl( kt )
544	!!----------------------------------------------------------------------
545	!! * ROUTINE stp_ctl *
546	!!
547	!! ** Purpose : Control the run
548	!!
549	!! ** Method : - Save the time step in numstp
550	!!
551	!! ** Actions : 'time.step' file containing the last ocean time-step
552	!!----------------------------------------------------------------------
553	INTEGER, INTENT(in ) :: kt ! ocean time-step index
554	!!----------------------------------------------------------------------
555	!
556	IF( kt == nit000 .AND. lwm ) THEN
557	WRITE(numout,*)
558	WRITE(numout,*) 'stp_ctl : time-stepping control'
559	WRITE(numout,*) '~~~~~~~'
560	! open time.step file
561	CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
562	ENDIF
563	!
564	IF(lwm) WRITE ( numstp, '(1x, i8)' ) kt !* save the current time step in numstp
565	IF(lwm) REWIND( numstp ) ! --------------------------
566	!
567	END SUBROUTINE stp_ctl
568	!!======================================================================
569	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: