New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcabl.F90 in NEMO/branches/2020/dev_r12563_ASINTER-06_ABL_improvement/src/ABL – NEMO

source: NEMO/branches/2020/dev_r12563_ASINTER-06_ABL_improvement/src/ABL/sbcabl.F90 @ 12588

Last change on this file since 12588 was 12588, checked in by gsamson, 4 years ago

revised ABL model version including:

  • albmod cleaning
  • new abl mixing length option (nn_amxl = 3)
  • use rho_air function from aerobulk everywhere
  • remove mxl_abl (replaced by master (mxlm_abl) and dissipative (mxlm_abl) mixing lengths)
  • temporary flag "ln_tpot" to disable potential temperature computation in sbcblk
File size: 20.3 KB
Line 
1MODULE sbcabl
2   !!======================================================================
3   !!                       ***  MODULE  sbcabl  ***
4   !! Ocean forcing:  momentum, heat and freshwater flux formulation
5   !!                 derived from an ABL model
6   !!=====================================================================
7   !! History :  4.0  !  2019-03  (F. Lemarié & G. Samson)  Original code
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_abl_init  : Initialization of ABL model based on namelist options
12   !!   sbc_abl       : driver for the computation of momentum, heat and freshwater
13   !!                   fluxes over ocean via the ABL model
14   !!----------------------------------------------------------------------
15   USE abl            ! ABL
16   USE par_abl        ! abl parameters
17   USE ablmod
18   USE ablrst
19
20   USE phycst         ! physical constants
21   USE fldread        ! read input fields
22   USE sbc_oce        ! Surface boundary condition: ocean fields
23   USE sbcblk         ! Surface boundary condition: bulk formulae
24   USE sbcblk_phy     ! Surface boundary condition: bulk formulae
25   USE dom_oce, ONLY  : tmask
26   !
27   USE iom            ! I/O manager library
28   USE in_out_manager ! I/O manager
29   USE lib_mpp        ! distribued memory computing library
30   USE lib_fortran    ! to use key_nosignedzero
31   USE timing         ! Timing
32   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
33   USE prtctl         ! Print control
34#if defined key_si3
35   USE ice    , ONLY : u_ice, v_ice, tm_su, ato_i      ! ato_i = total open water fractional area
36   USE sbc_ice, ONLY : wndm_ice, utau_ice, vtau_ice
37#endif
38#if ! defined key_iomput
39   USE diawri    , ONLY : dia_wri_alloc_abl
40#endif
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   sbc_abl_init       ! routine called in sbcmod module
45   PUBLIC   sbc_abl            ! routine called in sbcmod module
46
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.7 , NEMO-consortium (2014)
49   !! $Id: sbcabl.F90 6416 2016-04-01 12:22:17Z clem $
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE sbc_abl_init
55      !!---------------------------------------------------------------------
56      !!                    ***  ROUTINE sbc_abl_init  ***
57      !!
58      !! ** Purposes :   - read namelist section namsbc_abl
59      !!                 - initialize and check parameter values
60      !!                 - initialize variables of ABL model
61      !!
62      !!----------------------------------------------------------------------
63      INTEGER            ::   ji, jj, jk, jbak, jbak_dta       ! dummy loop indices
64      INTEGER            ::   ios, ierror, ioptio              ! Local integer
65      INTEGER            ::   inum, indims, idimsz(4), id
66      CHARACTER(len=100) ::   cn_dir, cn_dom                   ! Atmospheric grid directory
67      REAL(wp)           ::   zcff,zcff1
68      LOGICAL            ::   lluldl
69      NAMELIST/namsbc_abl/ cn_dir, cn_dom, cn_ablrst_in, cn_ablrst_out,           &
70         &                 cn_ablrst_indir, cn_ablrst_outdir, ln_rstart_abl,      &
71         &                 ln_hpgls_frc, ln_geos_winds, nn_dyn_restore,           &
72         &                 rn_ldyn_min , rn_ldyn_max, rn_ltra_min, rn_ltra_max,   &
73         &                 nn_amxl, rn_Cm, rn_Ct, rn_Ce, rn_Ceps, rn_Rod, rn_Ric, &
74         &                 ln_smth_pblh
75      !!---------------------------------------------------------------------
76
77                                        ! Namelist namsbc_abl in reference namelist : ABL parameters
78      READ  ( numnam_ref, namsbc_abl, IOSTAT = ios, ERR = 901 )
79901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_abl in reference namelist' )
80      !
81                                        ! Namelist namsbc_abl in configuration namelist : ABL parameters
82      READ  ( numnam_cfg, namsbc_abl, IOSTAT = ios, ERR = 902 )
83902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_abl in configuration namelist' )
84      !
85      IF(lwm) WRITE( numond, namsbc_abl )
86      !
87      ! Check ABL mixing length option
88      IF( nn_amxl  < 0   .OR.  nn_amxl  > 2 )   &
89         &                 CALL ctl_stop( 'abl_init : bad flag, nn_amxl must be  0, 1 or 2 ' )
90      !
91      ! Check ABL dyn restore option
92      IF( nn_dyn_restore  < 0   .OR.  nn_dyn_restore  > 2 )   &
93         &                 CALL ctl_stop( 'abl_init : bad flag, nn_dyn_restore must be  0, 1 or 2 ' )
94
95      !!---------------------------------------------------------------------
96      !! Control prints
97      !!---------------------------------------------------------------------
98      IF(lwp) THEN                              ! Control print (other namelist variable)
99         WRITE(numout,*)
100         WRITE(numout,*) '      ABL -- cn_dir         = ', cn_dir
101         WRITE(numout,*) '      ABL -- cn_dom         = ', cn_dom
102         IF( ln_hpgls_frc ) THEN
103            WRITE(numout,*) '      ABL -- winds forced by large-scale pressure gradient'
104            IF(ln_geos_winds) THEN
105               ln_geos_winds = .FALSE.
106               WRITE(numout,*) '      ABL -- geostrophic guide disabled (not compatible with ln_hpgls_frc = .T.)'
107            END IF
108         ELSE IF( ln_geos_winds ) THEN
109            WRITE(numout,*) '      ABL -- winds forced by geostrophic winds'
110         ELSE
111            WRITE(numout,*) '      ABL -- Geostrophic winds and large-scale pressure gradient are ignored'
112         END IF
113         !
114         SELECT CASE ( nn_dyn_restore )
115         CASE ( 0 )
116            WRITE(numout,*) '      ABL -- No restoring for ABL winds'
117         CASE ( 1 )
118            WRITE(numout,*) '      ABL -- Restoring of ABL winds only in the equatorial region '
119         CASE ( 2 )
120            WRITE(numout,*) '      ABL -- Restoring of ABL winds activated everywhere '
121         END SELECT
122         !
123         IF( ln_smth_pblh )  WRITE(numout,*) '      ABL -- Smoothing of PBL height is activated'
124         !
125      ENDIF
126
127      !!---------------------------------------------------------------------
128      !! Convert nudging coefficient from hours to 1/sec
129      !!---------------------------------------------------------------------
130      zcff        = 1._wp / 3600._wp
131      rn_ldyn_min = zcff / rn_ldyn_min
132      rn_ldyn_max = zcff / rn_ldyn_max
133      rn_ltra_min = zcff / rn_ltra_min
134      rn_ltra_max = zcff / rn_ltra_max
135
136      !!---------------------------------------------------------------------
137      !! ABL grid initialization
138      !!---------------------------------------------------------------------
139      CALL iom_open( TRIM(cn_dir)//TRIM(cn_dom), inum )
140      id     = iom_varid( inum, 'e3t_abl', kdimsz=idimsz, kndims=indims, lduld=lluldl )
141      jpka   = idimsz(indims - COUNT( (/lluldl/) ) )
142      jpkam1 = jpka - 1
143
144      IF( abl_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'abl_init : unable to allocate arrays' )
145      CALL iom_get( inum, jpdom_unknown, 'e3t_abl', e3t_abl(:) )
146      CALL iom_get( inum, jpdom_unknown, 'e3w_abl', e3w_abl(:) )
147      CALL iom_get( inum, jpdom_unknown, 'ght_abl', ght_abl(:) )
148      CALL iom_get( inum, jpdom_unknown, 'ghw_abl', ghw_abl(:) )
149      CALL iom_close( inum )
150
151#if ! defined key_iomput
152      IF( dia_wri_alloc_abl()  /= 0 ) CALL ctl_stop( 'STOP', 'abl_init : unable to allocate arrays' )
153#endif
154
155      IF(lwp) THEN
156         WRITE(numout,*)
157         WRITE(numout,*) '    sbc_abl_init   : ABL Reference vertical grid'
158         WRITE(numout,*) '    ~~~~~~~'
159         WRITE(numout, "(9x,'  level ght_abl   ghw_abl   e3t_abl   e3w_abl  ')" )
160         WRITE(numout, "(10x, i4, 4f9.2)" ) ( jk, ght_abl(jk), ghw_abl(jk), e3t_abl(jk), e3w_abl(jk), jk = 1, jpka )
161      END IF
162
163      !!---------------------------------------------------------------------
164      !! Check TKE closure parameters
165      !!---------------------------------------------------------------------
166      rn_Sch  = rn_ce / rn_cm
167      mxl_min = (avm_bak / rn_cm) / sqrt( tke_min )
168      rn_Esfc =  1._wp / SQRT(rn_cm*rn_ceps)
169      rn_Lsfc = vkarmn * SQRT(SQRT(rn_cm*rn_ceps)) / rn_cm
170     
171      IF(lwp) THEN
172         WRITE(numout,*)
173         WRITE(numout,*) '    abl_zdf_tke   : ABL TKE turbulent closure'
174         WRITE(numout,*) '    ~~~~~~~~~~~'
175         IF(nn_amxl==0) WRITE(numout,*) 'Deardorff 80 length-scale '
176         IF(nn_amxl==1) WRITE(numout,*) 'Modified Deardorff 80 length-scale '
177         IF(nn_amxl==1) WRITE(numout,*) 'Bougeault and Lacarrere length-scale '     
178         IF(nn_amxl==3) WRITE(numout,*) 'Rodier et al. length-scale '   
179         WRITE(numout,*) ' Minimum value of atmospheric TKE           = ',tke_min,' m^2 s^-2'
180         WRITE(numout,*) ' Minimum value of atmospheric mixing length = ',mxl_min,' m'
181         WRITE(numout,*) ' Constant for turbulent viscosity           = ',rn_Cm
182         WRITE(numout,*) ' Constant for turbulent diffusivity         = ',rn_Ct
183         WRITE(numout,*) ' Constant for Schmidt number                = ',rn_Sch
184         WRITE(numout,*) ' Constant for TKE dissipation               = ',rn_Ceps
185         WRITE(numout,*) ' Constant for TKE sfc boundary condition    = ',rn_Esfc
186         WRITE(numout,*) ' Constant for mxl sfc boundary condition    = ',rn_Lsfc
187      END IF
188
189      !!-------------------------------------------------------------------------------------------
190      !! Compute parameters to build the vertical profile for the nudging term (used in abl_stp())
191      !!-------------------------------------------------------------------------------------------
192      zcff1       = 1._wp / ( jp_bmax - jp_bmin )**3
193      ! for active tracers
194      jp_alp3_tra = -2._wp * zcff1                       * ( rn_ltra_max - rn_ltra_min )
195      jp_alp2_tra =  3._wp * zcff1 * (jp_bmax + jp_bmin) * ( rn_ltra_max - rn_ltra_min )
196      jp_alp1_tra = -6._wp * zcff1 *  jp_bmax * jp_bmin  * ( rn_ltra_max - rn_ltra_min )
197      jp_alp0_tra = zcff1 * (  rn_ltra_max * jp_bmin*jp_bmin * (3._wp*jp_bmax - jp_bmin)      &
198         &                   - rn_ltra_min * jp_bmax*jp_bmax * (3._wp*jp_bmin - jp_bmax) )
199      ! for dynamics
200      jp_alp3_dyn = -2._wp * zcff1                       * ( rn_ldyn_max - rn_ldyn_min )
201      jp_alp2_dyn =  3._wp * zcff1 * (jp_bmax + jp_bmin) * ( rn_ldyn_max - rn_ldyn_min )
202      jp_alp1_dyn = -6._wp * zcff1 *  jp_bmax * jp_bmin  * ( rn_ldyn_max - rn_ldyn_min )
203      jp_alp0_dyn = zcff1 * (  rn_ldyn_max * jp_bmin*jp_bmin * (3._wp*jp_bmax - jp_bmin)      &
204         &                   - rn_ldyn_min * jp_bmax*jp_bmax * (3._wp*jp_bmin - jp_bmax) )
205
206      jp_pblh_min = ghw_abl(     4) / jp_bmin  !<-- at least 3 grid points at the bottom have value rn_ltra_min
207      jp_pblh_max = ghw_abl(jpka-3) / jp_bmax  !<-- at least 3 grid points at the top    have value rn_ltra_max
208
209      ! ABL timestep
210      rDt_abl = nn_fsbc * rn_Dt
211
212      ! Check parameters for dynamics
213      zcff  = ( jp_alp3_dyn * jp_bmin**3 + jp_alp2_dyn * jp_bmin**2   &
214         &    + jp_alp1_dyn * jp_bmin    + jp_alp0_dyn ) * rDt_abl
215      zcff1 = ( jp_alp3_dyn * jp_bmax**3 + jp_alp2_dyn * jp_bmax**2   &
216         &    + jp_alp1_dyn * jp_bmax    + jp_alp0_dyn ) * rDt_abl
217      IF(lwp) THEN
218         IF(nn_dyn_restore > 0) THEN
219            WRITE(numout,*) ' ABL Minimum value for dynamics restoring = ',zcff
220            WRITE(numout,*) ' ABL Maximum value for dynamics restoring = ',zcff1
221            ! Check that restoring coefficients are between 0 and 1
222            IF( zcff1 - nn_fsbc > 0.001_wp .OR. zcff1 < 0._wp )   &
223               &                   CALL ctl_stop( 'abl_init : wrong value for rn_ldyn_max' )
224            IF( zcff  - nn_fsbc > 0.001_wp .OR. zcff  < 0._wp )   &
225               &                   CALL ctl_stop( 'abl_init : wrong value for rn_ldyn_min' )
226            IF( zcff  > zcff1                    )   &
227               &                   CALL ctl_stop( 'abl_init : rn_ldyn_max must be smaller than rn_ldyn_min' )
228         END IF
229      END IF
230
231      ! Check parameters for active tracers
232      zcff  = ( jp_alp3_tra * jp_bmin**3 + jp_alp2_tra * jp_bmin**2   &
233         &    + jp_alp1_tra * jp_bmin    + jp_alp0_tra ) * rDt_abl
234      zcff1 = ( jp_alp3_tra * jp_bmax**3 + jp_alp2_tra * jp_bmax**2   &
235         &    + jp_alp1_tra * jp_bmax    + jp_alp0_tra ) * rDt_abl
236      IF(lwp) THEN
237         WRITE(numout,*) ' ABL Minimum value for tracers restoring = ',zcff
238         WRITE(numout,*) ' ABL Maximum value for tracers restoring = ',zcff1
239         ! Check that restoring coefficients are between 0 and 1
240         IF( zcff1 - nn_fsbc > 0.001_wp .OR. zcff1 < 0._wp )   &
241            &                   CALL ctl_stop( 'abl_init : wrong value for rn_ltra_max' )
242         IF( zcff  - nn_fsbc > 0.001_wp .OR. zcff  < 0._wp )   &
243            &                   CALL ctl_stop( 'abl_init : wrong value for rn_ltra_min' )
244         IF( zcff  > zcff1                    )   &
245            &                   CALL ctl_stop( 'abl_init : rn_ltra_max must be smaller than rn_ltra_min' )
246      END IF
247
248      !!-------------------------------------------------------------------------------------------
249      !! Initialize Coriolis frequency, equatorial restoring and land/sea mask
250      !!-------------------------------------------------------------------------------------------
251      fft_abl(:,:) = 2._wp * omega * SIN( rad * gphit(:,:) )
252
253      ! Equatorial restoring
254      IF( nn_dyn_restore == 1 ) THEN
255         zcff         = 2._wp * omega * SIN( rad * 90._wp )   !++ fmax
256         rest_eq(:,:) = SIN( 0.5_wp*rpi*( (fft_abl(:,:) - zcff) / zcff ) )**8
257      ELSE
258         rest_eq(:,:) = 1._wp
259      END IF
260      ! T-mask
261      msk_abl(:,:) = tmask(:,:,1)
262
263      !!-------------------------------------------------------------------------------------------
264
265      ! initialize 2D bulk fields AND 3D abl data
266      CALL sbc_blk_init
267
268      ! Initialize the time index for now time (nt_n) and after time (nt_a)
269      nt_n = 1 + MOD( nit000  , 2)
270      nt_a = 1 + MOD( nit000+1, 2)
271
272      ! initialize ABL from data or restart
273      IF( ln_rstart_abl ) THEN
274         CALL abl_rst_read
275      ELSE
276         CALL fld_read( nit000, nn_fsbc, sf ) ! input fields provided at the first time-step
277
278          u_abl(:,:,:,nt_n      ) = sf(jp_wndi)%fnow(:,:,:)
279          v_abl(:,:,:,nt_n      ) = sf(jp_wndj)%fnow(:,:,:)
280         tq_abl(:,:,:,nt_n,jp_ta) = sf(jp_tair)%fnow(:,:,:)
281         tq_abl(:,:,:,nt_n,jp_qa) = sf(jp_humi)%fnow(:,:,:)
282
283         tke_abl(:,:,:,nt_n     ) = tke_min
284         avm_abl(:,:,:          ) = avm_bak
285         avt_abl(:,:,:          ) = avt_bak
286         pblh   (:,:            ) = ghw_abl( 3 )  !<-- assume that the pbl contains 3 grid points
287         u_abl  (:,:,:,nt_a     ) = 0._wp
288         v_abl  (:,:,:,nt_a     ) = 0._wp
289         tq_abl (:,:,:,nt_a,:   ) = 0._wp
290         tke_abl(:,:,:,nt_a     ) = 0._wp
291      ENDIF
292
293      rhoa(:,:) = rho_air( tq_abl(:,:,2,nt_n,jp_ta), tq_abl(:,:,2,nt_n,jp_qa), sf(jp_slp)%fnow(:,:,1) ) !!GS: rhoa must be (re)computed here here to avoid division by zero in blk_ice_1 (TBI)
294
295   END SUBROUTINE sbc_abl_init
296
297
298   SUBROUTINE sbc_abl( kt )
299      !!---------------------------------------------------------------------
300      !!                     ***  ROUTINE sbc_abl  ***
301      !!
302      !! ** Purpose :   provide the momentum, heat and freshwater fluxes at
303      !!      the ocean surface from an ABL calculation at each oceanic time step
304      !!
305      !! ** Method  :
306      !!              - Pre-compute part of turbulent fluxes in blk_oce_1
307      !!              - Perform 1 time-step of the ABL model
308      !!              - Finalize flux computation in blk_oce_2
309      !!
310      !! ** Outputs : - utau    : i-component of the stress at U-point  (N/m2)
311      !!              - vtau    : j-component of the stress at V-point  (N/m2)
312      !!              - taum    : Wind stress module at T-point         (N/m2)
313      !!              - wndm    : Wind speed module at T-point          (m/s)
314      !!              - qsr     : Solar heat flux over the ocean        (W/m2)
315      !!              - qns     : Non Solar heat flux over the ocean    (W/m2)
316      !!              - emp     : evaporation minus precipitation       (kg/m2/s)
317      !!
318      !!---------------------------------------------------------------------
319      INTEGER ,         INTENT(in) ::   kt   ! ocean time step
320      !!
321      REAL(wp), DIMENSION(jpi,jpj) ::   zssq, zcd_du, zsen, zevp
322#if defined key_si3
323      REAL(wp), DIMENSION(jpi,jpj) ::   zssqi, zcd_dui, zseni, zevpi
324#endif
325      INTEGER                      ::   jbak, jbak_dta, ji, jj
326      !!---------------------------------------------------------------------
327      !
328      !!-------------------------------------------------------------------------------------------
329      !! 1 - Read Atmospheric 3D data for large-scale forcing
330      !!-------------------------------------------------------------------------------------------
331
332      CALL fld_read( kt, nn_fsbc, sf )             ! input fields provided at the current time-step
333
334      !!-------------------------------------------------------------------------------------------
335      !! 2 - Compute Cd x ||U||, Ch x ||U||, Ce x ||U||, and SSQ using now fields
336      !!-------------------------------------------------------------------------------------------
337
338      CALL blk_oce_1( kt,  u_abl(:,:,2,nt_n      ),  v_abl(:,:,2,nt_n      ),   &   !   <<= in
339         &                tq_abl(:,:,2,nt_n,jp_ta), tq_abl(:,:,2,nt_n,jp_qa),   &   !   <<= in
340         &                sf(jp_slp )%fnow(:,:,1) , sst_m, ssu_m, ssv_m     ,   &   !   <<= in
341         &                sf(jp_qsr )%fnow(:,:,1) , sf(jp_qlw )%fnow(:,:,1) ,   &   !   <<= in
342         &                tsk_m, zssq, zcd_du, zsen, zevp                       )   !   =>> out
343
344#if defined key_si3
345      CALL blk_ice_1(  u_abl(:,:,2,nt_n      ),  v_abl(:,:,2,nt_n      ),    &   !   <<= in
346         &            tq_abl(:,:,2,nt_n,jp_ta), tq_abl(:,:,2,nt_n,jp_qa),    &   !   <<= in
347         &            sf(jp_slp)%fnow(:,:,1)  ,  u_ice, v_ice, tm_su    ,    &   !   <<= in
348         &            pseni=zseni, pevpi=zevpi, pssqi=zssqi, pcd_dui=zcd_dui )   !   <<= out
349#endif
350
351      !!-------------------------------------------------------------------------------------------
352      !! 3 - Advance ABL variables from now (n) to after (n+1)
353      !!-------------------------------------------------------------------------------------------
354
355      CALL abl_stp( kt, tsk_m, ssu_m, ssv_m, zssq,                          &   !   <<= in
356         &              sf(jp_wndi)%fnow(:,:,:), sf(jp_wndj)%fnow(:,:,:),   &   !   <<= in
357         &              sf(jp_tair)%fnow(:,:,:), sf(jp_humi)%fnow(:,:,:),   &   !   <<= in
358         &              sf(jp_slp )%fnow(:,:,1),                            &   !   <<= in
359         &              sf(jp_hpgi)%fnow(:,:,:), sf(jp_hpgj)%fnow(:,:,:),   &   !   <<= in
360         &              zcd_du, zsen, zevp,                                 &   !   <=> in/out
361         &              wndm, utau, vtau, taum                              &   !   =>> out
362#if defined key_si3
363         &            , tm_su, u_ice, v_ice, zssqi, zcd_dui                 &   !   <<= in
364         &            , zseni, zevpi, wndm_ice, ato_i                       &   !   <<= in
365         &            , utau_ice, vtau_ice                                  &   !   =>> out
366#endif
367         &                                                                  )
368      !!-------------------------------------------------------------------------------------------
369      !! 4 - Finalize flux computation using ABL variables at (n+1), nt_n corresponds to (n+1) since
370      !!                                                                time swap is done in abl_stp
371      !!-------------------------------------------------------------------------------------------
372
373      CALL blk_oce_2( tq_abl(:,:,2,nt_n,jp_ta),                            &
374         &            sf(jp_qsr )%fnow(:,:,1) , sf(jp_qlw )%fnow(:,:,1),   &
375         &            sf(jp_prec)%fnow(:,:,1) , sf(jp_snow)%fnow(:,:,1),   &
376         &            tsk_m, zsen, zevp                                )
377
378      CALL abl_rst_opn( kt )                       ! Open abl restart file (if necessary)
379      IF( lrst_abl ) CALL abl_rst_write( kt )      ! -- abl restart file
380
381#if defined key_si3
382      ! Avoid a USE abl in icesbc module
383      sf(jp_tair)%fnow(:,:,1) = tq_abl(:,:,2,nt_n,jp_ta);  sf(jp_humi)%fnow(:,:,1) = tq_abl(:,:,2,nt_n,jp_qa)
384#endif
385
386   END SUBROUTINE sbc_abl
387
388   !!======================================================================
389END MODULE sbcabl
Note: See TracBrowser for help on using the repository browser.