New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2020/dev_r12740_TOP-01_rlod_Antarctic_ice_Sheet_Fe_Source/src/OCE – NEMO

source: NEMO/branches/2020/dev_r12740_TOP-01_rlod_Antarctic_ice_Sheet_Fe_Source/src/OCE/nemogcm.F90 @ 13524

Last change on this file since 13524 was 13524, checked in by rlod, 4 years ago

First step of nutrient sources from Antarctic Ice Sheet

  • Property svn:keywords set to Id
File size: 36.2 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tide_mod, ONLY : tide_init ! tidal components initialization   (tide_init routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE diamlr         ! IOM context management for multiple-linear-regression analysis
62   USE step           ! NEMO time-stepping                 (stp     routine)
63   USE isfstp         ! ice shelf                     (isf_stp_init routine)
64   USE icbini         ! handle bergs, initialisation
65   USE icbstp         ! handle bergs, calving, themodynamics and transport
66   USE cpl_oasis3     ! OASIS3 coupling
67   USE c1d            ! 1D configuration
68   USE step_c1d       ! Time stepping loop for the 1D configuration
69   USE dyndmp         ! Momentum damping
70   USE stopar         ! Stochastic param.: ???
71   USE stopts         ! Stochastic param.: ???
72   USE diu_layers     ! diurnal bulk SST and coolskin
73   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
74   USE crsini         ! initialise grid coarsening utility
75   USE dia25h         ! 25h mean output
76   USE diadetide      ! Weights computation for daily detiding of model diagnostics
77   USE sbc_oce , ONLY : lk_oasis
78   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
79#if defined key_top
80   USE trcini         ! passive tracer initialisation
81#endif
82#if defined key_nemocice_decomp
83   USE ice_domain_size, only: nx_global, ny_global
84#endif
85   !
86   USE in_out_manager ! I/O manager
87   USE lib_mpp        ! distributed memory computing
88   USE mppini         ! shared/distributed memory setting (mpp_init routine)
89   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
90   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
91#if defined key_iomput
92   USE xios           ! xIOserver
93#endif
94#if defined key_agrif
95   USE agrif_all_update   ! Master Agrif update
96#endif
97
98   IMPLICIT NONE
99   PRIVATE
100
101   PUBLIC   nemo_gcm    ! called by model.F90
102   PUBLIC   nemo_init   ! needed by AGRIF
103   PUBLIC   nemo_alloc  ! needed by TAM
104
105   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
106
107#if defined key_mpp_mpi
108   ! need MPI_Wtime
109   INCLUDE 'mpif.h'
110#endif
111
112   !!----------------------------------------------------------------------
113   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
114   !! $Id$
115   !! Software governed by the CeCILL license (see ./LICENSE)
116   !!----------------------------------------------------------------------
117CONTAINS
118
119   SUBROUTINE nemo_gcm
120      !!----------------------------------------------------------------------
121      !!                     ***  ROUTINE nemo_gcm  ***
122      !!
123      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
124      !!              curvilinear mesh on the sphere.
125      !!
126      !! ** Method  : - model general initialization
127      !!              - launch the time-stepping (stp routine)
128      !!              - finalize the run by closing files and communications
129      !!
130      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
131      !!              Madec, 2008, internal report, IPSL.
132      !!----------------------------------------------------------------------
133      INTEGER ::   istp   ! time step index
134      REAL(wp)::   zstptiming   ! elapsed time for 1 time step
135      !!----------------------------------------------------------------------
136      !
137#if defined key_agrif
138      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
139#endif
140      !                            !-----------------------!
141      CALL nemo_init               !==  Initialisations  ==!
142      !                            !-----------------------!
143#if defined key_agrif
144      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
145      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
146      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
147# if defined key_top
148      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
149# endif
150# if defined key_si3
151      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
152# endif
153#endif
154      ! check that all process are still there... If some process have an error,
155      ! they will never enter in step and other processes will wait until the end of the cpu time!
156      CALL mpp_max( 'nemogcm', nstop )
157
158      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
159
160      !                            !-----------------------!
161      !                            !==   time stepping   ==!
162      !                            !-----------------------!
163      !
164      !                                               !== set the model time-step  ==!
165      !
166      istp = nit000
167      !
168#if defined key_c1d
169      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
170         CALL stp_c1d( istp )
171         istp = istp + 1
172      END DO
173#else
174      !
175# if defined key_agrif
176      !                                               !==  AGRIF time-stepping  ==!
177      CALL Agrif_Regrid()
178      !
179      ! Recursive update from highest nested level to lowest:
180      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
181      CALL Agrif_step_child_adj(Agrif_Update_All)
182      !
183      DO WHILE( istp <= nitend .AND. nstop == 0 )
184         CALL stp
185         istp = istp + 1
186      END DO
187      !
188      IF( .NOT. Agrif_Root() ) THEN
189         CALL Agrif_ParentGrid_To_ChildGrid()
190         IF( ln_diaobs )   CALL dia_obs_wri
191         IF( ln_timing )   CALL timing_finalize
192         CALL Agrif_ChildGrid_To_ParentGrid()
193      ENDIF
194      !
195# else
196      !
197      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
198         !
199         DO WHILE( istp <= nitend .AND. nstop == 0 )
200
201            ncom_stp = istp
202            IF( ln_timing ) THEN
203               zstptiming = MPI_Wtime()
204               IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
205               IF ( istp ==         nitend ) elapsed_time = zstptiming - elapsed_time
206            ENDIF
207           
208            CALL stp        ( istp ) 
209            istp = istp + 1
210
211            IF( lwp .AND. ln_timing )   WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
212
213         END DO
214         !
215      ELSE                                            !==  diurnal SST time-steeping only  ==!
216         !
217         DO WHILE( istp <= nitend .AND. nstop == 0 )
218            CALL stp_diurnal( istp )   ! time step only the diurnal SST
219            istp = istp + 1
220         END DO
221         !
222      ENDIF
223      !
224# endif
225      !
226#endif
227      !
228      IF( ln_diaobs   )   CALL dia_obs_wri
229      !
230      IF( ln_icebergs )   CALL icb_end( nitend )
231
232      !                            !------------------------!
233      !                            !==  finalize the run  ==!
234      !                            !------------------------!
235      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
236      !
237      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
238         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
239         CALL ctl_stop( ctmp1 )
240      ENDIF
241      !
242      IF( ln_timing )   CALL timing_finalize
243      !
244      CALL nemo_closefile
245      !
246#if defined key_iomput
247                                    CALL xios_finalize  ! end mpp communications with xios
248      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
249#else
250      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
251      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop      ! end mpp communications
252      ENDIF
253#endif
254      !
255      IF(lwm) THEN
256         IF( nstop == 0 ) THEN   ;   STOP 0
257         ELSE                    ;   STOP 123
258         ENDIF
259      ENDIF
260      !
261   END SUBROUTINE nemo_gcm
262
263
264   SUBROUTINE nemo_init
265      !!----------------------------------------------------------------------
266      !!                     ***  ROUTINE nemo_init  ***
267      !!
268      !! ** Purpose :   initialization of the NEMO GCM
269      !!----------------------------------------------------------------------
270      INTEGER ::   ios, ilocal_comm   ! local integers
271      !!
272      NAMELIST/namctl/ sn_cfctl,  nn_print, nn_ictls, nn_ictle,             &
273         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
274         &             ln_timing, ln_diacfl
275      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
276      !!----------------------------------------------------------------------
277      !
278      cxios_context = 'nemo'
279      !
280      !                             !-------------------------------------------------!
281      !                             !     set communicator & select the local rank    !
282      !                             !  must be done as soon as possible to get narea  !
283      !                             !-------------------------------------------------!
284      !
285#if defined key_iomput
286      IF( Agrif_Root() ) THEN
287         IF( lk_oasis ) THEN
288            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
289            CALL xios_initialize( "not used"       , local_comm =ilocal_comm )   ! send nemo communicator to xios
290         ELSE
291            CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
292         ENDIF
293      ENDIF
294      CALL mpp_start( ilocal_comm )
295#else
296      IF( lk_oasis ) THEN
297         IF( Agrif_Root() ) THEN
298            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
299         ENDIF
300         CALL mpp_start( ilocal_comm )
301      ELSE
302         CALL mpp_start( )
303      ENDIF
304#endif
305      !
306      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
307      lwm = (narea == 1)                ! control of output namelists
308      !
309      !                             !---------------------------------------------------------------!
310      !                             ! Open output files, reference and configuration namelist files !
311      !                             !---------------------------------------------------------------!
312      !
313      ! open ocean.output as soon as possible to get all output prints (including errors messages)
314      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
315      ! open reference and configuration namelist files
316                  CALL load_nml( numnam_ref,        'namelist_ref',                                           -1, lwm )
317                  CALL load_nml( numnam_cfg,        'namelist_cfg',                                           -1, lwm )
318      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
319      ! open /dev/null file to be able to supress output write easily
320      IF( Agrif_Root() ) THEN
321                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
322#ifdef key_agrif
323      ELSE
324                  numnul = Agrif_Parent(numnul)   
325#endif
326      ENDIF
327      !                             !--------------------!
328      !                             ! Open listing units !  -> need sn_cfctl from namctl to define lwp
329      !                             !--------------------!
330      !
331      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
332901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
333      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
334902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
335      !
336      ! finalize the definition of namctl variables
337      IF( sn_cfctl%l_allon ) THEN
338         ! Turn on all options.
339         CALL nemo_set_cfctl( sn_cfctl, .TRUE., .TRUE. )
340         ! Ensure all processors are active
341         sn_cfctl%procmin = 0 ; sn_cfctl%procmax = 1000000 ; sn_cfctl%procincr = 1
342      ELSEIF( sn_cfctl%l_config ) THEN
343         ! Activate finer control of report outputs
344         ! optionally switch off output from selected areas (note this only
345         ! applies to output which does not involve global communications)
346         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
347           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
348           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
349      ELSE
350         ! turn off all options.
351         CALL nemo_set_cfctl( sn_cfctl, .FALSE., .TRUE. )
352      ENDIF
353      !
354      lwp = (narea == 1) .OR. sn_cfctl%l_oceout    ! control of all listing output print
355      !
356      IF(lwp) THEN                      ! open listing units
357         !
358         IF( .NOT. lwm )   &            ! alreay opened for narea == 1
359            &            CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
360         !
361         WRITE(numout,*)
362         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
363         WRITE(numout,*) '                       NEMO team'
364         WRITE(numout,*) '            Ocean General Circulation Model'
365         WRITE(numout,*) '                NEMO version 4.0  (2019) '
366         WRITE(numout,*)
367         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
368         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
369         WRITE(numout,*)
370         WRITE(numout,*) "           o         _,           _,             "
371         WRITE(numout,*) "            o      .' (        .-' /             "
372         WRITE(numout,*) "           o     _/..._'.    .'   /              "
373         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
374         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
375         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
376         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
377         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
378         WRITE(numout,*) "       )  ) jgs                     `    (   (   "
379         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
380         WRITE(numout,*)
381         !
382         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
383         !
384      ENDIF
385      !
386      IF(lwm) WRITE( numond, namctl )
387      !
388      !                             !------------------------------------!
389      !                             !  Set global domain size parameters !
390      !                             !------------------------------------!
391      !
392      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
393903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
394      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
395904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
396      !
397      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
398         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
399      ELSE                              ! user-defined namelist
400         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
401      ENDIF
402      !
403      IF(lwm)   WRITE( numond, namcfg )
404      !
405      !                             !-----------------------------------------!
406      !                             ! mpp parameters and domain decomposition !
407      !                             !-----------------------------------------!
408      CALL mpp_init
409
410      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
411      CALL nemo_alloc()
412
413      ! Initialise time level indices
414      Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
415
416      !                             !-------------------------------!
417      !                             !  NEMO general initialization  !
418      !                             !-------------------------------!
419
420      CALL nemo_ctl                          ! Control prints
421      !
422      !                                      ! General initialization
423      IF( ln_timing    )   CALL timing_init     ! timing
424      IF( ln_timing    )   CALL timing_start( 'nemo_init')
425      !
426                           CALL     phy_cst         ! Physical constants
427                           CALL     eos_init        ! Equation of state
428      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
429                           CALL     wad_init        ! Wetting and drying options
430                           CALL     dom_init( Nbb, Nnn, Naa, "OPA") ! Domain
431      IF( ln_crs       )   CALL     crs_init(      Nnn )       ! coarsened grid: domain initialization
432      IF( sn_cfctl%l_prtctl )   &
433         &                 CALL prt_ctl_init        ! Print control
434     
435                           CALL diurnal_sst_bulk_init       ! diurnal sst
436      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
437      !                           
438      IF( ln_diurnal_only ) THEN                    ! diurnal only: a subset of the initialisation routines
439         CALL  istate_init( Nbb, Nnn, Naa )         ! ocean initial state (Dynamics and tracers)
440         CALL     sbc_init( Nbb, Nnn, Naa )         ! Forcings : surface module
441         CALL tra_qsr_init                          ! penetrative solar radiation qsr
442         IF( ln_diaobs ) THEN                       ! Observation & model comparison
443            CALL dia_obs_init( Nnn )                ! Initialize observational data
444            CALL dia_obs( nit000 - 1, Nnn )         ! Observation operator for restart
445         ENDIF     
446         IF( lk_asminc )   CALL asm_inc_init( Nbb, Nnn, Nrhs )   ! Assimilation increments
447         !
448         RETURN                                       ! end of initialization
449      ENDIF
450      !
451     
452                           CALL  istate_init( Nbb, Nnn, Naa )    ! ocean initial state (Dynamics and tracers)
453
454      !                                      ! external forcing
455                           CALL    tide_init                     ! tidal harmonics
456                           CALL     sbc_init( Nbb, Nnn, Naa )    ! surface boundary conditions (including sea-ice)
457                           CALL     bdy_init                     ! Open boundaries initialisation
458
459      !                                      ! Ocean physics
460                           CALL zdf_phy_init( Nnn )    ! Vertical physics
461                                     
462      !                                         ! Lateral physics
463                           CALL ldf_tra_init      ! Lateral ocean tracer physics
464                           CALL ldf_eiv_init      ! eddy induced velocity param.
465                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
466
467      !                                      ! Active tracers
468      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
469                           CALL tra_bbc_init      ! bottom heat flux
470                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
471                           CALL tra_dmp_init      ! internal tracer damping
472                           CALL tra_adv_init      ! horizontal & vertical advection
473                           CALL tra_ldf_init      ! lateral mixing
474
475      !                                      ! Dynamics
476      IF( lk_c1d       )   CALL dyn_dmp_init         ! internal momentum damping
477                           CALL dyn_adv_init         ! advection (vector or flux form)
478                           CALL dyn_vor_init         ! vorticity term including Coriolis
479                           CALL dyn_ldf_init         ! lateral mixing
480                           CALL dyn_hpg_init( Nnn )  ! horizontal gradient of Hydrostatic pressure
481                           CALL dyn_spg_init         ! surface pressure gradient
482
483      !                                      ! Icebergs
484                           CALL icb_init( rn_Dt, nit000)   ! initialise icebergs instance
485
486                                                ! ice shelf
487                           CALL isf_init( Nbb, Nnn, Naa )
488
489#if defined key_top
490      !                                      ! Passive tracers
491                           CALL     trc_init( Nbb, Nnn, Naa )
492#endif
493
494      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
495
496      !                                      ! Misc. options
497                           CALL sto_par_init    ! Stochastic parametrization
498      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
499     
500      !                                      ! Diagnostics
501                           CALL     flo_init( Nnn )    ! drifting Floats
502      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
503!                           CALL dia_ptr_init    ! Poleward TRansports initialization
504                           CALL dia_dct_init    ! Sections tranports
505                           CALL dia_hsb_init( Nnn )    ! heat content, salt content and volume budgets
506                           CALL     trd_init( Nnn )    ! Mixed-layer/Vorticity/Integral constraints trends
507                           CALL dia_obs_init( Nnn )    ! Initialize observational data
508                           CALL dia_25h_init( Nbb )    ! 25h mean  outputs
509                           CALL dia_detide_init ! Weights computation for daily detiding of model diagnostics
510      IF( ln_diaobs    )   CALL dia_obs( nit000-1, Nnn )   ! Observation operator for restart
511                           CALL dia_mlr_init    ! Initialisation of IOM context management for multiple-linear-regression analysis
512
513      !                                      ! Assimilation increments
514      IF( lk_asminc    )   CALL asm_inc_init( Nbb, Nnn, Nrhs )   ! Initialize assimilation increments
515      !
516      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
517      !
518      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
519      !
520   END SUBROUTINE nemo_init
521
522
523   SUBROUTINE nemo_ctl
524      !!----------------------------------------------------------------------
525      !!                     ***  ROUTINE nemo_ctl  ***
526      !!
527      !! ** Purpose :   control print setting
528      !!
529      !! ** Method  : - print namctl and namcfg information and check some consistencies
530      !!----------------------------------------------------------------------
531      !
532      IF(lwp) THEN                  ! control print
533         WRITE(numout,*)
534         WRITE(numout,*) 'nemo_ctl: Control prints'
535         WRITE(numout,*) '~~~~~~~~'
536         WRITE(numout,*) '   Namelist namctl'
537         WRITE(numout,*) '                              sn_cfctl%l_glochk  = ', sn_cfctl%l_glochk
538         WRITE(numout,*) '                              sn_cfctl%l_allon   = ', sn_cfctl%l_allon
539         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
540         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
541         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
542         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
543         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
544         WRITE(numout,*) '                              sn_cfctl%l_prtctl  = ', sn_cfctl%l_prtctl
545         WRITE(numout,*) '                              sn_cfctl%l_prttrc  = ', sn_cfctl%l_prttrc
546         WRITE(numout,*) '                              sn_cfctl%l_oasout  = ', sn_cfctl%l_oasout
547         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
548         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
549         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
550         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
551         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
552         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
553         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
554         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
555         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
556         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
557         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
558         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
559         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
560      ENDIF
561      !
562      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
563      nictls    = nn_ictls
564      nictle    = nn_ictle
565      njctls    = nn_jctls
566      njctle    = nn_jctle
567      isplt     = nn_isplt
568      jsplt     = nn_jsplt
569
570      IF(lwp) THEN                  ! control print
571         WRITE(numout,*)
572         WRITE(numout,*) '   Namelist namcfg'
573         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
574         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
575         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
576         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
577         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
578         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
579      ENDIF
580      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
581      !
582      !                             ! Parameter control
583      !
584      IF( sn_cfctl%l_prtctl .OR. sn_cfctl%l_prttrc ) THEN              ! sub-domain area indices for the control prints
585         IF( lk_mpp .AND. jpnij > 1 ) THEN
586            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
587         ELSE
588            IF( isplt == 1 .AND. jsplt == 1  ) THEN
589               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
590                  &           ' - the print control will be done over the whole domain' )
591            ENDIF
592            ijsplt = isplt * jsplt            ! total number of processors ijsplt
593         ENDIF
594         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
595         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
596         !
597         !                              ! indices used for the SUM control
598         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
599            lsp_area = .FALSE.
600         ELSE                                             ! print control done over a specific  area
601            lsp_area = .TRUE.
602            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
603               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
604               nictls = 1
605            ENDIF
606            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
607               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
608               nictle = jpiglo
609            ENDIF
610            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
611               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
612               njctls = 1
613            ENDIF
614            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
615               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
616               njctle = jpjglo
617            ENDIF
618         ENDIF
619      ENDIF
620      !
621      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
622         &                                                'Compile with key_nosignedzero enabled:',   &
623         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
624      !
625#if defined key_agrif
626      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
627#endif
628      !
629   END SUBROUTINE nemo_ctl
630
631
632   SUBROUTINE nemo_closefile
633      !!----------------------------------------------------------------------
634      !!                     ***  ROUTINE nemo_closefile  ***
635      !!
636      !! ** Purpose :   Close the files
637      !!----------------------------------------------------------------------
638      !
639      IF( lk_mpp )   CALL mppsync
640      !
641      CALL iom_close                                 ! close all input/output files managed by iom_*
642      !
643      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
644      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
645      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
646      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
647      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
648      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
649      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
650      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
651      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
652      !
653      numout = 6                                     ! redefine numout in case it is used after this point...
654      !
655   END SUBROUTINE nemo_closefile
656
657
658   SUBROUTINE nemo_alloc
659      !!----------------------------------------------------------------------
660      !!                     ***  ROUTINE nemo_alloc  ***
661      !!
662      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
663      !!
664      !! ** Method  :
665      !!----------------------------------------------------------------------
666      USE diawri    , ONLY : dia_wri_alloc
667      USE dom_oce   , ONLY : dom_oce_alloc
668      USE trc_oce   , ONLY : trc_oce_alloc
669      USE bdy_oce   , ONLY : bdy_oce_alloc
670      !
671      INTEGER :: ierr
672      !!----------------------------------------------------------------------
673      !
674      ierr =        oce_alloc    ()    ! ocean
675      ierr = ierr + dia_wri_alloc()
676      ierr = ierr + dom_oce_alloc()    ! ocean domain
677      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
678      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
679      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
680      !
681      CALL mpp_sum( 'nemogcm', ierr )
682      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
683      !
684   END SUBROUTINE nemo_alloc
685
686   
687   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
688      !!----------------------------------------------------------------------
689      !!                     ***  ROUTINE nemo_set_cfctl  ***
690      !!
691      !! ** Purpose :   Set elements of the output control structure to setto.
692      !!                for_all should be .false. unless all areas are to be
693      !!                treated identically.
694      !!
695      !! ** Method  :   Note this routine can be used to switch on/off some
696      !!                types of output for selected areas but any output types
697      !!                that involve global communications (e.g. mpp_max, glob_sum)
698      !!                should be protected from selective switching by the
699      !!                for_all argument
700      !!----------------------------------------------------------------------
701      LOGICAL :: setto, for_all
702      TYPE(sn_ctl) :: sn_cfctl
703      !!----------------------------------------------------------------------
704      IF( for_all ) THEN
705         sn_cfctl%l_runstat = setto
706         sn_cfctl%l_trcstat = setto
707      ENDIF
708      sn_cfctl%l_oceout  = setto
709      sn_cfctl%l_layout  = setto
710      sn_cfctl%l_prtctl  = setto
711      sn_cfctl%l_prttrc  = setto
712      sn_cfctl%l_oasout  = setto
713   END SUBROUTINE nemo_set_cfctl
714
715   !!======================================================================
716END MODULE nemogcm
717
Note: See TracBrowser for help on using the repository browser.