New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in NEMO/branches/2020/dev_r12953_ENHANCE-10_acc_fix_traqsr/src/OCE/SBC – NEMO

source: NEMO/branches/2020/dev_r12953_ENHANCE-10_acc_fix_traqsr/src/OCE/SBC/sbcwave.F90 @ 13121

Last change on this file since 13121 was 13121, checked in by acc, 4 years ago

2020/dev_r12953_ENHANCE-10_acc_fix_traqsr. Merge in trunk changes from 12953 to current HEAD (13115). Fully SETTE tested

  • Property svn:keywords set to Id
File size: 23.9 KB
RevLine 
[2990]1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
[7646]6   !! History :  3.3  !  2011-09  (M. Adani)  Original code: Drag Coefficient
7   !!         :  3.4  !  2012-10  (M. Adani)  Stokes Drift
8   !!            3.6  !  2014-09  (E. Clementi,P. Oddo) New Stokes Drift Computation
9   !!             -   !  2016-12  (G. Madec, E. Clementi) update Stoke drift computation
10   !!                                                    + add sbc_wave_ini routine
[2990]11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
[7646]14   !!   sbc_stokes    : calculate 3D Stokes-drift velocities
15   !!   sbc_wave      : wave data from wave model in netcdf files
16   !!   sbc_wave_init : initialisation fo surface waves
[2990]17   !!----------------------------------------------------------------------
[7646]18   USE phycst         ! physical constants
19   USE oce            ! ocean variables
[5836]20   USE sbc_oce        ! Surface boundary condition: ocean fields
[9019]21   USE zdf_oce,  ONLY : ln_zdfswm
[7646]22   USE bdy_oce        ! open boundary condition variables
23   USE domvvl         ! domain: variable volume layers
[5836]24   !
25   USE iom            ! I/O manager library
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! distribued memory computing library
28   USE fldread        ! read input fields
[2990]29
30   IMPLICIT NONE
31   PRIVATE
32
[7646]33   PUBLIC   sbc_stokes      ! routine called in sbccpl
[9023]34   PUBLIC   sbc_wstress     ! routine called in sbcmod
[7646]35   PUBLIC   sbc_wave        ! routine called in sbcmod
36   PUBLIC   sbc_wave_init   ! routine called in sbcmod
[2990]37   
[7646]38   ! Variables checking if the wave parameters are coupled (if not, they are read from file)
39   LOGICAL, PUBLIC ::   cpl_hsig   = .FALSE.
40   LOGICAL, PUBLIC ::   cpl_phioc  = .FALSE.
41   LOGICAL, PUBLIC ::   cpl_sdrftx = .FALSE.
42   LOGICAL, PUBLIC ::   cpl_sdrfty = .FALSE.
43   LOGICAL, PUBLIC ::   cpl_wper   = .FALSE.
[9023]44   LOGICAL, PUBLIC ::   cpl_wfreq  = .FALSE.
[7646]45   LOGICAL, PUBLIC ::   cpl_wnum   = .FALSE.
[9115]46   LOGICAL, PUBLIC ::   cpl_tauwoc = .FALSE.
[9023]47   LOGICAL, PUBLIC ::   cpl_tauw   = .FALSE.
[7646]48   LOGICAL, PUBLIC ::   cpl_wdrag  = .FALSE.
[5836]49
[7646]50   INTEGER ::   jpfld    ! number of files to read for stokes drift
51   INTEGER ::   jp_usd   ! index of stokes drift  (i-component) (m/s)    at T-point
52   INTEGER ::   jp_vsd   ! index of stokes drift  (j-component) (m/s)    at T-point
53   INTEGER ::   jp_hsw   ! index of significant wave hight      (m)      at T-point
54   INTEGER ::   jp_wmp   ! index of mean wave period            (s)      at T-point
[9023]55   INTEGER ::   jp_wfr   ! index of wave peak frequency         (1/s)    at T-point
[2990]56
[7646]57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_cd      ! structure of input fields (file informations, fields read) Drag Coefficient
58   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sd      ! structure of input fields (file informations, fields read) Stokes Drift
59   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_wn      ! structure of input fields (file informations, fields read) wave number for Qiao
[9115]60   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tauwoc  ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
[9023]61   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tauw    ! structure of input fields (file informations, fields read) ocean stress components from wave model
62
[7646]63   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   cdn_wave            !:
64   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   hsw, wmp, wnum      !:
[9023]65   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   wfreq               !:
[7646]66   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wave          !: 
[9023]67   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauw_x, tauw_y      !: 
[7646]68   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tsd2d               !:
69   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   div_sd              !: barotropic stokes drift divergence
70   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   ut0sd, vt0sd        !: surface Stokes drift velocities at t-point
71   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   usd  , vsd  , wsd   !: Stokes drift velocities at u-, v- & w-points, resp.
[5836]72
[3680]73   !! * Substitutions
[12377]74#  include "do_loop_substitute.h90"
[2990]75   !!----------------------------------------------------------------------
[10068]76   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
[5215]77   !! $Id$
[10068]78   !! Software governed by the CeCILL license (see ./LICENSE)
[2990]79   !!----------------------------------------------------------------------
80CONTAINS
81
[12377]82   SUBROUTINE sbc_stokes( Kmm )
[7646]83      !!---------------------------------------------------------------------
84      !!                     ***  ROUTINE sbc_stokes  ***
85      !!
86      !! ** Purpose :   compute the 3d Stokes Drift according to Breivik et al.,
87      !!                2014 (DOI: 10.1175/JPO-D-14-0020.1)
88      !!
89      !! ** Method  : - Calculate Stokes transport speed
90      !!              - Calculate horizontal divergence
91      !!              - Integrate the horizontal divergenze from the bottom
92      !! ** action 
93      !!---------------------------------------------------------------------
[12377]94      INTEGER, INTENT(in) :: Kmm ! ocean time level index
[7646]95      INTEGER  ::   jj, ji, jk   ! dummy loop argument
96      INTEGER  ::   ik           ! local integer
[9019]97      REAL(wp) ::  ztransp, zfac, zsp0
98      REAL(wp) ::  zdepth, zsqrt_depth,  zexp_depth, z_two_thirds, zsqrtpi !sqrt of pi
99      REAL(wp) ::  zbot_u, zbot_v, zkb_u, zkb_v, zke3_u, zke3_v, zda_u, zda_v
100      REAL(wp) ::  zstokes_psi_u_bot, zstokes_psi_v_bot
[9029]101      REAL(wp) ::  zdep_u, zdep_v, zkh_u, zkh_v
[9115]102      REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   zk_t, zk_u, zk_v, zu0_sd, zv0_sd     ! 2D workspace
103      REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   zstokes_psi_u_top, zstokes_psi_v_top ! 2D workspace
104      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ze3divh                              ! 3D workspace
[7646]105      !!---------------------------------------------------------------------
106      !
[9115]107      ALLOCATE( ze3divh(jpi,jpj,jpk) )
108      ALLOCATE( zk_t(jpi,jpj), zk_u(jpi,jpj), zk_v(jpi,jpj), zu0_sd(jpi,jpj), zv0_sd(jpi,jpj) )
[7646]109      !
[9023]110      ! select parameterization for the calculation of vertical Stokes drift
111      ! exp. wave number at t-point
[9115]112      IF( ll_st_bv_li ) THEN   ! (Eq. (19) in Breivik et al. (2014) )
[9023]113         zfac = 2.0_wp * rpi / 16.0_wp
[12377]114         DO_2D_11_11
115            ! Stokes drift velocity estimated from Hs and Tmean
116            ztransp = zfac * hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj), 0.0000001_wp )
117            ! Stokes surface speed
118            tsd2d(ji,jj) = SQRT( ut0sd(ji,jj)*ut0sd(ji,jj) + vt0sd(ji,jj)*vt0sd(ji,jj))
119            ! Wavenumber scale
120            zk_t(ji,jj) = ABS( tsd2d(ji,jj) ) / MAX( ABS( 5.97_wp*ztransp ), 0.0000001_wp )
121         END_2D
122         DO_2D_10_10
123            zk_u(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji+1,jj) )
124            zk_v(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji,jj+1) )
125            !
126            zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
127            zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
128         END_2D
[9115]129      ELSE IF( ll_st_peakfr ) THEN    ! peak wave number calculated from the peak frequency received by the wave model
[12377]130         DO_2D_11_11
131            zk_t(ji,jj) = ( 2.0_wp * rpi * wfreq(ji,jj) ) * ( 2.0_wp * rpi * wfreq(ji,jj) ) / grav
132         END_2D
133         DO_2D_10_10
134            zk_u(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji+1,jj) )
135            zk_v(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji,jj+1) )
136            !
137            zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
138            zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
139         END_2D
[9023]140      ENDIF
[7646]141      !
142      !                       !==  horizontal Stokes Drift 3D velocity  ==!
[9115]143      IF( ll_st_bv2014 ) THEN
[12377]144         DO_3D_00_00( 1, jpkm1 )
145            zdep_u = 0.5_wp * ( gdept(ji,jj,jk,Kmm) + gdept(ji+1,jj,jk,Kmm) )
146            zdep_v = 0.5_wp * ( gdept(ji,jj,jk,Kmm) + gdept(ji,jj+1,jk,Kmm) )
147            !                         
148            zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
149            zkh_v = zk_v(ji,jj) * zdep_v
150            !                                ! Depth attenuation
151            zda_u = EXP( -2.0_wp*zkh_u ) / ( 1.0_wp + 8.0_wp*zkh_u )
152            zda_v = EXP( -2.0_wp*zkh_v ) / ( 1.0_wp + 8.0_wp*zkh_v )
153            !
154            usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
155            vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
156         END_3D
[9115]157      ELSE IF( ll_st_li2017 .OR. ll_st_peakfr ) THEN
158         ALLOCATE( zstokes_psi_u_top(jpi,jpj), zstokes_psi_v_top(jpi,jpj) )
[12377]159         DO_2D_10_10
160            zstokes_psi_u_top(ji,jj) = 0._wp
161            zstokes_psi_v_top(ji,jj) = 0._wp
162         END_2D
[9117]163         zsqrtpi = SQRT(rpi)
164         z_two_thirds = 2.0_wp / 3.0_wp
[12377]165         DO_3D_00_00( 1, jpkm1 )
166            zbot_u = ( gdepw(ji,jj,jk+1,Kmm) + gdepw(ji+1,jj,jk+1,Kmm) )  ! 2 * bottom depth
167            zbot_v = ( gdepw(ji,jj,jk+1,Kmm) + gdepw(ji,jj+1,jk+1,Kmm) )  ! 2 * bottom depth
168            zkb_u  = zk_u(ji,jj) * zbot_u                             ! 2 * k * bottom depth
169            zkb_v  = zk_v(ji,jj) * zbot_v                             ! 2 * k * bottom depth
170            !
171            zke3_u = MAX(1.e-8_wp, 2.0_wp * zk_u(ji,jj) * e3u(ji,jj,jk,Kmm))     ! 2k * thickness
172            zke3_v = MAX(1.e-8_wp, 2.0_wp * zk_v(ji,jj) * e3v(ji,jj,jk,Kmm))     ! 2k * thickness
[9115]173
[12377]174            ! Depth attenuation .... do u component first..
175            zdepth      = zkb_u
176            zsqrt_depth = SQRT(zdepth)
177            zexp_depth  = EXP(-zdepth)
178            zstokes_psi_u_bot = 1.0_wp - zexp_depth  &
179                 &              - z_two_thirds * ( zsqrtpi*zsqrt_depth*zdepth*ERFC(zsqrt_depth) &
180                 &              + 1.0_wp - (1.0_wp + zdepth)*zexp_depth )
181            zda_u                    = ( zstokes_psi_u_bot - zstokes_psi_u_top(ji,jj) ) / zke3_u
182            zstokes_psi_u_top(ji,jj) =   zstokes_psi_u_bot
[9115]183
[12377]184            !         ... and then v component
185            zdepth      =zkb_v
186            zsqrt_depth = SQRT(zdepth)
187            zexp_depth  = EXP(-zdepth)
188            zstokes_psi_v_bot = 1.0_wp - zexp_depth  &
189                 &              - z_two_thirds * ( zsqrtpi*zsqrt_depth*zdepth*ERFC(zsqrt_depth) &
190                 &              + 1.0_wp - (1.0_wp + zdepth)*zexp_depth )
191            zda_v                    = ( zstokes_psi_v_bot - zstokes_psi_v_top(ji,jj) ) / zke3_v
192            zstokes_psi_v_top(ji,jj) =   zstokes_psi_v_bot
193            !
194            usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
195            vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
196         END_3D
[9115]197         DEALLOCATE( zstokes_psi_u_top, zstokes_psi_v_top )
[9023]198      ENDIF
199
[10425]200      CALL lbc_lnk_multi( 'sbcwave', usd, 'U', -1., vsd, 'V', -1. )
[9019]201
[7646]202      !
203      !                       !==  vertical Stokes Drift 3D velocity  ==!
204      !
[12377]205      DO_3D_01_01( 1, jpkm1 )
206         ze3divh(ji,jj,jk) = (  e2u(ji  ,jj) * e3u(ji  ,jj,jk,Kmm) * usd(ji  ,jj,jk)    &
207            &                 - e2u(ji-1,jj) * e3u(ji-1,jj,jk,Kmm) * usd(ji-1,jj,jk)    &
208            &                 + e1v(ji,jj  ) * e3v(ji,jj  ,jk,Kmm) * vsd(ji,jj  ,jk)    &
209            &                 - e1v(ji,jj-1) * e3v(ji,jj-1,jk,Kmm) * vsd(ji,jj-1,jk)  ) * r1_e1e2t(ji,jj)
210      END_3D
[7646]211      !
[10425]212      CALL lbc_lnk( 'sbcwave', ze3divh, 'T', 1. )
[7646]213      !
214      IF( ln_linssh ) THEN   ;   ik = 1   ! none zero velocity through the sea surface
215      ELSE                   ;   ik = 2   ! w=0 at the surface (set one for all in sbc_wave_init)
216      ENDIF
217      DO jk = jpkm1, ik, -1          ! integrate from the bottom the hor. divergence (NB: at k=jpk w is always zero)
218         wsd(:,:,jk) = wsd(:,:,jk+1) - ze3divh(:,:,jk)
219      END DO
220      !
221      IF( ln_bdy ) THEN
222         DO jk = 1, jpkm1
223            wsd(:,:,jk) = wsd(:,:,jk) * bdytmask(:,:)
224         END DO
225      ENDIF
226      !                       !==  Horizontal divergence of barotropic Stokes transport  ==!
227      div_sd(:,:) = 0._wp
228      DO jk = 1, jpkm1                                 !
229        div_sd(:,:) = div_sd(:,:) + ze3divh(:,:,jk)
230      END DO
231      !
232      CALL iom_put( "ustokes",  usd  )
233      CALL iom_put( "vstokes",  vsd  )
234      CALL iom_put( "wstokes",  wsd  )
235      !
[9115]236      DEALLOCATE( ze3divh )
237      DEALLOCATE( zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
[7646]238      !
239   END SUBROUTINE sbc_stokes
240
241
[9023]242   SUBROUTINE sbc_wstress( )
243      !!---------------------------------------------------------------------
244      !!                     ***  ROUTINE sbc_wstress  ***
245      !!
246      !! ** Purpose :   Updates the ocean momentum modified by waves
247      !!
248      !! ** Method  : - Calculate u,v components of stress depending on stress
249      !!                model
250      !!              - Calculate the stress module
251      !!              - The wind module is not modified by waves
252      !! ** action 
253      !!---------------------------------------------------------------------
254      INTEGER  ::   jj, ji   ! dummy loop argument
255      !
[9033]256      IF( ln_tauwoc ) THEN
[9023]257         utau(:,:) = utau(:,:)*tauoc_wave(:,:)
258         vtau(:,:) = vtau(:,:)*tauoc_wave(:,:)
259         taum(:,:) = taum(:,:)*tauoc_wave(:,:)
260      ENDIF
261      !
262      IF( ln_tauw ) THEN
[12377]263         DO_2D_10_10
264            ! Stress components at u- & v-points
265            utau(ji,jj) = 0.5_wp * ( tauw_x(ji,jj) + tauw_x(ji+1,jj) )
266            vtau(ji,jj) = 0.5_wp * ( tauw_y(ji,jj) + tauw_y(ji,jj+1) )
267            !
268            ! Stress module at t points
269            taum(ji,jj) = SQRT( tauw_x(ji,jj)*tauw_x(ji,jj) + tauw_y(ji,jj)*tauw_y(ji,jj) )
270         END_2D
[10425]271         CALL lbc_lnk_multi( 'sbcwave', utau(:,:), 'U', -1. , vtau(:,:), 'V', -1. , taum(:,:) , 'T', -1. )
[9023]272      ENDIF
273      !
274   END SUBROUTINE sbc_wstress
275
276
[12377]277   SUBROUTINE sbc_wave( kt, Kmm )
[2990]278      !!---------------------------------------------------------------------
[7646]279      !!                     ***  ROUTINE sbc_wave  ***
[2990]280      !!
[7646]281      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
[2990]282      !!
283      !! ** Method  : - Read namelist namsbc_wave
284      !!              - Read Cd_n10 fields in netcdf files
[3680]285      !!              - Read stokes drift 2d in netcdf files
[7646]286      !!              - Read wave number in netcdf files
287      !!              - Compute 3d stokes drift using Breivik et al.,2014
288      !!                formulation
289      !! ** action 
[2990]290      !!---------------------------------------------------------------------
[7646]291      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
[12377]292      INTEGER, INTENT(in   ) ::   Kmm  ! ocean time index
[2990]293      !!---------------------------------------------------------------------
294      !
[7646]295      IF( ln_cdgw .AND. .NOT. cpl_wdrag ) THEN     !==  Neutral drag coefficient  ==!
296         CALL fld_read( kt, nn_fsbc, sf_cd )             ! read from external forcing
[9821]297         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1) * tmask(:,:,1)
[7646]298      ENDIF
299
[9115]300      IF( ln_tauwoc .AND. .NOT. cpl_tauwoc ) THEN  !==  Wave induced stress  ==!
301         CALL fld_read( kt, nn_fsbc, sf_tauwoc )         ! read wave norm stress from external forcing
[9821]302         tauoc_wave(:,:) = sf_tauwoc(1)%fnow(:,:,1) * tmask(:,:,1)
[7646]303      ENDIF
304
[9023]305      IF( ln_tauw .AND. .NOT. cpl_tauw ) THEN      !==  Wave induced stress  ==!
306         CALL fld_read( kt, nn_fsbc, sf_tauw )           ! read ocean stress components from external forcing (T grid)
[9821]307         tauw_x(:,:) = sf_tauw(1)%fnow(:,:,1) * tmask(:,:,1)
308         tauw_y(:,:) = sf_tauw(2)%fnow(:,:,1) * tmask(:,:,1)
[9023]309      ENDIF
310
[7646]311      IF( ln_sdw )  THEN                           !==  Computation of the 3d Stokes Drift  ==!
[6140]312         !
[7646]313         IF( jpfld > 0 ) THEN                            ! Read from file only if the field is not coupled
314            CALL fld_read( kt, nn_fsbc, sf_sd )          ! read wave parameters from external forcing
[9821]315            IF( jp_hsw > 0 )   hsw  (:,:) = sf_sd(jp_hsw)%fnow(:,:,1) * tmask(:,:,1)  ! significant wave height
316            IF( jp_wmp > 0 )   wmp  (:,:) = sf_sd(jp_wmp)%fnow(:,:,1) * tmask(:,:,1)  ! wave mean period
317            IF( jp_wfr > 0 )   wfreq(:,:) = sf_sd(jp_wfr)%fnow(:,:,1) * tmask(:,:,1)  ! Peak wave frequency
318            IF( jp_usd > 0 )   ut0sd(:,:) = sf_sd(jp_usd)%fnow(:,:,1) * tmask(:,:,1)  ! 2D zonal Stokes Drift at T point
319            IF( jp_vsd > 0 )   vt0sd(:,:) = sf_sd(jp_vsd)%fnow(:,:,1) * tmask(:,:,1)  ! 2D meridional Stokes Drift at T point
[7646]320         ENDIF
[2990]321         !
[7646]322         ! Read also wave number if needed, so that it is available in coupling routines
[9019]323         IF( ln_zdfswm .AND. .NOT.cpl_wnum ) THEN
[7646]324            CALL fld_read( kt, nn_fsbc, sf_wn )          ! read wave parameters from external forcing
[9821]325            wnum(:,:) = sf_wn(1)%fnow(:,:,1) * tmask(:,:,1)
[6140]326         ENDIF
[7646]327           
[9115]328         ! Calculate only if required fields have been read
329         ! In coupled wave model-NEMO case the call is done after coupling
[6140]330         !
[9115]331         IF( ( ll_st_bv_li   .AND. jp_hsw>0 .AND. jp_wmp>0 .AND. jp_usd>0 .AND. jp_vsd>0 ) .OR. &
[12377]332           & ( ll_st_peakfr  .AND. jp_wfr>0 .AND. jp_usd>0 .AND. jp_vsd>0                ) ) CALL sbc_stokes( Kmm )
[6140]333         !
[7646]334      ENDIF
335      !
336   END SUBROUTINE sbc_wave
337
338
339   SUBROUTINE sbc_wave_init
340      !!---------------------------------------------------------------------
341      !!                     ***  ROUTINE sbc_wave_init  ***
342      !!
343      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
344      !!
345      !! ** Method  : - Read namelist namsbc_wave
346      !!              - Read Cd_n10 fields in netcdf files
347      !!              - Read stokes drift 2d in netcdf files
348      !!              - Read wave number in netcdf files
349      !!              - Compute 3d stokes drift using Breivik et al.,2014
350      !!                formulation
351      !! ** action 
352      !!---------------------------------------------------------------------
353      INTEGER ::   ierror, ios   ! local integer
354      INTEGER ::   ifpr
355      !!
[9115]356      CHARACTER(len=100)     ::  cn_dir                            ! Root directory for location of drag coefficient files
[9023]357      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   slf_i, slf_j     ! array of namelist informations on the fields to read
[7646]358      TYPE(FLD_N)            ::  sn_cdg, sn_usd, sn_vsd,  &
[9023]359                             &   sn_hsw, sn_wmp, sn_wfr, sn_wnum, &
[9115]360                             &   sn_tauwoc, sn_tauwx, sn_tauwy     ! informations about the fields to be read
[7646]361      !
[9023]362      NAMELIST/namsbc_wave/  sn_cdg, cn_dir, sn_usd, sn_vsd, sn_hsw, sn_wmp, sn_wfr, &
[9033]363                             sn_wnum, sn_tauwoc, sn_tauwx, sn_tauwy
[7646]364      !!---------------------------------------------------------------------
365      !
366      READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
[11536]367901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_wave in reference namelist' )
[7646]368         
369      READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
[11536]370902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist' )
[7646]371      IF(lwm) WRITE ( numond, namsbc_wave )
372      !
373      IF( ln_cdgw ) THEN
374         IF( .NOT. cpl_wdrag ) THEN
[9115]375            ALLOCATE( sf_cd(1), STAT=ierror )               !* allocate and fill sf_wave with sn_cdg
[7646]376            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
[3680]377            !
378                                   ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1)   )
379            IF( sn_cdg%ln_tint )   ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
[7646]380            CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
[5836]381         ENDIF
[7646]382         ALLOCATE( cdn_wave(jpi,jpj) )
383      ENDIF
384
[9033]385      IF( ln_tauwoc ) THEN
386         IF( .NOT. cpl_tauwoc ) THEN
387            ALLOCATE( sf_tauwoc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_tauwoc
[7646]388            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
[3680]389            !
[9115]390                                     ALLOCATE( sf_tauwoc(1)%fnow(jpi,jpj,1)   )
[9033]391            IF( sn_tauwoc%ln_tint )  ALLOCATE( sf_tauwoc(1)%fdta(jpi,jpj,1,2) )
392            CALL fld_fill( sf_tauwoc, (/ sn_tauwoc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
[7646]393         ENDIF
394         ALLOCATE( tauoc_wave(jpi,jpj) )
395      ENDIF
396
[9023]397      IF( ln_tauw ) THEN
398         IF( .NOT. cpl_tauw ) THEN
399            ALLOCATE( sf_tauw(2), STAT=ierror )           !* allocate and fill sf_wave with sn_tauwx/y
400            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_tauw structure' )
401            !
402            ALLOCATE( slf_j(2) )
403            slf_j(1) = sn_tauwx
404            slf_j(2) = sn_tauwy
405                                    ALLOCATE( sf_tauw(1)%fnow(jpi,jpj,1)   )
406                                    ALLOCATE( sf_tauw(2)%fnow(jpi,jpj,1)   )
407            IF( slf_j(1)%ln_tint )  ALLOCATE( sf_tauw(1)%fdta(jpi,jpj,1,2) )
408            IF( slf_j(2)%ln_tint )  ALLOCATE( sf_tauw(2)%fdta(jpi,jpj,1,2) )
409            CALL fld_fill( sf_tauw, (/ slf_j /), cn_dir, 'sbc_wave_init', 'read wave input', 'namsbc_wave' )
410         ENDIF
411         ALLOCATE( tauw_x(jpi,jpj) )
412         ALLOCATE( tauw_y(jpi,jpj) )
413      ENDIF
414
[7646]415      IF( ln_sdw ) THEN   ! Find out how many fields have to be read from file if not coupled
416         jpfld=0
[9023]417         jp_usd=0   ;   jp_vsd=0   ;   jp_hsw=0   ;   jp_wmp=0   ;   jp_wfr=0
[7646]418         IF( .NOT. cpl_sdrftx ) THEN
419            jpfld  = jpfld + 1
420            jp_usd = jpfld
421         ENDIF
422         IF( .NOT. cpl_sdrfty ) THEN
423            jpfld  = jpfld + 1
424            jp_vsd = jpfld
425         ENDIF
[9115]426         IF( .NOT. cpl_hsig  .AND. ll_st_bv_li  ) THEN
[7646]427            jpfld  = jpfld + 1
428            jp_hsw = jpfld
429         ENDIF
[9115]430         IF( .NOT. cpl_wper  .AND. ll_st_bv_li  ) THEN
[7646]431            jpfld  = jpfld + 1
432            jp_wmp = jpfld
433         ENDIF
[9115]434         IF( .NOT. cpl_wfreq .AND. ll_st_peakfr ) THEN
[9023]435            jpfld  = jpfld + 1
436            jp_wfr = jpfld
437         ENDIF
[7646]438
439         ! Read from file only the non-coupled fields
440         IF( jpfld > 0 ) THEN
441            ALLOCATE( slf_i(jpfld) )
442            IF( jp_usd > 0 )   slf_i(jp_usd) = sn_usd
443            IF( jp_vsd > 0 )   slf_i(jp_vsd) = sn_vsd
444            IF( jp_hsw > 0 )   slf_i(jp_hsw) = sn_hsw
445            IF( jp_wmp > 0 )   slf_i(jp_wmp) = sn_wmp
[9023]446            IF( jp_wfr > 0 )   slf_i(jp_wfr) = sn_wfr
447
[7646]448            ALLOCATE( sf_sd(jpfld), STAT=ierror )   !* allocate and fill sf_sd with stokes drift
449            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
450            !
[3680]451            DO ifpr= 1, jpfld
452               ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
453               IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
454            END DO
[7646]455            !
456            CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
[3680]457         ENDIF
[7646]458         ALLOCATE( usd  (jpi,jpj,jpk), vsd  (jpi,jpj,jpk), wsd(jpi,jpj,jpk) )
459         ALLOCATE( hsw  (jpi,jpj)    , wmp  (jpi,jpj)     )
[9023]460         ALLOCATE( wfreq(jpi,jpj) )
[7646]461         ALLOCATE( ut0sd(jpi,jpj)    , vt0sd(jpi,jpj)     )
462         ALLOCATE( div_sd(jpi,jpj) )
463         ALLOCATE( tsd2d (jpi,jpj) )
[9019]464
465         ut0sd(:,:) = 0._wp
466         vt0sd(:,:) = 0._wp
467         hsw(:,:) = 0._wp
468         wmp(:,:) = 0._wp
469
[7646]470         usd(:,:,:) = 0._wp
471         vsd(:,:,:) = 0._wp
472         wsd(:,:,:) = 0._wp
[9019]473         ! Wave number needed only if ln_zdfswm=T
[7646]474         IF( .NOT. cpl_wnum ) THEN
475            ALLOCATE( sf_wn(1), STAT=ierror )           !* allocate and fill sf_wave with sn_wnum
476            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable toallocate sf_wave structure' )
477                                   ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1)   )
478            IF( sn_wnum%ln_tint )  ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
479            CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
[5836]480         ENDIF
[7646]481         ALLOCATE( wnum(jpi,jpj) )
[3680]482      ENDIF
[5836]483      !
[7646]484   END SUBROUTINE sbc_wave_init
485
[2990]486   !!======================================================================
487END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.